1260 ' ****** ADJUST RECORDS TO FILL DELETED RECORD SPACE ******
1270 FOR K%=J% TO 19
1280 GET #1,K%+1:PUT #1,K%:NEXT
1290 GOSUB 980:J%=20:GOSUB 1210
1300 RETURN
1310 '
1320 ' ****** ADJUST RECORDS TO INSERT NEW RECORD ******
1330 PRINT
1340 PRINT "Do you wish to insert the record in a specific postion ? (Y/N) "
1350 Z$="YyNn"
1360 K$=INKEY$:IF K$="" THEN 1360
1370 K=INSTR(Z$,K$)
1380 ON K GOTO 1400,1400,1460,1460
1390 BEEP:GOTO 1360
1400 PRINT "Which position ? ( 1 to";J%-1;")";
1410 INPUT R%:IF R%=0 THEN 1340
1420 IF R%>J%-1 THEN 1400
1430 J%=R%
1440 FOR K%=19 TO R% STEP-1
1450 GET #1,K%:PUT #1,K%+1:NEXT
1460 RETURN
1470 '
1480 ' ****** END OF JOB ROUTINE ******
1490 CLOSE #1:GOTO 40
1500 'END PART CHANGE/ADD/DELETE ELEMENTS
1510 REM ******* Groundsation data change v.1.0 OE1HSI jan.-1985**********
1520 SCREEN 0,1:WIDTH 80:COLOR 14,1,0:CLS
1530 PRINT"CURRENT GROUND STATION DATA":PRINT:GOSUB 1840
1540 PRINT"Do you want to CHANGE this DATA ? (Y/N)"
1550 Z$="YyNn"
1560 K$=INKEY$:IF K$=""THEN 1560
1570 K=INSTR(Z$,K$)
1580 ON K GOTO 1670,1670,1950,1950
1590 BEEP:COLOR 28:GOTO 1540
1600 PRINT:PRINT:GOSUB 1870
1610 PRINT"Do you want a further CHANGE ? (Y/N) "
1620 Z$="YyNn"
1630 K$=INKEY$:IF K$=""THEN 1630
1640 K=INSTR(Z$,K$)
1650 ON K GOTO 1670,1670,1940,1940
1660 BEEP:COLOR 28:GOTO 1610
1670 COLOR 14:PRINT:PRINT "ENTER NEW DATA OR <RETURN> FOR UNCHANGED DATA":
1680 OPEN "GROUND.DAT" AS #1 LEN=42
1690 FIELD #1, 10 AS GR$,20 AS GL$,4 AS GH$,4 AS LO$, 4 AS LA$
1700 PRINT:INPUT "CALL max. 10 chrs.) : ",U$: IF U$ <>"" THEN GS$=U$ ELSE GS$=GR1$
1710 INPUT "Location of station (max. 20 chrs.) : ",U$: IF U$ <>"" THEN GC$=U$ ELSE GC$=GL1$
1720 INPUT "Groundstation height above sealevel in mtrs. : ",U$: IF U$ <>"" THEN SH=VAL(U$) ELSE SH=CVS(GH1$)
1730 PRINT "LONGITUDE WEST of Greenwich (max +360) or East of Greenw. entered as -0 to -180":PRINT:INPUT "Enter (with decimals) : ",U$: IF U$ <>"" THEN LO=VAL(U$) ELSE LO=CVS(LO1$)
1740 IF LO < 0 THEN LO=360+LO
1750 PRINT "LATITUDE NORTH of Equator + (max 90) SOUTH of Equator - (max 90)":PRINT:INPUT "ENTER (With decimals) : ",U$: IF U$ <>"" THEN LA=VAL(U$) ELSE LA=CVS(LA1$)
1760 LSET GR$=GS$
1770 LSET GL$=GC$
1780 RSET GH$=MKS$(SH)
1790 RSET LO$=MKS$(LO)
1800 RSET LA$=MKS$(LA)
1810 PUT #1,1
1820 CLOSE
1830 GOTO 1600
1840 OPEN "GROUND.DAT" AS #1 LEN=42
1850 FIELD #1, 10 AS GR$,20 AS GL$,4 AS GH$,4 AS LO$, 4 AS LA$
1860 GET #1,1
1870 PRINT "CALL IS : ";GR$
1880 PRINT "LOCATION IS : ";GL$
1890 PRINT USING "HEIGHT AB. SEAL. (mtrs.)= : #####";CVS(GH$)
1900 PRINT USING "WESTERN LONGITUDE (deg.)= : ###.##";CVS(LO$)
1910 PRINT USING "LATITUDE (deg.)= : +##.##";CVS(LA$):PRINT
1920 GR1$=GR$:GL1$=GL$:GH1$=GH$:LO1$=LO$:LA1$=LA$
1930 CLOSE:RETURN
1940 COLOR 14:PRINT:PRINT "DATA SAVED AS GROUND.DAT":GOTO 1960
1950 COLOR 14:PRINT:PRINT "DATA NOT CHANGED"
1960 GOTO 50 'MAIN MENU
1970 '**** END PROGRAM GROUNDSTATION DATA CHANGE/STORAGE OE1HSI JAN. 1985 ****