home *** CD-ROM | disk | FTP | other *** search
/ Media Share 9 / MEDIASHARE_09.ISO / progmisc / nfsrc21.zip / SAVEATT.ASM < prev    next >
Assembly Source File  |  1992-10-03  |  6KB  |  165 lines
  1. ; File......: SAVEATT.ASM
  2. ; Author....: Ted Means
  3. ; Date......: $Date:   03 Oct 1992 14:35:14  $
  4. ; Revision..: $Revision:   1.2  $
  5. ; Log file..: $Logfile:   C:/nanfor/src/saveatt.asv  $
  6. ; 
  7. ; This is an original work by Ted Means and is placed in the
  8. ; public domain.
  9. ;
  10. ; Modification history:
  11. ; ---------------------
  12. ;
  13. ; $Log:   C:/nanfor/src/saveatt.asv  $
  14. ;  
  15. ;     Rev 1.2   03 Oct 1992 14:35:14   GLENN
  16. ;  Ted Means made modifications to support use of dispBegin()/dispEnd().
  17. ;  
  18. ;     Rev 1.1   15 Aug 1991 23:07:58   GLENN
  19. ;  Forest Belt proofread/edited/cleaned up doc
  20. ;  
  21. ;     Rev 1.0   12 Jun 1991 01:30:20   GLENN
  22. ;  Initial revision.
  23. ;
  24.  
  25.  
  26. ;  $DOC$
  27. ;  $FUNCNAME$
  28. ;     FT_SAVEATT()
  29. ;  $CATEGORY$
  30. ;     Video
  31. ;  $ONELINER$
  32. ;     Save the attribute bytes of a specified screen region.
  33. ;  $SYNTAX$
  34. ;     FT_SAVEATT( <nTop>, <nLeft>, <nBottom>, <nRight>  ) -> cAttributes
  35. ;  $ARGUMENTS$
  36. ;     <nTop>, <nLeft>, <nBottom>, and <nRight> define the screen region.
  37. ;  $RETURNS$
  38. ;     A character string containing the screen attribute bytes for the
  39. ;     specified region.  If the memory to store the return value could
  40. ;     not be allocated, the function returns NIL.
  41. ;  $DESCRIPTION$
  42. ;     This function is similar to Clipper's SaveScreen(), except that it only
  43. ;     saves the attribute bytes.  This is useful if you want to change the
  44. ;     screen color without affecting the text.
  45. ;
  46. ;     *** INTERNALS ALERT ***
  47. ;
  48. ;     This function calls the Clipper internal __gtMaxCol to obtain the
  49. ;     maximum column value for the current video mode.  If you're too gutless
  50. ;     to use internals, then this function isn't for you.
  51. ;  $EXAMPLES$
  52. ;     // Save attributes of row 4
  53. ;     cBuffer := FT_SAVEATT( 4, 0, 4, maxcol())
  54. ;
  55. ;     // Save attributes from middle of screen
  56. ;     cBuffer := FT_SAVEATT(10,20,14,59)
  57. ;  $SEEALSO$
  58. ;     FT_RESTATT()
  59. ;  $END$
  60. ;
  61.  
  62. IDEAL
  63.  
  64. Public   FT_SaveAtt
  65.  
  66. Extrn    __ParNI:Far
  67. Extrn    __RetCLen:Far
  68. Extrn    __xGrab:Far
  69. Extrn    __xFree:Far
  70. Extrn    __gtSave:Far                        ; ** INTERNAL **
  71.  
  72. nTop     EQU       Word Ptr BP - 2
  73. nLeft    EQU       Word Ptr BP - 4
  74. nBottom  EQU       Word Ptr BP - 6
  75. nRight   EQU       Word Ptr BP - 8
  76. nAttr    EQU       Byte Ptr BP - 10
  77. nBufLen  EQU       Word Ptr BP - 12
  78.  
  79. cBuffer  EQU       DWord Ptr BP - 16
  80. nBufOfs  EQU       Word Ptr BP - 16
  81. nBufSeg  EQU       Word Ptr BP - 14
  82.  
  83. Segment  _NanFor   Word      Public    "CODE"
  84.          Assume    CS:_NanFor
  85.  
  86. Proc     FT_SaveAtt          Far
  87.  
  88.          Push      BP                        ; Save BP
  89.          Mov       BP,SP                     ; Set up stack reference
  90.          Sub       SP,16                     ; Allocate locals
  91.  
  92.          Mov       CX,4                      ; Set param count
  93. @@Coord: Push      CX                        ; Put on stack
  94.          Call      __ParNI                   ; Retrieve param
  95.          Pop       CX                        ; Get count back
  96.          Push      AX                        ; Put value on stack
  97.          Loop      @@Coord                   ; Get next value
  98.  
  99.          Pop       [nTop]                    ; Store top coordinate
  100.          Pop       [nLeft]                   ; Store left coordinate
  101.          Pop       [nBottom]                 ; Store bottom coordinate
  102.          Pop       [nRight]                  ; Store right coordinate
  103.  
  104.          Mov       AX,[nBottom]              ; Load bottom coordinate
  105.          Sub       AX,[nTop]                 ; Subtract top
  106.          Inc       AX                        ; Calc length
  107.  
  108.          Mov       CX,[nRight]               ; Load right coordinate
  109.          Sub       CX,[nLeft]                ; Subtract left
  110.          Inc       CX                        ; Calc width
  111.          Mul       CX                        ; Multiply length by width
  112.          SHL       AX,1                      ; Calc buffer size
  113.          Mov       [nBufLen],AX              ; Store buffer size
  114.  
  115. @@Alloc: Push      AX                        ; Put size on stack
  116.          Call      __xGrab                   ; Allocate memory
  117.          Add       SP,2                      ; Realign stack
  118.          Mov       [nBufSeg],DX              ; Store segment
  119.          Mov       [nBufOfs],AX              ; Store offset
  120.  
  121.          Push      DX                        ; Load parameters for __gtSave
  122.          Push      AX                        ; onto stack
  123.          Push      [nRight]
  124.          Push      [nBottom]
  125.          Push      [nLeft]
  126.          Push      [nTop]
  127.          Call      __gtSave                  ; Grab screen image
  128.  
  129.          Push      DS                        ; Save required registers
  130.          Push      SI
  131.          Push      DI
  132.  
  133.          Mov       DS,[nBufSeg]              ; Load pointer to buffer
  134.          Mov       SI,[nBufOfs]              ; into DS:SI
  135.  
  136.          Push      DS                        ; Duplicate pointer in ES:DI
  137.          Push      SI
  138.          Pop       DI
  139.          Pop       ES
  140.          Inc       SI                        ; Start with attribute byte
  141.  
  142.          Mov       CX,[nBufLen]              ; Load buffer length
  143.          SHR       CX,1                      ; Divide by two
  144. @@Attr:  Lodsw                               ; Grab a screen word
  145.          Stosb                               ; Store attribute only
  146.          Loop      @@Attr                    ; Do next
  147.  
  148.          Pop       DI                        ; Restore registers
  149.          Pop       SI
  150.          Pop       DS
  151.  
  152. Done:    Mov       AX,[nBufLen]              ; Load buffer length
  153.          SHR       AX,1                      ; Divide by 2
  154.          Push      AX                        ; Put length on stack
  155.          Push      [nBufSeg]                 ; Put segment on stack
  156.          Push      [nBufOfs]                 ; Put offset on stack
  157.          Call      __RetClen                 ; Return attribute string
  158.          Call      __xFree                   ; Free memory
  159.          Mov       SP,BP                     ; Realign stack
  160.          Pop       BP                        ; Restore BP
  161.          Ret
  162. Endp     FT_SaveAtt
  163. Ends     _NanFor
  164. End
  165.