Magazyn Amiga Shareware Floppies/ma30.dms/ma30.adf/PDPatch/Instalacja_HD

Text File | 1994-09-01 | 6KB | 247 lines

; Skrypt sîuûâcy do zainstalowania PDPatcha na twardy dysk.

; $VER: Instalacja_HD 37.3 (28.8.94)
; Copyright (C) 1994 Kamil Iskra

; Przed pytaniem o znajomoôê Amigi sprawdúmy wersjë systemu...
(if (< (/ (getversion) $10000) 37)
    (abort "PDPatch 2.0a+ wymaga co najmniej systemu 2.04!")
)

(welcome)

(set ustawiony_poziom @user-level)

; Ustawmy na chwilë EXPERT
(user 2)

; Wybór katalogu do zainstalowania
(set katalogpom
    (tackon
        (askdir
            (prompt "Gdzie ma zostaê utworzony katalog \"PDPatch\"?")
            (help "W katalogu, który wybierzesz, zostanie utworzony podkatalog "
                "\"PDPatch\", do którego zostanie skopiowany ten program.\n\n"
                @askdir-help
            )
            (default @default-dest)
        )
        "PDPatch"
    )
)

; Wprowadziîem pomocniczâ zmiennâ katalogpom, gdyû pojawiaîy sië problemy, gdy
; klikniëto "Abort Install" przy wyborze katalogu.
(set @default-dest katalogpom)

; Przywróêmy ustawiony poziom instalacji.
(user ustawiony_poziom)

; Proôba o potwierdzenie, utworzenie katalogu.
(makedir @default-dest
    (prompt ("PDPatch zostanie zainstalowany w katalogu \"%s\""
        @default-dest)
    )
    (help @makedir-help)
    (infos)
    (confirm)
)

; Wybierz czëôci pakietu do zainstalowania
(set czesci_pakietu
    (askoptions
        (prompt "Które czëôci programu majâ zostaê zainstalowane?")
        (choices "Program gîówny" "Wersja DEMO" "Dokumentacja"
            "Pliki preferencji" "ReqTools"
        )
        (default %11111)
        (help
            "Program gîówny - zostanie skopiowana gîówna czëôê programu, czyli "
            "plik \"PDPatch\" wraz z ikonâ. Instalacja tej czëôci odbëdzie "
            "sië tylko w przypadku posiadania wersji licencjonowanej.\n\n"
            "Wersja DEMO - zostanie skopiowana wersja demonstracyjna programu, "
            "czyli plik \"PDPatchDEMO\" wraz z ikonâ.\n\n"
            "Dokumentacja - zostanie skopiowana dokumentacja OnLine-Help "
            "(plik \"PDPatch.guide\") oraz skrypt umoûliwiajâcy odczytanie tej "
            "dokumentacji bez koniecznoôci uruchamiania programu Konwersja "
            "(plik \"Konwersja.DOC\").\n\n"
            "Pliki preferencji - zostanâ zainstalowane pliki preferencji dla "
            "poszczególnych drukarek oraz ich opisy (i ew. przykîady). "
            "Otrzymasz moûliwoôê wyboru, które pliki majâ zostaê zainstalowane."
            "\n\n"
            "ReqTools - w katalogu \"LIBS:\" zostanie zainstalowana biblioteka "
            "\"reqtools.library\". Jest ona niezbëdna dla PDPatcha. Przed jej "
            "instalacjâ zostanie sprawdzone, czy w katalogu \"LIBS:\" nie "
            "znajduje sië przypadkiem nowsza jej wersja.\n\n"
            @askoptions-help
        )
    )
)

; Wybierz pliki preferencji
(user 2)
(if (IN czesci_pakietu 3)
    (set pliki_preferencji
        (askoptions
            (prompt "Które pliki preferencji majâ zostaê zainstalowane?")
            (choices "AmigaPL Generic" "AmigaPL->Latin2 (Generic)"
                "AmigaPL->Mazowia (Generic)" "AmigaPL->Windows (Generic)"
                "Epson LQ 100 (EscP2)" "Star LC 24-20")
            (default 0)
            (help
                "Wybrane przez Ciebie pliki preferencji zostanâ skopiowane do "
                "podkatalogu \"Drukarki\". Oprócz samych plików zostanâ "
                "skopiowane równieû ich ikony oraz dokumentacje do tych "
                "plików (i ew. przykîady, o ile istniejâ).\n\n"
                @askoptions-help
            )
        )
    )
)
(user ustawiony_poziom)

