home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
HAM Radio 1
/
HamRadio.cdr
/
ant
/
beamdraw
/
beamdraw.bas
Wrap
BASIC Source File
|
1986-08-12
|
3KB
|
107 lines
5 REM ***** BEAM.BAS - HAM RADIO ANTENNA DESIGN FOR 3 ELEMENT YAGI *****
10 CLS
20 SCREEN 2
30 LOCATE 1,20:PRINT"YAGI BEAM ANTENNA DESIGN"
40 PRINT
60 LOCATE 5,10:PRINT"Enter the desired optimum frequency -Mhz- ";:INPUT F$:IF F$="" THEN 60
65 F=VAL(F$):IF F =< 0 THEN GOTO 60
70 MT = 304.8/F:MT = INT(MT)
80 IF F<109 GOTO 110
90 V = 234
100 GOTO 120
110 V = 126 + F
120 S = V/F
130 S = INT(S*100+.5)/100
140 L = 2*S
150 R = 500/F
160 R = INT(R*100+.5)/100
170 D = 475/F
180 D = INT(D*100+.5)/100
190 H = 455/F
200 H = INT(H*100+.5)/100
210 K = L*30.48
220 M = S*30.48
230 O = R*30.48
240 P = D*30.48
250 Q = H*30.48
270 PRINT
280 PRINT "DIMENSIONS OF THE 3 ELEMENT WIDE-SPACED YAGI ARE:"
290 PRINT
295 Z = (240 - (Q/8))
300 PRINT "OVERALL BOOM LENGTH IS ";L;"FEET, OR ";K;"CM., AND"
310 PRINT "SPACING BETWEEN ELEMENTS IS";S;"FEET, OR";M;"CM."
320 PRINT
330 PRINT "THE FEED POINT IMPEDANCE AT";F;" MHZ WILL BE ";
340 PRINT "ABOUT 35 OHMS,"
350 PRINT "THE GAIN ABOUT 7.5 DB AND THE F/B RATIO UP TO 30."
360 PRINT
370 PRINT "REFLECTOR";TAB(27);"DRIVEN";TAB(53);"DIRECTOR"
380 PRINT TAB(2);"FEET";TAB(28);"FEET";TAB(55);"FEET"
390 PRINT TAB(2);"(CM)";TAB(28);"(CM)";TAB(55);"(CM)"
400 PRINT
410 PRINT R;TAB(26);D;TAB(52);H
420 PRINT O;TAB(26);P;TAB(52);Q
430 LOCATE 23,20:PRINT"PRESS ENTER TO DRAW ANTENNA "
440 IF INKEY$="" THEN 440
450 REM * * GRAPHICS SECTION * *
460 CLS
470 FOR Y = 30 TO 150
480 PSET(236,Y)
485 PSET(243,Y)
490 NEXT Y
500 FOR X = 130 TO 340
510 PSET(X,30)
515 NEXT X
520 FOR X = 120 TO 360
550 PSET(X,90)
552 NEXT X
555 FOR X = 100 TO 380
580 PSET(X,150)
590 NEXT X
600 REM - - DIMENSIONS - -
610 LOCATE 1,20:PRINT" 3 ELEMENT BEAM ANTENNA"
620 FOR N = 1 TO 2000
630 NEXT N
640 LOCATE 3,20:PRINT"DIRECTOR =";H;"FT.";
650 LOCATE 21,20:PRINT"CENTER FREQUENCY =";F;"Mhz"'
655 LOCATE 22,20:PRINT"IN THE ";MT;" METER BAND"
660 LOCATE 11,20:PRINT"DRIVEN ELEMENT =";D;"FT."
680 LOCATE 18,20:PRINT"REFLECTOR =";R;"FT."
720 X = 400
730 Y = 31
740 GOSUB 920
750 FOR Y = 30 TO 152
760 PSET(X+1,Y)
765 NEXT Y
767 FOR Y = 89 TO 152
780 PSET(X+11,Y)
790 NEXT Y
800 Y = 150
810 GOSUB 980
820 X = X + 10
830 GOSUB 980
840 Y = 90
850 GOSUB 920
860 LOCATE 17,53:PRINT S;"ft.";
870 LOCATE 7,54:PRINT L;"ft.";
890 LOCATE 23,25:PRINT"ANOTHER (Y/n) ";:E$=INKEY$
900 IF E$="Y" OR E$="y" THEN GOTO 10
901 IF E$="" THEN 890
910 GOTO 1040
920 REM ----UP ARROW----
930 PSET(X,Y)
940 PSET(X+2,Y)
950 PSET(X-1,Y+1)
960 PSET(X+3,Y+1)
970 RETURN
980 REM ---- DOWN ARROW ----
990 PSET(X-1,Y)
1000 PSET(X+3,Y)
1010 PSET(X,Y+1)
1020 PSET(X+2,Y+1)
1030 RETURN
1040 END
10000 SAVE"B:BEAM.BAS",A
DIMENSIONS OF THE 3 ELEMENT WIDE-SPACED YAGI ARE:"
290 PRINT
295 Z = (240 - (Q/8