home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
HAM Radio 1
/
HamRadio.cdr
/
circuit
/
lcres
/
lcres.bas
next >
Wrap
BASIC Source File
|
1989-04-04
|
7KB
|
218 lines
10 REM:THIS PROGRAM IS FOR THE ANALYSIS & DESIGN OF L/C RESONANT CIRCUITS
20 REM:THIS PROGRAM IS FILED AS LCRES.BAS
30 CLS
40 PRINT TAB(20);"ANALYSIS AND DESIGN OF L/C CIRCUITS (FILE LCRES)"
50 PRINT TAB(33);"REMETAYER 8/01/83"
60 PRINT
70 PRINT
80 PRINT
90 PRINT TAB(32);"DEFINITIONS"
100 PRINT
110 PRINT
120 PRINT TAB(20);"CAP=CAPACITANCE IN PICOFARADS"
130 PRINT
140 PRINT TAB(20);"IND=INDUCTANCE IN MICROHENRIES"
150 PRINT
160 PRINT TAB(20);"FREQ=FREQUENCY IN MEGAHERTZ"
170 PRINT
180 PRINT TAB(20);"MAX=THE MAXIMUM VALUE OF THE VARIABLE"
190 PRINT
200 PRINT TAB(20);"MIN=THE MINIMUM VALUE OF THE VARIABLE"
210 PRINT
220 PRINT TAB(20);"OTHER VARIABLES OBVIOUS OR DEFINED LATER
230 PRINT
240 PRINT
250 INPUT "PRESS RETURN TO CONTINUE",A$
260 CLS
270 PRINT
280 PRINT
290 PRINT
300 PRINT
310 PRINT TAB(38);"MENU"
320 PRINT
330 PRINT
340 PRINT TAB(15);"(A) KNOWN VALUES ARE MAXCAP,MINCAP,MAXFREQ,MINFREQ"
350 PRINT TAB(19);"UNKNOWN VALUES ARE MAXIND,MININD"
360 PRINT
370 PRINT TAB(15);"(B) KNOWN VALUES ARE MAXCAP,MINCAP,IND
380 PRINT TAB(19);"UNKNOWN VALUES ARE MAXFREQ,MINFREQ
390 PRINT
400 PRINT TAB(15);"(C) KNOWN IS IND,COILENGTH,COILDIA
410 PRINT TAB(19);"UNKNOWN IS NUMTURNS OF WIRE(CONV.COIL)
420 PRINT
430 PRINT TAB(15);"(D) KNOWN IS IND,TOROIDCHAR
440 PRINT TAB(19);"UNKNOWN IS NUMTURNS OF WIRE(TOROID COIL)
450 PRINT
460 PRINT TAB(15);"(E) KNOWN IS CAP,IND,,CIRQ
470 PRINT TAB(19);"CIRQ BASED ON A COIL WITH A SERIES RESISTER"
480 PRINT TAB(19);"UNKNOWN IS BEHAVIOR NEAR RESONANCE-PARALLEL CIRCUIT"
490 PRINT
500 PRINT
510 PRINT
520 PRINT
530 INPUT "SELECT ONE OF A THRU E";PGRM$
540 IF PGRM$="A" OR PGRM$="a" THEN 660
550 IF PGRM$="B" OR PGRM$="b" THEN 950
560 IF PGRM$="C" OR PGRM$="c" THEN 1190
570 IF PGRM$="D" OR PGRM$="d" THEN 1430
580 IF PGRM$="E" OR PGRM$="e" THEN 1660
590 CLS
600 PRINT "GO BACK AND TRY AGAIN"
610 PRINT
620 PRINT
630 PRINT
640 PRINT
650 GOTO 530
660 CLS
670 REM:SUBRTNE WHEN MAXCAP,MINCAP,MAXFREQ,MINFREQ ARE KNOWN
680 REM:UNKNOWN ARE MAXIND,MININD
690 INPUT "INPUT MAXIMUM VALUE OF CAPACITANCE IN PFDS! ",MAXCAP
700 PRINT
710 INPUT "INPUT MINIMUM VALUE OF CAPACITANCE IN PFDS! ",MINCAP
720 PRINT
730 INPUT "INPUT MAXIMUM DESIGN FREQUENCY IN MEGAHERTZ! ",MAXFREQ
740 PRINT
750 INPUT "INPUT MINIMUM DESIGN FREQUENCY IN MEGAHERTZ! ",MINFREQ
760 PRINT
770 PRINT
780 PRINT
790 PRINT
800 MAXIND=(159.15494#)^2/((MAXFREQ)^2*MINCAP)
810 MININD=(159.15494#)^2/((MINFREQ)^2*MAXCAP)
820 IF MAXIND<MININD GOTO 930
830 PRINT "MAXIMUM INDUCTOR TO MEET DESIGN REQUIREMENT IS ";MAXIND;"MICROH."
840 PRINT
850 PRINT "MINIMUM INDUCTOR TO MEET DESIGN REQUIREMENT IS ";MININD;"MICROH."
860 PRINT
870 PRINT
880 PRINT
890 INPUT "DO YOU WANT TO TRY AGAIN? (Y/N) ";A$
900 CLS
910 IF A$="Y" OR A$="y" THEN GOTO 660
920 END
930 PRINT "CANNOT MEET THE DESIGN RANGE REQUIRED"
940 GOTO 860
950 CLS
960 REM:SUBRTNE WHEN MAXCAP,MINCAP,IND ARE KNOWN
970 REM:UNKNOWN ARE MAXFREQ,MINFREQ
980 INPUT "INPUT MAXIMUM VALUE OF CAPACITANCE IN PFDS! ",MAXCAP
990 PRINT
1000 INPUT "INPUT MINIMUM VALUE OF CAPACITANCE IN PFDS! ",MINCAP
1010 PRINT
1020 INPUT "INPUT VALUE OF THE INDUCTANCE IN MICROHENRIES! ",IND
1030 PRINT
1040 PRINT
1050 PRINT
1060 PRINT
1070 MAXFREQ=159.15494#/((IND*MINCAP)^.5)
1080 MINFREQ=159.15494#/((IND*MAXCAP)^.5)
1090 PRINT "MAXIMUM FREQUENCY WITH THIS L/C CIRCUIT IS ";MAXFREQ;"MEGAHERTZ"
1100 PRINT
1110 PRINT "MINIMUM FREQUENCY WITH THIS L/C CIRCUIT IS ";MINFREQ;"MEGAHERTZ"
1120 PRINT
1130 PRINT
1140 PRINT
1150 INPUT "DO YOU WANT TO TRY AGAIN? (Y/N)";A$
1160 CLS
1170 IF A$="Y" OR A$="y" THEN GOTO 950
1180 END
1190 CLS
1200 REM:SUBRTNE WHEN IND, COILENGTH, COILDIA ARE KNOWN
1210 REM:UNKNOWN IS NUMTURNS
1220 REM:REF. ARRL HNDBK FOR COILENGTH >= .4COILDIA
1230 INPUT "INPUT VALUE OF DESIGN INDUCTANCE IN MICROHENRIES! ",IND
1240 PRINT
1250 INPUT "INPUT COIL LENGTH IN INCHES! ",COILENGTH
1260 PRINT
1270 INPUT "INPUT COIL DIAMETER IN INCHES! ",COILDIA
1280 PRINT
1290 PRINT
1300 PRINT
1310 PRINT
1320 NUMTURNS=(IND*(18*COILDIA+40*COILENGTH))^.5/(COILDIA)
1330 NUMTURNS=INT(100*(NUMTURNS+.005))/100
1340 PRINT "NUMBER OF TURNS FOR THE DESIGN INDUCTANCE IS ";NUMTURNS
1350 PRINT "NOTE: COILENGTH SHOULD BE >= .4*COILDIA."
1360 PRINT
1370 PRINT
1380 PRINT
1390 INPUT "DO YOU WANT TO TRY AGAIN? (Y/N)";A$
1400 CLS
1410 IF A$="Y" OR A$="y" THEN GOTO 1190
1420 END
1430 CLS
1440 REM:SUBRTNE WHEN IND, TOROIDCHAR ARE KNOWN
1450 REM:UNKNOWN IS NUMTURNS
1460 REM:REF. ARRL HNDBK COILCHAR=INDUCTANCE INDEX
1470 REM:LEAVE 30 DEGREES OF FORM OPEN TO MINIMIZE CAPACITANCE
1480 INPUT "INPUT VALUE OF DESIGN INDUCTANCE IN MICROHENRIES! ",IND
1490 PRINT
1500 INPUT "INPUT VALUE OF THE INDUCTANCE INDEX IN MICROHENRIES/100 TURNS ",COILCHAR
1510 PRINT
1520 PRINT
1530 PRINT
1540 PRINT
1550 NUMTURNS=100*((IND/COILCHAR)^.5)
1560 NUMTURNS=INT(100*(NUMTURNS+.005))/100
1570 PRINT "NUMBER OF TURNS FOR THE DESIGN INDUCTANCE IS ";NUMTURNS
1580 PRINT "NOTE: LEAVE 30 DEGREES OF TOROID OPEN"
1590 PRINT
1600 PRINT
1610 PRINT
1620 INPUT "DO YOU WANT TO TRY AGAIN? (Y/N)";A$
1630 CLS
1640 IF A$="Y" OR A$="y" THEN GOTO 1430
1650 END
1660 CLS
1670 REM:SUBRTNE WHEN CAP,IND,CIRQ ARE KNOWN
1680 REM:UNKNOWN IS BEHAVIOR NEAR RESONANCE-PARALLEL CIRCUIT (COIL WITH SERIES RESISTANCE)
1690 PRINT
1700 PRINT
1710 PRINT
1720 PRINT
1730 PRINT TAB(38);"DEFINITIONS"
1740 PRINT
1750 PRINT
1760 PRINT TAB(20);"RESFREQ=RESONANT FREQUENCY IN MEGAHERTZ"
1770 PRINT
1780 PRINT TAB(20)"CAPREACT=CAPACATIVE REACTANCE"
1790 PRINT
1800 PRINT TAB(20);"INDREACT=INDUCTIVE REACTANCE"
1810 PRINT
1820 PRINT TAB(20);"IMPEDANCE=IMPEDANCE OF THE PARALLEL CIRCUIT"
1830 PRINT
1840 PRINT
1850 INPUT "PRESS RETURN TO CONTINUE";A$
1860 CLS
1870 INPUT "INPUT VALUE OF CAPACITANCE IN PICOFARADS! ",CAP
1880 PRINT
1890 INPUT "INPUT VALUE OF INDUCTOR IN MICROHENRIES! ",IND
1900 PRINT
1910 INPUT "INPUT VALUE OF CIRCUIT Q! ",CIRQ
1920 PRINT
1930 PRINT
1940 PRINT
1950 PRINT
1960 RESFREQ=159.15494#/(CAP*IND)^.5
1970 FREQ=I*RESFREQ/100
1980 PRINT "RESFREQ= ";RESFREQ;"MEGAHERTZ";TAB(33);"CIRQ= ";CIRQ
1990 PRINT "IND= ";IND;"MICROH.";TAB(33);"CAP= ";CAP;"PFDS."
2000 PRINT
2010 PRINT
2020 FOR I=90 TO 110 STEP 5
2030 FREQ=I*RESFREQ/100
2040 CAPREACT=1/(2*3.14159*FREQ*.000001*CAP)
2050 INDREACT=2*3.14159*FREQ*IND
2060 INDIMP=((2*3.14159*RESFREQ*IND/CIRQ)^2+(2*3.14159*FREQ*IND)^2)^.5
2070 COMBIMP=((2*3.14159*RESFREQ*IND/CIRQ)^2+(INDREACT-CAPREACT)^2)^.5
2080 IMPEDANCE=CAPREACT*INDIMP/COMBIMP
2090 PRINT "FREQ= ";FREQ;"MH";TAB(33);"INDREACT= ";INDREACT;"OHMS"
2100 PRINT "IMPEDANCE= ";IMPEDANCE;"OHMS";TAB(33);"CAPREACT";CAPREACT;"OHMS"
2110 PRINT
2120 NEXT I
2130 PRINT
2140 PRINT
2150 INPUT "DO YOU WANT TO TRY AGAIN?(Y/N)";A$
2160 IF A$="Y" OR A$="y" THEN GOTO 1860
2170 END