home *** CD-ROM | disk | FTP | other *** search
/ HAM Radio 1 / HamRadio.cdr / control / hamyaesu / yaesu.bas next >
BASIC Source File  |  1988-09-13  |  3KB  |  86 lines
  1. 1 'YAESU.BAS  FROM OCT. 1985 QST, ADAPTED FOR IBM PC BY NR0T
  2. 100 DEFINT H,D: H=16
  3. 105 KEY OFF:CLOSE
  4. 110 OPEN "COM1:4800,N,8,1" AS #1
  5. 120 T$=""
  6. 130 FOR I = 0 TO 9
  7. 140 FOR J = 0 TO 9
  8. 150 T$ = T$ + CHR$(I * H + J)
  9. 160 NEXT: NEXT
  10. 200 CLS
  11. 205 PRINT: PRINT:LOCATE 3,14:COLOR 0,7: PRINT TAB(27);"   YAESU FT-757GX";SPC(16)
  12. 206 LOCATE 4,14 :PRINT TAB(27);"DIGI-CAT CONTROLLER";SPC(14):COLOR 7,0:PRINT:PRINT
  13. 210 PRINT ,"     1)  Split           2)  MR/VFO":PRINT
  14. 220 PRINT ,"     3)  V => M          4)  Dial Lock":PRINT
  15. 230 PRINT ,"     5)  VFO A/B         6)  M => V":PRINT
  16. 240 PRINT ,"     7)  500 KHz Up      8)  500 KHz Down":PRINT
  17. 250 PRINT ,"     9)  Clar (RIT)      A)  Frequency":PRINT
  18. 260 PRINT ,"     B)  V =>/<= M       C)  Quit":PRINT
  19. 300 LOCATE 19,18 : PRINT "         Enter Choice:"
  20. 305 LOCATE 19,41 : MM$=INKEY$: IF MM$="" THEN 305
  21. 306 PRINT MM$
  22. 307 IF MM$<>"1" AND MM$<>"2" AND MM$<>"3" AND MM$<>"4" AND MM$<>"5" AND MM$<>"6" AND MM$<>"7" AND MM$<>"8" AND MM$<>"9" AND MM$<>"a" AND MM$<>"A" AND MM$<>"b" AND MM$<>"B" AND MM$<>"c" AND MM$<>"C" THEN 305
  23. 310 'IF C < 1 OR C > 12 THEN 300
  24. 320 C=VAL(MM$): M$=CHR$(C)
  25. 330 IF MM$ = "A" OR MM$ = "a" THEN M$=CHR$(10): GOTO 1000
  26. 335 IF MM$ = "B" OR MM$ = "b" THEN M$=CHR$(11)
  27. 340 IF MM$ = "C" OR MM$ = "c" THEN 2000
  28. 500 PRINT#1,CHR$(0);CHR$(0);CHR$(0);CHR$(0);M$
  29. 510 GOTO 300
  30. 1000 ' FREQUENCY CONTROL
  31. 1010 CLS:PRINT
  32. 1020 INPUT  "             Frequency MHz";A
  33. 1030 IF A < .5 OR A > 29.99999 THEN 1010
  34. 1040 GOSUB 1700
  35. 1050 CLS: COLOR 0,7: LOCATE 1,14: PRINT USING"  ##.##### \     \";A;" MHz": COLOR 7,0
  36. 1055 'ALT 1050 CLS|PRINT A;" MHz"
  37. 1060 PRINT"  New frequency [F]     Other [O]"
  38. 1070 PRINT:PRINT"          Fine tuning:"
  39. 1080 PRINT " [A]100        <<-(KHz)+>>        100[']"
  40. 1090 PRINT
  41. 1100 PRINT " 10  5   1  .1  .01  .01 .1   1   5   10"
  42. 1110 PRINT "[Z] [X] [C] [V] [B]  [N] [M] [,] [.] [/]";
  43. 1120 C$=INKEY$:IF C$="" THEN 1120
  44. 1130 IF C$="B" OR C$="b" THEN A=A-.00001:GOTO 1300
  45. 1140 IF C$="N" OR C$="n" THEN A=A+.00001:GOTO 1300
  46. 1150 IF C$="V" OR C$="v" THEN A=A-.0001:GOTO 1300
  47. 1160 IF C$="M" OR C$="m" THEN A=A+.0001:GOTO 1300
  48. 1170 IF C$="C" OR C$="c" THEN A=A-.001: GOTO 1300
  49. 1180 IF C$="," OR C$="<" THEN A=A+.001: GOTO 1300
  50. 1190 IF C$="X" OR C$="x" THEN A=A-.005: GOTO 1300
  51. 1200 IF C$="." OR C$=">" THEN A=A+.005: GOTO 1300
  52. 1210 IF C$="Z" OR C$="z" THEN A=A-.01 : GOTO 1300
  53. 1220 IF C$="/" OR C$="?" THEN A=A+.01 : GOTO 1300
  54. 1230 IF C$="A" OR C$="a" THEN A=A-.1 :  GOTO 1300
  55. 1240 IF C$="'"           THEN A=A+.1 :  GOTO 1300
  56. 1250 IF C$="F" OR C$="f" THEN 1010
  57. 1260 IF C$="O" OR C$="o" THEN 200
  58. 1300 IF A < .5 OR A > 29.99999 THEN 1050
  59. 1310 GOSUB 1700
  60. 1320 LOCATE 1,14: COLOR 0,7: PRINT USING "  ##.##### \     \";A;" MHz": COLOR 7,0: GOTO 1120
  61. 1325 'alt 1320 GOTO 1050
  62. 1700 'Hex/Dec & Output
  63. 1710 A$ = MID$ (STR$ (A), 2)
  64. 1720 IF A = INT (A) THEN A$ = A$ + "."
  65. 1730 A$ = "000" + A$ + "00000"
  66. 1740 FOR I = 1 TO LEN(A$)
  67. 1750 DP$ = MID$ (A$, I, 1)
  68. 1760 IF DP$ = "." THEN DP = I : GOTO 1800
  69. 1770 NEXT
  70. 1800 A$=MID$(A$,DP-3,3)+MID$(A$,DP+1,5)
  71. 1810 F1=VAL(MID$(A$,1,2))
  72. 1820 F2=VAL(MID$(A$,3,2))
  73. 1830 F3=VAL(MID$(A$,5,2))
  74. 1840 F4=VAL(MID$(A$,7,2))
  75. 1850 G1$=MID$(T$,F1+1,1)
  76. 1860 G2$=MID$(T$,F2+1,1)
  77. 1870 G3$=MID$(T$,F3+1,1)
  78. 1880 G4$=MID$(T$,F4+1,1)
  79. 1890 PRINT#1,G4$;G3$;G2$;G1$;M$
  80. 1900 RETURN
  81. 2000 INPUT "      Are you sure";C$
  82. 2010 IF C$="Y" OR C$="y" THEN CLOSE#1:GOTO 2030
  83. 2020 GOTO 200
  84. 2030 END
  85. 2500 '
  86.