home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
HAM Radio 1
/
HamRadio.cdr
/
tech
/
maxfltr1
/
pr1.bas
< prev
next >
Wrap
BASIC Source File
|
1988-08-03
|
1KB
|
50 lines
10 PRINT "PRINTER PORT ADDRESS FOR LPT1: "
20 PRINT " 3BC ( PORT ON DISPLAY ADAPTER ) =0 "
30 PRINT " 378 ( PORT NOT ON DISPLAY ADAPTER ) =1 ";
40 INPUT P : IF P>2 OR P<0 THEN 10
50 IF P=0 THEN PORT=956 ELSE PORT=888 ' SET PORT ADDRESS
60 FOR CHIP=1 TO 2
70 PRINT "CHIP # ";CHIP
80 AB$="FILTER A "
90 GOSUB 180 : REM GET DATA FOR SECTION A
100 ADD=0 : REM FILTER A ADDRESS
110 GOSUB 290 : REM WRITE DATA TO THE PRINTER PORT
120 AB$="FILTER B "
130 GOSUB 180 : REM GET DATA FOR SECTION B
140 ADD=32 : REM FILTER B ADDRESS
150 GOSUB 290 : REM WRITE DATA TO THE PRINTER PORT
160 NEXT
170 GOTO 60
180 PRINT "MODE (1 TO 4, SEE TABLE 5) "; AB$;
190 INPUT M
200 IF M<1 OR M>4 THEN 180
210 PRINT "CLOCK RATIO (0 TO 63, N OF TABLE 2) "; AB$;
220 INPUT F
230 IF F<0 OR F>63 THEN 210
240 PRINT "Q (0 TO 127, N OF TABLE 3) "; AB$;
250 INPUT Q
260 IF Q<0 OR Q>127 THEN 240
270 PRINT
280 RETURN
290 X=(ADD+M-1)
300 GOSUB 450
310 ADD=ADD+4
320 FOR I=1 TO 3
330 X=ADD+(F-4*INT(F/4))
340 GOSUB 450
350 F=INT(F/4)
360 ADD=ADD+4
370 NEXT I
380 FOR I=1 TO 4
390 X=ADD+(Q-4*INT(Q/4))
400 GOSUB 450
410 Q=INT(Q/4)
420 ADD=ADD+4
430 NEXT I
440 RETURN
450 '>>>>>>> OUTPUT <<<<<<<<<<<<
460 OUT PORT,X
470 OUT PORT+2,CHIP
480 OUT PORT+2,0
490 RETURN