home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Media Share 9
/
MEDIASHARE_09.ISO
/
pcboard
/
fpcb_106.zip
/
FPCBNM.PPS
< prev
next >
Wrap
Text File
|
1993-06-27
|
7KB
|
181 lines
;*******************************************************************
;* *
;* FPCBNM.PPE v1.06 *
;* PCBOARD 15.0 FidoPCB NETMAIL ASSISTANCE PROGRAM *
;* *
;* Written by John Luce *
;* Written in PCBoard Programming Language *
;* Compiled on 6-27-93 *
;* *
;* *
;* "Chronicles InfoNet BBS" *
;* 203-445-0607 - [16.8 DS] *
;* FidoNet 1:320/124 *
;* DoorNet 75:7203/0 *
;* DDS/DFN/PDN/SDN/SDS/SoundNet/UtilNet *
;* *
;* Freq FPCBNM for the latest updated version *
;* *
;*******************************************************************
;*******************************************************************
;* Define variable types *
;*******************************************************************
STRING Command_Line, Mail_select, Help_select, FSCREEN
STRING NAME, SUBJ, NODE
STRING NNAME, NNAME1, GATE, NSITE, NSITE1, NSUBJ, DOMAIN, DOMAIN1, ADLINE
;*******************************************************************
;* Variables *
;*******************************************************************
ADLINE = " "
;*******************************************************************
;* Check the command line for any parameters *
;*******************************************************************
IF (Command_line = "1") GOTO FIDONET
IF (Command_line = "2") GOTO UUCP
IF (Command_line <> "") Mail_select = ""
;*******************************************************************
;* Start of main program *
;*******************************************************************
:START_PROG
CLS
Mail_select = ""
IF (EXIST (PPEPATH() + "NET_IN")) DISPFILE PPEPATH() + "NET_IN", GRAPH + SEC + LANG
INPUTSTR " @X0F(@X0AQ@X0F)uit, Netmail Selection Command", Mail_select, 0Fh, 1, "q, Q, 1, 2", FIELDLEN + GUIDE + LFBEFORE + UPCASE
IF (Mail_select = "1") GOTO FIDONET
IF (Mail_select = "2") GOTO UUCP
IF (Mail_select = "Q") GOTO END_PROG
IF (Mail_select = "" ) GOTO END_PROG
GOTO START_PROG
;*******************************************************************
;* Tell the user he's about to enter a FidoNet NetMail Msg *
;*******************************************************************
: FIDONET
CLS
IF (EXIST(PPEPATH() + "FIDO_A")) DISPFILE PPEPATH() + "FIDO_A", GRAPH + SEC + LANG
NEWLINE
DISPTEXT 199, LOGIT
INPUTTEXT "", NAME, 11, 60
PRINTLN
DISPTEXT 200, LOGIT
INPUTTEXT "", SUBJ, 11, 60
IF (LEN(SUBJ) < 2) GOTO END_PROG
GETUSER
IF (U_FSEP=0) THEN
FSCREEN = NOCHAR()
ELSEIF (U_FSEP=1)
FSCREEN = YESCHAR()
ENDIF
;*******************************************************************
;* Ask the user for the node number of the addressee.. *
;*******************************************************************
NEWLINE
INPUTSTR "@X0FEnter FidoNet Node Number@X0A", NODE, 14, 20, "1234567890/:.", FIELDLEN + GUIDE + UPCASE
IF (U_FSEP=0) GOTO ALTSTUFF
;*******************************************************************
;* If the msg screen settings match stuff the keyboard *
;*******************************************************************
kbdstuff "E " + chr(13) + NAME + chr(13) + subj + CHR(13) + FSCREEN + CHR(13)
kbdstuff "(" + NODE + ")" + CHR(13)
kbdstuff "(IMM)" + CHR(13)
GOTO END_PROG
;*******************************************************************
;* if the msg screen didn't match the first setting then stuff the *
;* keyboard this way instead *
;*******************************************************************
:ALTSTUFF
kbdstuff "E " + chr(13) + NAME + chr(13) + subj + CHR(13)
kbdstuff "(" + NODE + ")" + CHR(13)
kbdstuff "(IMM)" + CHR(13)
GOTO END_PROG
:UUCP
;*******************************************************************
;* Tell the user he's about to enter a InterNet NetMail Msg *
;*******************************************************************
CLS
IF (EXIST(PPEPATH() + "INET_A")) DISPFILE PPEPATH() + "INET_A", GRAPH + SEC + LANG
NEWLINE
DISPTEXT 200, LOGIT
INPUTTEXT "", SUBJ, 11, 53
IF (LEN(SUBJ) < 2) GOTO END_PROG
NEWLINE
GETUSER
IF (U_FSEP=0) THEN
FSCREEN = NOCHAR()
ELSEIF (U_FSEP=1)
FSCREEN = YESCHAR()
ENDIF
;*******************************************************************
;* Read the config file for the nearest FidoNet UUCP Gateway *
;*******************************************************************
FOPEN 1, PPEPATH() + "FPCBNM.CFG", O_RD, S_DB
FGET 1, GATE
FCLOSE 1
;*******************************************************************
;* Ask the user for the node number of the addressee.. *
;*******************************************************************
INPUTSTR "@X0FEnter the user's @X0ANAME@X0F mail is intended for@X0A", NNAME, 32, 60, "abcdefghijklmnopqrstuvwxyzABCDEFGHIJKLMNOPQRSTUVWXYZ", FIELDLEN + GUIDE + LFAFTER
INPUTSTR "@X0FEnter the InterNet @X0ASITE@X0F this msg is to be sent to@X0A", NSITE, 20, 60, "abcdefghijklmnopqrstuvwxyz.", FIELDLEN + GUIDE + LFAFTER
INPUTSTR "@X0FEnter the InterNet @X0ADOMAIN@X0F this msg is to be sent to@X0A", DOMAIN, 20, 60, "abcdefghijklmnopqrstuvwxyz.", FIELDLEN + GUIDE
NNAME1 = LOWER(NNAME)
NSITE1 = LOWER(NSITE)
DOMAIN1= LOWER(DOMAIN)
IF (U_FSEP=0) GOTO ALTNSTUFF
;*******************************************************************
;* If the msg screen settings match stuff the keyboard *
;*******************************************************************
kbdstuff "E "+ CHR(13) + "UUCP" + CHR(13) + SUBJ + CHR(13) + FSCREEN + CHR(13)
kbdstuff "(" + GATE + ")" + CHR(13)
kbdstuff "(IMM)" + CHR(13)
kbdstuff "To: " + NNAME1 + "@" + NSITE1 + "." + DOMAIN1 + CHR(13) + ADLINE + CHR(13) + ADLINE + CHR(13)
GOTO END_PROG
;*******************************************************************
;* if the msg screen didn't match the first setting then stuff the *
;* keyboard this way instead *
;*******************************************************************
:ALTNSTUFF
kbdstuff "E "+ CHR(13) + "UUCP" + CHR(13) + SUBJ + CHR(13)
kbdstuff "(" + GATE + ")" + CHR(13)
kbdstuff "(IMM)" + CHR(13)
kbdstuff "To: " + NNAME1 + "@" + NSITE1 + "." + DOMAIN1 + CHR(13) + ADLINE + CHR(13) + ADLINE + CHR(13)
GOTO END_PROG
:END_PROG
END