home *** CD-ROM | disk | FTP | other *** search
/ HAM Radio 1 / HamRadio.cdr / packet / autopac / packet.cmd < prev   
OS/2 REXX Batch file  |  1987-07-10  |  8KB  |  208 lines
  1. ;          *** PACKET.CMD *** A ProComm SCRIPT FILE FOR PACKET OPERATION
  2. ;                             ver. 1.50  07/12/87
  3. ;                           by KE4SW, Joel Ackerman
  4. ;
  5. ;THIS SCRIPT WAS BUILT FOR USE WITH TAPR (CLONE) TNC-2 AND PC COMPATIBLE.
  6. ;YOU MUST HAVE PROCOMM (VER. 2.3 OR ABOVE)...BE SURE COMMAND.COM IS IN THE 
  7. ;SAME DIRECTORY THAT THIS RUNS FROM.  
  8. ;REPLACE FUTURE REFERENCES TO "KE4SW" WITH YOUR CALL, AND "Joel" WITH YOUR NAME
  9. ;FOR MESSAGE TO ALL NEW CALLERS CREATE (READ-ONLY) FILE CALLED "OM" 
  10. ;MESSAGES FROM CALLERS GO TO FILE "PACLOG" (AND TO PRINTER IF YOU WISH)  BE
  11. ;SURE TO CLEAR THIS FILE FROM TIME TO TIME.
  12. SET BAUDRATE 1200          ;REINIT COMM PARAMS IN CASE SET FOR MODEM
  13. SET PARITY EVEN            ;THE SCRIPT MAY NOT FOLLOW 9600 BAUD. SPEED,
  14. SET DATABITS 7             ;PARITY AND DATABITS MAY BE CHANGED IF YOU WISH
  15. SET PORT COM1              ;AS LONG AS THEY MATCH YOUR TNC
  16. TRANSMIT "^C!"
  17. WAITFOR "cmd:"
  18. MESSAGE "DO YOU WANT MESSAGES PRINTED?"  ; PRINTS MESSAGES AND CONNECTS
  19. RGET S9 1 15                ;WAITS 15 SECONDS THEN GOES W/DEFAULT CASE
  20. SWITCH S9
  21.  
  22. ;THE FOLLOWING LINES DETERMINE PRINTER STATUS.  IF YOU WANT THE PRINTER TO 
  23. ;DEFAULT TO *ON* SWAP THE "N" AND "Y" ASSIGNMENTS IN THE NEXT 7 LINES.  YOU 
  24. ;MUST ALSO SWAP THE "WILL" AND "WILL *NOT* MESSAGES. CURRENT DEFAULT IS OFF. 
  25.  
  26.     CASE "Y"                ;MAKE THIS AN N FOR DEFAULT PRINTER ON
  27.     ASSIGN S9 "Y"           ;MAKE THIS AN N FOR DEFAULT PRINTER ON
  28.     MESSAGE "!MESSAGES WILL BE PRINTED!"
  29.     ENDCASE                 ; WARNING..PRINTER MUST BE ON LINE OR COULD LOCK UP
  30.     DEFAULT                 ;IF YOU DON'T DO SOMETHING IT WILL DO WHAT FOLLOWS
  31.     ASSIGN S9 "N"           ;MAKE THIS AN Y FOR DEFAULT PRINTER ON...
  32.     MESSAGE "!MESSAGES WILL *NOT* BE PRINTED!"
  33.     ENDCASE
  34. ENDSWITCH
  35. TRANSMIT "^x"                ;KILLS THE "BAD" PACKET FROM THE REPLY ABOVE
  36. GOTO START:
  37. 
  38. ALARM:                      ;MAIN LOOP AFTER CONNECT
  39. TRANSMIT "^CCONV!     QRX...!" ;CONVERSE MODE, THEN QRX
  40. TRANSMIT "HANG ON...I'M CALLING THE BOSS...!"
  41. TRANSMIT "!"
  42. ALARM 10                    ;YOU THERE, BOSS? (10 SECOND ALARM)
  43. TRANSMIT"This is Joel's computer speaking.  Joel's not here....!"
  44. ASSIGN S2 "OM"              ;INITIALIZE (NAME) VARIABLE
  45. ASSIGN S3 " "               ;CLEAR S3 (DELETE FILE VARIABLE)
  46. ASSIGN S4 " "               ;CLEAR S4 (CALL FILE VARIABLE)
  47. GOSUB TEST:                 ;TEST FOR SPECIAL CASES 
  48. LOG OPEN "PACLOG"           ;OPEN LOG FILE
  49. MESSAGE "! ! !"             ;3 CRS IN LOG
  50. MESSAGE S0                  ;CONNECT STRING IN LOG
  51. TRANSMIT"I have opened a file to receive your transmissions, ^v"
  52. TRANSMIT S2
  53. TRANSMIT "^v!"
  54. TRANSMIT "^v!You have 8 minutes to send your message.^v!"
  55. TRANSMIT"Please end your message with a /AR ... QRV. K!"
  56. SWITCH S9
  57.     CASE "Y"                ;IF SET UP FOR PRINTER ON
  58.     PRINTER ON              ;PRINTER IS NOW ACTIVE
  59.     MESSAGE S0              ;PRINTS CONNECT STRING
  60.     MESSAGE S2              ;AND HANDLE
  61.     ENDCASE
  62.     DEFAULT
  63.     PRINTER OFF             ;IF NOT PRINTER (REMAINS) OFF
  64.     ENDCASE
  65. ENDSWITCH
  66. 
  67. WAITFOR  "/AR!" 420         ;WAIT 420+60 SECONDS FOR /AR WITH RETURN
  68. 
  69. IF NOT WAITFOR
  70. GOSUB 1MORE:                ;SENDS 1 MIN. WARNING MESSAGE
  71. ENDIF
  72. 
  73.    TRANSMIT "Thanks for calling, "
  74.    TRANSMIT S2
  75.    TRANSMIT ".  73 es CUL....de KE4SW  AR SK! !"
  76. ;IF YOU WANT TO TRANSMIT A LONGER GOODBYE MESSAGE INSERT A STATEMENT HERE
  77. ;LIKE:   SENDFILE ASCII "BYEBYE"
  78.    PAUSE 15                 ;LET HIM DISCONNECT IF HE WANTS
  79.    TRANSMIT "^CDISCONNECT!" ;OR WE DO IT AND RESTART BELOW
  80. 
  81. START:                     ;RESET, RESTART AFTER MESSAGE CYCLE
  82. PRINTER OFF
  83. LOG CLOSE
  84. TRANSMIT "^C^Q!"           ;CMD MODE: XON
  85. TRANSMIT "MONITOR OFF!"
  86. WAITFOR "MONITOR  was O" 60 ;MAY TAKE AWHILE 
  87. TRANSMIT "CMSG OFF!"       ;SETUP
  88. WAITFOR "CMSG     was O"
  89. TRANSMIT "MCON OFF!"
  90. WAITFOR "MCON     was O"
  91. TRANSMIT "MONITOR ON!"      ;DELETE THESE TWO LINES IF YOU WISH TO
  92. WAITFOR "MONITOR  was O"    ;LEAVE MONITOR OFF
  93. 
  94. WAITMORE:                   ;WAIT FOR CONNECT LOOP
  95. WAITFOR "*** CONNE" 999
  96.     IF WAITFOR              ;CONNECTED
  97.     RGET S0                 ;GET CONNECT STRING
  98.     GOTO ALARM:             ;GO TO MAIN LOOP
  99.     ELSE                    ;TIMEOUT ON WAITFOR...DO IT AGAIN
  100.     TRANSMIT"^CDA!"         ;JUST PUT THE TIME OUT THERE
  101.     GOTO WAITMORE:
  102.     ENDIF
  103. 
  104. TEST:                       ;TEST FOR SPECIAL CALLERS
  105. FIND S0 "KF4CX"             ;TO SEND THEM MESSAGE IF CALL IS FOUND
  106.     IF FOUND
  107.     ASSIGN S2 "Doc"
  108.     ASSIGN S3 "DEL KF4CX"
  109.     ASSIGN S4 "KF4CX"
  110.     GOTO MESSAGE:
  111.     endif
  112. 
  113. FIND S0 "WD4FSU"                 ;\
  114.     IF FOUND                     ; \
  115.         ASSIGN S2 "Owen"         ;  \
  116.         ASSIGN S3 "DEL WD4FSU"   ;   \YOU CAN HAVE AS MANY OF THESE AS NEEDED.
  117.         ASSIGN S4 "WD4FSU"       ;   /LEAVE MESSAGE TO CALLER IN FILE WITH HIS
  118.         GOTO MESSAGE:            ;  / CALL AS ITS NAME (E.G. FILENAME=WD4FSU)
  119.     ELSE                         ; /
  120.     ENDIF                        ;/
  121. 
  122. FIND S0 "W4HR"
  123.     IF FOUND
  124.         ASSIGN S2 "Bob"
  125.         ASSIGN S3 "DEL W4HR"
  126.         ASSIGN S4 "W4HR"
  127.         GOTO MESSAGE:
  128.     ELSE
  129.     ENDIF
  130. 
  131. MESSAGE:
  132.     TRANSMIT "(de computer) Hi, "
  133.     TRANSMIT S2
  134.     TRANSMIT "...!"
  135. 
  136. REMESSAGE:
  137.     ISFILE S4                   ;LOOKING FOR FILENAME=CALL
  138.         IF NOT SUCCESS
  139.             GOSUB FAIL:         ;DIDN'T FIND IT
  140.             RETURN
  141.         ELSE                    ;DID FIND IT.
  142.             TRANSMIT "Standby for a message from KE4SW in 5 seconds!"
  143.             PAUSE 5
  144.             SENDFILE ASCII S4   ;SENDS THE FILE--CHECK YOUR ASCII
  145. FILE PARAMS
  146.             TRANSMIT "!Do you want to (R)eplay your message^v!"
  147.             TRANSMIT "               (D)elete it & continue^v!"
  148.             TRANSMIT "            or (C)ontinue without deleting?!"
  149. AFTERMSG:
  150.             TRANSMIT "^v!Which do you want to do, "
  151.             TRANSMIT S2
  152.             TRANSMIT "?!"
  153.             RFLUSH              ;CLEARS RECEIVE BUFFER IF NOT EMPTY
  154.             RFLUSH
  155.             RGET S1 1 999      ;WAITS FOR 1 CHARACTER REPLY 
  156.             SWITCH S1
  157.                 CASE "R"
  158.                     GOTO REMESSAGE:
  159.                 ENDCASE
  160.                 CASE "D"
  161.                     MESSAGE S3
  162.                     DOS S3
  163.                     TRANSMIT"* MESSAGE DELETED *!"
  164.                     RETURN
  165.                 ENDCASE
  166.                 CASE "C"
  167.                     RETURN
  168.                 ENDCASE
  169.                 CASE "_NULL"
  170.                     RETURN
  171.                 ENDCASE
  172.                 DEFAULT         ; WASN'T R, D, OR C....
  173.                     TRANSMIT "ENTER `"R, D, or C`" PLEASE"
  174.                     GOTO AFTERMSG:
  175.                 ENDCASE
  176.              ENDSWITCH
  177.         ENDIF
  178.         RETURN
  179. 
  180. FAIL:
  181. 
  182.         TRANSMIT "No messages for you "
  183.         TRANSMIT S2
  184.         TRANSMIT "!"
  185.         RETURN
  186. 
  187. 1MORE:
  188. TRANSMIT "Just one minute remaining before time out, "
  189. TRANSMIT S2
  190. TRANSMIT ".!"
  191. WAITFOR  "/AR!" 60 
  192.   IF NOT WAITFOR
  193.   GOSUB TIMEOUT:
  194.   ELSE
  195.   ENDIF
  196. RETURN
  197. 
  198. TIMEOUT:
  199. TRANSMIT "TIME EXPIRED!" ;TIMEOUT
  200. PAUSE 5
  201. TRANSMIT "^CDISCONNECT!" ;DISCONNECT AND RESTART
  202. TRANSMIT "DA!"           ;TIME IN THE LOG
  203. PAUSE 2
  204. RETURN
  205. ;End of AutoPac Script.  Address all comments to KE4SW (@ WA4VMV) or mail to
  206. ; Joel Ackerman, 5118 Highland Trail, Acworth, GA  30101.      
  207. ;ENJOY!!
  208.