home *** CD-ROM | disk | FTP | other *** search
/ Mega A/V / mega_av.zip / mega_av / GRAPHUTL / POVSCN.ZIP / LEVEL3.ZIP / CHESS.POV < prev    next >
Text File  |  1992-07-03  |  15KB  |  701 lines
  1. // Persistence Of Vision raytracer version 1.0 sample file.
  2.  
  3. // By Ville Saari
  4. // Copyright (c) 1991 Ferry Island Pixelboys
  5.  
  6. /*
  7. *
  8. * POV-Ray scene description for chess board.
  9. * 
  10. * Created: 01-Feb-91
  11. * Updated: 02-Mar-91
  12. *
  13. * This scene has 430 primitives in objects and 41 in bounding shapes and
  14. * it takes over 40 hours to render by standard amiga.
  15. *
  16. * If you do some nice modifications or additions to this file, please send 
  17. * me a copy. My Internet address is:
  18. *
  19. *         vsaari@niksula.hut.fi
  20. */
  21.  
  22. #include "shapes.inc"
  23. #include "colors.inc"
  24. #include "textures.inc"
  25.  
  26. camera {
  27.    location <59 20 -48>
  28.    direction <0 0 1>
  29.    up <0 1 0>
  30.    right <1.33 0 0>
  31.    look_at <0 0 1>
  32. }
  33.  
  34. object {
  35.    light_source { <800 600 -200>
  36.       colour White
  37.    }
  38. }
  39.  
  40. #declare Pawn = union {
  41.    sphere { <0 7 0> 1.5 }
  42.  
  43.    quadric { Ellipsoid 
  44.       scale <1.2 0.3 1.2>
  45.       translate <0 5.5 0>
  46.    }
  47.  
  48.    intersection {
  49.       plane { <0 1 0> 5.5 }
  50.       quadric { Hyperboloid_Y
  51.          translate <0 5 0>
  52.          scale <0.5 1 0.5>
  53.       }
  54.       plane { <0 -1 0> -2.5 }
  55.    }
  56.  
  57.    quadric { Ellipsoid 
  58.       scale <2 0.5 2>
  59.       translate <0 2.3 0>
  60.    }
  61.  
  62.    intersection {
  63.       sphere { <0 0 0> 2.5 }
  64.       plane { <0 -1 0> 0 }
  65.    }
  66. }
  67.  
  68. #declare Rook = union {
  69.    intersection {
  70.       union {
  71.          plane { < 1 0 0> -0.5 }
  72.          plane { <-1 0 0> -0.5 }
  73.          plane { < 0 1 0>  9   }
  74.       }
  75.  
  76.       union {
  77.          plane { <0 0  1> -0.5 }
  78.          plane { <0 0 -1> -0.5 }
  79.          plane { <0 1  0>  9   }
  80.       }
  81.  
  82.       plane { <0 1 0> 10 }
  83.       quadric { Cylinder_Y scale <2 1 2> }
  84.       quadric { Cylinder_Y scale <1.2 1 1.2> inverse }
  85.       plane { <0 -1 0> -8 }
  86.    }
  87.  
  88.    intersection {
  89.       plane { <0 1 0> 8 }
  90.       quadric { Hyperboloid_Y
  91.          scale <1 1.5 1>
  92.          translate <0 5.401924 0>
  93.       }
  94.       plane { <0 -1 0> -3 }
  95.    }
  96.  
  97.    quadric { Ellipsoid 
  98.       scale <2.5 0.5 2.5>
  99.       translate <0 2.8 0>
  100.    }
  101.  
  102.    intersection {
  103.       sphere { <0 0 0> 3 }
  104.       plane { <0 -1 0> 0 }
  105.    }
  106. }
  107.  
  108. #declare Knight = union {
  109.    intersection {
  110.       quadric { Cylinder_Z
  111.          scale <17.875 17.875 1>
  112.          translate <-18.625 7 0>
  113.          inverse
  114.       }
  115.  
  116.       quadric { Cylinder_Z
  117.          scale <17.875 17.875 1>
  118.          translate <18.625 7 0>
  119.          inverse
  120.       }
  121.  
  122.       quadric { Cylinder_X
  123.          scale <1 5.1 5.1>
  124.          translate <0 11.2 -5>
  125.          inverse
  126.       }
  127.  
  128.       union {
  129.          plane { <0 1 0> 0
  130.             rotate <30 0 0>
  131.             translate <0 9.15 0>
  132.          }
  133.          plane { <0 0 1> 0
  134.             rotate <-20 0 0>
  135.             translate <0 10 0>
  136.          }
  137.       }
  138.  
  139.       union {
  140.          plane { <0 -1 0> 0
  141.             rotate <30 0 0>
  142.             translate <0 7.15 0>
  143.          }
  144.          plane { <0 1 0> 0
  145.             rotate <60 0 0>
  146.             translate <0 7.3 0>
  147.          }
  148.       }
  149.  
  150.       union {
  151.          plane { <0 1 0> 0
  152.             rotate <0 0 -45>
  153.          }
  154.          plane { <0 1 0> 0
  155.             rotate <0 0 45>
  156.          }
  157.          translate <0 9 0>
  158.       }
  159.  
  160.       quadric { Cylinder_Y scale <2 1 2> }
  161.       sphere { <0 7 0> 4 }
  162.    }
  163.  
  164.    quadric { Ellipsoid 
  165.       scale <2.5 0.5 2.5>
  166.       translate <0 2.8 0>
  167.    }
  168.  
  169.    intersection {
  170.       sphere { <0 0 0> 3 }
  171.       plane { <0 -1 0> 0 }
  172.    }
  173. }
  174.  
  175. #declare Bishop = union {
  176.    sphere { <0 10.8 0> 0.4 }
  177.  
  178.    intersection {
  179.       union {
  180.          plane { <0 0 -1> -0.25 }
  181.          plane { <0 0  1> -0.25 }
  182.          plane { <0 1  0>  0    }
  183.          rotate <30 0 0>
  184.          translate <0 8.5 0>
  185.       }
  186.  
  187.       quadric { Ellipsoid 
  188.          scale <1.4 2.1 1.4>
  189.          translate <0 8.4 0>
  190.       }
  191.  
  192.       plane { <0 -1 0> -7 }
  193.    }
  194.  
  195.    quadric { Ellipsoid 
  196.       scale <1.5 0.4 1.5>
  197.       translate <0 7 0>
  198.    }
  199.  
  200.    intersection {
  201.       plane { <0 1 0> 7 }
  202.       quadric { Hyperboloid_Y
  203.          scale <0.6 1.4 0.6>
  204.          translate <0 7 0>
  205.       }
  206.       plane { <0 -1 0> -3 }
  207.    }
  208.  
  209.    quadric { Ellipsoid 
  210.       scale <2.5 0.5 2.5>
  211.       translate <0 2.8 0>
  212.    }
  213.  
  214.    intersection {
  215.       sphere { <0 0 0> 3 }
  216.       plane { <0 -1 0> 0 }
  217.    }
  218. }
  219.  
  220. #declare QueenAndKing = union {
  221.    sphere { <0 10.5 0> 1.5 }
  222.  
  223.    intersection {
  224.       union {
  225.          sphere { <1.75 12 0> 0.9 rotate <0 150 0> }
  226.          sphere { <1.75 12 0> 0.9 rotate <0 120 0> }
  227.          sphere { <1.75 12 0> 0.9 rotate <0  90 0> }
  228.          sphere { <1.75 12 0> 0.9 rotate <0  60 0> }
  229.          sphere { <1.75 12 0> 0.9 rotate <0  30 0> }
  230.          sphere { <1.75 12 0> 0.9                   }
  231.          sphere { <1.75 12 0> 0.9 rotate <0  -30 0> }
  232.          sphere { <1.75 12 0> 0.9 rotate <0  -60 0> }
  233.          sphere { <1.75 12 0> 0.9 rotate <0  -90 0> }
  234.          sphere { <1.75 12 0> 0.9 rotate <0 -120 0> }
  235.          sphere { <1.75 12 0> 0.9 rotate <0 -150 0> }
  236.          sphere { <1.75 12 0> 0.9 rotate <0 180 0> }
  237.          inverse
  238.       }
  239.  
  240.       plane { <0 1 0> 11.5 }
  241.  
  242.       quadric { QCone_Y
  243.          scale <1 3 1>
  244.          translate <0 5 0>
  245.       }
  246.  
  247.       plane { <0 -1 0> -8 }
  248.    }
  249.  
  250.    quadric { Ellipsoid 
  251.       scale <1.8 0.4 1.8>
  252.       translate <0 8 0>
  253.    }
  254.  
  255.    intersection {
  256.       plane { <0 1 0> 8 }
  257.       quadric { Hyperboloid_Y
  258.          scale <0.7 1.6 0.7>
  259.          translate <0 7 0>
  260.       }
  261.       plane { <0 -1 0> -3 }
  262.    }
  263.  
  264.    quadric { Ellipsoid 
  265.       scale <2.5 0.5 2.5>
  266.       translate <0 2.8 0>
  267.    }
  268.  
  269.    intersection {
  270.       sphere { <0 0 0> 3 }
  271.       plane { <0 -1 0> 0 }
  272.    }
  273. }
  274.  
  275. #declare Queen = union {
  276.    sphere { <0 12.3 0> 0.4 }
  277.    union { QueenAndKing }
  278. }
  279.  
  280. #declare King = union {
  281.    intersection {
  282.       union {
  283.          intersection {
  284.             plane { <0  1 0>  13 }
  285.             plane { <0 -1 0> -12.5 }
  286.          }
  287.  
  288.          intersection {
  289.             plane { < 1 0 0> 0.25 }
  290.             plane { <-1 0 0> 0.25 }
  291.          }
  292.       }
  293.  
  294.       plane { < 0  0  1>   0.25 }
  295.       plane { < 0  0 -1>   0.25 }
  296.       plane { < 1  0  0>   0.75 }
  297.       plane { <-1  0  0>   0.75 }
  298.       plane { < 0  1  0>  13.5  }
  299.       plane { < 0 -1  0> -11.5  }
  300.    }
  301.  
  302.    union { QueenAndKing }
  303. }
  304.  
  305. #declare WWood = texture {
  306.    wood
  307.    turbulence 0.1
  308.    colour_map {
  309.       [ 0.0 0.35 colour red 0.7  green 0.4
  310.       colour red 0.7  green 0.4  ]
  311.       [ 0.35 1.0 colour red 0.95 green 0.62
  312.       colour red 0.95 green 0.62 ]
  313.    }
  314.    scale <0.6 1000.0 0.6>
  315.    translate <200.0 0.0 100.0>
  316.    specular 1
  317.    roughness 0.02
  318. }
  319.  
  320. #declare BWood = texture {
  321.    wood
  322.    turbulence 0.1
  323.    colour_map {
  324.       [ 0.0 0.55 colour red 0.45 green 0.25
  325.       colour red 0.45 green 0.25 ]
  326.       [ 0.55 1.0 colour red 0.30 green 0.16
  327.       colour red 0.30 green 0.16 ]
  328.    }
  329.    scale <0.6 1000.0 0.6>
  330.    translate <100.0 0.0 -200.0>
  331.    specular 1
  332.    roughness 0.02
  333. }
  334.  
  335. #declare WPawn = object {
  336.    union { Pawn }
  337.  
  338.    bounded_by {
  339.       sphere { <0 4 0> 4.72 }
  340.    }
  341.  
  342.    texture { WWood }
  343.    colour red 0.95 green 0.62
  344. }
  345.  
  346. #declare BPawn = object {
  347.    union { Pawn }
  348.  
  349.    bounded_by {
  350.       sphere { <0 4 0> 4.72 }
  351.    }
  352.  
  353.    texture { BWood }
  354.    colour red 0.4 green 0.2
  355. }
  356.  
  357. #declare WRook = object {
  358.    union { Rook }
  359.  
  360.    bounded_by {
  361.       sphere { <0 5 0> 5.831 }
  362.    }
  363.  
  364.    texture { WWood }
  365.    colour red 0.95 green 0.62
  366. }
  367.  
  368. #declare BRook = object {
  369.    union { Rook }
  370.  
  371.    bounded_by {
  372.       sphere { <0 5 0> 5.831 }
  373.    }
  374.  
  375.    texture { BWood }
  376.    colour red 0.4 green 0.2
  377. }
  378.  
  379. #declare WKnight = object {
  380.    union { Knight }
  381.  
  382.    bounded_by {
  383.       sphere { <0 5 0> 5.831 }
  384.    }
  385.  
  386.    texture { WWood }
  387.    colour red 0.95 green 0.62
  388. }
  389.  
  390. #declare BKnight = object {
  391.    union { Knight }
  392.    rotate <0 180 0>
  393.  
  394.    bounded_by {
  395.       sphere { <0 5 0> 5.831 }
  396.    }
  397.  
  398.    texture { BWood }
  399.    colour red 0.4 green 0.2
  400. }
  401.  
  402. #declare WBishop = object {
  403.    union { Bishop }
  404.  
  405.    bounded_by {
  406.       sphere { <0 5.5 0> 6.265 }
  407.    }
  408.  
  409.    texture { WWood }
  410.    colour red 0.95 green 0.62
  411. }
  412.  
  413. #declare BBishop = object {
  414.    union { Bishop }
  415.    rotate <0 180 0>
  416.  
  417.    bounded_by {
  418.       sphere { <0 5.5 0> 6.265 }
  419.    }
  420.  
  421.    texture { BWood }
  422.    colour red 0.4 green 0.2
  423. }
  424.  
  425. #declare WQueen = object {
  426.    union { Queen }
  427.  
  428.    bounded_by {
  429.       intersection {
  430.          sphere { <0 6 0> 6.71 }
  431.          quadric { Cylinder_Y scale <3 1 3> }
  432.       }
  433.    }
  434.  
  435.    texture { WWood }
  436.    colour red 0.95 green 0.62
  437. }
  438.  
  439. #declare BQueen = object {
  440.    union { Queen }
  441.  
  442.    bounded_by {
  443.       intersection {
  444.          sphere { <0 6 0> 6.71 }
  445.          quadric { Cylinder_Y scale <3 1 3> }
  446.       }
  447.    }
  448.  
  449.    texture { BWood }
  450.    colour red 0.4 green 0.2
  451. }
  452.  
  453. #declare WKing = object {
  454.    union { King }
  455.  
  456.    bounded_by {
  457.       intersection {
  458.          sphere { <0 6.5 0> 7.16 }
  459.          quadric { Cylinder_Y scale <3 1 3> }
  460.       }
  461.    }
  462.  
  463.    texture { WWood }
  464.    colour red 0.95 green 0.62
  465. }
  466.  
  467. #declare BKing = object {
  468.    union { King }
  469.  
  470.    bounded_by {
  471.       intersection {
  472.          sphere { <0 6.5 0> 7.16 }
  473.          quadric { Cylinder_Y scale <3 1 3> }
  474.       }
  475.    }
  476.  
  477.    texture { BWood }
  478.    colour red 0.4 green 0.2
  479. }
  480.  
  481. object { /* Sky */
  482.    sphere { <0 -39000 0> 40000 inverse }
  483.  
  484.    texture {
  485.       bozo
  486.       turbulence 0.6
  487.       colour_map {
  488.          [0 0.5 colour red 0.4 green 0.5 blue 1
  489.          colour red 0.4 green 0.5 blue 1.0]
  490.          [0.5 0.7 colour red 0.4 green 0.5 blue 1
  491.          colour red 1 green 1 blue 1.0]
  492.          [0.7 1 colour red 1 green 1 blue 1
  493.          colour red 0.7 green 0.7 blue 0.7]
  494.       }
  495.       scale <500 500 500>
  496.       ambient 1
  497.       diffuse 0
  498.    }
  499.  
  500.    colour red 0.4 green 0.5 blue 1
  501. }
  502.  
  503. object { /* Ground */
  504.    plane { <0 1 0> -80 }
  505.  
  506.    texture {
  507.       0.05
  508.       colour green 1
  509.       ambient 0.5
  510.       diffuse 0.5
  511.    }
  512.    colour green 1
  513. }
  514.  
  515. #declare Frame = intersection {
  516.    plane { < 0  1  0> -0.0001 }
  517.    plane { < 0 -1  0>  3 }
  518.    plane { < 0  0 -1> 35 }
  519.    plane { <-1  0  1>  0 }
  520.    plane { < 1  0  1>  0 }
  521. }
  522.  
  523. composite {
  524.    composite {
  525.       object {
  526.          union {
  527.             intersection { Frame }
  528.             intersection { Frame rotate <0 180 0> }
  529.          }
  530.  
  531.          texture {
  532.             wood
  533.             turbulence 0.3
  534.             scale <0.8 1000 0.8>
  535.             rotate <0 0 -88>
  536.             translate <200 40 -20>
  537.             specular 1
  538.             roughness 0.02
  539.          }
  540.  
  541.          colour red 0.5 green 0.25
  542.       }
  543.  
  544.       object {
  545.          union {
  546.             intersection { Frame rotate <0 -90 0> }
  547.             intersection { Frame rotate <0  90 0> }
  548.          }
  549.  
  550.          texture {
  551.             wood
  552.             turbulence 0.3
  553.             scale <0.8 1000 0.8>
  554.             rotate <-91 0 0>
  555.             translate <100 30 0>
  556.             specular 1
  557.             roughness 0.02
  558.          }
  559.  
  560.          colour red 0.5 green 0.25
  561.       }
  562.  
  563.       object { /* Board */
  564.          intersection {
  565.             plane { < 1  0  0> 32 }
  566.             plane { <-1  0  0> 32 }
  567.             plane { < 0  1  0>  0 }
  568.             plane { < 0 -1  0>  1 }
  569.             plane { < 0  0  1> 32 }
  570.             plane { < 0  0 -1> 32 }
  571.          }
  572.  
  573.          texture {
  574.             tiles {
  575.                texture {
  576.                   marble
  577.                   turbulence 1.0
  578.                   colour_map {
  579.                      [0.0 0.7 colour White
  580.                      colour White]
  581.                      [0.7 0.9 colour White
  582.                      colour red 0.8 green 0.8 blue 0.8]
  583.                      [0.9 1.0 colour red 0.8 green 0.8 blue 0.8
  584.                      colour red 0.5 green 0.5 blue 0.5]
  585.                   }
  586.                   scale <0.6 1 0.6>
  587.                   rotate <0 -30 0>
  588.                }
  589.                tile2
  590.                texture {
  591.                   granite
  592.                   scale <0.3 1 0.3>
  593.                   colour_map {
  594.                      [0 1 colour Black
  595.                      colour red 0.5 green 0.5 blue 0.5]
  596.                   }
  597.                }
  598.             }                        /* end_checker_texture */
  599.             scale <8 1 8>
  600.             specular 1
  601.             roughness 0.02
  602.             reflection 0.25
  603.          }
  604.  
  605.          colour red 0.63 green 0.52 blue 0.45
  606.       }
  607.  
  608.       object { /* Table */
  609.          union {
  610.             intersection {
  611.                plane {  <0  1 0> -3 }
  612.                plane {  <0 -1 0>  8 }
  613.                sphere { <0 -5.5 0> 55 }
  614.             }
  615.  
  616.             intersection {
  617.                plane { <0 1 0> -8 }
  618.                quadric { Hyperboloid_Y
  619.                   scale <10 20 10>
  620.                   translate <0 -20 0>
  621.                }
  622.             }
  623.          }
  624.  
  625.          texture { granite
  626.             scale <6 6 6>
  627.             specular 1
  628.             roughness 0.02
  629.             reflection 0.3
  630.          }
  631.  
  632.          colour red 0.5 green 0.5 blue 0.5
  633.       }
  634.  
  635.       bounded_by {
  636.          plane { <0 1 0> 0 }
  637.       }
  638.    }
  639.  
  640.    composite {
  641.       object { WPawn translate <-28 0 -20> }
  642.       object { WPawn translate <-20 0 -20> }
  643.       object { WPawn translate <-12 0 -20> }
  644.       object { WPawn translate < -4 0 -20> }
  645.       object { WPawn translate <  4 0 -20> }
  646.       object { WPawn translate < 12 0 -20> }
  647.       object { WPawn translate < 20 0 -20> }
  648.       object { WPawn translate < 28 0 -20> }
  649.  
  650.       object { WRook   translate <-28 0 -28> }
  651.       object { WKnight translate <-20 0 -28> }
  652.       object { WBishop translate <-12 0 -28> }
  653.       object { WQueen  translate < -4 0 -28> }
  654.       object { WKing   translate <  4 0 -28> }
  655.       object { WBishop translate < 12 0 -28> }
  656.       object { WKnight translate < 20 0 -28> }
  657.       object { WRook   translate < 28 0 -28> }
  658.  
  659.       bounded_by {
  660.          quadric { Cylinder_X
  661.             scale <1 9.56 9.56>
  662.             translate <0 6.5 -24>
  663.          }
  664.       }
  665.    }
  666.  
  667.    composite {
  668.       object { BPawn translate <-28 0 20> }
  669.       object { BPawn translate <-20 0 20> }
  670.       object { BPawn translate <-12 0 20> }
  671.       object { BPawn translate < -4 0 20> }
  672.       object { BPawn translate <  4 0 20> }
  673.       object { BPawn translate < 12 0 20> }
  674.       object { BPawn translate < 20 0 20> }
  675.       object { BPawn translate < 28 0 20> }
  676.  
  677.       object { BRook   translate <-28 0 28> }
  678.       object { BKnight translate <-20 0 28> }
  679.       object { BBishop translate <-12 0 28> }
  680.       object { BQueen  translate < -4 0 28> }
  681.       object { BKing   translate <  4 0 28> }
  682.       object { BBishop translate < 12 0 28> }
  683.       object { BKnight translate < 20 0 28> }
  684.       object { BRook   translate < 28 0 28> }
  685.  
  686.       bounded_by {
  687.          quadric { Cylinder_X
  688.             scale <1 9.56 9.56>
  689.             translate <0 6.5 24>
  690.          }
  691.       }
  692.    }
  693.  
  694.    bounded_by {
  695.       intersection {
  696.          plane { <0 1 0> 13.5 }
  697.          sphere { <0 -30 0> 63 }
  698.       }
  699.    }
  700. }
  701.