home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
HAM Radio 1
/
HamRadio.cdr
/
ant
/
antenna
/
tline.bas
< prev
next >
Wrap
BASIC Source File
|
1979-12-31
|
6KB
|
184 lines
10 REM TRANSMISSION LINE DESIGN
20 REM "ANTENNA DESIGN USING PERSONAL COMPUTERS"
30 PI=3.141593
40 KEY OFF
50 DEF FNLOG10(X)=.4343*LOG(X)
60 CLS
70 COLOR 1,0
80 PRINT "THIS PROGRAM CALCULATES COMMON TRANSMISSION LINE CHARACTERISTICS"
90 COLOR 4,0
100 PRINT
110 PRINT "TRANSMISSION LINES AVAILABLE:"
120 PRINT " 1-COAXIAL LINE (IMPEDANCE)"
130 PRINT " 2-TWO WIRE LINE (IMPEDANCE)"
140 PRINT " 3-MICROSTRIP LINE (IMPEDANCE)"
150 PRINT " 4-MICROSTRIP LINE (DIMENSIONS)"
160 PRINT " 5-STRIPLINE (IMPEDANCE)"
170 PRINT " 6-STRIPLINE (DIMENSIONS)"
180 PRINT " 7-EXIT PROGRAM"
190 PRINT
200 INPUT "WHICH OPTION DO YOU WANT(1 TO 7)";LT
210 CLS
220 IF LT=1 THEN GOTO 300
230 IF LT=2 THEN GOTO 420
240 IF LT=3 THEN GOTO 550
250 IF LT=4 THEN GOTO 720
260 IF LT=5 THEN GOTO 970
270 IF LT=6 THEN GOTO 1210
280 IF LT=7 THEN GOTO 1810
290 GOTO 200
300 REM COAXIAL LINE
310 PRINT "COAXIAL LINE DESIGN"
320 INPUT "WHAT IS THE DIELECTRIC CONSTANT";EPS
330 INPUT "WHAT IS THE INNER RADIUS(meters)";A
340 INPUT "WHAT IS THE OUTER RADIUS(meters)";B
350 Z0=60*LOG(B/A)/SQR(EPS)
360 COLOR 14,0
370 PRINT USING "THE CHARACTERISTIC IMPEDANCE IS ###.# ohms";Z0
380 GOSUB 1470
390 AC=RS*(1/B+1/A)/(4*PI*Z0)*8.68
400 AD=OMEGA*EPSDP*377*E0/(2*SQR(EPS))*8.68
410 GOSUB 1710
420 REM TWO WIRE LINE
430 PRINT "TWO-WIRE LINE DESIGN"
440 INPUT "WHAT IS THE DIELECTRIC CONSTANT";EPS
450 INPUT "WHAT IS THE CONDUCTOR DIAMETER(meters)";D
460 INPUT "WHAT IS THE CONDUCTOR SEPARATION(meters)";S
470 X=S/D
480 Z0=120*LOG(X+SQR(X*X-1))/SQR(EPS)
490 COLOR 14,0
500 PRINT USING "THE CHARACTERISTIC IMPEDANCE IS ###.# ohms";Z0
510 GOSUB 1470
520 AC=RS*X/(SQR(X*X-1)*PI*D*Z0)*8.68
530 AD=OMEGA*EPSDP*377*E0/(2*SQR(EPS))*8.68
540 GOSUB 1710
550 REM MICROSTRIP LINE DESIGN
560 PRINT "MICROSTRIP LINE DESIGN"
570 INPUT "WHAT IS THE DIELECTRIC CONSTANT";EPS
580 INPUT "WHAT IS THE SUBSTRATE THICKNESS(meters)";H
590 INPUT "WHAT IS THE LINE WIDTH(meters)";W
600 WOH=W/H
610 IF WOH<=1 THEN EEF=(EPS+1)/2+(EPS-1)/2*(1!/SQR(1+12/WOH)+.04*(1-WOH)^2)
620 IF WOH>1 THEN EEF=(EPS+1)/2+(EPS-1)/2/SQR(1+12/WOH)
630 IF WOH<=1 THEN Z0=60*LOG(8/WOH+.25*WOH)/SQR(EEF)
640 IF WOH>1 THEN Z0=120*PI/(SQR(EEF)*(WOH+1.393+.667*LOG(WOH+1.444)))
650 COLOR 14,0
660 PRINT USING "EPSILON EFFECTIVE=##.##";EEF
670 PRINT USING "THE CHARACTERISTIC IMPEDANCE IS ###.# ohms";Z0
680 GOSUB 1470
690 AC=8.68*RS/(Z0*W)
700 AD=27.3*EPS*(EEF-1)*TAND/(SQR(EEF)*(EPS-1)*L0)
710 GOSUB 1710
720 REM MICROSTRIP LINE
730 PRINT "MICROSTRIP LINE DESIGN"
740 INPUT "WHAT IS THE DIELECTRIC CONSTANT";EPS
750 INPUT "WHAT IS THE CHARACTERISTIC IMPEDANCE(ohms)";Z0
760 A=Z0*SQR(EPS/2+.5)/60+(EPS-1)/(EPS+1)*(.23+.11/EPS)
770 B=377*PI/(2*Z0*SQR(EPS))
780 WOH1=8*EXP(A)/(EXP(2*A)-2)
790 WOH2=2/PI*(B-1-LOG(2*B-1)+(EPS-1)/(2*EPS)*(LOG(B-1)+.39-.61/EPS))
800 WOH=WOH1
810 IF WOH2>=2 THEN WOH=WOH2
820 EEF=(EPS+1)/2+(EPS-1)/2/SQR(1+10/WOH)
830 COLOR 14,0
840 PRINT USING "EPSILON EFFECTIVE= ##.##";EEF
850 PRINT USING "W/H=##.##";WOH
860 COLOR 4,0
870 INPUT "ENTER (-1*W) OR (H) (meters)";X
880 COLOR 14,0
890 H=X
900 W=WOH*H
910 IF X<0 THEN W=-X
920 IF X<0 THEN H=W/WOH
930 IF X<0 THEN PRINT USING "THE SUBSTRATE THICKNESS IS ##.##### meters";H
940 IF X>0 THEN PRINT USING "THE LINE WIDTH IS ##.##### meters";W
950 GOSUB 1470
960 GOTO 690
970 REM STRIPLINE
980 PRINT "STRIPLINE DESIGN"
990 INPUT "WHAT IS THE DIELECTRIC CONSTANT";EPS
1000 INPUT "WHAT IS THE GROUND PLANE SPACING(meters)";B
1010 INPUT "WHAT IS THE CONDUCTOR WIDTH(meters)";W
1020 INPUT "WHAT IS THE CONDUCTOR THICKNESS(meters)";T
1030 WOB=W/B
1040 TOB=T/B
1050 WEOB=WOB
1060 IF W/(B-T)<.35 THEN WEOB=WEOB-(.35-WEOB)^2/(1+12*TOB)
1070 IF TOB=0 THEN CF=1.386
1080 IF TOB>0 THEN CF=2*LOG(1/(1-TOB)+1)-TOB*LOG(1/(1-TOB)^2-1)
1090 Z0=30*PI*(1-TOB)/(SQR(EPS)*(WEOB+CF/PI))
1100 COLOR 14,0
1110 PRINT USING "THE CHARACTERISTIC IMPEDANCE IS ###.# ohms";Z0
1120 GOSUB 1470
1130 IF T=0 THEN T=W/1000
1140 ZB=Z0*SQR(EPS)*(1+2.3*TOB)
1150 AA=1+2*W/(B-T)+(B+T)/(PI*(B-T))*LOG((2*B-T)/T)
1160 BB=(.35-WOB)*(TOB*(17.45*B+35*W)-9*W+5.85-32.4*TOB*T)/(B-T)/(1+12*TOB)^2
1170 IF ZB<120 THEN BB=0
1180 AC=.0231*RS*EPS*Z0*(AA+BB)/(30*PI*(B-T))
1190 AD=27.3*SQR(EPS)*TAND/L0
1200 GOSUB 1710
1210 REM STRIPLINE DESIGN
1220 PRINT "STRIPLINE DESIGN"
1230 INPUT "WHAT IS THE DIELECTRIC CONSTANT";EPS
1240 INPUT "WHAT IS THE CHARACTERISTIC IMPEDANCE(ohms)";Z0
1250 INPUT "WHAT IS THE STRIP THCK/GRND. PLANE SPACING RATIO";TOB
1260 ZB=Z0*SQR(EPS)*(1+2.3*TOB)
1270 CF=1.386
1280 IF TOB>0 THEN CF=2*LOG(1/(1-TOB)+1)-TOB*LOG(1/(1-TOB)^2-1)
1290 X=30*PI*(1-TOB)/(Z0*SQR(EPS))-CF/PI
1300 IF ZB>120 THEN WOB=(6*TOB+.85)-SQR((6*TOB+.85)^2-X*(12*TOB+1)-.1225)
1310 IF ZB<120 THEN WOB=X
1320 COLOR 14,0
1330 PRINT USING"W/B=##.##";WOB
1340 COLOR 4,0
1350 INPUT "ENTER (-1*W) OR (B) (meters)";X
1360 COLOR 14,0
1370 B=X
1380 W=WOB*B
1390 IF X<0 THEN W=-X
1400 IF X<0 THEN B=W/WOB
1410 IF X<0 THEN PRINT USING "THE GROUND PLANE SPACING IS ##.#### meters";B
1420 IF X>0 THEN PRINT USING "THE LINE WIDTH IS ##.#### meters";W
1430 T=TOB*B
1440 GOSUB 1470
1450 GOTO 1130
1460 END
1470 REM ATTENUATION DATA
1480 PRINT
1490 COLOR 4,0
1500 INPUT "DO YOU WANT TO CALCULATE ATTENUATION(Y,N)";AT$
1510 IF AT$="N" THEN GOTO 1760
1520 INPUT "WHAT IS THE FREQUENCY(MHz)";FMC
1530 INPUT "WHAT IS THE DIELECTRIC LOSS TANGENT";TAND
1540 PRINT "WHAT IS THE CONDUCTOR MATERIAL:"
1550 PRINT " 1-GOLD"
1560 PRINT " 2-SILVER"
1570 PRINT " 3-COPPER"
1580 PRINT " 4-OTHER"
1590 INPUT "ENTER 1-4";CM
1600 IF CM<1 OR CM>4 THEN GOTO 1590
1610 IF CM=1 THEN SIG=4.1E+07
1620 IF CM=2 THEN SIG=6.17E+07
1630 IF CM=3 THEN SIG=5.8E+07
1640 IF CM=4 THEN INPUT "WHAT IS THE CONDUCTIVITY(mhos/meter)";SIG
1650 OMEGA=2*PI*FMC*1000000!
1660 RS=SQR(PI*FMC*1000000!*.0000004*PI/SIG)
1670 EPSDP=EPS*TAND
1680 E0=8.85E-12
1690 L0=300/FMC
1700 RETURN
1710 REM PRINT ATTENUATION
1720 COLOR 14,0
1730 PRINT USING "ATTEN. DUE TO CONDUCTOR =##.#### dB/meter";AC
1740 PRINT USING "ATTEN. DUE TO DIELECTRIC=##.#### dB/meter";AD
1750 PRINT USING "TOTAL ATTEN. =##.#### dB/meter";AD+AC
1760 PRINT
1770 COLOR 4,0
1780 INPUT "CONTINUE(Y,N)";IS$
1790 IF IS$="N" THEN GOTO 1810
1800 GOTO 60
1810 COLOR 7,0
1820 KEY ON
1830 END