home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
HAM Radio 1
/
HamRadio.cdr
/
log
/
hamsys
/
hamcnfg.bas
< prev
next >
Wrap
BASIC Source File
|
1987-02-03
|
4KB
|
115 lines
10 ' HAMCNFG - PROGRAM TO SET UP AND MAINTAIN THE DEFAULT FILE
15 'CHANGE DATE - 1/16/87
20 DEF SEG = 64 : POKE 23,64 : ' SET CAPS LOCK ON
30 KEY OFF
40 FOR I = 1 TO 10:KEY I,"":NEXT
50 FOR I = 1 TO 3 :KEY(I) ON : NEXT
60 CLS
70 PRINT "Do you want to copy the configuration file to another drive (Y/N) ?"
80 O$=INKEY$ : IF O$="" THEN GOTO 80
90 IF O$ <> "Y" THEN GOTO 190
100 PRINT "What drive do you want this copied to?"
110 GOSUB 1100
120 DR1$=O$+":"
130 OPEN "cnfg.dat" AS 1 LEN = 58
140 FIELD 1,58 AS A$ : GET 1,1
150 OPEN DR1$+"cnfg.dat" AS 2 LEN = 58
160 FIELD 2,58 AS B$ : LSET B$ = A$ : PUT 2,1
170 CLOSE
180 GOTO 60
190 GOSUB 1020
200 ON KEY (1) GOSUB 680
210 ON KEY (2) GOSUB 710
220 CLS
230 PRINT "The present default values are:"
240 PRINT
250 PRINT "F1 Data drive - ";DR1$
260 PRINT "F2 Fast lookup drive - ";SPEEDLUK$
270 GOSUB 1060 ' Wait for user
280 O$=INKEY$:IF O$="" GOTO 280
290 IF ASC(O$) = 27 THEN RUN "mmenu"
300 IF ASC(O$) <> 13 THEN GOTO 280
310 ON KEY (1) GOSUB 740
320 ON KEY (2) GOSUB 770
330 ON KEY (3) GOSUB 800
340 CLS
350 PRINT " Antennas "
360 PRINT "F1 ";ANT1$
370 PRINT "F2 ";ANT2$
380 PRINT "F3 ";ANT3$
390 GOSUB 1060
400 O$=INKEY$:IF O$="" GOTO 400
410 IF ASC(O$) = 27 THEN RUN "mmenu"
420 IF ASC(O$) <> 13 THEN GOTO 400
430 ON KEY (1) GOSUB 830
440 ON KEY (2) GOSUB 860
450 ON KEY (3) GOSUB 890
460 CLS
470 PRINT " Default rigs"
480 PRINT "F1 ";RIG1$
490 PRINT "F2 ";RIG2$
500 PRINT "F3 ";RIG3$
510 GOSUB 1060 ' Wait for user
520 O$=INKEY$:IF O$="" GOTO 520
530 IF ASC(O$) = 27 THEN RUN "mmenu"
540 IF ASC(O$) <> 13 THEN GOTO 520
550 ON KEY (1) GOSUB 920
560 ON KEY (2) GOSUB 950
570 ON KEY (3) GOSUB 980
580 CLS
590 PRINT " Default transmission type"
600 PRINT "F1 ";TRT1$
610 PRINT "F2 ";TRT2$
620 PRINT "F3 ";TRT3$
630 GOSUB 1060 ' Wait for user
640 O$=INKEY$:IF O$="" GOTO 640
650 IF ASC(O$) = 27 THEN RUN "mmenu"
660 IF ASC(O$) <> 13 THEN GOTO 640
670 GOTO 220 ' Go back to start at top
680 PRINT "Enter in the letter of the drive that you want your data file on"
690 GOSUB 1100
700 LSET DR1$=O$+":" : GOSUB 1010 : RETURN 220
710 PRINT "Enter in the letter of the drive where you want you fast lookup"
720 GOSUB 1100
730 LSET SPEEDLUK$=O$+":" : GOSUB 1010 : RETURN 220
740 PRINT "Enter the name of your primary antenna"
750 INPUT A$
760 LSET ANT1$=LEFT$(A$,8) : GOSUB 1010 : RETURN 340
770 PRINT "Enter the name of you second antenna"
780 INPUT A$
790 LSET ANT2$=LEFT$(A$,8) :GOSUB 1010 : RETURN 340
800 PRINT "Enter the name of your third antenna"
810 INPUT A$
820 LSET ANT3$=LEFT$(A$,8) : GOSUB 1010 : RETURN 340
830 PRINT "Enter the name of your primary rig"
840 INPUT A$
850 LSET RIG1$=LEFT$(A$,8) : GOSUB 1010 :RETURN 460
860 PRINT "Enter the name of your second rig"
870 INPUT A$
880 LSET RIG2$=LEFT$(A$,8) : GOSUB 1010 :RETURN 460
890 PRINT "Enter the name of your third rig"
900 INPUT A$
910 LSET RIG3$=LEFT$(A$,8) : GOSUB 1010 :RETURN 460
920 PRINT "Enter the name of your primary transmission type"
930 INPUT A$
940 LSET TRT1$=LEFT$(A$,8) : GOSUB 1010 : RETURN 580
950 PRINT "Enter the name of your second transmission type"
960 INPUT A$
970 LSET TRT2$=LEFT$(A$,8) : GOSUB 1010 : RETURN 580
980 PRINT "Enter the name of your third transmission type"
990 INPUT A$
1000 LSET TRT3$=LEFT$(A$,8) : GOSUB 1010 : RETURN 580
1010 PUT 1,1 : CLOSE ' Write out file and close it.
1020 OPEN "CNFG.DAT" AS 1 LEN = 58 ' Open the config file
1030 FIELD 1,2 AS DR1$,2 AS SPEEDLUK$,8 AS ANT1$,8 AS ANT2$,8 AS ANT3$,5 AS RIG1$,5 AS RIG2$,5 AS RIG3$,5 AS TRT1$,5 AS TRT2$,5 AS TRT3$
1040 GET 1,1 ' Get configuration record
1050 RETURN
1060 PRINT: PRINT "To change any value press the function key listed in front of the value"
1070 PRINT "ESC quits the program and return continues to next section"
1080 PRINT
1090 RETURN
1100 O$=INKEY$:IF O$="" GOTO 1100
1110 IF O$="A" OR O$="B" THEN RETURN
1120 IF O$="C" OR O$="D" THEN RETURN
1130 GOTO 1100