Meeting Pearls 3/Meeting_Pearls_III.iso/Pearls/tcp/Networking/TCP/FTP/DaFTP/Install-DaFTP

Text File | 1995-02-09 | 4.2 KB | 175 lines

; $VER: Install_DaFTP 0.1 (1.2.94)
; Description: Installer script for DaFTP, a graphical FTP client

(complete 0)

(welcome "Welcome to the DaFTP installation utility.\n\n"
    "This script installs the selected DaFTP client based "
    "on your choice of TCP stacks.  It also installs any "
    "complimentary files you decide to use.\n\n"
)

(set daftp_dir
    (askdir
        (prompt "Where should we install the DaFTP client? (A drawer will NOT be created for you)")
        (help "This is where DaFTP and it's complimentary "
            "files will be copied."
        )
        (default @default-dest)
    )
)

(complete 10)

(set daftp_type
    (askchoice
        (prompt "Select which version of DaFTP you wish to install")
        (help "This will determine which protocol stack you "
            "wish to use with DaFTP."
        )
        (choices "AS225" "AmiTCP")
    )
)

(if (= daftp_type 0)
    (copyfiles
        (source "DaFTP_AS225")
        (dest daftp_dir)
        (newname "DaFTP")
        (prompt "Installing AS225 DaFTP")
        (help "The AS225 version of DaFTP will be installed in "
            "the directory you selected."
        )
        (optional "force" "askuser")
        (confirm)
        (infos)
    )
    (
        (copyfiles
            (source "DaFTP_AmiTCP")
            (dest daftp_dir)
            (newname "DaFTP")
            (prompt "Installing AmiTCP DaFTP")
            (help "The AmiTCP version of DaFTP will be install in "
                "the directory you selected."
            )
            (optional "force" "askuser")
            (confirm)
            (infos)
        )
    )
)

(complete 40)

(copyfiles
    (source "DaFTPAbout.anim")
    (dest daftp_dir)
)

(if (askbool
        (prompt "Do you want to install the sample hotlist?")
        (help "This will install a sample hotlist file with some "
            "sample entries as your default hotlist file."
        )
    )
    (copyfiles
        (source "SampleHotlist.prefs")
        (dest daftp_dir)
        (newname "DaFTPHotlist.prefs")
        (optional "force")
    )
)

(complete 50)

(set install-rexx
    (askbool
        (prompt "Do you want to install the ARexx files?")
        (help "There are a few ARexx files which make DaFTP more "
            "useful.  One file is for post-processing of downloaded "
            "files.  Another is an Aminet browsing script which "
            "uses DaFTP to effectively recreate ADT."
        )
    )
)

(set install-processfile 0)
(set install-browse 1)

(if install-rexx
    (set rexx-to-install
        (askoptions
            (prompt "Select the ARexx scripts which you wish to copy")
            (choices "ProcessFile.Rexx  Post processing"
                     "Browse.DaFTP      Aminet Browser"
            )
            (help "ProcessFile.Rexx allows for configured post-processing "
                "of downloaded files.  By editing the script, you may "
                "select the type of viewer to use on a particular file "
                "extension.  See the script for more details.\n\n"
                "Browse.DaFTP is a script that controls DaFTP to allow for "
                "browsing of Recent files on Aminet.  It uses Amigaguide "
                "documents to build lists of recent files, allows file "
                "searches (AmiTCP only), file marking, and more."
            )
        )
    )
)

(if (IN rexx-to-install install-processfile)
    (copyfiles
        (source "Rexx/ProcessFile.rexx")
        (dest "REXX:")
        (prompt "Installing ARexx script for file processing")
        (help "ProcessFile.rexx is an ARexx script that automatically "
            "processes a downloaded file.  It can for example show "
            "text files, play samples, etc."
        )
        (optional "force" "askuser")
        (confirm)
    )
)

(complete 70)

(if (IN rexx-to-install install-browse)
    (
        (copyfiles
            (source "Rexx/Browse.DaFTP")
            (dest "REXX:")
            (prompt "Installing ARexx script for Aminet browsing")
            (help "Browse.DaFTP is an ARexx script that controls DaFTP "
                "to browse through Aminet's recent files.  It is "
                "recommended to either put DaFTP in your path, or "
                "make a link to DaFTP somewhere in your path"
            )
            (optional "force" "askuser")
            (confirm)
        )
        (copyfiles
            (source "Rexx/BrowseAminet.guide")
            (dest "HELP:")
            (prompt "Installing Amigaguide help for Browse.DaFTP")
            (help "This installs a nice help file for Browse.DaFTP "
                "in your HELP: directory, which should be in your "
                "Amigaguide path."
            )
            (optional "force" "askuser")
            (confirm)
        )
    )
)

(complete 80)


(set @default-dest daftp_dir)

(message "Your installation of DaFTP is now complete. "
    "Special note of this version: The program prefs format "
    "has changed to an ASCII format.  To avoid problems, "
    "please resave your preferences, if you have a previously "
    "installed version of DaFTP."
)
(complete 100)