home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
HAM Radio 1
/
HamRadio.cdr
/
misc
/
vhfpro
/
vhfprop!.asc
next >
Wrap
Text File
|
1988-03-20
|
7KB
|
196 lines
' VHFPROP.BAS Calculates communications range and reliability
' for VHF terrestrial communications.
27 REM *** PROGRAM IS BASED ON EGLI
28 REM *** PROPAGATION MODEL DESCRIBED
29 REM *** IN "RADIO PROPAGATION ABOVE
30 REM *** 40 MC OVER IRREGULAR TERRAIN"
31 REM *** BY JOHN J. EGLI
32 REM *** PROC. IRE, OCTOBER 1957,
33 REM *** PP 1383-1391
34 REM ***
35 REM *** AND FURTHER DESCRIBED AND
36 REM *** VALIDATED IN "REVIEW OF
37 REM *** PROPAGATION IN THE 470-
38 REM *** 890 MHZ BAND WITH EMPHASIS
39 REM *** ON LAND MOBILE AND CELLULAR
40 REM *** SYSTEMS" BY F.H. PALMER,
41 REM *** COMMUNICATIONS RESEARCH CENTRE
42 REM *** REPORT NO. 1288, FEBRUARY 1976,
43 REM *** OTTAWA, ONTARIO (AVAILABLE
44 REM *** THROUGH N.T.I.S. AS N76-27450)
45 REM ***
90 DEF FN LGT(X) = .4342945 * LOG (X)
MENU:
CLS
PRINT "╔═══════════════════════════════════════════════════════════════╗"
PRINT "║ VHF TERRESTRIAL PROPAGATION - MODULE 3 ║"
PRINT "╚═══════════════════════════════════════════════════════════════╝"
155 PRINT
160 INPUT "ENTER FREQUENCY IN MHZ. ";F
180 REM CALCULATE STD DEVIATION(SIGMA) OF PATH LOSS
185 REM AND STORE AS S
190 S = (5.47 * FN LGT(F)) - 3.22
195 PRINT
200 PRINT "ARE BOTH RECEIVING AND TRANSMITTING ANTENNAS HIGHER THAN"
210 PRINT "30 FEET? ENTER YES OR NO: ";
220 INPUT Z$
230 IF LEFT$(Z$,1) = "Y" OR LEFT$(Z$,1) = "y" THEN 300
235 PRINT
240 PRINT "ARE BOTH RECEIVING AND TRANSMITTING ANTENNAS LOWER THAN"
250 PRINT "30 FEET? ENTER YES OR NO: ";
260 INPUT Y$
270 IF LEFT$(Y$,1) = "Y" OR LEFT$(Y$,1) = "y" THEN 320
275 PRINT
280 PRINT "COMPUTER ASSUMES ONE ANT. IS HIGHER, THE OTHER LOWER THAN 30'"
290 GOTO 0340
300 E = 1.0
310 GOTO 0345
320 E = 2.0
330 GOTO 0345
340 E = 3.0
345 PRINT
350 PRINT "ENTER HEIGHT OF HIGHER ANTENNA, IN FEET: ";
360 INPUT H1
370 REM H1 IS H(T) IN EGLI MODEL
375 PRINT
380 PRINT "ENTER HEIGHT OF LOWER ANTENNA IN FEET: ";
390 INPUT H2
400 REM H2 IS H(R) IN EGLI MODEL
405 PRINT
410 PRINT "ENTER TRANSMITTER POWER OUTPUT IN WATTS: ";
420 INPUT P
430 P = 10 * ( FN LGT(P / .001))
440 REM P IS NOW STORED IN DBM, REF 1 MW/50 OHMS
445 PRINT
450 PRINT "ENTER TRANSMITTING ANTENNA GAIN IN DB ABOVE ISOTROPIC: ";
460 INPUT G1
485 PRINT
490 PRINT "ENTER TRANSMITTER TRANSMISSION LINE LOSS"
500 PRINT "IN DB FOR LENGTH ACTUALLY USED-ENTER AS POSITIVE VALUE: ";
510 INPUT L1
505 PRINT
520 PRINT "ENTER ANY ADDITIONAL LOSSES BETWEEN TRANSMITTER AND ANTENNA"
530 PRINT "SUCH AS FILTERS, DUPLEXER OR RELAY LOSSES, IN DB. "
535 PRINT "IF NONE, ENTER 0 : ";
550 INPUT A
560 L1 = L1 + A
565 PRINT
570 PRINT "ENTER RECEIVING ANTENNA GAIN IN DB ABOVE ISOTROPIC: ";
580 INPUT G2
605 PRINT
610 PRINT "ENTER RECEIVING TRANSMISSION LINE LOSS IN DB."
620 PRINT "FOR LENGTH ACTUALLY USED: ";
630 INPUT L2
635 PRINT
640 PRINT "ENTER ANY ADDITIONAL LOSSES SUCH AS FILTERS, DUPLEXERS OR"
650 PRINT "RELAY LOSSES IN DB. IF NONE , ENTER 0 :";
660 INPUT B
670 L2 = L2 + B
675 PRINT
680 PRINT "ENTER REQUIRED RECEIVED SIGNAL LEVEL IN MICROVOLTS."
690 PRINT "AT RECEIVER INPUT. USE VALUE REPRESENTATIVE OF LEVEL"
700 PRINT "NEEDED FOR GOOD OPERATIONAL S/N, NOT THE TYPICAL "
710 PRINT "10 OR 20DB S/N AS IN THE SENSITIVITY SPECIFICATION."
720 PRINT "IF NOT KNOWN, TRY 3 TIMES THE SENSITIVITY FIGURE :";
730 INPUT R
735 R = R * 1E-06
740 R = 10 * FN LGT(((R ^ 2) / 50) / .001)
750 REM R IS NOW STORED IN DBM
760 REM CALCULATE ALLOWABLE MEDIAN PATH LOSS IN DB
770 Q = P + G1 - L1 + G2 - L2 - R
776 REM ARRAY Q( ) TO START WITH 1
780 Q(1) = Q
790 Q(2) = Q - 0.53 * S
800 Q(3) = Q - 1.27 * S
810 Q(4) = Q - 1.65 * S
820 Q(5) = Q - 2.30 * S
830 Q(6) = Q - 3.05 * S
840 REM ALLOWABLE PATH LOSS FOR VARIOUS RELIABILITIES CALCULATED.
850 IF E = 1.0 THEN 1000
860 IF E = 2.0 THEN 0900
870 IF E = 3.0 THEN 0900
880 PRINT "ERROR IN PGM LINE 0880"
900 FOR I = 1 TO 6 STEP 1
910 M(I) = Q(I) - 114.8 - (20 * FN LGT(F)) + (20 * FN LGT(H1)) + (20 * FN LGT(H2))
915 MM(I) = Q(I) - 36.6 - (20 * FN LGT(F))
920 N(I) = M(I) / 40
922 NN(I) = MM(I) / 20
925 IF NN(I) < N(I) THEN N(I) = NN(I)
930 D(I) = 10 ^ N(I)
933 D(I) = INT (D(I) * 100) / 100
935 NEXT I
940 GOTO 1100
1000 FOR I = 1 TO 6 STEP 1
1010 M(I) = Q(I) - 100.0 - (20 * FN LGT(F)) + (20 * FN LGT(H1)) + (10 * FN LGT(H2))
1015 MM(I) = Q(I) - 36.6 - (20 * FN LGT(F))
1020 N(I) = M(I) / 40
1023 NN(I) = MM(I) / 20
1025 IF NN(I) < N(I) THEN N(I) = NN(I)
1030 D(I) = 10 ^ N(I)
1033 D(I) = INT (D(I) * 100) / 100
1035 NEXT I
1040 GOTO 1100
1100 CLS
1101 PRINT "╔═══════════════════════════════════════════════════════════════╗"
1102 PRINT "║ VHF TERRESTRIAL PROPAGATION - MODULE 3 ║"
1103 PRINT "╚═══════════════════════════════════════════════════════════════╝"
1110 PRINT
1115 PRINT
1120 PRINT
1125 PRINT
1130 REM LINES RESERVED
1200 PRINT " RELIABILITY / COMMUNICATIONS RANGE"
1205 PRINT "__________________________________________________"
1220 PRINT
1225 PRINT
1245 PRINT
1246 PRINT
1250 PRINT USING "RANGE WITH 50% RELIABILITY IS ###.# MILES ";D(1)
1260 PRINT USING "RANGE WITH 75% RELIABILITY IS ###.# MILES ";D(2)
1270 PRINT USING "RANGE WITH 90% RELIABILITY IS ###.# MILES ";D(3)
1280 PRINT USING "RANGE WITH 95% RELIABILITY IS ###.# MILES ";D(4)
1290 PRINT USING "RANGE WITH 99% RELIABILITY IS ###.# MILES ";D(5)
1300 PRINT USING "RANGE WITH 99_.9% RELIABILITY IS ###.# MILES ";D(6)
1310 PRINT
1320 PRINT "CHOOSE:"
1330 PRINT " 1) MORE CALCULATIONS"
1340 PRINT " 2) QUIT"
1345 PRINT " ENTER CHOICE (1 or 2): ";
1350 INPUT CX
1360 IF CX = 1 THEN GOTO MENU ELSE GOTO ENDING
ENDING:
CLS
PRINT
LOCATE 10,25
PRINT "≡≡≡ PROGRAM COMPLETED ≡≡≡"
END
'╔═══════════════════════════════════════════════════════════╗
'║ Program Authorship Notice ║
'║ ≡≡≡≡≡≡≡≡≡≡≡≡≡≡≡≡≡≡≡≡≡≡≡≡≡ ║
'║ ║
'║ Jacob Z. Schanker, P.E. ║
'║ ║
'║ Scientific Radio Systems, Inc. ║
'║ 367 Orchard Street ║
'║ Rochester, NY 14606 ║
'║ (716) 235-2040 ║
'║ ║
'║ Last revised: March 1988 ║
'║ ║
'╚═══════════════════════════════════════════════════════════╝