home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
HAM Radio 1
/
HamRadio.cdr
/
misc
/
hamscan
/
grcircle.bas
< prev
next >
Wrap
BASIC Source File
|
1987-03-25
|
1KB
|
33 lines
5 CLEAR 500
10 REM ******* GREAT CIRCLE CALCULATIONS *********
20 PRINT "THE GREAT CIRCLE CALCULATOR"
30 PRINT "BY THE GREAT BIG WHEEL HISSELF"
40 PRINT "NAMELY, OLE J. R., OTHERWISE KNOWN AS WB2LEI"
50 LPRINT " GREAT CIRCLE BEARINGS FROM CHARLOTTE, N. C.":LPRINT
60 LPRINT "PREFIX LAT. LON. BEARING":LPRINT STRING$(64,"-")
65 REM NORTH LAT AND WEST LONG ARE POSITIVE,
66 REM SOUTH LAT AND EAST LONG ARE NEGATIVE.
70 INPUT "INPUT PREFIX";A$
80 INPUT "LATITUDE OF COUNTRY IN DEGREES";B
90 INPUT "LONGITUDE OF COUNTRY IN DEGREES";F
95 REM THE LINE BELOW IS MY LAT & LONG, CHANGE FOR YOUR LOCATION
100 A=35.1333333#:G=80.76666666#
110 REM A=YOUR LATITUDE, G=YOUR LONGITUDE, B=X LAT, F=X LONG
120 L=G-F
130 IF L<180 THEN GOTO 150
140 L=L-360
150 IF L>(-180) THEN GOTO 170
160 L=L+360
170 R=57.29577951#
180 A1=A/R:B1=B/R:L1=L/R
190 D=SIN(A1)*SIN(B1)+COS(A1)*COS(B1)*COS(L1)
200 D1=-ATN(D/SQR(-D*D+1))+1.5708
210 C=(SIN(B1)-(SIN(A1)*COS(D1)))/(COS(A1)*SIN(D1))
220 C1=-ATN(C/SQR(-C*C+1))+1.5708
230 B2=R*C1
240 IF L>=0 THEN GOTO 260
250 B2=360-B2
260 PRINT B2
270 LPRINT A$,B,F,INT(B2+.5)
280 GOTO 70