home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
HAM Radio 1
/
HamRadio.cdr
/
packet
/
autopac
/
packet.cmd
< prev
Wrap
OS/2 REXX Batch file
|
1987-07-10
|
8KB
|
208 lines
; *** PACKET.CMD *** A ProComm SCRIPT FILE FOR PACKET OPERATION
; ver. 1.50 07/12/87
; by KE4SW, Joel Ackerman
;
;THIS SCRIPT WAS BUILT FOR USE WITH TAPR (CLONE) TNC-2 AND PC COMPATIBLE.
;YOU MUST HAVE PROCOMM (VER. 2.3 OR ABOVE)...BE SURE COMMAND.COM IS IN THE
;SAME DIRECTORY THAT THIS RUNS FROM.
;REPLACE FUTURE REFERENCES TO "KE4SW" WITH YOUR CALL, AND "Joel" WITH YOUR NAME
;FOR MESSAGE TO ALL NEW CALLERS CREATE (READ-ONLY) FILE CALLED "OM"
;MESSAGES FROM CALLERS GO TO FILE "PACLOG" (AND TO PRINTER IF YOU WISH) BE
;SURE TO CLEAR THIS FILE FROM TIME TO TIME.
SET BAUDRATE 1200 ;REINIT COMM PARAMS IN CASE SET FOR MODEM
SET PARITY EVEN ;THE SCRIPT MAY NOT FOLLOW 9600 BAUD. SPEED,
SET DATABITS 7 ;PARITY AND DATABITS MAY BE CHANGED IF YOU WISH
SET PORT COM1 ;AS LONG AS THEY MATCH YOUR TNC
TRANSMIT "^C!"
WAITFOR "cmd:"
MESSAGE "DO YOU WANT MESSAGES PRINTED?" ; PRINTS MESSAGES AND CONNECTS
RGET S9 1 15 ;WAITS 15 SECONDS THEN GOES W/DEFAULT CASE
SWITCH S9
;THE FOLLOWING LINES DETERMINE PRINTER STATUS. IF YOU WANT THE PRINTER TO
;DEFAULT TO *ON* SWAP THE "N" AND "Y" ASSIGNMENTS IN THE NEXT 7 LINES. YOU
;MUST ALSO SWAP THE "WILL" AND "WILL *NOT* MESSAGES. CURRENT DEFAULT IS OFF.
CASE "Y" ;MAKE THIS AN N FOR DEFAULT PRINTER ON
ASSIGN S9 "Y" ;MAKE THIS AN N FOR DEFAULT PRINTER ON
MESSAGE "!MESSAGES WILL BE PRINTED!"
ENDCASE ; WARNING..PRINTER MUST BE ON LINE OR COULD LOCK UP
DEFAULT ;IF YOU DON'T DO SOMETHING IT WILL DO WHAT FOLLOWS
ASSIGN S9 "N" ;MAKE THIS AN Y FOR DEFAULT PRINTER ON...
MESSAGE "!MESSAGES WILL *NOT* BE PRINTED!"
ENDCASE
ENDSWITCH
TRANSMIT "^x" ;KILLS THE "BAD" PACKET FROM THE REPLY ABOVE
GOTO START:
ALARM: ;MAIN LOOP AFTER CONNECT
TRANSMIT "^CCONV! QRX...!" ;CONVERSE MODE, THEN QRX
TRANSMIT "HANG ON...I'M CALLING THE BOSS...!"
TRANSMIT "!"
ALARM 10 ;YOU THERE, BOSS? (10 SECOND ALARM)
TRANSMIT"This is Joel's computer speaking. Joel's not here....!"
ASSIGN S2 "OM" ;INITIALIZE (NAME) VARIABLE
ASSIGN S3 " " ;CLEAR S3 (DELETE FILE VARIABLE)
ASSIGN S4 " " ;CLEAR S4 (CALL FILE VARIABLE)
GOSUB TEST: ;TEST FOR SPECIAL CASES
LOG OPEN "PACLOG" ;OPEN LOG FILE
MESSAGE "! ! !" ;3 CRS IN LOG
MESSAGE S0 ;CONNECT STRING IN LOG
TRANSMIT"I have opened a file to receive your transmissions, ^v"
TRANSMIT S2
TRANSMIT "^v!"
TRANSMIT "^v!You have 8 minutes to send your message.^v!"
TRANSMIT"Please end your message with a /AR ... QRV. K!"
SWITCH S9
CASE "Y" ;IF SET UP FOR PRINTER ON
PRINTER ON ;PRINTER IS NOW ACTIVE
MESSAGE S0 ;PRINTS CONNECT STRING
MESSAGE S2 ;AND HANDLE
ENDCASE
DEFAULT
PRINTER OFF ;IF NOT PRINTER (REMAINS) OFF
ENDCASE
ENDSWITCH
WAITFOR "/AR!" 420 ;WAIT 420+60 SECONDS FOR /AR WITH RETURN
IF NOT WAITFOR
GOSUB 1MORE: ;SENDS 1 MIN. WARNING MESSAGE
ENDIF
TRANSMIT "Thanks for calling, "
TRANSMIT S2
TRANSMIT ". 73 es CUL....de KE4SW AR SK! !"
;IF YOU WANT TO TRANSMIT A LONGER GOODBYE MESSAGE INSERT A STATEMENT HERE
;LIKE: SENDFILE ASCII "BYEBYE"
PAUSE 15 ;LET HIM DISCONNECT IF HE WANTS
TRANSMIT "^CDISCONNECT!" ;OR WE DO IT AND RESTART BELOW
START: ;RESET, RESTART AFTER MESSAGE CYCLE
PRINTER OFF
LOG CLOSE
TRANSMIT "^C^Q!" ;CMD MODE: XON
TRANSMIT "MONITOR OFF!"
WAITFOR "MONITOR was O" 60 ;MAY TAKE AWHILE
TRANSMIT "CMSG OFF!" ;SETUP
WAITFOR "CMSG was O"
TRANSMIT "MCON OFF!"
WAITFOR "MCON was O"
TRANSMIT "MONITOR ON!" ;DELETE THESE TWO LINES IF YOU WISH TO
WAITFOR "MONITOR was O" ;LEAVE MONITOR OFF
WAITMORE: ;WAIT FOR CONNECT LOOP
WAITFOR "*** CONNE" 999
IF WAITFOR ;CONNECTED
RGET S0 ;GET CONNECT STRING
GOTO ALARM: ;GO TO MAIN LOOP
ELSE ;TIMEOUT ON WAITFOR...DO IT AGAIN
TRANSMIT"^CDA!" ;JUST PUT THE TIME OUT THERE
GOTO WAITMORE:
ENDIF
TEST: ;TEST FOR SPECIAL CALLERS
FIND S0 "KF4CX" ;TO SEND THEM MESSAGE IF CALL IS FOUND
IF FOUND
ASSIGN S2 "Doc"
ASSIGN S3 "DEL KF4CX"
ASSIGN S4 "KF4CX"
GOTO MESSAGE:
endif
FIND S0 "WD4FSU" ;\
IF FOUND ; \
ASSIGN S2 "Owen" ; \
ASSIGN S3 "DEL WD4FSU" ; \YOU CAN HAVE AS MANY OF THESE AS NEEDED.
ASSIGN S4 "WD4FSU" ; /LEAVE MESSAGE TO CALLER IN FILE WITH HIS
GOTO MESSAGE: ; / CALL AS ITS NAME (E.G. FILENAME=WD4FSU)
ELSE ; /
ENDIF ;/
FIND S0 "W4HR"
IF FOUND
ASSIGN S2 "Bob"
ASSIGN S3 "DEL W4HR"
ASSIGN S4 "W4HR"
GOTO MESSAGE:
ELSE
ENDIF
MESSAGE:
TRANSMIT "(de computer) Hi, "
TRANSMIT S2
TRANSMIT "...!"
REMESSAGE:
ISFILE S4 ;LOOKING FOR FILENAME=CALL
IF NOT SUCCESS
GOSUB FAIL: ;DIDN'T FIND IT
RETURN
ELSE ;DID FIND IT.
TRANSMIT "Standby for a message from KE4SW in 5 seconds!"
PAUSE 5
SENDFILE ASCII S4 ;SENDS THE FILE--CHECK YOUR ASCII
FILE PARAMS
TRANSMIT "!Do you want to (R)eplay your message^v!"
TRANSMIT " (D)elete it & continue^v!"
TRANSMIT " or (C)ontinue without deleting?!"
AFTERMSG:
TRANSMIT "^v!Which do you want to do, "
TRANSMIT S2
TRANSMIT "?!"
RFLUSH ;CLEARS RECEIVE BUFFER IF NOT EMPTY
RFLUSH
RGET S1 1 999 ;WAITS FOR 1 CHARACTER REPLY
SWITCH S1
CASE "R"
GOTO REMESSAGE:
ENDCASE
CASE "D"
MESSAGE S3
DOS S3
TRANSMIT"* MESSAGE DELETED *!"
RETURN
ENDCASE
CASE "C"
RETURN
ENDCASE
CASE "_NULL"
RETURN
ENDCASE
DEFAULT ; WASN'T R, D, OR C....
TRANSMIT "ENTER `"R, D, or C`" PLEASE"
GOTO AFTERMSG:
ENDCASE
ENDSWITCH
ENDIF
RETURN
FAIL:
TRANSMIT "No messages for you "
TRANSMIT S2
TRANSMIT "!"
RETURN
1MORE:
TRANSMIT "Just one minute remaining before time out, "
TRANSMIT S2
TRANSMIT ".!"
WAITFOR "/AR!" 60
IF NOT WAITFOR
GOSUB TIMEOUT:
ELSE
ENDIF
RETURN
TIMEOUT:
TRANSMIT "TIME EXPIRED!" ;TIMEOUT
PAUSE 5
TRANSMIT "^CDISCONNECT!" ;DISCONNECT AND RESTART
TRANSMIT "DA!" ;TIME IN THE LOG
PAUSE 2
RETURN
;End of AutoPac Script. Address all comments to KE4SW (@ WA4VMV) or mail to
; Joel Ackerman, 5118 Highland Trail, Acworth, GA 30101.
;ENJOY!!