home *** CD-ROM | disk | FTP | other *** search
/ HAM Radio 1 / HamRadio.cdr / tech / rf4 / mstrip.asc < prev    next >
Text File  |  1986-04-16  |  4KB  |  114 lines
  1. 10 REM
  2. 20 REM                      MICROSTRIP DESIGN PROGRAM
  3. 30 REM                      -------------------------
  4. 40 REM                         BY KEVIN MCCLANING
  5. 50 REM
  6. 60 REM     THIS PROGRAM IS BASED ON THE ARTICLE "SYNTHESIZE AND ANALYZE
  7. 70 REM MICROSTRIP LINES BY JAMES J. LEV, MICROWAVES AND RF MAGAZINE,
  8. 80 REM JANUARY 1986, PG 111.
  9. 90 REM
  10. 100 REM
  11. 110 REM
  12. 120 CLS:PRINT
  13. 130 PRINT"                 MICROSTRIP DESIGN PROGRAM"
  14. 140 PRINT"                 -------------------------"
  15. 150 PRINT
  16. 160 PRINT "    THIS PROGRAM ALLOWS THE USER TO DESIGN MICROSTRIP TRANSMISSION"
  17. 170 PRINT "LINES FROM USER-SUPPLIED PHYSICAL PARAMETERS."
  18. 180 PRINT
  19. 190 PRINT "    NOTE: THE EQUATIONS USED IN THIS PROGRAM ARE FIRST-"
  20. 200 PRINT "ORDER APPROXIMATIONS, BUT THEY SHOULD BE OK FOR INITIAL DESIGNS."
  21. 210 GOSUB 820
  22. 220 PRINT "WHAT'LL IT BE:"
  23. 230 PRINT "  1 - COMPUTE RELATIVE DIELECTRIC CONSTANT FROM MEASURED"
  24. 240 PRINT "              PHYSICAL PARAMETERS"
  25. 250 PRINT "  2 - FIND THE WIDTH OF A MICROSTRIP T-LINE"
  26. 260 PRINT "  3 - END"
  27. 270 INPUT ANS
  28. 280 IF ANS = 1 THEN 320
  29. 290 IF ANS = 2 THEN 570
  30. 300 IF ANS = 3 THEN END
  31. 310 BEEP:GOTO 210
  32. 320 REM
  33. 330 REM
  34. 340 REM
  35. 350 REM         FIND RELATIVE DIELECTRIC CONSTANT
  36. 360 REM
  37. 370 REM
  38. 380 GOSUB 820:PRINT
  39. 390 PRINT "FIND RELATIVE DIELECTRIC CONSTANT":PRINT
  40. 400 INPUT "ENTER THE AREA OF THE BOARD (SQUARE INCHES)";AREASI
  41. 410 AREA = AREASI*(.0254)*(.0254)
  42. 420 INPUT "ENTER THE THICKNESS OF THE DIELECTRIC (INCHES)";DTHICKI
  43. 430 DTHICK = DTHICKI*.0254
  44. 440 INPUT "ENTER THE MEASURED CAPACITANCE (pF)";CAPPF
  45. 450 CAP = CAPPF*1E-12
  46. 460 ESUBR = (CAP*DTHICK)/(AREA*8.854E-12)
  47. 470 GOSUB 860
  48. 480 PRINT "WHAT'LL IT BE:"
  49. 490 PRINT "  1 - FIND ANOTHER RELATIVE DIELECTRIC CONSTANT"
  50. 500 PRINT "  2 - PRINT"
  51. 510 PRINT "  3 - MAIN MENU"
  52. 520 INPUT ANS
  53. 530 IF ANS = 1 THEN 380
  54. 540 IF ANS = 2 THEN GOSUB 940:GOSUB 820:GOTO 480
  55. 550 IF ANS = 3 THEN 210
  56. 560 BEEP:GOTO 480
  57. 570 REM
  58. 580 REM
  59. 590 REM
  60. 600 REM         COMPUTE THE WIDTH OF A MICROSTRIP SECTION
  61. 610 REM
  62. 620 REM
  63. 630 GOSUB 820:PRINT
  64. 640 PRINT "COMPUTE WIDTH OF A MICROSTRIP SECTION":PRINT
  65. 650 INPUT "ENTER THE EFFECTIVE DIELECTRIC CONSTANT";ESUBR
  66. 660 INPUT "ENTER THE THICKNESS OF THE DIELECTRIC (INCHES)";DTHICKI
  67. 670 DTHICK = DTHICKI*.0254
  68. 680 INPUT "ENTER THE DESIRED CHARACTERISTIC IMPEDENCE (OHMS)";Z0
  69. 690 TEMP = EXP(Z0*SQR(1+ESUBR)/42.4)-1
  70. 700 TOP = 8*SQR(TEMP*((7+(4/ESUBR))/11)+((1+(1/ESUBR))/.81))
  71. 710 TWIDTH = DTHICKI*TOP/TEMP
  72. 720 GOSUB 1010
  73. 730 PRINT "WHAT'LL IT BE:"
  74. 740 PRINT "  1 - FIND ANOTHER MICROSTRIP T-LINE WIDTH"
  75. 750 PRINT "  2 - PRINT"
  76. 760 PRINT "  3 - MAIN MENU"
  77. 770 INPUT ANS
  78. 780 IF ANS = 1 THEN 630
  79. 790 IF ANS = 2 THEN GOSUB 1080:GOSUB 820:GOTO 730
  80. 800 IF ANS = 3 THEN 210
  81. 810 BEEP:GOTO 730
  82. 820 PRINT "----------------------------":RETURN
  83. 830 REM
  84. 840 LPRINT "----------------------------":RETURN
  85. 850 REM
  86. 860 GOSUB 820
  87. 870 PRINT "RELATIVE DIELECTRIC CONSTANT"
  88. 880 PRINT "    BOARD AREA = ";AREASI;" SQUARE INCHES"
  89. 890 PRINT "    DIELECTRIC THICKNESS = ";DTHICKI;" INCHES"
  90. 900 PRINT "    MEASURED CAPACITANCE = ";CAPPF;" pF"
  91. 910 PRINT "    RELATIVE DIELECTRIC CONSTANT = ";INT(ESUBR*1000)/1000
  92. 920 GOSUB 820:RETURN
  93. 930 REM
  94. 940 GOSUB 840
  95. 950 LPRINT "RELATIVE DIELECTRIC CONSTANT"
  96. 960 LPRINT "    BOARD AREA = ";AREASI;" SQUARE INCHES"
  97. 970 LPRINT "    DIELECTRIC THICKNESS = ";DTHICKI;" INCHES"
  98. 980 LPRINT "    MEASURED CAPACITANCE = ";CAPPF;" pF"
  99. 990 LPRINT "    RELATIVE DIELECTRIC CONSTANT = ";INT(ESUBR*1000)/1000
  100. 1000 GOSUB 840:RETURN
  101. 1010 GOSUB 820
  102. 1020 PRINT "WIDTH OF A MICROSTRIP T-LINE (Z0 = ";Z0;" OHMS)"
  103. 1030 PRINT "    DIELECTRIC THICKNESS = ";DTHICKI;" INCHES"
  104. 1040 PRINT "    RELATIVE DIELECTRIC CONSTANT = ";INT(ESUBR*1000)/1000
  105. 1050 PRINT "    COMPUTED WIDTH = ";INT(1000*TWIDTH)/1000;" INCHES"
  106. 1060 GOSUB 820:RETURN
  107. 1070 REM
  108. 1080 GOSUB 840
  109. 1090 LPRINT "WIDTH OF A MICROSTRIP T-LINE (Z0 = ";Z0;" OHMS)"
  110. 1100 LPRINT "    DIELECTRIC THICKNESS = ";DTHICKI;" INCHES"
  111. 1110 LPRINT "    RELATIVE DIELECTRIC CONSTANT = ";INT(ESUBR*1000)/1000
  112. 1120 LPRINT "    COMPUTED WIDTH = ";INT(1000*TWIDTH)/1000;" INCHES"
  113. 1130 GOSUB 840:RETURN
  114.