home *** CD-ROM | disk | FTP | other *** search
/ Freesoft 1997 May / Freesoft_1997-05_cd.bin / recenz / Antiviry / VIRUSCAN / BOOTSHLD / INSTALL.BAT < prev    next >
DOS Batch File  |  1996-03-26  |  32KB  |  557 lines
  1. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  2. ::                              INSTALL.BAT                                ::
  3. ::               Copyright 1995, 1996 McAfee Associates, Inc.              ::
  4. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  5.   @IF NOT "%3" == "DEBUG2" ECHO OFF
  6. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  7. :: Check for troubleshooting mode switches.                                ::
  8. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  9.   IF "%3" == "GOTO"   GOTO JumpCheck
  10.   IF "%3" == "DEBUG"  GOTO JumpCheck
  11.   IF "%3" == "DEBUG2" GOTO JumpCheck
  12.   GOTO SourceCheck
  13. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  14. :: If specified, go directly to label (case-sensitive), except JumpCheck.  ::
  15. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  16.   :JumpCheck
  17.     IF "%4" == "JumpCheck" GOTO SourceCheck
  18.     IF "%4" == ""          GOTO SourceCheck
  19.     GOTO %4
  20. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  21. :: Display help if user fails to specify installation source directory.    ::
  22. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  23.   :SourceCheck
  24.     IF "%1" == ""          GOTO WhereAmI
  25.     IF "%1" == "GOTO"      GOTO WhereAmI
  26.     GOTO TargetCheck
  27.   :WhereAmI
  28.     IF "%3" == "DEBUG"  PAUSE
  29.     IF "%3" == "DEBUG2" PAUSE
  30.     CLS
  31.     ECHO +======================================================================+
  32.     ECHO I                    BootShield Installation Error!                    I
  33.     ECHO +----------------------------------------------------------------------+
  34.     ECHO I                                                                      I
  35.     ECHO I The BootShield installation requires that you specify which          I
  36.     ECHO I directory the source files are located in.                           I
  37.     ECHO I                                                                      I
  38.     ECHO I Examples:                                                            I
  39.     ECHO I   A:\INSTALL A:                                                      I
  40.     ECHO I   B:\INSTALL B:                                                      I
  41.     ECHO I   C:\TEMP\INSTALL C:\TEMP                                            I
  42.     ECHO I                                                                      I
  43.     ECHO +----------------------------------------------------------------------+
  44.     ECHO.
  45.     GOTO Aborted
  46. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  47. :: Rerun with default if target directory is not specified.                ::
  48. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  49.   :TargetCheck
  50.     IF "%2" == ""          GOTO DefaultTarget
  51.     IF "%2" == "GOTO"      GOTO DefaultTarget
  52.     GOTO PackingCheck
  53.   :DefaultTarget
  54.     %1\INSTALL.BAT %1 C:\McAfee\BShield %2 %3
  55.     GOTO Abend
  56. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  57. :: Verify all files in the packing list are in the source directory.       ::
  58. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  59.   :PackingCheck
  60.     %1\SELFCHEK.EXE %1\PACKING.LST Directory of /were validated
  61.     IF NOT ERRORLEVEL 1 GOTO OSInstalledCheck
  62.     GOTO PackingError
  63.   :PackingError
  64.     IF "%3" == "DEBUG"  PAUSE
  65.     IF "%3" == "DEBUG2" PAUSE
  66.     CLS
  67.     ECHO +======================================================================+
  68.     ECHO I                    BootShield Installation Error!                    I
  69.     ECHO +----------------------------------------------------------------------+
  70.     ECHO I                                                                      I
  71.     ECHO I One or more of the installation files are missing from the source    I
  72.     ECHO I directory specified.                                                 I
  73.     ECHO I                                                                      I
  74.     ECHO I Please check the file PACKING.LST for required files.                I
  75.     ECHO I                                                                      I
  76.     ECHO +----------------------------------------------------------------------+
  77.     ECHO.
  78.     GOTO Aborted
  79. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  80. :: Check to see what operating systems are installed and warn if 32-bit.   ::
  81. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  82.   :OSInstalledCheck
  83.     IF EXIST C:\SYSTEM.1ST   GOTO InstalledOS
  84.     IF EXIST C:\NTLDR        GOTO InstalledOS
  85.     IF EXIST C:\NTDETECT.COM GOTO InstalledOS
  86.     IF EXIST C:\OS2LDR       GOTO InstalledOS
  87.     IF EXIST C:\OS2KRNL      GOTO InstalledOS
  88.     GOTO OSRunningCheck
  89.   :InstalledOS
  90.     IF "%3" == "DEBUG"  PAUSE
  91.     IF "%3" == "DEBUG2" PAUSE
  92.     CLS
  93.     ECHO +======================================================================+
  94.     ECHO I                    BootShield Installation Error!                    I
  95.     ECHO +----------------------------------------------------------------------+
  96.     ECHO I                                                                      I
  97.     ECHO I WARNING:  BootShield installation has detected that one or more of   I
  98.     ECHO I the following operating systems are installed on this computer:      I
  99.     ECHO I   Windows 95, Windows NT, OS/2.                                      I
  100.     ECHO I                                                                      I
  101.     ECHO I Due to the nature of the BootLock feature of BootShield, it is not   I
  102.     ECHO I recommended that you install BootShield on this computer.  If you    I
  103.     ECHO I continue, you may experience serious problems with your computer.    I
  104.     ECHO I                                                                      I
  105.     ECHO I For more information, please refer to the BootShield manual.         I
  106.     ECHO I                                                                      I
  107.     ECHO +----------------------------------------------------------------------+
  108.     ECHO.
  109.     %1\GETREPLY.EXE Do you wish to continue the installation (Y/N)? ;yn
  110.     ECHO.
  111.     IF ERRORLEVEL 2 GOTO Aborted
  112.     IF ERRORLEVEL 1 GOTO OSRunningCheck
  113.     GOTO Abend
  114. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  115. :: Check to see what operating system is running and abort if needed.      ::
  116. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  117.   :OSRunningCheck
  118.     IF NOT "%windir%"     == "" GOTO RunningOS
  119.     IF NOT "%winbootdir%" == "" GOTO RunningOS
  120.     IF NOT "%systemroot%" == "" GOTO RunningOS
  121.     IF NOT "%os2_shell%"  == "" GOTO RunningOS
  122.     GOTO ReadManualWarning
  123.   :RunningOS
  124.     IF "%3" == "DEBUG"  PAUSE
  125.     IF "%3" == "DEBUG2" PAUSE
  126.     CLS
  127.     ECHO +======================================================================+
  128.     ECHO I                    BootShield Installation Error!                    I
  129.     ECHO +----------------------------------------------------------------------+
  130.     ECHO I                                                                      I
  131.     ECHO I BootShield installation detected that you are attempting to install  I
  132.     ECHO I while running Windows or OS/2.  Due to the nature of these           I
  133.     ECHO I environments, installation cannot continue.                          I
  134.     ECHO I                                                                      I
  135.     ECHO +----------------------------------------------------------------------+
  136.     ECHO.
  137.     GOTO Aborted
  138. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  139. :: Remind user to review manual before installing.                         ::
  140. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  141.   :ReadManualWarning
  142.     IF "%3" == "DEBUG"  PAUSE
  143.     IF "%3" == "DEBUG2" PAUSE
  144.     CLS
  145.     ECHO +======================================================================+
  146.     ECHO I                        BootShield Installation                       I
  147.     ECHO +----------------------------------------------------------------------+
  148.     ECHO I                                                                      I
  149.     ECHO I WARNING:  BootShield replaces critical system startup areas, such as I
  150.     ECHO I the Master Boot Record, which may affect your computer's normal      I
  151.     ECHO I operation.  While BootShield is an effective boot virus deterent, if I
  152.     ECHO I installed and operated improperly, BootShield may significantly      I
  153.     ECHO I corrupt system data.                                                 I
  154.     ECHO I                                                                      I
  155.     ECHO I YOU MUST READ AND UNDERSTAND THE USER MANUAL BEFORE INSTALLING!      I
  156.     ECHO I                                                                      I
  157.     ECHO I Failure to do so may result in serious loss of data.  If you         I
  158.     ECHO I frequently modify your system boot area, such as changing operating  I
  159.     ECHO I systems, adding or removing partitions, or using sector editors to   I
  160.     ECHO I directly access the drive, you will have to uninstall BootShield     I
  161.     ECHO I often.  It is also suggested to frequently utilize ImageStor or your I
  162.     ECHO I favorite backup utility as a disaster recovery method.  Once again,  I
  163.     ECHO I if you are unsure about any of the above requirements, we suggest    I
  164.     ECHO I that you delay your installation.                                    I
  165.     ECHO I                                                                      I
  166.     ECHO +----------------------------------------------------------------------+
  167.     ECHO.
  168.     %1\GETREPLY.EXE Do you wish to install BootShield now (Y/N)? ;yn
  169.     ECHO.
  170.     IF ERRORLEVEL 2 GOTO Aborted
  171.     IF ERRORLEVEL 1 GOTO UpgradeWarning
  172.     GOTO Abend
  173. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  174. :: Warn user to uninstall a previous version before upgrading.             ::
  175. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  176.   :UpgradeWarning
  177.     IF "%3" == "DEBUG"  PAUSE
  178.     IF "%3" == "DEBUG2" PAUSE
  179.     CLS
  180.     ECHO +======================================================================+
  181.     ECHO I                        BootShield Installation                       I
  182.     ECHO +----------------------------------------------------------------------+
  183.     ECHO I                                                                      I
  184.     ECHO I If this installation of BootLock is an upgrade (eg., from evaluation I
  185.     ECHO I to license version or, from license to evaluation version), you must I
  186.     ECHO I use the PREVIOUS version to uninstall BootLock before installing the I
  187.     ECHO I upgrade.                                                             I
  188.     ECHO I                                                                      I
  189.     ECHO I If you are upgrading BootLock and have not uninstalled with your     I
  190.     ECHO I previous version, you need to abort this installation and uninstall  I
  191.     ECHO I before continuing.                                                   I
  192.     ECHO I                                                                      I
  193.     ECHO +----------------------------------------------------------------------+
  194.     ECHO.
  195.     %1\GETREPLY.EXE Do you wish to continue installing BootShield (Y/N)? ;yn
  196.     ECHO.
  197.     IF ERRORLEVEL 2 GOTO Aborted
  198.     IF ERRORLEVEL 1 GOTO ScanHD
  199.     GOTO Abend
  200. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  201. :: Verify memory and system area of C: drive are virus-free.               ::
  202. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  203.   :ScanHD
  204.     IF "%3" == "DEBUG"  PAUSE
  205.     IF "%3" == "DEBUG2" PAUSE
  206.     CLS
  207.     ECHO +======================================================================+
  208.     ECHO I                        BootShield Installation                       I
  209.     ECHO +----------------------------------------------------------------------+
  210.     ECHO I                                                                      I
  211.     ECHO I BootShield installation will now check your memory and the system    I
  212.     ECHO I area of your C: drive for viruses.                                   I
  213.     ECHO I                                                                      I
  214.     ECHO +----------------------------------------------------------------------+
  215.     ECHO.
  216.     %1\SCAN C: /BOOT /NOBREAK /PAUSE
  217.     IF NOT ERRORLEVEL 1 GOTO DirSetup
  218.     ECHO.
  219.     ECHO +----------------------------------------------------------------------+
  220.     ECHO I                                                                      I
  221.     ECHO I An error has occured while scanning your system for viruses!         I
  222.     ECHO I                                                                      I
  223.     ECHO +----------------------------------------------------------------------+
  224.     ECHO.
  225.     GOTO Aborted
  226. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  227. :: Create target directory.  If directory cannot be created, offer using   ::
  228. :: default instead.                                                        ::
  229. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  230.   :DirSetup
  231.     IF NOT "%2" == "C:\McAfee\BShield" GOTO CreateDir
  232.     IF NOT EXIST C:\MCAFEE\CON MD C:\McAfee
  233.   :CreateDir
  234.     IF NOT EXIST %2\CON MD %2
  235.     IF NOT EXIST %2\CON GOTO TryDefaultDir
  236.     GOTO CopyFiles
  237.   :TryDefaultDir
  238.     IF "%3" == "DEBUG"  PAUSE
  239.     IF "%3" == "DEBUG2" PAUSE
  240.     CLS
  241.     ECHO +======================================================================+
  242.     ECHO I                    BootShield Installation Error!                    I
  243.     ECHO +----------------------------------------------------------------------+
  244.     ECHO I                                                                      I
  245.     ECHO I Unable to create the specified target directory.  Either you have    I
  246.     ECHO I insufficient rights or disk space, the target's parent directory     I
  247.     ECHO I does not exist, or the target directory name is invalid.             I
  248.     ECHO I                                                                      I
  249.     ECHO I It is recommended that you attempt to install BootShield to the      I
  250.     ECHO I default directory of C:\McAfee\BShield.                              I
  251.     ECHO I                                                                      I
  252.     ECHO +----------------------------------------------------------------------+
  253.     ECHO.
  254.     %1\GETREPLY.EXE Do you want to use default directory (Y/N) ;yn
  255.     ECHO.
  256.     IF ERRORLEVEL 2 GOTO Aborted
  257.     IF ERRORLEVEL 1 GOTO UseDefaultDir
  258.     GOTO Abend
  259.   :UseDefaultDir
  260.     if "%3" == "DEBUG"  %1\INSTALL.BAT %1 C:\McAfee\BShield DEBUG  DirSetup
  261.     if "%3" == "DEBUG2" %1\INSTALL.BAT %1 C:\McAfee\BShield DEBUG2 DirSetup
  262.                         %1\INSTALL.BAT %1 C:\McAfee\BShield GOTO   DirSetup
  263.     GOTO Abend
  264. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  265. :: Copy files from source to target directory                              ::
  266. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  267.   :CopyFiles
  268.     IF "%3" == "DEBUG"  PAUSE
  269.     IF "%3" == "DEBUG2" PAUSE
  270.     CLS
  271.     ECHO +======================================================================+
  272.     ECHO I                        BootShield Installation                       I
  273.     ECHO +----------------------------------------------------------------------+
  274.     ECHO I                                                                      I
  275.     ECHO I BootShield installation will now copy all of the files from the      I
  276.     ECHO I source to the target directory.                                      I
  277.     ECHO I                                                                      I
  278.     ECHO +----------------------------------------------------------------------+
  279.     ECHO. 
  280.     COPY /V %1\*.* %2
  281.     ECHO ;BootShield files... >> %2\DRIVER.LST
  282.     ECHO COPY %2\BSSETUP.EXE %%c: >> %2\DRIVER.LST
  283.     ECHO COPY %2\BSSETUP.INI %%c: >> %2\DRIVER.LST
  284.     ECHO COPY %2\BSSHELP.HLP %%c: >> %2\DRIVER.LST
  285.     COPY /V %2\BSSETUP.IN1 %2\BSSETUP.INI
  286.     ECHO %2 >> %2\BSSETUP.INI
  287.     COPY /V %2\BSSETUP.INI + BSSETUP.IN2 %2\BSSETUP.INI
  288.     GOTO DestPackingCheck
  289. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  290. :: Make sure all files in the packing list were copied to the hard drive.  ::
  291. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  292.   :DestPackingCheck
  293.     %1\SELFCHEK.EXE %2\PACKING.LST Directory of /were validated
  294.     IF ERRORLEVEL 1 GOTO CopyError
  295.     if "%3" == "DEBUG"  %2\INSTALL.BAT %2 %2 DEBUG  RunFromHD
  296.     if "%3" == "DEBUG2" %2\INSTALL.BAT %2 %2 DEBUG2 RunFromHD
  297.                         %2\INSTALL.BAT %2 %2 GOTO   RunFromHD
  298.     GOTO Abend
  299. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  300. :: Display message about error while copying files.                        ::
  301. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  302.   :CopyError
  303.     ECHO.
  304.     ECHO +----------------------------------------------------------------------+
  305.     ECHO I                                                                      I
  306.     ECHO I An error has occured while copying files!  One or more files are     I
  307.     ECHO I missing.                                                             I
  308.     ECHO I                                                                      I
  309.     ECHO +----------------------------------------------------------------------+
  310.     ECHO.
  311.     GOTO Aborted
  312. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  313. :: Ensure C: is current drive and change to target directory.              ::
  314. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  315.   :RUNFROMHD
  316.   :RunFromHD
  317.     C:
  318.     CD %2
  319.     GOTO InsertDisk
  320. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  321. :: Instruct user to insert a pre-formatted, empty diskette into A: drive.  ::
  322. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  323.   :InsertDisk
  324.     IF "%3" == "DEBUG"  PAUSE
  325.     IF "%3" == "DEBUG2" PAUSE
  326.     CLS
  327.     ECHO +======================================================================+
  328.     ECHO I                        BootShield Installation                       I
  329.     ECHO +----------------------------------------------------------------------+
  330.     ECHO I                                                                      I
  331.     ECHO I BootShield installation will now setup a clean boot disk.  Please    I
  332.     ECHO I place a pre-formatted, empty diskette into the A: drive.             I
  333.     ECHO I                                                                      I
  334.     ECHO +----------------------------------------------------------------------+
  335.     ECHO.
  336.     %2\GETREPLY.EXE Press 'C' to continue when ready or 'A' to abort installation. ;ca
  337.     ECHO.
  338.     IF ERRORLEVEL 2 GOTO Aborted
  339.     IF ERRORLEVEL 1 GOTO AskImage
  340.     GOTO Abend
  341. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  342. :: Ask user if ImageStor should make a backup.                             ::
  343. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  344.   :AskImage
  345.     ECHO.
  346.     %2\GETREPLY.EXE Would you like ImageStor to backup your hard drive before proceeding (Y/N)? ;yn
  347.     ECHO.
  348.     IF ERRORLEVEL 2 GOTO SysDrive
  349.     IF ERRORLEVEL 1 GOTO ImageBoot
  350.     GOTO Abend
  351. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  352. :: Create an ImageStor boot disk.                                          ::
  353. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  354.   :ImageBoot
  355.     %2\ISBOOT.EXE
  356.     IF NOT ERRORLEVEL 1 GOTO RunIsEng
  357.     ECHO.
  358.     ECHO +----------------------------------------------------------------------+
  359.     ECHO I                                                                      I
  360.     ECHO I An error occurred while ImageStor was creating a bootable diskette.  I
  361.     ECHO I                                                                      I
  362.     ECHO +----------------------------------------------------------------------+
  363.     ECHO.
  364.     %2\GETREPLY.EXE Please press 'R' to retry or 'A' to abort installation. ;ra
  365.     ECHO.
  366.     IF ERRORLEVEL 2 GOTO Aborted
  367.     IF ERRORLEVEL 1 GOTO ISRetry
  368.     GOTO Abend
  369. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  370. :: Retry creating boot disk on failure.                                    ::
  371. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  372.   :ISRetry
  373.     IF "%3" == "DEBUG"  PAUSE
  374.     IF "%3" == "DEBUG2" PAUSE
  375.     CLS
  376.     ECHO +======================================================================+
  377.     ECHO I                        BootShield Installation                       I
  378.     ECHO +----------------------------------------------------------------------+
  379.     ECHO I                                                                      I
  380.     ECHO I BootShield installation will now attempt to retry making a clean     I
  381.     ECHO I boot disk.  Please place another pre-formatted, empty diskette into  I
  382.     ECHO I the A: drive.                                                        I
  383.     ECHO I                                                                      I
  384.     ECHO +----------------------------------------------------------------------+
  385.     ECHO.
  386.     %2\GETREPLY.EXE Press 'C' to continue when ready or 'A' to abort installation. ;ca
  387.     ECHO.
  388.     IF ERRORLEVEL 2 GOTO Aborted
  389.     IF ERRORLEVEL 1 GOTO ImageBoot
  390.     GOTO Abend
  391. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  392. :: Run the ImageStor backup engine.                                        ::
  393. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  394.   :RunIsEng
  395.     ECHO.
  396.     %2\SETUPENG.EXE %2\ISENG.EXE
  397.     ECHO.
  398.     IF ERRORLEVEL 1 GOTO IsEngError
  399.     CALL %2\SETUPENG.BAT
  400.     IF EXIST %2\SETUPENG.BAT DEL %2\SETUPENG.BAT
  401.     IF EXIST %2\ZERO.BYT     DEL %2\ZERO.BYT
  402.     IF NOT EXIST %2\SETUPENG.FLG GOTO SetUpBS
  403.     GOTO IsEngError
  404. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  405. :: Inform user of error while ImageStor was running and offer to retry.    ::
  406. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  407.   :IsEngError
  408.     DEL %2\SETUPENG.FLG
  409.     ECHO +----------------------------------------------------------------------+
  410.     ECHO I                                                                      I
  411.     ECHO I An error occurred while IMAGESTOR was backing up your hard drive or, I
  412.     ECHO I you terminated IMAGESTOR by pressing 'Ctrl-C'.                       I
  413.     ECHO I                                                                      I
  414.     ECHO +----------------------------------------------------------------------+
  415.     ECHO.
  416.     %2\GETREPLY.EXE Please press 'R' to retry, 'S' to skip backup, or 'A' to abort installation. ;rsa
  417.     ECHO.
  418.     IF ERRORLEVEL 3 GOTO Aborted
  419.     IF ERRORLEVEL 2 GOTO SetUpBS
  420.     IF ERRORLEVEL 1 GOTO RunISEng
  421.     GOTO Abend
  422. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  423. :: Backup not performed so create a bootable floppy for BSSETUP to access. ::
  424. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  425.   :SysDrive
  426.     ECHO.
  427.     ECHO +----------------------------------------------------------------------+
  428.     ECHO I                                                                      I
  429.     ECHO I Transferring system files to the A: drive.                           I
  430.     ECHO I                                                                      I
  431.     ECHO +----------------------------------------------------------------------+
  432.     ECHO.
  433.     SYS A:
  434.     IF NOT ERRORLEVEL 1 GOTO CopyBootLock
  435.     ECHO.
  436.     ECHO +----------------------------------------------------------------------+
  437.     ECHO I                                                                      I
  438.     ECHO I An error occurred while SYS was creating a bootable diskette.        I
  439.     ECHO I                                                                      I
  440.     ECHO +----------------------------------------------------------------------+
  441.     ECHO.
  442.     %2\GETREPLY.EXE Please press 'R' to retry or 'A' to abort installation. ;ra
  443.     ECHO.
  444.     IF ERRORLEVEL 2 GOTO SysDriveErr
  445.     IF ERRORLEVEL 1 GOTO SysRetry
  446.     GOTO Abend
  447. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  448. :: Prompt user to insert another floppy diskette is SYS fails.             ::
  449. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  450.   :SysRetry
  451.     ECHO.
  452.     ECHO +----------------------------------------------------------------------+
  453.     ECHO I                                                                      I
  454.     ECHO I Place another pre-formatted, empty diskette into the A: drive.       I
  455.     ECHO I                                                                      I
  456.     ECHO +----------------------------------------------------------------------+
  457.     ECHO.
  458.     %2\GETREPLY.EXE Press 'C' to continue when ready or 'A' to abort installation. ;ca
  459.     ECHO.
  460.     IF ERRORLEVEL 2 GOTO Aborted
  461.     IF ERRORLEVEL 1 GOTO SysDrive
  462.     GOTO Abend
  463. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  464. :: Detail possible causes of errors during system transfer.                ::
  465. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  466.   :SysDriveErr
  467.     ECHO.
  468.     ECHO +----------------------------------------------------------------------+
  469.     ECHO I                                                                      I
  470.     ECHO I An error occurred while transferring system files to the A: drive.   I
  471.     ECHO I Either SYS.COM could not be found or the SYS command was             I
  472.     ECHO I unsuccessful.  Consult your DOS manual for assistance.               I
  473.     ECHO I                                                                      I
  474.     ECHO +----------------------------------------------------------------------+
  475.     ECHO.
  476.     GOTO Aborted
  477. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  478. :: Backup not performed so transfer BootLock files to system floppy.       ::
  479. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  480.   :CopyBootLock
  481.     ECHO.
  482.     ECHO +----------------------------------------------------------------------+
  483.     ECHO I                                                                      I
  484.     ECHO I Transferring BootLock setup files to the A: drive.                   I
  485.     ECHO I                                                                      I
  486.     ECHO +----------------------------------------------------------------------+
  487.     ECHO.
  488.     COPY %2\BSSETUP.EXE /V A:
  489.     COPY %2\BSSETUP.INI /V A:
  490.     COPY %2\BSSHELP.HLP /V A:
  491.     IF NOT EXIST A:\BSSETUP.EXE GOTO CopyBootLockError
  492.     IF NOT EXIST A:\BSSETUP.INI GOTO CopyBootLockError
  493.     IF NOT EXIST A:\BSSHELP.HLP GOTO CopyBootLockError
  494.     GOTO SetUpBS
  495.   :CopyBootLockError
  496.     ECHO.
  497.     ECHO +----------------------------------------------------------------------+
  498.     ECHO I                                                                      I
  499.     ECHO I An error occurred while copying BootLock files to the A: drive.  One I
  500.     ECHO I or more files failed to transfer properly.  Please verify the media  I
  501.     ECHO I in the A: drive and try again.                                       I
  502.     ECHO I                                                                      I
  503.     ECHO +----------------------------------------------------------------------+
  504.     ECHO.
  505.     %2\GETREPLY.EXE Please press 'R' to retry or 'A' to abort installation. ;ra
  506.     ECHO.
  507.     IF ERRORLEVEL 2 GOTO Aborted
  508.     IF ERRORLEVEL 1 GOTO SysRetry
  509.     GOTO Abend
  510. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  511. :: Run the BSSETUP utility to install BootLock to the hard drive.          ::
  512. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  513.   :SetUpBS
  514.     IF "%3" == "DEBUG"  PAUSE
  515.     IF "%3" == "DEBUG2" PAUSE
  516.     CLS
  517.     ECHO +======================================================================+
  518.     ECHO I                        BootShield Installation                       I
  519.     ECHO +----------------------------------------------------------------------+
  520.     ECHO I                                                                      I
  521.     ECHO I BootShield installation is about to run the BootLock setup program.  I
  522.     ECHO I                                                                      I
  523.     ECHO I Please leave the diskette in the A: drive until you are instructed   I
  524.     ECHO I to remove it.  This disk is needed to store important recovery       I
  525.     ECHO I information.  Once the installation is complete, be sure to label    I
  526.     ECHO I this disk "BootLock Recovery Diskette" and place it in a safe place. I
  527.     ECHO I                                                                      I
  528.     ECHO +----------------------------------------------------------------------+
  529.     PAUSE
  530.     %2\BSSETUP.EXE
  531.     ECHO +======================================================================+
  532.     ECHO I                        BootShield Installation                       I
  533.     ECHO +----------------------------------------------------------------------+
  534.     ECHO I                                                                      I
  535.     ECHO I BootLock implantation bypassed.  BootShield will be unable to        I
  536.     ECHO I protect this computer from virus attacks.                            I
  537.     ECHO I                                                                      I
  538.     ECHO +----------------------------------------------------------------------+
  539.     ECHO.
  540.     GOTO Aborted
  541. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  542. :: Display error message if install terminates inappropriately.            ::
  543. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  544.   :Abend
  545.     ECHO Abnormal Installation failure.
  546. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  547. :: Display error message if install is terminated.                         ::
  548. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  549.   :Aborted
  550.     ECHO Installation Aborted!
  551. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  552. :: End INSTALL.BAT file.                                                   ::
  553. :::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::::
  554.   :Finished
  555.     ECHO.
  556.  
  557.