Magazyn Amiga Shareware Floppies/ma59.dms/ma59.adf/Trashman/Install-Trashman

Text File | 1996-07-04 | 4KB | 180 lines

;------------------------------------------------------------------------
;
; Install-Trashman
;
; $VER: Install-Trashman 1.0 (28.5.96)
;
;------------------------------------------------------------------------

;
; initialize variables
;

(set #FlagENGLISH 0)
(set #FlagPOLSKI  1)
(set #FlagOTHER   2)

(if (= @language "polski")
(
    (set #welcome (cat "Witam w instalacji Trashman'a."))
    (set #trashdestdir-prompt (cat "Proszë wybraê katalog w którym Trashman powinien byê zainstalowany. Katalog nie bëdzie utworzony.\n"))
    (set #trashdestdir-help (cat "Wybierz katalog lub dysk w którym bëdzie zainstalowany katalog Trashmana.\n"))
    (set #language-prompt (cat "Wybierz jakie chcesz zainstalowaê wersje jëzykowe"))
    (set #language-help (cat "Trashman pozwala na pracë w róûnych jëzykach. Domyôlnie wbudowany jest jëzyk angielski.\nJeôli wybierzesz 'inny' to bëdziesz mógî sam przetîumaczyê Trashman'a na dowolny jëzyk. Zaznacz wtedy jeszcze jakiô inny jëzyk (np. angielski) aby skopiowaê pliki pomocy."))
    (set #gadget-prompt (cat "Czy mam skopiowaê progress.gadget?"))
    (set #gadget-help (cat "Progress.gadget jest potrzebny do uruchomienia Trashman'a"))
    (set #translation (cat "inny - pliki tîumaczeï"))
)
(
    (set #welcome (cat "Welcome to the Installation of Trashman."))
    (set #trashdestdir-prompt (cat "Please select the drawer where Trashman should be installed. Directory will not be created.\n"))
    (set #trashdestdir-help (cat "If you want to start Trashman at startup select SYS:WBStartup.\n"))
    (set #language-prompt (cat "Select what language versions you prefer to install."))
    (set #language-help (cat "Trashman can work in many languages. Default language is english - built in.\nIf you select other you will be able to translate Trashman yourself, with this option select also other language."))
    (set #gadget-prompt (cat "Do you want to copy progress.gadget?"))
    (set #gadget-help (cat "Progress.gadget is required to run Trashman"))
    (set #translation (cat "other - translation files"))
)
)

;
; begin installation
;

(welcome #welcome)
(complete 0)

(set @default-dest (cat "SYS:Utilities"))
(set #DestDir
    (askdir    (prompt #trashdestdir-prompt)
        (help    #trashdestdir-help)
        (default    @default-dest)
        (newpath)
    )
)

(set #Languages    (askoptions    (prompt    #language-prompt)
                (help    #language-help)
                (choices    "english" "polski" #translation)
        )
)

(complete 10)

;
; copy libraries and gadgets
;

(copylib    (prompt    #gadget-prompt)
        (help    #gadget-help)
        (source    "gadgets/progress.gadget")
        (dest    "SYS:Classes/gadgets")
        (confirm)
)

(copyfiles    (source    "Trashman")
        (dest    #DestDir)
        (infos)
)

(complete 20)

;
; copy polish version
;

(if (IN #Languages #FlagPOLSKI)
(
    (if (<> (exists    "LOCALE:catalogs/polski") 2)
        (makedir "LOCALE:catalogs/polski")
    )
    (complete 30)
    (copyfiles    (source    "catalogs/polski")
            (dest    "LOCALE:catalogs/polski")
            (all)
    )
    (complete 40)

    (set #HELPdest (tackon #DestDir "Help/Polski"))
    (if (<> (exists    #HELPdest) 2)
        (makedir #HELPdest)
    )
    (complete 50)
    (copyfiles    (source    "Help/Polski")
            (dest    #HELPdest)
            (infos)
            (all)
    )
    (complete 60)
    (set #HELPdest (tackon #DestDir "Help"))
    (copyfiles    (source    "Help/Polski.info")
            (dest    #HELPdest)
            (nogauge)
    )
    (copyfiles    (source    "Help.info")
            (dest    #DestDir)
            (nogauge)
    )
))

;
; copy english version
;

(if (IN #Languages #FlagENGLISH)
(
    (set #HELPdest (tackon #DestDir "Help/English"))
    (if (<> (exists    #HELPdest) 2)
        (makedir #HELPdest)
    )
    (complete 70)
    (copyfiles    (source    "Help/English")
            (dest    #HELPdest)
            (infos)
            (all)
    )
    (complete 80)
    (set #HELPdest (tackon #DestDir "Help"))
    (copyfiles    (source    "Help/English.info")
            (dest    #HELPdest)
            (nogauge)
    )
    (copyfiles    (source    "Help.info")
            (dest    #DestDir)
            (nogauge)
    )
))

;
; copy catalog description and translation template
;

(if (IN #Languages #FlagOTHER)
(
    (set #CATAdest (tackon #DestDir "catalogs"))
    (if (<> (exists    #CATAdest) 2)
        (makedir #CATAdest)
    )

    (copyfiles    (source    "catalogs.info")
            (dest    #DestDir)
            (nogauge)
    )

    (complete 90)
    (copyfiles    (source    "catalogs/Trashman.cd")
            (dest    #CATAdest)
    )
    (complete 95)
    (copyfiles    (source    "catalogs/Trashman.ct")
            (dest    #CATAdest)
    )
))

;
; say goodbye
;

(complete 100)
(exit)