home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
HAM Radio 1
/
HamRadio.cdr
/
tech
/
palsum5
/
vlsyncg.pds
< prev
next >
Wrap
Text File
|
1987-08-26
|
4KB
|
134 lines
TITLE LINE SYNC GENERATOR.
PATTERN 02.
REVISION 03.
AUTHOR CHRIS JAY.
COMPANY MMI SANTA CLARA, CA.
DATE 20TH AUGUST 1986.
;
CHIP VIDEO_1 PAL32VX10
;
;LINE SYNC GENERATOR PAL
;
;PINS 1 2 3 4 5 6
CLK /RST /CEI /WR S0 S1
;PINS 7 8 9 10 11 12
S2 /ENST NC NC NC GND
;PINS 13 14 15 16 17 18
NC MA0 MA1 MA2 MA3 MA4
;PINS 19 20 21 22 23 24
MA5 MA6 BLANK HSYNC /CEO VCC
GLOBAL Q0 Q1 Q2 Q3 Q4 Q5 Q6 Q7 Q8 Q9
STRING HEX50 '/Q0*/Q1*/Q2*/Q3*Q4*/Q5*Q6' ;START BLANK PULSE
STRING HEX6B 'Q0*Q1*/Q2*Q3*/Q4*Q5*Q6' ;END BLANK PULSE
STRING TGLQ2 'Q0*Q1*CEI*/ENST' ;TOGGLE Q2 ENABLE
STRING TGLSQ2 'Q0*Q1*S0*S1*S2*ENST' ;ENABLE STATE I/P
STRING HEX57 'Q0*Q1*Q2*/Q3*Q4*/Q5*Q6' ;SET HSYNC ACTIVE
STRING HEX67 'Q0*Q1*Q2*/Q3*/Q4*Q5*Q6' ;END HSYNC ACTIVE
STRING HEX6A '/Q0*Q1*/Q2*Q3*/Q4*Q5*Q6' ;START CEO ACTIVE
STRING STINP 'S0*S1*S2' ;VIDEO SHIFT
;REGISTER STATE
;INPUT.
EQUATIONS
GLOBAL.SETF = RST ;ASYNCHCRONOUS RESET
;
/Q0 := /Q0 ;HOLD Q0
:+: CEI*/ENST ;CEI ENABLE OR STATE
+ STINP*ENST ;INPUT TO TOGGLE Q0
+ Q0*HEX6B ;K-RESET Q0
MA0 = Q0 ;ENABLE MA0 OUTPUT
MA0.CMBF = GND ;ENABLE REGISTER O/P
MA0.TRST = /WR ;3-STATE CONTROL
;
/Q1 := /Q1 ;HOLD Q1
:+: Q0*CEI*/ENST ;ENABLE OR STATE
+ Q0*STINP*ENST ;INPUT TO TOGGLE Q1
+ Q1*HEX6B ;K-RESET Q1
MA1 = Q1 ;ENABLE MA1 OUTPUT
MA1.CMBF = GND ;ENABLE REGISTER O/P
MA1.TRST = /WR ;3-STATE CONTROL
;
/Q2 := /Q2 ;HOLD Q2
:+: TGLQ2*Q2 ;DISABLE TOGGLE Q2
+ TGLQ2*/Q3 ;DISABLE TOGGLE Q2
+ TGLQ2*Q4 ;DISABLE TOGGLE Q2
+ TGLQ2*/Q5 ;DISABLE TOGGLE Q2
+ TGLQ2*/Q6 ;DISABLE TOGGLE Q2
+ TGLSQ2*Q2 ;FOR STATE INPUT
+ TGLSQ2*/Q3 ;REPEAT EQUATIONS
+ TGLSQ2*Q4 ;FOR TOGGLING Q2
+ TGLSQ2*/Q5 ;
+ TGLSQ2*/Q6 ;
MA2 = Q2 ;ENABLE MA2 OUTPUT
MA2.CMBF = GND ;ENABLE REGISTER O/P
MA2.TRST = /WR ;3-STATE CONTROL
;
/Q3 := /Q3 ;HOLD Q3
:+: Q2*Q1*Q0*CEI*/ENST ;ENABLE OR STATE
+ Q2*Q1*Q0*STINP*ENST ;INPUT TO TOGGLE Q3
+ Q3*HEX6B ;K-RESET Q3
MA3 = Q3 ;ENABLE MA3 OUTPUT
MA3.CMBF = GND ;ENABLE REGISTER O/P
MA3.TRST = /WR ;3-STATE CONTROL
;
/Q4 := /Q4 ;HOLD Q4
:+: Q3*Q2*Q1*Q0*CEI*/ENST ;ENABLE OR STATE
+ Q3*Q2*Q1*Q0*STINP*ENST ;INPUT TO TOGGLE Q4
+ Q4*HEX6B ;K-RESET Q4
MA4 = Q4 ;ENABLE MA4 OUTPUT
MA4.CMBF = GND ;ENABLE REGISTER O/P
MA4.TRST = /WR ;3-STATE CONTROL
;
/Q5 := /Q5 ;HOLD Q5
:+: Q4*Q3*Q2*Q1*Q0*CEI*/ENST ;ENABLE OR STATE
+ Q4*Q3*Q2*Q1*Q0*STINP*ENST ;INPUT TO TOGGLE Q5
+ Q5*HEX6B ;K-RESET Q5
MA5 = Q5 ;ENABLE MA5 OUTPUT
MA5.CMBF = GND ;ENABLE REGISTER O/P
MA5.TRST = /WR ;3-STATE CONTROL
;
/Q6 := /Q6 ;HOLD Q6
:+: Q5*Q4*Q3*Q2*Q1*Q0*CEI*/ENST ;ENABLE OR STATE
+ Q5*Q4*Q3*Q2*Q1*Q0*STINP*ENST ;INPUT TO TOGGLE Q6
+ Q6*HEX6B ;K-RESET Q6
MA6 = Q6 ;ENABLE MA6 OUTPUT
MA6.CMBF = GND ;ENABLE REGISTER O/P
MA6.TRST = /WR ;3-STATE CONTROL
;
/Q7 := /Q7 ;J-K FUNCTION
:+: /Q7*HEX50 ;J-SET BLANK HIGH
+ Q7*HEX6B ;K-RESET BLANK LOW
BLANK = Q7 ;ASSIGN Q7 TO BLANK
BLANK.CMBF = GND ;ENABLE REGISTER O/P
;
/Q8 := /Q8 ;J-K FUNCTION
:+: /Q8*HEX57 ;J-SET HSYNC HIGH
+ Q8*HEX67 ;K-RESET HSYNC LOW
HSYNC = Q8 ;ASSIGN Q8 TO HSYNC
HSYNC.CMBF = GND ;ENABLE REGISTER O/P
;
/Q9 := /Q9 ;J-K FUNCTION
:+: /Q9*HEX6A*CEI*/ENST ;J-SET CEO ACTIVE
+ Q9*HEX6B*CEI*/ENST ;K-RESET CEO FOR CEI
+ /Q9*HEX6A*STINP*ENST ;OR FOR STATE INPUT
+ Q9*HEX6B*STINP*ENST ;
CEO = Q9 ;ENABLE Q9 TO CEO
CEO.CMBF = GND ;ENABLE REGISTER O/P
;
SIMULATION ;START OF SIMULATION.
TRACE_ON CLK /RST CEI MA0 MA1 MA2 MA3 ;TRACE ALL INPUTS
MA4 MA5 MA6 BLANK HSYNC /CEO /WR ;AND OUTPUTS. RESET
SETF RST /CLK /CEI WR ENST /S0 /S1 /S2 ;SYSTEM. SET CLOCK
SETF /WR ;INACTIVE SET WRITE
SETF /RST ;INACTIVE. ENABLE
FOR I := 0 TO 7 DO ;COUNT AND REMOVE
BEGIN CLOCKF CLK ;RESET
END ;
SETF S0 S1 S2 ;
FOR I := 0 TO 110 DO ;RESET.APPLY 110 CLOCK
BEGIN CLOCKF CLK ;PULSES.
END ;END OF SIMULATION.
TRACE_OFF