home *** CD-ROM | disk | FTP | other *** search
/ HAM Radio 1 / HamRadio.cdr / control / catm100 / cat.do next >
Text File  |  1991-09-07  |  3KB  |  99 lines
  1. 10 '==============================
  2. 20 'CAT CONTROL FOR YAESU FT-757GX
  3. 30 '  BY Kjell W. Strom, SM6CPI
  4. 40 '
  5. 50 '              November 5,1984
  6. 60 '==============================
  7. 100 DEFINT F,H:H=16
  8. 105 GOSUB 3000
  9. 110 OPEN "COM:78N2E"FOR OUTPUT AS #1
  10. 120 T$=""
  11. 130 FOR I=0 TO 9
  12. 140 FOR J=0 TO 9
  13. 150 T$=T$+CHR$(I*H+J)
  14. 160 NEXT:NEXT
  15. 200 CLS
  16. 210 PRINT" [1] Split        [2] MR/VFO"
  17. 220 PRINT" [3] V=>M         [4] Dial Lock"
  18. 230 PRINT" [5] VFO A/B      [6] M=>V"
  19. 240 PRINT" [7] 500 Khz Up   [8] 500 Khz Down"
  20. 250 PRINT" [9] Clarifier   [10] Frequency"
  21. 260 PRINT"[11] V=>/<=M     [12] Quit"
  22. 300 INPUT"      What is your Choice";C
  23. 310 IF C<1 OR C>12 THEN 300
  24. 320 M$=CHR$(C)
  25. 330 IF C=10 THEN 1000
  26. 340 IF C=12 THEN 2000
  27. 500 PRINT #1, CHR$(0);CHR$(0);CHR$(0);CHR$(0);M$;
  28. 510 GOTO 200
  29. 1000 ' FREQUENCY CONTROL
  30. 1010 CLS:PRINT
  31. 1020 INPUT"          Frequency Mhz";A
  32. 1030 IF A<.5 OR A>29.99999 THEN 1010
  33. 1040 GOSUB 1700
  34. 1050 CLS:PRINT A," MHZ"
  35. 1060 PRINT"  New Frequency [F]            Other [O]"
  36. 1070 PRINT"              Fine Tuning:"
  37. 1080 PRINT"[A] 100       <<-<Khz>+>>         100[']"
  38. 1090 'PRINT
  39. 1100 PRINT"10   5   1  .1 .01  .01 .1   1   5  10"
  40. 1110 PRINT"[Z] [X] [C] [V] [B] [N] [M] [,] [.] [/]";
  41. 1120 C$=INKEY$:IF C$="" THEN 1120
  42. 1130 IF C$="B" OR C$="b" THEN A=A-.00001:GOTO 1300
  43. 1140 IF C$="N" OR C$="n" THEN A=A+.00001:GOTO 1300
  44. 1150 IF C$="V" OR C$="v" THEN A=A-.0001:GOTO 1300
  45. 1160 IF C$="M" OR C$="m" THEN A=A+.0001:GOTO 1300
  46. 1170 IF C$="C" OR C$="c" THEN A=A-.001:GOTO 1300
  47. 1180 IF C$="," THEN A=A+.001:GOTO 1300
  48. 1190 IF C$="X" OR C$="x" THEN A=A-.005:GOTO 1300
  49. 1200 IF C$="." THEN A=A+.005:GOTO 1300
  50. 1210 IF C$="Z" OR C$="z" THEN A=A-.01:GOTO 1300
  51. 1220 IF C$="/" THEN A=A+.01:GOTO 1300
  52. 1230 IF C$="A" OR C$="A" THEN A= A-.1:GOTO 1300
  53. 1240 IF C$="'" THEN A=A+.1:GOTO 1300
  54. 1250 IF C$="F" OR C$="f" THEN 1010
  55. 1260 IF C$="O" OR C$="o" THEN 200
  56. 1300 IF A <.5 OR A> 29.99999 THEN 1050
  57. 1310 GOSUB 1700
  58. 1320 GOTO 1050
  59. 1700 'HEX/DEC & OUTPUT
  60. 1710 A$=MID$(STR$(A),2)
  61. 1720 IF A=INT(A) THEN A$=A$+"."
  62. 1730 A$="000"+A$+"00000"
  63. 1740 FOR I=1 TO LEN(A$)
  64. 1750 DP$=MID$(A$,I,1)
  65. 1760 IF DP$="." THEN DP=I:GOTO 1800
  66. 1770 NEXT
  67. 1800 A$=MID$(A$,DP-3,3)+MID$(A$,DP+1,5)
  68. 1810 F1=VAL(MID$(A$,1,2))
  69. 1820 F2=VAL(MID$(A$,3,2))
  70. 1830 F3=VAL(MID$(A$,5,2))
  71. 1840 F4=VAL(MID$(A$,7,2))
  72. 1850 G1$=MID$(T$,F1+1,1)
  73. 1860 G2$=MID$(T$,F2+1,1)
  74. 1870 G3$=MID$(T$,F3+1,1)
  75. 1880 G4$=MID$(T$,F4+1,1)
  76. 1890 PRINT#1,G4$;G3$;G2$;G1$;M$;
  77. 1900 RETURN
  78. 2000 INPUT"      Are you sure";C$
  79. 2010 IF C$="Y" OR C$="y" THEN CLOSE1:MENU
  80. 2020 GOTO 200
  81. 2030 END
  82. 3000 'TITLE SCREEN
  83. 3010 H1$="      C A T   p r o g r a m  f o r"
  84. 3020 H2$="      Y A E S U  F T - 7 5 7 G X"
  85. 3030 H3$="              By Kjell W. Strom SM6CPI"
  86. 3040 CLS:PRINT:PRINT
  87. 3050 FOR I=1 TO LEN(H1$)
  88. 3060 PRINT MID$(H1$,I,1);
  89. 3070 NEXT
  90. 3080 PRINT:PRINT
  91. 3090 FOR I= 1 TO LEN(H2$)
  92. 3100 PRINT MID$(H2$,I,1);
  93. 3110 NEXT
  94. 3120 PRINT:PRINT:PRINT
  95. 3130 FOR I=1 TO LEN(H3$)
  96. 3140 PRINT MID$(H3$,I,1);
  97. 3150 NEXT
  98. 3160 RETURN
  99.