home *** CD-ROM | disk | FTP | other *** search
/ GEMini Atari / GEMini_Atari_CD-ROM_Walnut_Creek_December_1993.iso / files / mint / mntlib24 / bzero.cpp < prev    next >
Encoding:
C/C++ Source or Header  |  1993-08-03  |  2.3 KB  |  116 lines
  1. |    new version of bcopy and memset
  2. |    uses movem to set 256 bytes blocks faster.
  3. |    Alexander Lehmann    alexlehm@iti.informatik.th-darmstadt.de
  4. |    sortof inspired by jrbs bcopy
  5. |    has to be preprocessed (int parameter in memset)
  6.  
  7.     .text
  8.     .even
  9.     .globl _bzero
  10.     .globl __bzero
  11.     .globl _memset
  12.  
  13. |    void *memset( void *dest, int val, size_t len );
  14. |    returns dest
  15. |    two versions for 16/32 bits
  16.  
  17. _memset:
  18.     movl    sp@(4),a0    | dest
  19. #ifdef __MSHORT__
  20.     movb    sp@(9),d0    | value
  21.     movl    sp@(10),d1    | length
  22. #else
  23.     movb    sp@(11),d0    | value
  24.     movl    sp@(12),d1    | length
  25. #endif
  26.     jeq    exit        | length==0? (size_t)
  27.     jra    do_set
  28.  
  29. |    void bzero( void *dest, size_t length );
  30. |    void _bzero( void *dest, size_t length );
  31. |    return value not used (returns dest)
  32.  
  33. _bzero:
  34. __bzero:
  35.     movl    sp@(4),a0    | dest
  36.     movl    sp@(8),d1    | length
  37.     jeq    exit        | length==0? (size_t)
  38.     clrb    d0        | value
  39.  
  40. do_set:             | a0 dest, d0.b byte, d1.l length
  41.     movel    d2,sp@-
  42.  
  43.     addl    d1,a0        | a0 points to end of area, needed for predec
  44.  
  45.     movw    a0,d2        | test for alignment
  46.     btst    #0,d2        | odd ?
  47.     jeq    even
  48.     movb    d0,a0@-     | set one byte, now we are even
  49.     subql    #1,d1
  50. even:
  51.     movb    d0,d2
  52.     lslw    #8,d0
  53.     movb    d2,d0
  54.     movw    d0,d2
  55.     swap    d2
  56.     movw    d0,d2        | d2 has byte now four times
  57.  
  58.     clrw    d0        | save length less 256
  59.     movb    d1,d0
  60.     lsrl    #8,d1        | number of 256 bytes blocks
  61.     jeq    less256
  62.     movml    d3-d7/a2-a6,sp@-    | d2 is already saved
  63.     movl    d2,d3
  64.     movl    d2,d4
  65.     movl    d2,d5
  66.     movl    d2,d6
  67.     movl    d2,d7
  68.     movl    d2,a2
  69.     movl    d2,a3
  70.     movl    d2,a4
  71.     movl    d2,a5
  72.     movl    d2,a6
  73. set256:
  74.     movml    d2-d7/a2-a6,a0@-    | set 5*44+36=256 bytes
  75.     movml    d2-d7/a2-a6,a0@-
  76.     movml    d2-d7/a2-a6,a0@-
  77.     movml    d2-d7/a2-a6,a0@-
  78.     movml    d2-d7/a2-a6,a0@-
  79.     movml    d2-d7/a2-a4,a0@-
  80.     subql    #1,d1
  81.     jne    set256            | next, please
  82.     movml    sp@+,d3-d7/a2-a6
  83. less256:            | set 16 bytes blocks
  84.     movw    d0,sp@-     | save length below 256 for last 3 bytes
  85.     lsrw    #2,d0        | number of 4 bytes blocks
  86.     jeq    less4        | less that 4 bytes left
  87.     movw    d0,d1
  88.     negw    d1
  89.     andw    #3,d1        | d1 = number of bytes below 16 (-n)&3
  90.     subqw    #1,d0
  91.     lsrw    #2,d0        | number of 16 bytes blocks minus 1, if d1==0
  92.     addw    d1,d1        | offset in code (movl two bytes)
  93.     jmp    pc@(2,d1:w)    | jmp into loop
  94. set16:
  95.     movl    d2,a0@-
  96.     movl    d2,a0@-
  97.     movl    d2,a0@-
  98.     movl    d2,a0@-
  99.     dbra    d0,set16
  100. less4:
  101.     movw    sp@+,d0
  102.     btst    #1,d0
  103.     jeq    less2
  104.     movw    d2,a0@-
  105. less2:
  106.     btst    #0,d0
  107.     jeq    none
  108.     movb    d2,a0@-
  109. none:
  110. exit_d2:
  111.     movl    sp@+,d2
  112. exit:
  113.     movl sp@(4),d0        | return dest (for memset only)
  114.     rts
  115.  
  116.