home *** CD-ROM | disk | FTP | other *** search
/ Meeting Pearls 3 / Meeting_Pearls_III.iso / SYS / Rexx / BatchConvert.isrx < prev    next >
Text File  |  1995-05-12  |  7KB  |  295 lines
  1. /* ImageStudio ARexx script **************************************/
  2.  
  3. /* Allow commands to return results */
  4.  
  5. options results
  6.  
  7. /* On error, goto ERROR:. Comment out this line if you wish to */
  8. /* perform your own error checking. */
  9.  
  10. signal on error
  11.  
  12. /* BEGIN PROGRAM *************************************************/
  13.  
  14. /* Warn the user if they are about to overwrite their current project */
  15.  
  16. IMAGEINFO_GET STEM imageinfo.
  17.  
  18. if imageinfo.changed == 1 then
  19.     REQUEST_MESSAGE TEXT '"Project has changed, continue?"',
  20.         BUTTONTEXT '"OK|Cancel"' AUTOCANCEL
  21.  
  22. /* Choose source files */
  23.  
  24. REQUEST_MULTIFILE TITLE '"Choose source files..."' STEM srcfiles.
  25.  
  26. /* Use separate destination directory ? */
  27.  
  28. REQUEST_MESSAGE TEXT '"Use different destination directory?"',
  29.     BUTTONTEXT '"Yes|No|Cancel"' AUTOCANCEL
  30.  
  31. if result == 1 then
  32.     REQUEST_DIR TITLE '"Choose destination directory..."' VAR destdir
  33. else
  34.     destdir = ':NONE:'
  35.  
  36. REQUEST_LIST TITLE '"Choose output format..."' STRINGS,
  37.     '"IFF-ILBM"',
  38.     '"BMP"',
  39.     '"EPS"',
  40.     '"GIF"',
  41.     '"JPEG"',
  42.     '"PCX"',
  43.     '"Targa"' STEM saveformat.
  44.  
  45. /* Set up a blank ARGS string, which we can add to */
  46.  
  47. saveargs = 'ARGS "'
  48.  
  49. /* Get any IFF-ILBM args ? */
  50.  
  51. if saveformat.string == 'IFF-ILBM' then do
  52.     /* Get a subformat */
  53.  
  54.     REQUEST_MESSAGE TEXT '"Choose ILBM format..."' BUTTONTEXT,
  55.         '"As buffer|HAM6|HAM8|EHB|Cancel"' AUTOCANCEL
  56.  
  57.     /* Store subformat */
  58.  
  59.     if result == 2 then
  60.         saveargs = saveargs||'SUBFORMAT HAM6'
  61.     else if result == 3 then
  62.         saveargs = saveargs||'SUBFORMAT HAM8'
  63.     else if result == 4 then
  64.         saveargs = saveargs||'SUBFORMAT EHB'
  65.  
  66.     /* Get the dither if not saving as buffer */
  67.  
  68.     if result ~= 1 then do
  69.         REQUEST_MESSAGE TEXT '"Choose ILBM dither..."' BUTTONTEXT,
  70.             '"None|Floyd-Steinberg|Cancel"' AUTOCANCEL
  71.  
  72.         /* Store the dither */
  73.  
  74.         if result == 2 then
  75.             saveargs = saveargs||' DITHER FS'
  76.  
  77.         end
  78.  
  79.     /* Ask whether should set screenmode of images */
  80.  
  81.     REQUEST_MESSAGE TEXT '"Set screenmode of images?"',
  82.         BUTTONTEXT '"Yes|No|Cancel"' AUTOCANCEL
  83.  
  84.     if result == 1 then do
  85.         setscreenmode = 1
  86.  
  87.         REQUEST_SCREENMODE STEM screenmode.
  88.  
  89.         imagescreenmode = screenmode.modeid
  90.  
  91.         end
  92.     else
  93.         setscreenmode = 0
  94.     end
  95. else if saveformat.string == 'EPS' then do
  96.     /* Get the DPI of the image */
  97.  
  98.     REQUEST_STRING TEXT1 '"Enter the DPI resolution of"',
  99.         TEXT2 '"the EPS files to be saved:"',
  100.         STRING 300 VAR dpiinfo
  101.  
  102.     saveargs = saveargs||dpiinfo
  103.  
  104.     /* Ask whether to save as colour or greyscale */
  105.  
  106.     REQUEST_MESSAGE TEXT '"Greyscale or colour EPS?"' BUTTONTEXT,
  107.         '"Greyscale|Colour|Cancel"' AUTOCANCEL
  108.  
  109.     if result == 2 then
  110.         saveargs = saveargs||' COLOUR'
  111.  
  112.     end
  113. else if saveformat.string == 'JPEG' then do
  114.     /* Get the DPI of the image */
  115.  
  116.     REQUEST_STRING TEXT1 '"Enter the JPEG quality setting"',
  117.         TEXT2 '"for the files to be saved."',
  118.         TEXT3 '"(Valid values 25 to 100):"',
  119.         STRING 75 VAR qualityinfo
  120.  
  121.     saveargs = saveargs||qualityinfo
  122.  
  123.     /* Ask whether to save as colour or greyscale */
  124.  
  125.     REQUEST_MESSAGE TEXT '"Greyscale or colour JPEG?"' BUTTONTEXT,
  126.         '"Greyscale|Colour|Cancel"' AUTOCANCEL
  127.  
  128.     if result == 1 then
  129.         saveargs = saveargs||' GREYSCALE'
  130.  
  131.     end
  132.  
  133. /* We may or may not have created an ARGS string. If we have, lets */
  134. /* finish it off, else lets delete it */
  135.  
  136. if saveargs == 'ARGS "' then
  137.     saveargs = ''
  138. else
  139.     saveargs = saveargs||'"'
  140.  
  141. /* Rename filenames ? */
  142.  
  143. REQUEST_MESSAGE TEXT '"Rename filenames ?"' BUTTONTEXT,
  144.     '"Yes|No|Cancel"' AUTOCANCEL
  145.  
  146. if result == 1 then do
  147.     /* Set the rename files */
  148.  
  149.     renamefiles = 1
  150.  
  151.     /* Get the rename pattern */
  152.  
  153.     REQUEST_STRING TEXT1 '"Choose the filename extension. For"',
  154.         TEXT2 '"example: . .ILBM would rename all"',
  155.         TEXT3 '"files to .ILBM, see docs for more info"',
  156.         STRING '". .'||saveformat.string||'"',
  157.         VAR renamestring
  158.     end
  159. else
  160.     renamefiles = 0
  161.  
  162. /* If we're renaming, we should ask if they want the source file */
  163. /* deleted. If we're not renaming, we should warn the user that */
  164. /* the source file will be overwritten. */
  165.  
  166. if renamefiles == 1 then do
  167.     REQUEST_MESSAGE TEXT '"Delete source files ?"',
  168.         BUTTONTEXT '"Yes|No|Cancel"' AUTOCANCEL
  169.  
  170.     if result == 1 then
  171.         deletesource = 1
  172.     else
  173.         deletesource = 0
  174.     end
  175. else if renamefiles == 0 & destdir == ':NONE:' then
  176.     REQUEST_MESSAGE TEXT '"WARNING : Source files will\nbe overwritten."',
  177.         BUTTONTEXT '"OK|Cancel"' AUTOCANCEL
  178.  
  179. /* Loop around and convert all the files */
  180.  
  181. do l = 0 to (srcfiles.files.count - 1)
  182.     /* Open the file */
  183.  
  184.     OPEN FILE '"'srcfiles.files.l'"' FORCE
  185.  
  186.     /* Set the screenmode if neccessary */
  187.  
  188.     if setscreenmode == 1 then
  189.         IMAGEINFO_SET MODEID imagescreenmode
  190.  
  191.     /* Create the output filename */
  192.  
  193.     if destdir ~= ':NONE:' then do
  194.         /* Get the filepart of the source filename */
  195.  
  196.         FILE_SPLIT FILE '"'srcfiles.files.l'"' STEM filesplit.
  197.  
  198.         /* Create the destfile */
  199.  
  200.         FILE_JOIN PATHPART '"'destdir'"',
  201.             FILEPART '"'filesplit.filepart'"' VAR 'destfile'
  202.  
  203.         end
  204.     else
  205.         destfile = srcfiles.files.l
  206.  
  207.     /* Rename file ? */
  208.  
  209.     if renamefiles == 1 then 
  210.         FILE_RENAME FILE '"'destfile'"' renamestring,
  211.             VAR 'destfile'
  212.  
  213.     /* Save the fileout in the new format */
  214.  
  215.     SAVE FILE '"'destfile'"' FORMAT '"'saveformat.string'"',
  216.         saveargs FORCE
  217.  
  218.     /* Delete source file (and icon) if required */
  219.  
  220.     if renamefiles == 1 & deletesource == 1 then do
  221.         /* Make sure hasn't been renamed to same name */
  222.  
  223.         if upper(srcfiles.files.l) == upper(destfile) then
  224.             break
  225.  
  226.         address command 'delete <NIL: >NIL: "'||srcfiles.files.l||'"'
  227.  
  228.         if exists(srcfiles.files.l||'.info') == 1 then
  229.             address command 'delete <NIL: >NIL: "'||,
  230.                 srcfiles.files.l||'.info"'
  231.         end
  232.     end
  233.  
  234.  
  235. /* END PROGRAM ***************************************************/
  236.  
  237. exit
  238.  
  239. /* On ERROR */
  240.  
  241. ERROR:
  242.  
  243. /* If we get here, either an error occurred with the command's */
  244. /* execution or there was an error with the command itself. */
  245. /* In the former case, rc2 contains the error message and in */
  246. /* the latter, rc2 contains an error number. SIGL contains */
  247. /* the line number of the command which caused the jump */
  248. /* to ERROR: */
  249.  
  250. if datatype(rc2,'NUMERIC') == 1 then do
  251.     /* See if we can describe the error with a string */
  252.  
  253.     select
  254.         when rc2 == 103 then
  255.             err_string = "ERROR 103, "||,
  256.                 "out of memory at line "||SIGL
  257.         when rc2 == 114 then
  258.             err_string = "ERROR 114, "||,
  259.                 "bad command template at line "||SIGL
  260.         when rc2 == 115 then
  261.             err_string = "ERROR 115, "||,
  262.                 "bad number for /N argument at line "||SIGL
  263.         when rc2 == 116 then
  264.             err_string = "ERROR 116, "||,
  265.                 "required argument missing at line "||SIGL
  266.         when rc2 == 117 then
  267.             err_string = "ERROR 117, "||,
  268.                 "value after keywork missing at line "||SIGL
  269.         when rc2 == 118 then
  270.             err_string = "ERROR 118, "||,
  271.                 "wrong number of arguments at line "||SIGL
  272.         when rc2 == 119 then
  273.             err_string = "ERROR 119, "||,
  274.                 "unmatched quotes at line "||SIGL
  275.         when rc2 == 120 then
  276.             err_string = "ERROR 120, "||,
  277.                 "line too long at line "||SIGL
  278.         when rc2 == 236 then
  279.             err_string = "ERROR 236, "||,
  280.                 "unknown command at line "||SIGL
  281.         otherwise
  282.             err_string = "ERROR "||rc2||", at line "||SIGL
  283.         end
  284.         end
  285. else if rc2 == 'RC2' then do
  286.     err_string = "ERROR in command at line "||SIGL
  287.     end
  288. else do
  289.         err_string = rc2||", line "||SIGL
  290.         end
  291.  
  292. request_message TEXT '"'err_string'"'
  293.  
  294. exit
  295.