home *** CD-ROM | disk | FTP | other *** search
/ Media Share 9 / MEDIASHARE_09.ISO / progmisc / nfsrc21.zip / NTXHANDL.ASM < prev    next >
Assembly Source File  |  1992-10-16  |  4KB  |  115 lines
  1. ; File......: NTXHANDL.ASM
  2. ; Author....: Ted Means
  3. ; Date......: $Date:   15 Oct 1992 23:59:12  $
  4. ; Revision..: $Revision:   1.0  $
  5. ; Log file..: $Logfile:   C:/nanfor/src/ntxhandl.asv  $
  6. ; 
  7. ; This is an original work by Ted Means and is placed in the
  8. ; public domain.
  9. ;
  10. ; Modification history:
  11. ; ---------------------
  12. ;
  13. ; $Log:   C:/nanfor/src/ntxhandl.asv  $
  14. ;  
  15. ;     Rev 1.0   15 Oct 1992 23:59:12   GLENN
  16. ;  Initial revision.
  17. ;  
  18.  
  19. ; $DOC$
  20. ; $FUNCNAME$
  21. ;     FT_NTXHand()
  22. ; $CATEGORY$
  23. ;     Database
  24. ; $ONELINER$
  25. ;     Obtain the handle associated with an open .NTX file.
  26. ; $SYNTAX$
  27. ;     FT_NTXHand( <nOrderNum> ) -> nHandle
  28. ; $ARGUMENTS$
  29. ;     <nOrderNum> is a numeric value indicating the active index for which
  30. ;     the handle is to be obtained.
  31. ; $RETURNS$
  32. ;    The file handle, or zero if no .NTX is open in the specified
  33. ;    work area or if <nOrderNum> does not represent an open index.
  34. ; $DESCRIPTION$
  35. ;    For your own twisted reasons you may need make direct use of the
  36. ;    file handle associated with an index.  This function gives you
  37. ;    that capability, but use it with care and don't blame me if you
  38. ;    botch something up.
  39. ;
  40. ;    By default this function works on the current work area, but can be
  41. ;    made to work on any work area through the use of the standard Clipper
  42. ;    alias operator.
  43. ;
  44. ;    Be aware that this function makes use of Clipper's internal work
  45. ;    area information which is subject to change in future versions of
  46. ;    Clipper.  If this makes you uncomfortable then don't use this function,
  47. ;    you gutless weasel.
  48. ;
  49. ;    This function is written to adhere to Turbo Assembler's IDEAL mode.
  50. ;    To use another assembler, rearrange the SEGMENT and PROC directives
  51. ;    and make any other necessary changes to the source code.
  52. ;
  53. ; $EXAMPLES$
  54. ;      // Get the handle for the second index
  55. ;
  56. ;      QOut( FT_NTXHand( 2 ) )
  57. ;
  58. ;      // Try a non-current work area
  59. ;
  60. ;      nHandle := THISFILE->( FT_NTXHand( 1 ) )
  61. ;
  62. ;      // This will return zero because only 15 indexes can be active
  63. ;
  64. ;      nHandle := THATFILE->( FT_NTXHand( 22 ) )
  65. ; $END$
  66.  
  67. IDEAL
  68.  
  69. Public   FT_NTXHand
  70.  
  71. Extrn    __WorkAreas:DWord                   ; INTERNAL!!!
  72. Extrn    __RetNI:Far
  73. Extrn    __ParNI:Far
  74.  
  75. Segment  _NanFor   Word      Public    "CODE"
  76.          Assume    CS:_NanFor
  77.  
  78. Proc     FT_NTXHand          Far
  79.  
  80.          Mov       AX,1                      ; Specify param #1
  81.          Push      AX                        ; Put on stack
  82.          Call      __ParNI                   ; Retrieve parameter
  83.          Add       SP,2                      ; Realign stack
  84.          Or        AX,AX                     ; Make sure parameter is
  85.          JZ        @@Done                    ; within acceptable range
  86.          Cmp       AX,15
  87.          JBE       @@Okay
  88.          Xor       AX,AX                     ; If not, return zero
  89.          Jmp       Short @@Done
  90.  
  91. @@Okay:  LES       BX,[__WorkAreas]          ; Load pointer to work areas
  92.          Mov       DX,AX                     ; Move index specifier into DX
  93.          Mov       AX,[Word Ptr ES:BX]       ; Check to see if work area
  94.          Or        AX,[Word Ptr ES:BX + 2]   ; is in use
  95.          JZ        @@Done                    ; If not, return zero
  96.          LES       BX,[DWord Ptr ES:BX]      ; Load work area pointer
  97.          Dec       DX                        ; Compute offset to locate
  98.          SHL       DX,1                      ; pointer to index info
  99.          SHL       DX,1
  100.          Add       BX,DX
  101.          Mov       AX,[Word Ptr ES:BX + 98h] ; See if specified index is open
  102.          Or        AX,[Word Ptr ES:BX + 9Ah]
  103.          JZ        @@Done                    ; If not, return zero
  104.          LES       BX,[ES:BX + 98h]          ; Load index info pointer
  105.          Mov       AX,[Word Ptr ES:BX]       ; Get handle
  106.  
  107. @@Done:  Push      AX                        ; Put return value on stack
  108.          Call      __RetNI                   ; Return it
  109.          Add       SP,2                      ; Realign stack
  110.          Ret
  111. Endp     FT_NTXHand
  112. Ends     _NanFor
  113. End
  114.  
  115.