home *** CD-ROM | disk | FTP | other *** search
/ HAM Radio 1 / HamRadio.cdr / ant / antdesgn / rotman.bas < prev    next >
BASIC Source File  |  1979-12-31  |  2KB  |  61 lines
  1. 10 REM ROTMAN LENS DESIGN
  2. 20 REM "ANTENNA ANALYSIS USING PERSONAL COMPUTERS"
  3. 30 KEY OFF
  4. 40 CLS
  5. 50 PI=3.14159
  6. 60 COLOR 1,0
  7. 70 PRINT "ROTMAN LENS ARRAY FEED DESIGN"
  8. 80 COLOR 4,0
  9. 90 PRINT
  10. 100 INPUT "HOW MANY ARRAY ELEMENTS";NE
  11. 110 INPUT "ELEMENT SPACING(F.S. WAVELENGTHS)";D
  12. 120 INPUT "DIELECTRIC CONSTANT OF LENS";EPS
  13. 130 INPUT "FOCAL LENGTH OF LENS(DIELECTRIC WVL)";F
  14. 140 INPUT "MAX. SCAN ANGLE(OR PERFECT FOCUS)(DEGREES)";ALP
  15. 150 INPUT "WHAT IS THE FREQUENCY OF OPERATION(MHz)";FMC
  16. 160 COLOR 14,0
  17. 170 PRINT
  18. 180 ALPR=ALP*PI/180
  19. 190 A0=COS(ALPR)
  20. 200 B0=SIN(ALPR)
  21. 210 G=1.137
  22. 220 XL0=300/FMC
  23. 230 XLD=XL0/SQR(EPS)
  24. 240 PRINT "INNER LENS CONTOUR COORDINATES AND CABLE LENGTHS:"
  25. 250 PRINT "  X(cm)    Y(cm)    W(DEGREES)"
  26. 260 FOR I=1 TO NE
  27. 270 ZN=-(NE-1)*D/2+(I-1)*D
  28. 280 ETA=ZN/F
  29. 290 A=1-ETA^2-((G-1)/(G-A0))^2
  30. 300 B=2*G*(G-1)/(G-A0)-(G-1)*B0*B0*ETA^2/(G-A0)^2
  31. 310 B=B+2*ETA^2-2*G
  32. 320 C=G*B0*B0*ETA^2/(G-A0)-B0^4*ETA^4/(4*(G-A0)^2)
  33. 330 C=C-ETA^2
  34. 340 DISC=B*B-4*A*C
  35. 350 IF DISC<0 THEN PRINT "ERROR IN DATA"
  36. 360 IF DISC<0 THEN GOTO 540
  37. 370 W=(-B-SQR(DISC))/(2*A)
  38. 380 Y=ETA*(1-W)
  39. 390 X=(2*W*(1-G)-B0*B0*ETA^2)/(2*(G-A0))
  40. 400 X=X*F*XLD*100
  41. 410 Y=Y*F*XLD*100
  42. 420 W=W*F*360
  43. 430 PRINT USING "####.##  ####.##      ####";X,Y,W
  44. 440 NEXT I
  45. 450 PRINT
  46. 460 G=G*F
  47. 470 R=((F*A0-G)^2+F*F*B0*B0)/(2*(G-F*A0))
  48. 480 G=G*XLD
  49. 490 R=R*XLD
  50. 500 CEN=(R-G)*100
  51. 510 R=R*100
  52. 520 PRINT USING "CENTER OF FOCAL ARC=####.## cm.";CEN
  53. 530 PRINT USING "RADIUS OF FOCAL ARC=####.## cm.";R
  54. 540 PRINT
  55. 550 COLOR 4,0
  56. 560 INPUT "CONTINUE(Y,N)"; IP$
  57. 570 IF IP$<>"N" THEN GOTO 40
  58. 580 COLOR 7,0
  59. 590 KEY ON
  60. 600 END
  61.