Magazyn Amiga Shareware Floppies/ma30.dms/ma30.adf/Konwersja/Instalacja_HD

Text File | 1994-08-16 | 5KB | 220 lines

; Skrypt sîuûâcy do zainstalowania Konwersji na twardy dysk.

; $VER: Instalacja_HD 37.7 (30.6.94)
; Copyright (C) 1993, 1994 Kamil Iskra

; Przed pytaniem o znajomoôê Amigi sprawdúmy wersjë systemu...
(if (< (/ (getversion) $10000) 37)
    (abort "Konwersja 3.0a+ wymaga co najmniej systemu 2.04!")
)

(welcome)

(set ustawiony_poziom @user-level)

; Ustawmy na chwilë EXPERT
(user 2)

; Wybór katalogu do zainstalowania
(set katalogpom
    (tackon
        (askdir
            (prompt "Gdzie ma zostaê utworzony katalog \"Konwersja\"?")
            (help "W katalogu, który wybierzesz, zostanie utworzony podkatalog "
                "\"Konwersja\", do którego zostanie skopiowany ten program.\n\n"
                @askdir-help
            )
            (default @default-dest)
        )
        "Konwersja"
    )
)

; Wprowadziîem pomocniczâ zmiennâ katalogpom, gdyû pojawiaîy sië problemy, gdy
; klikniëto "Abort Install" przy wyborze katalogu.
(set @default-dest katalogpom)

; Przywróêmy ustawiony poziom instalacji.
(user ustawiony_poziom)

; Proôba o potwierdzenie, utworzenie katalogu.
(makedir @default-dest
    (prompt ("Konwersja zostanie zainstalowana w katalogu \"%s\""
        @default-dest)
    )
    (help @makedir-help)
    (infos)
    (confirm)
)

; Wybierz czëôci pakietu do zainstalowania
(set czesci_pakietu
    (askoptions
        (prompt "Które czëôci programu majâ zostaê zainstalowane?")
        (choices "Program gîówny" "Wersja DEMO" "Dokumentacja"
            "Standardy dyskowe" "Biblioteki" "Przykîady ARexxa"
        )
        (default %111111)
        (help
            "Program gîówny - zostanie skopiowana gîówna czëôê programu, czyli "
            "plik \"Konwersja\" wraz z ikonâ. Instalacja tej czëôci odbëdzie "
            "sië tylko w przypadku posiadania wersji licencjonowanej.\n\n"
            "Wersja DEMO - zostanie skopiowana wersja demonstracyjna programu, "
            "czyli plik \"KonwersjaDEMO\" wraz z ikonâ.\n\n"
            "Dokumentacja - zostanie skopiowana dokumentacja OnLine-Help "
            "(plik \"Konwersja.guide\"), skrypt umoûliwiajâcy odczytanie tej "
            "dokumentacji bez koniecznoôci uruchamiania programu Konwersja "
            "(plik \"Konwersja.DOC\") oraz plik zawierajâcy opis standardów - "
            "\"PolskieLitery.DOC\".\n\n"
            "Standardy dyskowe - zostanâ zainstalowane pliki umoûliwiajâce "
            "Konwersji konwersjë plików pomiëdzy standardami nie wbudowanymi w "
            "program.\n\n"
            "Biblioteki - zostanâ zainstalowane w katalogu \"LIBS:\" dwie "
            "biblioteki - \"reqtools.library\" i \"powerpacker.library\". Sâ "
            "one niezbëdne dla Konwersji. Przed ich instalacjâ zostanie "
            "sprawdzone, czy w katalogu \"LIBS:\" nie znajdujâ sië przypadkiem "
            "nowsze ich wersje.\n\n"
            "Przykîady ARexxa - zostanâ zainstalowane w katalogu \"REXX:\" "
            "przykîadowe skrypty jëzyka ARexx, bëdâce demonstracjâ moûliwoôci "
            "interfejsu ARexxa wbudowanego w Konwersjë.\n\n"
            @askoptions-help
        )
    )
)

