home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
HAM Radio 1
/
HamRadio.cdr
/
tech
/
david4
/
stlstdya.bas
< prev
next >
Wrap
BASIC Source File
|
1987-01-24
|
4KB
|
118 lines
10 REM STL STUDY PROGRAM
40 TE=10
50 DEF FNA(A)=LOG(A)/LOG(TE)
85 PRINT"THE BROADCASTERS DATABASE PRESENTS:"
90 PRINT"STL PATH STUDY...TO FIND ANTENNA SIZE NEEDED."
95 PRINT"ALL WORK IS IN DBW (DBD)...EXCEPT TRANSMITTER"
97 PRINT"POWER IS IN WATTS."
100 INPUT"CUSTOMER CALL OR ID";CI$
110 INPUT"FREQUENCY (mhz)";F
120 INPUT"PATH LENGTH (mi) ";M
130 INPUT"COAX LOSS (db/100')";CL
140 INPUT"COAX LENGTH (ft.)";CF
150 INPUT"TRANSMITTER OUTPUT POWER (W)";P
160 INPUT"FADE FACTOR (db, 0 UNKNOWN)";FF:FF=ABS(FF)
170 INPUT"TRANSMITTER TOWER/ANT HEIGHT (ft.)";HT
180 INPUT"EXTRA LOSS (ie.3db FOR COMBINER,ETC)";EL:EL=ABS(EL)
185 :
190 PRINT" RECEIVER 606C IS 93.5dbw"
193 PRINT" 606 IS 111dbw"
195 PRINT" SENSITIVITY 505C IS 94.5dbw"
197 PRINT" 505 IS 111dbw"
200 PRINT" BELOW STL-10 IS 114dbw"
210 PRINT" PTS-10N IS 116.8dbw
220 PRINT" 0 dbw PTS-10C IS 103dbw"
230 PRINT" M/A COM IS 102dbw"
240 INPUT SR:SR=ABS(SR)
250 PRINT" WORKING.....":PRINT
260 FO=FNA(F):D=FNA(M):W=FNA(P)
270 PL=36.6+(20*FO)+(20*D)
275 CC=CL/100
280 XL= (CC*CF)+.25
290 TG=10*W
300 FC=1316*SQR(((M/2)^2)/F*M)
350 DH=1.41*SQR(HT)
400 TL=TG-PL-XL-EL-FF
900 PRINT:PRINT:PRINT
1000 PRINT"PATH STUDY FOR ";CI$;" ON ";F;" mhz."
1010 PRINT:PRINT"FOR A ";M;" MILE PATH THERE IS ";PL;"dbw. LOSS."
1020 PRINT"FOR ";CF;" FT. COAX RATED AT ";CL;" db/100' EXPECT"
1025 PRINT XL;" dbw LOSS INCLUDING .25dbw FOR CONNECTORS."
1030 PRINT:PRINT"WITH ";P;"WATTS TOP AND ";FF;"dbw FADE"
1035 PRINT"FACTOR AND ";EL;" dbw LOSS, YOU MAY ASSUME"
1040 PRINT"THE TOTAL RECIEVER SIGNAL WITH NO ANTENNAS"
1050 PRINT"SHOULD BE ";TL;" dbw. THE GAIN NEEDED FOR THE 2"
1055 AG=-TL-SR
1060 PRINT"ANTENNAS IS ";AG;" dbw FOR -";SR;"dbw SENSITIVITY."
1070 PRINT:PRINT"THIS WOULD BE ABOUT ";AG/2;"dbw PER ANTENNA."
1080 PRINT"THE DISTANCE TO THE HORIZON IS ";DH;" MILES."
1090 PRINT"AND THE FATTEST PART OF .6 OF THE 1ST. FRESNEL"
1094 PRINT"ZONE IS ";FC;" FT."
1095 IF I=0 THEN GOTO 1097
1097 PRINT: IF I>0 THEN 3000:
2000 GOTO 5700
2010 IF X$="Y" THEN GOSUB 5000
3000 END
5000 :
5060 REM LAT & LONG SUBS
5070 GOSUB 5190
5080 PRINT"PLEASE ENTER DEGREES, MINUTES, SECONDS (D,M,S)"
5100 GOSUB 5280
5110 GOSUB 5360
5120 GOSUB 5470
5130 GOSUB 5520
5140 GOSUB 5570
5150 PRINT
5180 RETURN
5190 PI=3.141592654#
5200 REM ARCSINE FUNC
5210 DEF FN ASN(X)=ATN(X/SQR(-X*X+1))
5220 REM ARCCOSINE FUNC
5230 DEF FN ACS(X)=-ATN(X/SQR(-X*X+1))+PI/2
5240 REM DEG/RADIANS
5250 DEF FN RAD(D)=D*PI/180
5260 DEF FN DEG(R)=R/PI*180
5270 RETURN
5280 PRINT
5290 INPUT"FROM LATITUDE (D,M,S): ";D1,M1,S1
5300 INPUT"FROM LONGITUDE (D,M,S): ";D2,M2,S2
5330 INPUT"TO LATITUDE (D,M,S): ";D3,M3,S3
5340 INPUT"TO LONGITUDE (D,M,S): ";D4,M4,S4
5350 RETURN
5360 L1=D1+M1/60+S1/3600
5370 G1=D2+M2/60+S2/3600
5380 L2=D3+M3/60+S3/3600
5390 G2=D4+M4/60+S4/3600
5400 REM CONV TO RADIANS
5410 L1=FN RAD(L1)
5420 G1=FN RAD(G1)
5430 L2=FN RAD(L2)
5440 G2=FN RAD(G2)
5450 RETURN
5460 REM CALC DISTANCE
5470 ANGLE=COS (L1)*COS(L2)*COS(G1-G2)+SIN(L1)*SIN(L2)
5480 ARC=FN ACS(ANGLE)
5490 DIST=FN DEG (ARC)*69.09571
5500 RETURN
5510 REM CALC BEARING
5520 ANGLE=COS (L2)/SIN(ARC)*SIN (G1-G2)
5530 BEARING = FN DEG (FN ASN (ANGLE))
5540 IF L2<L1 THEN BEARING=180-BEARING
5550 IF BEARING<0 THEN BEARING=BEARING+360
5560 RETURN
5570 REM RESULTS
5580 M=DIST+.5:IF X$="Y" THEN PRINT
5590 PRINT:PRINT"FROM";D1;",";M1;",";S1;" & ";D2;",";M2;",";S2
5595 PRINT:PRINT"TO ";D3;",";M3;",";S3;" & ";D4;",";M4;",";S4
5600 PRINT:PRINT"IS ";M;" MILES"
5610 I=BEARING+.5
5616 PRINT
5620 PRINT"AND THE BEARING IS ";I;" DEGREES TRUE."
5625 PRINT
5630 RETURN
5700 PRINT:PRINT:INPUT"ANOTHER STUDY ? - (Y) OR (N) ";E$
5705 IF E$="Y" OR E$="y" THEN 10
5710 PRINT"THANK YOU FOR USING THE STL PATH STUDY PROGRAM"
5720 PRINT"PLEASE WAIT FOR THE SYSTEM TO REBOOT"
5730 SYSTEM