Magazyn Amiga Shareware Floppies/ma70.dms/ma70.adf/SoundBox/Install

Text File | 1996-05-11 | 5KB | 206 lines

; ************************************************
; *
; * SoundBox - HD Install Script
; *
; * $VER: Install-SoundBox 1.40
; *
; * Script written by Richard Körber
; *
; ************************************************

;------- Prompts ---------------------------------
;
(set DestDirPrompt
  (cat  "Where do you want to install SoundBox?\n"
        "A new drawer will be created."
  )
)
(set CopySBoxPrompt
  "Copying SoundBox..."
)
(set LanguagePrompt
  "What documentation language do you want?"
)
(set CopySBGuidePrompt
  "Copying SoundBox guide..."
)
(set DockIconPrompt
  "Do you want to copy the ToolManager dock icon?"
)
(set DockIconWherePrompt
  "Where do you store the dock icons?"
)
(set CopyDockIconPrompt
  "Copying dock icon..."
)
(set CopyLangPrompt
  "Copying language catalogs..."
)

;------- Help ------------------------------------
;
(set DestDirHelp
  (cat  "Choose a directory where to place SoundBox to.\n"
        "(e.g. Work:)"
  )
)

;------- Messages --------------------------------
;
(set StartupMsg
  (cat  "\nSoundBox installation\n\n"
        "This program installs the whole SoundBox\n"
        "system to your hard disk.\n\n"
        "This is only an evaluation version, with\n"
        "some limitations. Please register to get\n"
        "the fully functional version.\n\n"
        "Please read the guide file to see how you\n"
        "can obtain a registration."
  )
)
(set AllrightMsg
  (cat  "\nSoundBox is now installed.\n\n"
        "And please don't forget to\n"
        "register after one month ;-)\n\n"
        "Have fun!\n\n"
        "        Richard Körber"
  )
)

;------- Files -----------------------------------
;
(set SoundBoxFile   "SoundBox")
(set GuideDFile     "SoundBox-D.guide")
(set GuideEFile     "SoundBox-E.guide")
(set GuidePicFile   "SoundBox.pic")
(set DockIconFile   "SoundBoxDock.info")
(set LangSource     "catalogs")
(set LibSource1File "libs/provision.library")
(set LibSource2File "libs/reqtools.library")

;------- Installation ----------------------------
;
(message StartupMsg)            ;-------- Welcome the user

(set DestDir                    ;-------- Ask dir to create drawer into
  (askdir
    (prompt  DestDirPrompt)
    (help    DestDirHelp)
    (default "Work:")
  )
)
(set DestDir                            ; And create this directory
  (tackon DestDir "SoundBox")
)
(makedir
  (DestDir)
  (infos)
)
(set @default-dest (DestDir))

(copyfiles                              ; Copy SoundBox
  (prompt CopySBoxPrompt)
  (help   @copyfiles-help)
  (source SoundBoxFile)
  (dest   DestDir)
  (infos)
)

(set Lang                               ; What language?
  (askchoice
    (prompt LanguagePrompt)
    (help   @askchoice-help)
    (choices "Deutsch" "English")
    (default 1)
  )
)

(set GuideTarg DestDir)
(if (= Lang 0)
  (
    (set GuideFile GuideDFile)
    (if (= (exists "HELP:deutsch") 2)
      (set GuideTarg "HELP:deutsch")
    )
  )
  (
    (set GuideFile GuideEFile)
    (if (= (exists "HELP:english") 2)
      (set GuideTarg "HELP:english")
    )
  )
)

(copyfiles                              ; Copy SoundBox doc
  (prompt  CopySBGuidePrompt)
  (help    @copyfiles-help)
  (source  GuideFile)
  (dest    GuideTarg)
  (newname "SoundBox.guide")
  (infos)
)

(copyfiles                              ; and picture
  (help    @copyfiles-help)
  (source  GuidePicFile)
  (dest    GuideTarg)
  (infos)
)

(set DockIcon                           ; user needs dock icon?
  (askbool
    (prompt  DockIconPrompt)
    (help    @askbool-help)
    (default 0)
  )
)

(if (= DockIcon 1)                      ; Copy dock icon?
  (
    (set DockDest
      (askdir
        (help    @askdir-help)
        (prompt  DockIconWherePrompt)
        (default DestDir)
      )
    )
    (copyfiles
      (prompt  CopyDockIconPrompt)
      (help    @copyfiles-help)
      (source  DockIconFile)
      (dest    DockDest)
      (infos)
    )
  )
)

(copyfiles                              ;Catalogs
        (prompt CopyLangPrompt)
        (help    @copyfiles-help)
        (source LangSource)
        (dest   "LOCALE:Catalogs")
        (confirm)
        (all)
)

(copylib                                ;Libs
        (prompt CopyLib1Prompt)
        (help    @copyfiles-help)
        (source LibSource1File)
        (dest   "LIBS:")
        (confirm)
)

(copylib
        (prompt CopyLib2Prompt)
        (help    @copylib-help)
        (source LibSource2File)
        (dest   "LIBS:")
        (confirm)
)

(message AllrightMsg)

;------- Done ------------------------------------