home *** CD-ROM | disk | FTP | other *** search
/ HAM Radio 1 / HamRadio.cdr / ant / antenna / reflecto.bas < prev    next >
BASIC Source File  |  1979-12-31  |  2KB  |  75 lines
  1. 10 REM REFLECTOR ANTENNA DESIGN
  2. 20 REM "ANTENNA DESIGN USING PERSONAL COMPUTERS"
  3. 30 KEY OFF
  4. 40 CLS
  5. 50 COLOR 1,0
  6. 60 PRINT "REFLECTOR ANTENNA DESIGN"
  7. 70 COLOR 4,0
  8. 80 PI=3.141593
  9. 90 DEF FNLOG10(X)=.4343*LOG(X)
  10. 100 PRINT
  11. 110 INPUT "WHAT IS THE DISH DIAMETER(meters)";D
  12. 120 INPUT "WHAT IS THE f/d RATIO";FOD
  13. 130 INPUT "WHAT IS THE FREQUENCY(MHz)";FMC
  14. 140 XL=300/FMC
  15. 150 PRINT "HOW DO YOU WISH TO SPECIFY THE FEED POWER PATTERN:"
  16. 160 PRINT "               1- COS(TH)**N (N EVEN)"
  17. 170 PRINT "               2- 3 dB BEAMWIDTH"
  18. 180 PRINT "               3- 10 dB BEAMWIDTH"
  19. 190 INPUT IOP
  20. 200 IF IOP<1 OR IOP>3 THEN GOTO 150
  21. 210 IF IOP>1 THEN GOTO 260
  22. 220 INPUT "WHAT IS THE VALUE OF N (2,4,6,8)";N
  23. 230 IF N<>2 AND N<>4 AND N<>6 AND N<>8 THEN GOTO 220
  24. 240 COLOR 14,0
  25. 250 GOTO 370
  26. 260 IF IOP>2 THEN GOTO 300
  27. 270 INPUT "WHAT IS THE 3-dB BEAMWIDTH(degrees)";BW
  28. 280 N=-.693/LOG(COS(BW*PI/360))
  29. 290 GOTO 320
  30. 300 INPUT "WHAT IS THE 10-dB BEAMWIDTH(degrees)";BW
  31. 310 N=-2.3/LOG(COS(BW*PI/360))
  32. 320 N=2*INT(N/2)
  33. 330 IF N<2 THEN N=2
  34. 340 IF N>8 THEN N=8
  35. 350 COLOR 14,0
  36. 360 PRINT USING "WILL USE N=#";N
  37. 370 REM COMPUT APERTURE EFFICIENCY
  38. 380 F=FOD*D
  39. 390 Z0=F-D*D/(16*F)
  40. 400 TH=ATN(D/(2*Z0))
  41. 410 CTH=COS(TH)
  42. 420 STH=SIN(TH)
  43. 430 CTH2=COS(TH/2)
  44. 440 STH2=SIN(TH/2)
  45. 450 COT2=CTH2/STH2
  46. 460 LCT=LOG(CTH2)
  47. 470 STH22=STH2*STH2
  48. 480 COT22=COT2*COT2
  49. 490 MCT=(1-CTH)^3/3
  50. 500 NCT=(1-CTH^4)/4
  51. 510 EAP=18*(NCT-2*LCT-MCT-.5*STH*STH)^2*COT22
  52. 520 IF N=6 THEN EAP=14*(2*LCT+MCT+.5*STH*STH)^2*COT22
  53. 530 IF N=4 THEN EAP=40*(STH22*STH22+LCT)^2*COT22
  54. 540 IF N=2 THEN EAP=24*(STH22+LCT)^2*COT22
  55. 550 REM COMPUTE SPILLOVER EFFICIENCY: TAPER EFFICIENCY
  56. 560 ES=1-CTH^(N+1)
  57. 570 ET=EAP/ES
  58. 580 REM COMPUTE DIRECTIVITY
  59. 590 D=(PI*D/XL)^2*EAP
  60. 600 DDB=10*FNLOG10(D)
  61. 610 BW=SQR(33700!/D)
  62. 620 PRINT
  63. 630 PRINT USING "SPILLOVER EFFICIENCY= #.###";ES
  64. 640 PRINT USING "TAPER EFFICIENCY= #.###";ET
  65. 650 PRINT USING "APERTURE EFFICIENCY= #.###";EAP
  66. 660 PRINT USING "DIRECTIVITY= ######.# OR ##.# dB";D,DDB
  67. 670 PRINT USING "3 dB BEAMWIDTH= ##.## degrees";BW
  68. 680 PRINT
  69. 690 COLOR 4,0
  70. 700 INPUT "CONTINUE(Y,N)";K$
  71. 710 IF K$<>"N" THEN GOTO 40
  72. 720 COLOR 7,0
  73. 730 KEY ON
  74. 740 END
  75.