(set instaluj_wbudowane 1)
(if (AND (IN czesci_pakietu 3) (= @user-level 2))
    (set instaluj_wbudowane
        (askbool
            (prompt
                "Czy standardy dyskowe odpowiadajâce wbudowanym w program "
                "majâ równieû zostaê zainstalowane?"
            )
            (choices "Tak" "Nie")
            (default 1)
            (help
                "Wôród plików ze standardami znajdujâ sië równieû pliki "
                "standardów wbudowanych w program Konwersja. Ich instalacja nie "
                "jest w zasadzie potrzebna, gdyû i tak nie bëdâ przez Konwersjë "
                "uûywane."
            )
        )
    )
)

; Skopiujmy program gîówny
(if (IN czesci_pakietu 0)
    (
        (set blad
            (trap 4 ; Trzeba wziâê pod uwagë, ûe tych plików moûe nie byê.
                (copyfiles
                    (source "Konwersja")
                    (dest @default-dest)
                    (infos)
                )
            )
        )
        (if (> blad 0)
            (if (= @ioerr 205) ; Nie znaleziono pliku
                (message
                    "Nie zostaî zainstalowany \"Program gîówny\", gdyû nie byîo "
                    "go w katalogu úródîowym - masz zapewne do czynienia z wersjâ "
                    "demonstracyjnâ!"
                )
                ; inny bîâd
                (abort "Bîâd instalacji \"Programu gîównego\"!")
            )
        )
    )
)

; Skopiujmy wersjë DEMO
(if (IN czesci_pakietu 1)
    (copyfiles
        (source "KonwersjaDEMO")
        (dest @default-dest)
        (infos)
    )
)

; Skopiujmy dokumentacjë
(if (IN czesci_pakietu 2)
    (
        (copyfiles
            (source "Konwersja.guide")
            (dest @default-dest)
        )
        (copyfiles
            (source "Konwersja.DOC")
            (dest @default-dest)
            (infos)
        )
        (copyfiles
            (source "PolskieLitery.DOC")
            (dest @default-dest)
            (infos)
        )
    )
)

; Skopiujmy standardy dyskowe
(if (IN czesci_pakietu 3)
    (
        (if instaluj_wbudowane
            (set patstan "#?")
            (set patstan
                "~(AmigaPL.kon|BezPol.kon|Latin2.kon|Mazowia.kon|xJP.kon)"
            )
        )
        (copyfiles
            (source "Standardy")
            (dest (tackon @default-dest "Standardy"))
            (pattern patstan)
        )
    )
)

; Skopiujmy biblioteki
(if (IN czesci_pakietu 4)
    (
        (copylib
            (source "Libs/reqtools.library")
            (dest "LIBS:")
            (prompt "Zamierzam skopiowaê bibliotekë \"reqtools.library\"")
            (help @copylib-help)
            (confirm)
        )
        (copylib
            (source "Libs/powerpacker.library")
            (dest "LIBS:")
            (prompt "Zamierzam skopiowaê bibliotekë \"powerpacker.library\"")
            (help @copylib-help)
            (confirm)
        )
    )
)

; Skopiujmy skrypty ARexxa
(if (IN czesci_pakietu 5)
    (copyfiles
        (source "Rexx")
        (dest "REXX:")
        (all)
    )
)

; Sprawdúmy, czy jest amigaguide.library w OS 2.0
(if (= (/ (getversion) $10000) 37)
    (if (NOT (exists "LIBS:amigaguide.library"))
        (
            (user 2) ; message nie dziaîa z novice'em
            (message
                "Nie posiadasz w katalogu \"LIBS:\" biblioteki "
                "\"amigaguide.library\". Ta biblioteka jest Konwersji niezbëdna "
                "do uûywania OnLine-Help. Musisz jâ skâdô zdobyê!"
            )
            (user ustawiony_poziom)
        )
    )
)