home *** CD-ROM | disk | FTP | other *** search
/ GEMini Atari / GEMini_Atari_CD-ROM_Walnut_Creek_December_1993.iso / files / program / achlib / achslib.s < prev    next >
Encoding:
Text File  |  1988-03-22  |  17.5 KB  |  741 lines
  1. ;*** achslib.s
  2. ;
  3. ;    880103
  4.  
  5. ;*** ASCII Code Equates
  6.  
  7. BS        ==        $08
  8. HT        ==        $09
  9. LF        ==        $0a
  10. VT        ==        $0b
  11. FF        ==        $0c
  12. CR        ==        $0d
  13. ZEOF      ==        $1a
  14. ESC       ==        $1b
  15. SPACE     ==        $20
  16.  
  17. ;*** Atari ST Key Equates
  18.  
  19. ;    Shift Bits
  20. KRSHIFT   ==        $01
  21. KLSHIFT   ==        $02
  22. KCTRL     ==        $04
  23. KALT      ==        $08
  24. KCAPS     ==        $10
  25. KRMOUSE   ==        $20
  26. KLMOUSE   ==        $40
  27.  
  28. ;    Function Keys
  29. KF1       ==        $003b0000
  30. KF2       ==        $003c0000
  31. KF3       ==        $003d0000
  32. KF4       ==        $003e0000
  33. KF5       ==        $003f0000
  34. KF6       ==        $00400000
  35. KF7       ==        $00410000
  36. KF8       ==        $00420000
  37. KF9       ==        $00430000
  38. KF10      ==        $00440000
  39.  
  40. KESC      ==        $0001001b
  41. KRETURN   ==        $001c000d
  42. KENTER    ==        $0072000d
  43. KBS       ==        $000e0008
  44. KDEL      ==        $0053007f
  45.  
  46. KCTLDEL   ==        $0053001f
  47. KCTLLEFT  ==        $00730000
  48. KCTLRIGHT ==        $00740000
  49.  
  50. KHOME     ==        $00470000
  51. KUP       ==        $00480000          
  52. KLEFT     ==        $004b0000
  53. KRIGHT    ==        $004d0000
  54. KDOWN     ==        $00500000
  55. KTAB      ==        $000f0009
  56.  
  57. KINSERT   ==        $00520000
  58. KUNDO     ==        $00610000
  59. KHELP     ==        $00620000
  60.  
  61. ;*** GEMDOS Equates
  62.  
  63. CCONIN    ==        1    ; standard console in       
  64. CCONOUT   ==        2    ; standard console out
  65. CAUXIN    ==        3    ; auxilary in
  66. CAUXOUT   ==        4    ; auxilary out
  67. CPRNOUT   ==        5    ; standard printer out
  68. CRAWIO    ==        6    ; Raw I/O to standard I/O
  69. CRAWIN    ==        7    ; Raw console in, no echo, no ctrl interpret
  70. CNECIN    ==        8    ; Raw console in, no echo, ctrl interpreted
  71. CCONWS    ==        9    ; write NULL terminated string to standard output 
  72. CCONRS    ==        10   ; read edited string from standard input   
  73. CCONIS    ==        11   ; check status of standard input
  74.  
  75.  
  76. ;*** Atari System Variables
  77. ;
  78. ;    NOTE: must be in Supervisor mode to modify.
  79.  
  80. _DEFRES   ==        $44a      ; default monitor resolution
  81. _MONITOR  ==        $44c      ; monitor type
  82. _CONTERM  ==        $484      ; attributes for the console system
  83.  
  84.  
  85. ;*** Terminal Definition Area
  86.  
  87.           .data
  88.           .even
  89. _TERM::
  90. bell:     .dc.b     7,0            ; bell code string
  91.           .dc.b     0,0,0,0,0,0
  92.  
  93. tset:     .dc.b     0,0,0,0,0,0,0,0     ; terminal init
  94.  
  95. trst:     .dc.b     0,0,0,0,0,0,0,0     ;terminal de-init
  96.                      
  97. curhome:  .dc.b     ESC,'H',0      ; cursor home
  98.           .dc.b     0,0,0,0,0
  99.  
  100. clrscr:   .dc.b     ESC,'E',0      ; clear screen
  101.           .dc.b     0,0,0,0,0
  102.  
  103. clreol:   .dc.b     ESC,'K',0      ; clear to EOL
  104.           .dc.b     0,0,0,0,0
  105.  
  106. clreop:   .dc.b     ESC,'J',0      ; clear to EOP
  107.           .dc.b     0,0,0,0,0
  108.  
  109. curon:    .dc.b     ESC,'e',0      ; cursor on
  110.           .dc.b     0,0,0,0,0
  111.  
  112. curoff:   .dc.b     ESC,'f',0      ; cursor off
  113.           .dc.b     0,0,0,0,0
  114.  
  115. hilite:   .dc.b     ESC,'p',0      ; inverse on
  116.           .dc.b     0,0,0,0,0
  117.  
  118. lolite:   .dc.b     ESC,'q',0      ; inverse off
  119.           .dc.b     0,0,0,0,0
  120.  
  121. insline:  .dc.b     ESC,'L',0      ; insert line
  122.           .dc.b     0,0,0,0,0
  123.  
  124. delline:  .dc.b     ESC,'M',0      ; delete line
  125.           .dc.b     0,0,0,0,0
  126.  
  127. curup:    .dc.b     ESC,'A',0      ; cursor up
  128.           .dc.b     0,0,0,0,0
  129.  
  130. curdn:    .dc.b     ESC,'B',0      ; cursor down
  131.           .dc.b     0,0,0,0,0
  132.  
  133. currt:    .dc.b     ESC,'C',0      ; cursor right
  134.           .dc.b     0,0,0,0,0
  135.  
  136. curlt:    .dc.b     ESC,'D',0      ; cursor left
  137.           .dc.b     0,0,0,0,0
  138.  
  139.  
  140.  
  141. ;*** GotoXY for VT-52 terminal
  142. ;
  143. ; e  short X coord
  144. ;    short Y coord
  145. ;
  146. ; x  none
  147. ;
  148. ;    Position cursor at .text coords (X,Y).
  149.  
  150.           .data
  151.           .even
  152.      
  153. curaddr:  .dc.b     ESC,'Y',0      ; cursor addressing lead in
  154.           .dcb.b    5,0
  155.  
  156. cursep:   .dcb.b    8,0            ; cursor coord separator
  157.  
  158. curend:   .dcb.b    8,0            ; cursor addressing terminate
  159.  
  160. _XMAX::   .dc.w     80             ; max number of columns
  161. _YMAX::   .dc.w     25             ; max number of rows
  162. xoff:     .dc.w     32             ; x offset for columns
  163. yoff:     .dc.w     32             ; y offset for rows
  164.  
  165. _TABLEN:: .dc.w     4              ; tab length to use
  166. rows:     .dc.b     1              ; true if rows sent first
  167. binary:   .dc.b     1              ; true if .data sent in binary 
  168.      
  169.           .text
  170. _GOTOXY:: 
  171.           link      a6,#0
  172.           movea.l   #curaddr,a0    ; pnt to cursor addressing string
  173.           move.l    a0,-(sp)       ; put on stack
  174.           move.w    #CCONWS,-(sp)  ; send string to terminal
  175.           trap      #1             ;   do GEMDOS call
  176.           addq.l    #6,sp          ; correct stack
  177.  
  178.           move.w    _YMAX,d1       ; point to ymax value
  179.           move.w    10(a6),d0      ; get y argument
  180.           bsr.s     GOTOXY1
  181.  
  182.           move.w    _XMAX,d1       ; point to xmax value
  183.           move.w    8(a6),d0       ; get x argument
  184.           bsr.s     GOTOXY1
  185.           unlk      a6
  186.           rts
  187. GOTOXY1:
  188.           ext.l     d0
  189.           divu      d1,d0
  190.           swap      d0             ; q = q mod max
  191.           addi.w    #32,d0         ; q = q + offset
  192.  
  193.           move.w    d0,-(sp)
  194.           move.w    #CCONOUT,-(sp)
  195.           trap      #1
  196.           addq.l    #4,sp
  197.           rts
  198.  
  199.  
  200.  
  201. ;*** Move Memory
  202. ;
  203. ; e  long source pointer to char
  204. ;    long target pointer to char
  205. ;    long length of source
  206. ;
  207. ; x  none
  208. ;
  209. ;    Move a block of Length from Source to Target.
  210.  
  211.           .text 
  212.           .globl    _MOVEMEM
  213. _MOVEMEM:
  214.           movea.l   4(sp),a0       ; get source
  215.           movea.l   8(sp),a1       ; get target
  216.           move.l    12(sp),d0      ; get length
  217.           beq.s     MOVEMX         ; exit if length is zero 
  218.           cmpa.l    a1,a0          ; check  for s < t
  219.           blt.s     MOVEMT         ; move tail first
  220. MOVEMH:   
  221.           move.b    (a0)+,(a1)+    ; move source byte to target
  222.           subq.l    #1,d0          ; decrement length
  223.           bne       MOVEMH         ; loop till zero
  224.           bra.s     MOVEMX
  225. MOVEMT:
  226.           adda.l    d0,a0          ; do tail first
  227.           adda.l    d0,a1
  228. MOVEMTT:
  229.           move.b    -(a0),-(a1)
  230.           subq.l    #1,d0
  231.           bne       MOVEMTT
  232. MOVEMX:
  233.           rts
  234.           
  235.  
  236.  
  237. ;***String N Put
  238. ;
  239. ; e  long pointer to string
  240. ;    short n
  241. ;
  242. ; x  none 
  243. ;
  244. ;    Print n characters of a string
  245.  
  246.           .text
  247. _STRNPUT::
  248.           link      a6,#0
  249.           movem.l   d3/a3, -(sp)
  250.           movea.l   8(a6), a3
  251.           adda.w    12(a6), a3
  252.           cmpa.l    8(a6), a3
  253.           beq.s     STRNPUT1
  254.           move.b    (a3), d3
  255.           clr.b     (a3)
  256. STRNPUT1:
  257.           move.l    8(a6), -(sp)
  258.           move.w    #CCONWS, -(sp)
  259.           trap      #1
  260.           addq.l    #6, sp
  261.           cmpa.l    8(a6), a3
  262.           beq.s     STRNPUT2
  263.           move.b    d3, (a3)
  264. STRNPUT2:
  265.           movem.l   (sp)+, d3/a3
  266.           unlk      a6
  267.           rts
  268.  
  269.  
  270.  
  271. ;*** String N Copy
  272. ;
  273. ; e  long pointer source string
  274. ;    long pointer target string
  275. ;    short count
  276. ;
  277. ; x  none
  278. ;
  279. ;    Copy max n bytes of string 1 to string 2.
  280. ;    String 2 is NULL terminated.
  281.  
  282.           .text
  283. _STRNCPY::      
  284.           movea.l   4(sp),a0            ; get source
  285.           movea.l   8(sp),a1            ; get target
  286.           move.w    12(sp),d0           ; get count
  287.           beq.s     .X                  ; count = 0?
  288. .1:
  289.           tst.b     (a0)                ; EOS on s1
  290.           beq.s     .X
  291.           move.b    (a0)+,(a1)+         ; copy char s1 to s2
  292.           subq.w    #1,d0               ; --count
  293.           bne       .1                  ; if count not zero
  294. .X:
  295.           clr.b     (a1)
  296.           rts
  297.  
  298.  
  299.  
  300. ;*** String Concatination
  301. ;
  302. ; e  long pointer to string 1
  303. ;    long pointer to string 2
  304. ; 
  305. ; x  none
  306. ;
  307. ;    Append string two to the end of one.
  308.  
  309.           .text
  310. _STRCAT::
  311.           move.l    4(sp),a0
  312. .1:
  313.           tst.b     (a0)+
  314.           bne       .1
  315.           subq.l    #1,a0
  316.           movea.l   8(sp),a1
  317. .2:
  318.           move.b    (a1)+,(a0)+
  319.           bne       .2
  320.           rts
  321.  
  322.  
  323. ;*** Length of NULL terminated string
  324. ;
  325. ; e  long pointer to string
  326. ;
  327. ; x  D0.L = length of string up to NULL (but not including)
  328.  
  329.           .text
  330. _STRLEN::
  331.           moveq.l   #-1,d0
  332.           movea.l   4(sp),a0
  333. .1:
  334.           addq.l    #1,d0
  335.           tst.b     (a0)+
  336.           bne       .1
  337.           rts
  338.  
  339.  
  340.  
  341.  
  342. ;*** Find next token in string.
  343. ;
  344. ; e  long pointer to string / NULL to continue with last string
  345. ;    long pointer to delimeter string / NULL use default delimeters
  346. ;
  347. ; x  long pointer to start of token / NULL if no tokens left
  348. ;
  349. ;    Note: a) original string will be modified.
  350. ;          b) leading spaces are skipped.
  351.  
  352.           .data
  353. DEFDELIM: .dc.b     SPACE, ',', 0
  354.  
  355.           .bss
  356. _NEXTTOK::
  357.           .ds.l     1
  358.  
  359.           .text
  360. _STRTOK::
  361.           move.l    4(sp), d0           ;get string
  362.           bne.s     .1                  ;if NULL then
  363.           move.l    _NEXTTOK, d0        ; continue with previous
  364.           beq.s     .X                  ; string, return NULL if EOS
  365. .1:
  366.           movea.l   d0, a0
  367. .2:
  368.           cmpi.b    #SPACE, (a0)+       ;skip leading spaces
  369.           beq       .2
  370.           subq.l    #1, a0
  371.           move.l    a0, d0              ;start of token to return
  372.           move.l    8(sp), d1           ;get delimeter string
  373.           bne.s     .3                  ;if NULL then use default
  374.           move.l    #DEFDELIM, d1
  375. .3:
  376.           movea.l   d1, a1              ;reset delimeter string
  377.           move.b    (a0)+, d2           ;get char in token
  378. .4:
  379.           cmp.b     (a1), d2            ;check against delims
  380.           beq.s     .5
  381.           tst.b     (a1)+   
  382.           bne       .4                  ;end of delim string?
  383.           bra       .3
  384. .5:
  385.           clr.b     -1(a0)              ;terminate token at delim
  386.           tst.b     d2                  ;was it end of search string
  387.           bne.s     .6
  388.           suba.l    a0, a0              ;save NULL for next search
  389. .6:
  390.           move.l    a0, _NEXTTOK        ;remember current position
  391. .X:
  392.           rts
  393.  
  394.  
  395. ;*** Find index of character in string
  396. ;
  397. ; e  long pointer to string
  398. ;    word character value
  399. ;
  400. ; x  D0.L = index into string if character is found else -1
  401.  
  402.           .text
  403. _FINDI::   
  404.           move.l    4(sp),a0       ;pointer to string
  405.           moveq.l   #-1, d0
  406.           move.w    8(sp),d1       ;character
  407. .1:
  408.           tst.b     (a0)           ;EOS?
  409.           beq.s     .X
  410.           cmp.b     (a0)+, d1      ;check character
  411.           bne       .1
  412.           move.l    a0, d0
  413.           sub.l     4(sp), d0      ;current - original
  414.           subq.l    #1, d0         ;adjust overrun -1
  415. .X:
  416.           rts
  417.  
  418.  
  419. ;*** Find index of last occurence of character in string
  420. ;
  421. ; e  long pointer to string
  422. ;    word character value
  423. ;
  424. ; x  D0.L = index into string if character is found else -1
  425.  
  426.           .text
  427. _LFINDI::
  428.           movea.l   4(sp), a0
  429.           moveq.l   #-1, d0
  430.           move.w    8(sp), d1
  431.           bra.s     .2
  432. .1:
  433.           cmp.b     (a0)+, d1
  434.           bne.s     .2
  435.           move.l    a0, d0
  436.           sub.l     4(sp), d0
  437.           subq.l    #1, d0
  438. .2:
  439.           tst.b     (a0)
  440.           bne       .1
  441.           rts
  442.  
  443.  
  444. ;*** Deque Rouitines
  445.  
  446. ;*** Make Deque
  447. ;
  448. ; e  long      # of long words for deque
  449. ;
  450. ; x  D0.L =    ptr to deque structure / NULL unsuccessful
  451.  
  452.           .text
  453. _MKDEQ::
  454.           link      a6, #0
  455.           movem.l   a3-a4, -(sp)
  456.           move.l    8(a6), d1
  457.           lsl.l     #2, d1
  458.           addi.l    #16, d1
  459.           move.l    d1, -(sp)
  460.           move.w    #$48, -(sp)
  461.           trap      #1
  462.           addq.l    #6, sp
  463.           tst.l     d0
  464.           beq.s     .X
  465.           movea.l   d0, a0
  466.           movea.l   d0, a1
  467.           adda.l    #16, a1             ;base of deque
  468.           movea.l   a1, a2              ;left pointer
  469.           movea.l   a1, a3              ;right pointer
  470.           movea.l   a1, a4              
  471.           adda.l    d1, a4              ;end of deque +1
  472.           movem.l   a1-a4, (a0)         ;save deque structure
  473. .X:
  474.           movem.l   (sp), a3-a4
  475.           unlk      a6
  476.           rts     
  477.  
  478.  
  479. ;*** Remove Deque
  480. ;
  481. ; e  long      ptr to deque structure
  482. ;
  483. ; x  D0.W =    NULL for success / error code
  484.  
  485.           .text
  486. _RMDEQ::
  487.           move.l    4(sp), -(sp)
  488.           move.w    #$49, -(sp)
  489.           trap      #1
  490.           addq.l    #6, sp
  491.           rts
  492.  
  493.  
  494. ;*** Add an element to deque
  495. ;
  496. ; e  long      ptr to deque structure
  497. ;    word      0 left / 1 right 
  498. ;    long      value to store
  499.  
  500.           .text
  501. _DEQADD::
  502.           link      a6, #0
  503.           movem.l   a3-a4, -(sp)
  504.           movea.l   8(a6), a0           ;ptr to deque structure
  505.           movem.l   (a0), a1-a4         ;fetch deque structure
  506.           move.l    14(a6), d0          ;value
  507.           move.w    12(a6), d1          ;if adding to the right
  508.           bne.s     .2
  509.           cmpa.l    a1, a2
  510.           bhi.s     .1                  ;if begin < left then
  511.           movea.l   a4, a2              ;wrap deque to end
  512. .1:
  513.           move.l    d0, -(a2)           ;save value
  514.           bra.s     .X
  515. .2:
  516.           move.l    d0, (a3)+           ;save value
  517.           cmpa.l    a3, a4              ;if right < end then
  518.           bhi.s     .X
  519.           movea.l   a1, a3              ;wrap deque to beginning
  520. .X:
  521.           movem.l   a1-a4, (a0)         ;update deque structure
  522.           movem.l   (sp), a3-a4
  523.           unlk      a6
  524.           rts
  525.  
  526.  
  527. ;*** Delete value from deque
  528. ;
  529. ; e  long      ptr to deque structure
  530. ;    word      0 left / 1 right
  531. ;
  532. ; x  D0.L      value
  533.  
  534.           .text
  535. _DEQDEL::
  536.           link      a6, #0
  537.           movem.l   a3-a4, -(sp)
  538.           movea.l   8(a6), a0
  539.           movem.l   (a0), a1-a4
  540.           move.w    12(a6), d1
  541.           bne.s     .1
  542.           move.l    (a2)+, d0           ;get value
  543.           cmpa.l    a2, a4              ;if left < end then
  544.           bhi.s     .X
  545.           movea.l   a1, a2              ;wrap deque to beginning
  546.           bra.s     .X
  547. .1:
  548.           cmpa.l    a1, a3              ;if begin < right then
  549.           bhi.s     .2
  550.           movea.l   a4, a3              ;wrap deque to end
  551. .2:
  552.           move.l    -(a3), d0           ;get value
  553. .X:
  554.           movem.l   a1-a4, (a0)         ;update deque structure
  555.           movem.l   (sp), a3-a4
  556.           unlk      a6
  557.           rts
  558.           
  559.  
  560.           .globl    _PUTDEC
  561.           .globl    PUTDEC
  562.  
  563. ;*** Print Unsigned Decimal (0-65535)
  564. ;
  565. ; _PUTDEC      e    word value
  566. ; PUTDEC       e    D0.W value
  567. ;              x    none
  568.  
  569.           .text
  570. _PUTDEC:
  571.           move.w    4(sp),d0
  572. PUTDEC:          
  573.           ext.l     d0
  574.           divu      #10,d0
  575.           beq.s     PUTDEC1
  576.           move.l    d0,-(sp)
  577.           bsr       PUTDEC
  578.           move.l    (sp)+,d0
  579. PUTDEC1:
  580.           swap      d0
  581.           addi.w    #$30,d0
  582.           move.w    d0,-(sp)
  583.           move.w    #CCONOUT,-(sp)
  584.           trap      #1
  585.           addq.l    #4,sp
  586.           rts
  587.  
  588.             
  589. ;*** Print Unsigned Decimal
  590. ;
  591. ; _PUTLONG     e    long value
  592. ; PUTLONG      e    D0.L value
  593. ;              x    none
  594.  
  595.           .text
  596. _PUTLONG::
  597.           move.l    4(sp),d0
  598. PUTLONG::        
  599.           move.l    #10, -(sp)
  600.           move.l    d0, -(sp)
  601.           bsr.s     _ULD
  602.           addq.l    #8, sp
  603.           tst.l     d0
  604.           beq.s     .1
  605.           movem.l   d0-d1,-(sp)
  606.           bsr       PUTLONG
  607.           movem.l   (sp)+, d0-d1
  608. .1:
  609.           addi.w    #$30, d1
  610.           move.w    d1,-(sp)
  611.           move.w    #CCONOUT,-(sp)
  612.           trap      #1
  613.           addq.l    #4,sp
  614.           rts
  615.  
  616.  
  617.  
  618. ;*** Unsigned Long to ASCII
  619. ;
  620. ; e  long value
  621. ;    long pointer to string buffer
  622. ;
  623. ; x  ASCIIZ string in buffer
  624.  
  625.           .text
  626. _ULTOA::
  627.           move.l    4(sp),d0
  628.           movea.l   8(sp), a0
  629. ULTOA::
  630.           move.l    #10, -(sp)
  631.           move.l    d0, -(sp)
  632.           bsr.s     _ULD
  633.           addq.l    #8, sp
  634.           tst.l     d0
  635.           beq.s     .1
  636.           movem.l   d0-d1,-(sp)
  637.           bsr       ULTOA
  638.           movem.l   (sp)+, d0-d1
  639. .1:
  640.           addi.w    #$30, d1
  641.           move.b    d1, (a0)+
  642.           clr.b     (a0)   
  643.           rts
  644.  
  645.             
  646. ;*** Unsigned long division
  647. ;
  648. ; e  long dividend
  649. ;    long divisor
  650. ;
  651. ; x  D0.L = quoitent
  652. ;    D1.L = remainder
  653.           
  654.           .text
  655. _ULD::
  656.           move.l    4(sp), d0           ;dividend
  657.           move.l    8(sp), d2           ;divisor
  658.           move.w    d3, -(sp)
  659.           move.w    #31, d3             ;bit count
  660.           clr.l     d1                  ;remainder
  661. .1:
  662.           add.l     d0, d0
  663.           addx.l    d1, d1
  664.           sub.l     d2, d1
  665.           bcc.s     .2
  666.           add.l     d2, d1
  667.           bra.s     .3
  668. .2:
  669.           addq.l    #1, d0
  670. .3:
  671.           dbf       d3, .1
  672.           move.w    (sp)+, d3
  673.           rts
  674.  
  675.  
  676.           .globl    _DOS
  677.           .globl    ___BDOS
  678.  
  679. ;*** DOS Function Call (CP/M-68k)
  680. ;
  681. ; e  word function number
  682. ;    long parameter
  683. ;
  684. ; x  D0.L = returned value
  685.      
  686.           .text
  687. _DOS:
  688. ___BDOS:
  689.           move.w    4(sp),d0       ; get function number
  690.           move.l    8(sp),d1       ; get parameter
  691.           trap      #2             ; call DOS
  692.           rts      
  693.      
  694.  
  695.           .globl    _gemdos
  696.  
  697. ;*** GEM Dos Function Call
  698. ;
  699. ; e  word function number
  700. ;    word / long parameters
  701. ;
  702. ; x  D0 = return value if any
  703. ;
  704. ;    See GEM Dos notes
  705.      
  706.           .text
  707. _gemdos:
  708.           move.l    (sp)+, GEMRET
  709.           trap      #1
  710.           move.l    GEMRET, -(sp)
  711.           rts
  712.  
  713.           .bss
  714. GEMRET:   .ds.l     1
  715.  
  716.  
  717.  
  718.           .globl    _xbios
  719.  
  720. ;*** XBIOS Function Call
  721. ;
  722. ; e  word function number
  723. ;    word / long parameters
  724. ;
  725. ; x  D0 = return value if any
  726. ;
  727. ;    See XBIOS notes
  728.      
  729.           .text
  730. _xbios:
  731.           move.l    (sp)+, XBRET
  732.           trap      #14
  733.           move.l    XBRET, -(sp)
  734.           rts
  735.  
  736.           .bss
  737. XBRET:    .ds.l     1
  738.  
  739.  
  740.  
  741.