home *** CD-ROM | disk | FTP | other *** search
/ Media Share 9 / MEDIASHARE_09.ISO / progmisc / nfsrc21.zip / AINT86.ASM < prev    next >
Assembly Source File  |  1992-06-20  |  5KB  |  136 lines
  1. ; File......: AINT86.ASM
  2. ; Author....: Ted Means
  3. ; Date......: $Date:   20 Jun 1992 02:59:24  $
  4. ; Revision..: $Revision:   1.2  $
  5. ; Log file..: $Logfile:   C:/nanfor/src/aint86.asv  $
  6. ; 
  7. ; This is an original work by Ted Means and is placed in the
  8. ; public domain.
  9. ;
  10. ; Modification history:
  11. ; ---------------------
  12. ;
  13. ; $Log:   C:/nanfor/src/aint86.asv  $
  14. ;  
  15. ;     Rev 1.2   20 Jun 1992 02:59:24   GLENN
  16. ;  Rodgers Moore [75730,2244] added mod to save and restore the stack
  17. ;  segment and stack pointer registers around the interrupt vector.  He
  18. ;  was trying to call INT 2E and apparently some versions of DOS trash
  19. ;  SS and SP.
  20. ;  
  21. ;     Rev 1.1   15 Aug 1991 23:07:24   GLENN
  22. ;  Forest Belt proofread/edited/cleaned up doc
  23. ;  
  24. ;     Rev 1.0   27 May 1991 13:21:48   GLENN
  25. ;  Initial revision.
  26. ;
  27.  
  28.  
  29. ; This file is a part of the ft_int86() package.  For complete
  30. ; documentation, read cint86.c, available elsewhere in the 
  31. ; Nanforum Toolkit.
  32. ;
  33. ; This module should be compiled with TASM.
  34.  
  35.  
  36. Public   __ftint86
  37.  
  38. Segment  _NanFor   Word      Public    "CODE"
  39.          Assume    CS:_NanFor
  40.  
  41. Proc     __ftint86 Far
  42.  
  43.          Pop       CX                        ; Remove return address from
  44.          Pop       DX                        ; stack
  45.  
  46.          Pop       [CS:RegOfs]               ; Get pointer to register
  47.          Pop       [CS:RegSeg]               ; structure from stack
  48.  
  49.          Pop       AX                        ; Get desired interrupt
  50.  
  51.          Push      DX                        ; Put return address back onto
  52.          Push      CX                        ; stack to prevent underflow
  53.  
  54.          Push      DS                        ; Save modified registers
  55.          Push      SI
  56.          Push      DI
  57.          Push      BP
  58.  
  59.          Mov       AH,35h                    ; DOS service -- get vector
  60.          Int       21h                       ; Call DOS
  61.          Mov       [CS:HndSeg],ES            ; Store address of desired
  62.          Mov       [CS:HndOfs],BX            ; interrupt handler
  63.  
  64.          LDS       BX,[CS:RegPtr]            ; Load pointer to register values
  65.          Push      [Word Ptr BX + 16]        ; Put ES value on stack
  66.          Push      [Word Ptr BX + 14]        ; Put DS value on stack
  67.          Push      [Word Ptr BX + 12]        ; Put BP value on stack
  68.          Push      [Word Ptr BX + 10]        ; Put DI value on stack
  69.          Push      [Word Ptr BX + 8]         ; Put SI value on stack
  70.          Push      [Word Ptr BX + 6]         ; Put DX value on stack
  71.          Push      [Word Ptr BX + 4]         ; Put CX value on stack
  72.          Push      [Word Ptr BX + 2]         ; Put BX value on stack
  73.          Mov       AX,[Word Ptr BX + 0]      ; Get AX value
  74.          Pop       BX                        ; Get BX value
  75.          Pop       CX                        ; Get CX value
  76.          Pop       DX                        ; Get DX value
  77.          Pop       SI                        ; Get SI value
  78.          Pop       DI                        ; Get DI value
  79.          Pop       BP                        ; Get BP value
  80.          Pop       DS                        ; Get DS value
  81.          Pop       ES                        ; Get ES value
  82.  
  83.          Mov       [CS:SavSS],SS             ; Save Stack Segment
  84.          Mov       [CS:SavSP],SP             ; and Stack Pointer Registers
  85.  
  86.          PushF                               ; Simulate INT instruction by
  87.          CLI                                 ; using PushF and CLI
  88.          Call      [CS:Handler]              ; Call the interrupt handler
  89.  
  90.          Mov       SS,[CS:SavSS]             ; Restore Stack Segment
  91.          Mov       SP,[CS:SavSP]             ; and Stack Pointer Registers
  92.  
  93.          Push      AX                        ; Save all registers to preserve
  94.          Push      BX                        ; the state of the CPU after
  95.          Push      CX                        ; the interrupt executed
  96.          Push      DX
  97.          Push      SI
  98.          Push      DI
  99.          Push      BP
  100.          Push      DS
  101.          Push      ES
  102.          PushF
  103.  
  104.          LDS       BX,[CS:RegPtr]            ; Load pointer to register values
  105.          Pop       [Word Ptr BX + 18]        ; Get saved registers and load
  106.          Pop       [Word Ptr BX + 16]        ; into data structure
  107.          Pop       [Word Ptr BX + 14]
  108.          Pop       [Word Ptr BX + 12]
  109.          Pop       [Word Ptr BX + 10]
  110.          Pop       [Word Ptr BX + 8]
  111.          Pop       [Word Ptr BX + 6]
  112.          Pop       [Word Ptr BX + 4]
  113.          Pop       [Word Ptr BX + 2]
  114.          Pop       [Word Ptr BX + 0]
  115.  
  116.          Pop       BP                        ; Restore registers
  117.          Pop       DI
  118.          Pop       SI
  119.          Pop       DS
  120.          Ret
  121. Endp     __ftint86
  122.  
  123. SavSS    DW        0
  124. SavSP    DW        0
  125.  
  126. Label    Handler   DWord
  127. HndOfs   DW        ?
  128. HndSeg   DW        ?
  129.  
  130. Label    RegPtr    DWord
  131. RegOfs   DW        ?
  132. RegSeg   DW        ?
  133.  
  134. Ends     _NanFor
  135. End
  136.