home *** CD-ROM | disk | FTP | other *** search
/ Media Share 9 / MEDIASHARE_09.ISO / progmisc / nfsrc21.zip / MONTH.PRG < prev    next >
Text File  |  1992-09-28  |  4KB  |  117 lines
  1. /*
  2.  * File......: MONTH.PRG
  3.  * Author....: Jo W. French dba Practical Computing
  4.  * CIS ID....: 74731,1751
  5.  * Date......: $Date:   28 Sep 1992 00:40:00  $
  6.  * Revision..: $Revision:   1.3  $
  7.  * Log file..: $Logfile:   C:/nanfor/src/month.prv  $
  8.  * 
  9.  * The functions contained herein are the original work of Jo W. French
  10.  * and are placed in the public domain.
  11.  *
  12.  * Modification history:
  13.  * ---------------------
  14.  *
  15.  * $Log:   C:/nanfor/src/month.prv  $
  16.  * 
  17.  *    Rev 1.3   28 Sep 1992 00:40:00   GLENN
  18.  * Jo French cleaned up.
  19.  * 
  20.  *    Rev 1.2   15 Aug 1991 23:05:42   GLENN
  21.  * Forest Belt proofread/edited/cleaned up doc
  22.  * 
  23.  *    Rev 1.1   14 Jun 1991 19:52:28   GLENN
  24.  * Minor edit to file header
  25.  * 
  26.  *    Rev 1.0   01 Apr 1991 01:01:46   GLENN
  27.  * Nanforum Toolkit
  28.  *
  29.  */
  30.  
  31. /*  $DOC$
  32.  *  $FUNCNAME$
  33.  *     FT_MONTH()
  34.  *  $CATEGORY$
  35.  *     Date/Time
  36.  *  $ONELINER$
  37.  *     Return Calendar or Fiscal Month Data
  38.  *  $SYNTAX$
  39.  *     FT_MONTH( [ <dGivenDate> ], [nMonthNum] ) -> aDateInfo
  40.  *  $ARGUMENTS$
  41.  *     <dGivenDate> is any valid date in any date format.  Defaults
  42.  *     to current system date if not supplied.
  43.  *
  44.  *     <nMonthNum> is a number from 1 to 12 signifying a month.
  45.  *     Defaults to current month if not supplied.
  46.  *  $RETURNS$
  47.  *     A three element array containing the following data:
  48.  *
  49.  *        aDateInfo[1] - The year and month as a character string "YYYYMM"
  50.  *        aDateInfo[2] - The beginning date of the month
  51.  *        aDateInfo[3] - The ending date of the month
  52.  *  $DESCRIPTION$
  53.  *     FT_MONTH() returns an array containing data about the month
  54.  *     containing the given date.
  55.  *
  56.  *     Normally the return data will be based on a year beginning
  57.  *     on January 1st with weeks beginning on Sunday.
  58.  *
  59.  *     The beginning of year date and/or beginning of week day can be
  60.  *     changed by using FT_DATECNFG(), which will affect all subsequent
  61.  *     calls to FT_MONTH() until another call to FT_DATECNFG().
  62.  *
  63.  *     The beginning of year date and beginning of week day may be reset
  64.  *     to January 1 and Sunday by calling FT_DATECNFG() with no
  65.  *     parameters.
  66.  *  $EXAMPLES$
  67.  *     // get info about month containing 9/15/90
  68.  *     aDateInfo := FT_MONTH( CTOD("09/15/90") )
  69.  *     ? aDateInfo[1]   //  199009       (9th month)
  70.  *     ? aDateInfo[2]   //  09/01/90     beginning of month 9
  71.  *     ? aDateInfo[3]   //  09/30/90     end of week month 9
  72.  *
  73.  *     // get info about month 5 in year containing 9/15/90
  74.  *     aDateInfo := FT_MONTH( CTOD("09/15/90"), 5 )
  75.  *     ? aDateInfo[1]   //  199005
  76.  *     ? aDateInfo[2]   //  05/01/90   beginning of month 5
  77.  *     ? aDateInfo[3]   //  05/31/90   end of month 5
  78.  *
  79.  *     // get info about month 5 in current year (1991)
  80.  *     aDateInfo := FT_MONTH( , 5 )
  81.  *     ? aDateInfo[1]   //  199105
  82.  *     ? aDateInfo[2]   //  05/01/91   beginning of month 5
  83.  *     ? aDateInfo[3]   //  05/31/91   end of month 5
  84.  *  $SEEALSO$
  85.  *     FT_DATECNFG() FT_WEEK() FT_QTR() FT_YEAR()
  86.  *  $END$
  87. */
  88.  
  89. FUNCTION FT_MONTH( dGivenDate, nMonthNum )
  90. LOCAL lIsMonth, nTemp, aRetVal
  91.  
  92.   IF !( VALTYPE(dGivenDate) $ 'ND')
  93.      dGivenDate := DATE()
  94.   ELSEIF VALTYPE(dGivenDate) == 'N'
  95.      nMonthNum  := dGivenDate
  96.      dGivenDate := DATE()
  97.   ENDIF
  98.  
  99.   aRetVal   := FT_YEAR(dGivenDate)
  100.  
  101.   lIsMonth  := ( VALTYPE(nMonthNum) == 'N' )
  102.   IF lISMonth
  103.      IF( nMonthNum < 1 .OR. nMonthNum > 12, nMonthNum := 12, )
  104.      dGivenDate := FT_MADD(aRetVal[2], nMonthNum - 1)
  105.   ENDIF
  106.  
  107.   nTemp := MONTH( dGivenDate ) - MONTH( aRetVal[2] )
  108.   nTemp += IF(nTemp >= 0, 1, 13)
  109.  
  110.   aRetVal[1] += PADL(LTRIM(STR(nTemp, 2)), 2, '0')
  111.   aRetVal[2] := FT_MADD( aRetVal[2], nTemp - 1 )
  112.   aRetVal[3] := FT_MADD( aRetVal[2], 1 ) - 1
  113.  
  114. RETURN aRetVal
  115.  
  116.  
  117.