(set DefToolIkon
    (tackon @default-dest "PDPatchDEMO")
)

; Skopiujmy program gîówny
(if (IN czesci_pakietu 0)
    (
        (set blad
            (trap 4 ; Trzeba wziâê pod uwagë, ûe tych plików moûe nie byê.
                (copyfiles
                    (source "PDPatch")
                    (dest @default-dest)
                    (infos)
                )
            )
        )
        (if (> blad 0)
            (if (= @ioerr 205) ; Nie znaleziono pliku
                (message
                    "Nie zostaî zainstalowany \"Program gîówny\", gdyû nie byîo "
                    "go w katalogu úródîowym - masz zapewne do czynienia z wersjâ "
                    "demonstracyjnâ!"
                )
                ; inny bîâd
                (abort "Bîâd instalacji \"Programu gîównego\"!")
            )
            (set DefToolIkon ; O! Jest licencjonowana wersja!
                (tackon @default-dest "PDPatch")
            )
        )
    )
)

; Skopiujmy wersjë DEMO
(if (IN czesci_pakietu 1)
    (copyfiles
        (source "PDPatchDEMO")
        (dest @default-dest)
        (infos)
    )
)

; Skopiujmy dokumentacjë
(if (IN czesci_pakietu 2)
    (
        (copyfiles
            (source "PDPatch.guide")
            (dest @default-dest)
        )
        (copyfiles
            (source "PDPatch.DOC")
            (dest @default-dest)
            (infos)
        )
    )
)

; Skopiujmy pliki preferencji
(if (IN czesci_pakietu 3)
    (
        (makedir (tackon @default-dest "Drukarki"))
        (copyfiles
            (source "Drukarki.info")
            (dest @default-dest)
        )
        (set licznik 0)
        (while
            (set plikpref
                (select licznik
                    "AmigaPLGen"
                    "AmigaPL->Latin2"
                    "AmigaPL->Mazowia"
                    "AmigaPL->Windows"
                    "EpsonLQ100"
                    "StarLC2420"
                    ""
                )
            )
            (
                (if (IN pliki_preferencji licznik)
                    (
                        (copyfiles
                            (source (tackon "Drukarki" plikpref))
                            (dest (tackon @default-dest "Drukarki"))
                            (infos)
                        )
                        ; Dla StarLC24-20 istnieje teû driver generic
                        (if (= plikpref "StarLC2420")
                            (copyfiles
                                (source "Drukarki/StarLC2420_generic")
                                (dest (tackon @default-dest "Drukarki"))
                                (infos)
                            )
                        )
                        (copyfiles
                            (source (tackon "Drukarki" (cat plikpref ".guide")))
                            (dest (tackon @default-dest "Drukarki"))
                        )
                        ; Przykîadów moûe nie byê
                        (if (exists (tackon "Drukarki" (cat plikpref ".examples")))
                            (copyfiles
                                (source (tackon "Drukarki" (cat plikpref
                                    ".examples")))
                                (dest (tackon @default-dest "Drukarki"))
                            )
                        )
                        (tooltype
                            (dest (tackon (tackon @default-dest "Drukarki")
                                plikpref))
                            (setdefaulttool DefToolIkon)
                        )
                    )
                )
                (set licznik (+ licznik 1))
            )
        )
    )
)

; Skopiujmy ReqTools
(if (IN czesci_pakietu 4)
    (copylib
        (source "Libs/reqtools.library")
        (dest "LIBS:")
        (prompt "Zamierzam skopiowaê bibliotekë \"reqtools.library\"")
        (help @copylib-help)
        (confirm)
    )
)

; Sprawdúmy, czy jest amigaguide.library w OS 2.x
(if (= (/ (getversion) $10000) 37)
    (if (NOT (exists "LIBS:amigaguide.library"))
        (
            (user 2) ; message nie dziaîa z novice'em
            (message
                "Nie posiadasz w katalogu \"LIBS:\" biblioteki "
                "\"amigaguide.library\". Ta biblioteka jest PDPatchowi niezbëdna "
                "do uûywania OnLine-Help. Powinieneô jâ skâdô zdobyê!"
            )
            (user ustawiony_poziom)
        )
    )
)