home *** CD-ROM | disk | FTP | other *** search
/ The Glitch Apple Disk Collection / 2014.glitch.apple.collection.zip / indexed / TRANSYLX.DSK / TRANS.bas < prev   
BASIC Source File  |  2014-09-09  |  26KB  |  396 lines
  1. 1 LOC = 37888 +61
  2. 2  FOR C9 = LOC TO LOC +2: POKE C9,(14 *16 +10): NEXT 
  3. 3  REM  IMPORTANT NOTICE (!) WITHOUT THIS PATCH,EXECUTION FAILS
  4. 5  DIM OD$(39),T%(39),P%(39),RT%(38),D%(38,5):EC = 2: ONERR  GOTO 58
  5. 10  HOME : VTAB 21:R =  -21:O = 24: PRINT "<CTRL-D>BLOADPICDRAW2": POKE  -16301,0: PRINT "WOULD YOU LIKE TO RESTORE A SAVED GAME?";: GET E$: PRINT : IF E$ = "Y"  THEN 50
  6. 15  PRINT "<CTRL-D>OPENDATA": PRINT "<CTRL-D>READDATA"
  7. 20  INPUT NZ: DIM N%(NZ): FOR I = 1 TO NZ: INPUT N%(I): NEXT : INPUT M: FOR I = 1 TO M: INPUT OD$(I),P%(I),T%(I): NEXT : INPUT LZ: FOR I = 1 TO LZ: INPUT RT%(I): FOR X = 0 TO 5: INPUT D%(I,X): NEXT : NEXT 
  8. 25  IF E$ = "Y"  THEN  INPUT SM,GT,SH,PO,GN,DR,H,R,W,V,WF,VR,ZZ,YN$
  9. 30  PRINT "<CTRL-D>CLOSE":EC = 3: HOME : VTAB 21: IF E$ = "Y"  THEN  GOSUB 110: GOSUB 220: PRINT "SO ";YN$;", YOU CAME BACK?..<CTRL-M>GOOD LUCK...": GOTO 7990
  10. 35  GOTO 874
  11. 50 EC = 1: GOSUB 100: INPUT "NAME OF SAVED GAME : ";J$: PRINT "<CTRL-D>NOMONC,I,O": PRINT "<CTRL-D>OPEN";J$: PRINT "<CTRL-D>READ";J$: INPUT P,TU: GOTO 20
  12. 58  PRINT "<CTRL-G><CTRL-G>DISK ERROR.": ON EC GOTO 60,65,70
  13. 60  GOSUB 100: GOTO 50
  14. 65  GOSUB 110: GOTO 10
  15. 70  GOSUB 110: GOTO 1000
  16. 100  PRINT "INSERT YOUR DATA DISK.": RETURN 
  17. 110  PRINT "INSERT YOUR GAME DISK.": RETURN 
  18. 200  PRINT "IT'S LOCKED.": GOTO 7000
  19. 210  PRINT "NOT HERE.": GOTO 7000
  20. 220  PRINT "<PRESS A KEY TO CONTINUE>";: GET E$: PRINT : PRINT : RETURN 
  21. 230  PRINT "I'M SORRY - I DON'T UNDERSTAND.": GOTO 7000
  22. 240  PRINT "SORRY - YOU CAN'T.": GOTO 7000
  23. 260  PRINT "IT WON'T BUDGE.": GOTO 7000
  24. 270  GOSUB 8070: GOTO 7000
  25. 280  PRINT "IT'S ALREADY OPEN.": GOTO 7000
  26. 290  PRINT "NOTHING HAPPENED.": GOTO 7000
  27. 300  PRINT "YOU FOUND SOMETHING!":P%(15) = 37: RETURN 
  28. 310  PRINT "SLIPPERY MOSS COVERS THE TREES, MAKING  THEM IMPOSSIBLE TO CLIMB.": GOTO 7000
  29. 320  PRINT "YOU SLID BACK DOWN AS IF YOU WERE<CTRL-M>PUSHED.": GOTO 7000
  30. 330  PRINT "YOU DON'T HAVE IT.": GOTO 7000
  31. 874 ZZ = 10:P = 1:Y = 12: PRINT "VELCOME TO TRANSYLVANIA! VON'T YOU<CTRL-M>PLEASE SIGN THE GUEST REGISTER?...": INPUT "YOUR NAME? ";YN$: INPUT "AND YOUR NEXT OF KIN? ";E$
  32. 876  PRINT "FAR AWAY A CLOCK STRIKES ";Y;".": GOSUB 220: IF Y = 5  THEN 27000
  33. 880  GOTO 7990
  34. 990  VTAB O -1: IF B  THEN  POKE  -16304,0:B = 0: GOTO 1000
  35. 991  POKE  -16303,0:B = 1
  36. 1000  PRINT "COMMAND : ";: CALL 37901:I =  PEEK(37899):X =  PEEK(37898): IF I = 0  THEN 990
  37. 1010  IF I = 255  THEN  PRINT "I DON'T KNOW THAT COMMAND.": GOTO 1000
  38. 1020  IF X = 255  THEN  PRINT "I DON'T KNOW THAT WORD.": GOTO 1000
  39. 1022  IF X = 128  AND P = 5  THEN X = 25
  40. 1024  IF X = 128  AND P = 37  THEN X = 70
  41. 1030  IF N%(X) <0  THEN X =  -N%(X)
  42. 1165  ON I GOTO 5700,5700,5700,5700,5490,5490,5490,5490,5490,5490,3000,3000,3000,3000,4000,4000,4000,7700,7500,7600,1500,9700,4600,4500,4900,4700,9800,9800,6500,6600,1500,6700,30040,30040,9400,1500,3000,4800,6300,6400,7800,7800,9600,2990
  43. 1167  ON I -44 GOTO 25000,5950,6140,1110,8500,2000,8500,9000,7900,9400,9900,4900,4200,4300,9400,4400,4600,9800,10000,1500,11000,7700,290,290,290,10000,11000,4000,290,210,240,230,290,290,6142,3000,240,240,240,290,230,4000,240,240,1599
  44. 1500  IF X = 10  AND P%(8) = P  THEN  PRINT "IT LOOKS RATHER PECKISH.": GOTO 7000
  45. 1505  IF X = 37  AND P = 2  THEN  PRINT "THERE'S AN OLD, WOODEN COFFIN IN IT.": GOTO 7000
  46. 1507  IF X = 30  AND P%(37) = P  THEN  PRINT "IT LOOKS BACK.": GOTO 7000
  47. 1510  IF X = 13  AND RT%(P) <3  THEN 310
  48. 1515  IF X = 34  AND P%(34) = P  THEN  PRINT "HIS HAIR IS PERFECT.": GOTO 7000
  49. 1520  IF X = 52  AND P%(10) = P  THEN  PRINT "HE IS AN OBNOXIOUS-LOOKING CREATURE.": GOTO 7000
  50. 1525  IF X = 54  THEN  PRINT "I THOUGHT I SAW A LIGHT FLICKERING IN A HIGH TOWER ROOM.": GOTO 7000
  51. 1530  IF X = 66  AND P%(33) = P  THEN  PRINT "IT'S ENTITLED 'THE JOY OF MAGIC'.": GOTO 7000
  52. 1535  IF X = 71  AND P%(N%(71)) = P  THEN  PRINT "SUDDENLY YOUR MISSION SEEMS MUCH MORE<CTRL-M>WORTHWHILE...": GOTO 7000
  53. 1536  IF X = 72  AND (P = 24  OR P = 25)  THEN  PRINT "IN THE DISTANCE YOU SEE A CASTLE WITH A SKULL CHISELED IN ITS SIDE.": GOTO 7000
  54. 1540  IF X = 75  AND P%(27) =  -2  THEN  PRINT "THERE IS A BUTTON ON ITS SMOOTH BLACK<CTRL-M>SURFACE.": GOTO 7000
  55. 1545  IF X = 16  AND P%(2) = P  THEN  PRINT "A QUIVERING, MUFFLED VOICE WITHIN THE<CTRL-M>STATUE CRIES 'HELP!'": GOTO 7000
  56. 1550  IF X = 27  AND P%(13) = P  AND   NOT GT  THEN 200
  57. 1555  IF X = 25  AND P = 5  THEN  PRINT "IT SAYS 'HERE LIES ";YN$;"'<CTRL-M>... AND IT HAS TODAY'S DATE.": GOTO 7000
  58. 1560  IF X = 47  THEN 1700
  59. 1562  IF X = 61  THEN 1750
  60. 1570  IF X = 67  THEN 1780
  61. 1575  IF X = 51  THEN 9710
  62. 1599  PRINT "YOU SEE NOTHING UNUSUAL.": GOTO 7000
  63. 1700  IF P%(26) < > -1  THEN  PRINT "IT IS COVERED WITH SHINY RUNES AND<CTRL-M>STARS.": GOTO 7000
  64. 1720  IF P%(3) = P  OR P%(3) =  -2  THEN  PRINT "YOU FOUND A LOCK PICK IN THE FOLDS OF<CTRL-M>THE CLOAK'S FABRIC.":P%(26) = P:I = 26: GOTO 270
  65. 1730  GOTO 210
  66. 1750  IF P = 9  OR P = 10  THEN 1765
  67. 1755  IF P = 31  THEN  PRINT "IT'S GLOWING RED HOT.": GOTO 7000
  68. 1760  GOTO 210
  69. 1765  IF DR  THEN 280
  70. 1770  GOTO 200
  71. 1780  IF P < >10  THEN 210
  72. 1785  PRINT "AS YOU GAZE INTO THE CRYSTAL BALL YOU<CTRL-M>SEE A SMALL ORANGE FLAME BURNING WITH<CTRL-M>AN UNNATURAL BRILLIANCE. AS YOU PEER": GOSUB 220: PRINT "DEEPER INTO THE FIRE, YOU SEE YOURSELF<CTRL-M>STANDING SOMEWHERE IN THE WOODS, NEAR A"
  73. 1786  PRINT "STATUE. A FIGURE CLAD IN A WIZARD'S": GOSUB 220: PRINT "CLOAK APPROACHES THE STATUE. ON HIS HANDHE WEARS A SHINY GOLD RING WHICH GLOWS<CTRL-M>WITH A SOFT, WHITE FLAME. WITH A WAVE": GOSUB 220: PRINT "OF HIS HAND, EVERYTHING AROUND THE"
  74. 1787  PRINT "STATUE GOES ABLAZE WITH BRIGHT GREEN<CTRL-M>FIRE. YOU FEEL A JOLT OF THUNDER AND": GOSUB 220: PRINT "RETURN TO YOUR SENSES, STEPPING AWAY<CTRL-M>FROM THE CRYSTAL BALL.": GOSUB 220: GOTO 7000
  75. 2000  IF H >0  THEN 2020
  76. 2010  PRINT "YOU ARE CARRYING NOTHING.": GOTO 7000
  77. 2020  PRINT "YOU ARE CARRYING: ": FOR I = 1 TO M: IF P%(I) =  -2  THEN  PRINT OD$(I)
  78. 2030  NEXT I: GOTO 7000
  79. 2990  IF X < >121  THEN 3000
  80. 2995  IF P = 9  OR P = 10  THEN 6315
  81. 2996  GOTO 240
  82. 3000  IF X = 9  THEN 2000
  83. 3001  IF X = 6  THEN  PRINT "BOOGIE!": GOTO 7000
  84. 3002  IF X = 66  THEN 3080
  85. 3003  IF X = 65  THEN 3090
  86. 3005  IF X = 99  THEN 10000
  87. 3006  IF X = 117  THEN 11000
  88. 3008  IF X = 161  THEN  PRINT "GREEDY, HUH?"
  89. 3010 I = N%(X): IF   NOT I  THEN 240
  90. 3029  IF X = 36  OR X = 35  OR X = 22  THEN 3061
  91. 3030  IF T%(I) = 0  THEN 240
  92. 3035  IF H <5  THEN 3045
  93. 3040  PRINT "YOU ARE CARRYING TOO MUCH. BETTER DROP  SOMETHING FIRST.": GOTO 7000
  94. 3045  IF P%(I) =  -2  THEN  PRINT "YOU ARE ALREADY CARRYING IT!": GOTO 7000
  95. 3050  GOTO 3065
  96. 3061  IF P%(24) = 7  THEN  PRINT "THE CAT SCOWLS FIERCELY AND WON'T LET<CTRL-M>YOU NEAR.": GOTO 7000
  97. 3062  GOTO 3030
  98. 3065  IF P%(I) < >P  THEN 210
  99. 3066  IF X = 69  THEN  GOSUB 300
  100. 3067  IF X = 63  AND   NOT VR  THEN  PRINT "A MYSTERIOUS BARRIER PREVENTS YOU FROM<CTRL-M>TOUCHING IT.": GOTO 7000
  101. 3070 AX = 0: PRINT "OK.":H = H +1:P%(I) =  -2: GOTO 7000
  102. 3080  IF P = 9  THEN  PRINT "AS YOU TRY TO TAKE THE BOOK A MYSTERIOUSVOICE SHOUTS 'IT IS MINE! GO AWAY!'...<CTRL-M>YOU ARE BACK IN THE FOREST.": GOSUB 220:P = 1: GOTO 7000
  103. 3081  GOTO 240
  104. 3090  IF P%(31) > -2  THEN  PRINT "THE FLIES SCATTERED BEFORE YOU COULD<CTRL-M>CATCH ANY OF THEM.": GOTO 7000
  105. 3095  IF P%(7) = P  THEN  PRINT "MANY FLIES ESCAPED, BUT YOU DID MANAGE<CTRL-M>TO CATCH SEVERAL OF THEM WITH THE PAPER.": GOSUB 220:T%(7) = 1:OD$(7) = "FLIES.":H = H -1:P%(31) = P: GOTO 3010
  106. 3096  GOTO 210
  107. 4000 I = N%(X): IF   NOT I  THEN 240
  108. 4015  IF P%(I) < > -2  THEN 330
  109. 4035  PRINT "OK.":H = H -1
  110. 4047  IF X = 65  THEN 4090
  111. 4048  IF X = 31  THEN 4190
  112. 4070 P%(I) = P: GOTO 270
  113. 4090  IF P < >16  OR P%(8) < >16  THEN 4070
  114. 4100  PRINT "THE BULLFROG SPRINGS FORWARD AND WOLFS<CTRL-M>DOWN THE FLIES. 'THANKS,' HE SAYS, 'THATHOWLING SURE WHETS YOUR APPETITE. SAY"
  115. 4110  GOSUB 220: PRINT "'IJNID' TO THE GOBLIN FOR ME.' HE HOPS<CTRL-M>INTO THE MURKY WATERS OF THE LAKE AND<CTRL-M>VANISHES.": GOSUB 220:P%(8) =  -1:P%(7) =  -1:AX = 0: GOTO 7000
  116. 4190  IF P = 7  AND P%(24) = P  THEN ZZ = 11: PRINT "THE MICE RUN AWAY AND THE CAT CHASES<CTRL-M>AFTER THEM.":P%(24) =  -1:P%(20) =  -1:T%(25) = 1:T%(1) = 1:AX = 0: GOTO 7000
  117. 4191  GOTO 4070
  118. 4200  IF   NOT X  THEN  PRINT "HAVE YOU INSPECTED EVERYTHING?": GOTO 1000
  119. 4210  GOTO 240
  120. 4300  IF X = 10  AND P%(7) =  -2  AND P = 16  AND P%(8) = 16  THEN 4100
  121. 4310  GOTO 240
  122. 4400 I = N%(X): IF   NOT I  THEN 240
  123. 4405  IF P%(I) < > -2  THEN 330
  124. 4410  PRINT "OK.": GOTO 7000
  125. 4500  IF X < >33  THEN 230
  126. 4502  IF GN  THEN  PRINT "IT ALREADY IS.": GOTO 7000
  127. 4503  IF P%(17) < > -2  OR P%(22) < > -2  THEN 240
  128. 4510 P%(22) =  -1:GN = 1: PRINT "OK.":OD$(17) = "LOADED FLINTLOCK PISTOL.":H = H -1: GOTO 7000
  129. 4600  IF   NOT GN  OR P%(17) < > -2  OR I = 61  AND X < >33  THEN 240
  130. 4602  IF I = 61  THEN 4606
  131. 4605  IF P%(34) = P  AND X = 34  THEN  PRINT "GOT HIM!  WITH A DESPERATE HOWL THE<CTRL-M>WEREWOLF COLLAPSES. SLOWLY ITS OUTLINE<CTRL-M>CHANGES TO THAT OF A DECREPIT OLD MAN,": GOSUB 220: PRINT "THEN CRUMBLES INTO DUST!":WF = 1:P%(34) =  -1: GOTO 4607
  132. 4606  PRINT "MISSED.":P%(22) = P +3
  133. 4607 OD$(17) = "SMOKING FLINTLOCK PISTOL.":GN = 0:AX = 0: GOTO 7000
  134. 4700  IF X = 69  THEN 7820
  135. 4701  IF X < >46  THEN 260
  136. 4702  IF P < >21  AND P < >22  THEN 210
  137. 4703  PRINT "THE WALL SPINS AND...": IF P = 21  THEN P = 22: GOTO 7000
  138. 4704 P = 21: GOTO 7000
  139. 4800  IF X = 36  THEN 4860
  140. 4805  IF X < >28  THEN 230
  141. 4815  IF PO  THEN  PRINT "YOU ALREADY DID!": GOTO 7000
  142. 4820  IF P%(36) < > -2  THEN 230
  143. 4840  IF P < >37  OR P%(16) < >37  THEN 4856
  144. 4855  IF SH  THEN PO = 1: PRINT "OK.": PRINT "YOU SEE LIGHTNING OFF IN THE DISTANCE.": GOTO 4859
  145. 4856  PRINT "NOTHING HAPPENED."
  146. 4859 H = H -1:P%(36) =  -1: GOTO 7000
  147. 4860  IF P%(1) < > -2  THEN 230
  148. 4867  IF P = 1  THEN  PRINT "THE ACID SIZZLES VIOLENTLY OVER THE<CTRL-M>WRITING.  YOU CAN READ IT NOW.":SM = 1: GOTO 6666
  149. 4868  PRINT "SIZZLING SLIGHTLY, THE ACID SEEPS INTO<CTRL-M>THE GROUND.": GOTO 6666
  150. 4900  IF X < >76  THEN 260
  151. 4910  IF P%(27) < > -2  AND P%(27) < >P  THEN 210
  152. 4930  PRINT "DAZZLING LIGHT SHOOTS FROM THE BOX AND": IF P = 9  OR P = 10  THEN  PRINT "CAUSES THE ROOF OF THE CAVE TO COLLAPSE -- CRUSHING YOU INSTANTLY.": GOTO 30000
  153. 4933  IF P%(15) = P  THEN  PRINT "ENVELOPS THE SARCOPHAGUS. IN A VIOLENT<CTRL-M>BLAST THE LID FLIES OFF AND EXPLODES IN": GOSUB 220: PRINT "A CASCADE OF GLOWING DUST.":P%(15) =  -1:P%(16) = 37:AX = 0: GOTO 7000
  154. 4934  IF P <38  AND P >26  THEN  PRINT "SHAKES THE ROOM WITH A FANTASTIC JOLT OFPOWER.": GOSUB 220: GOTO 7000
  155. 4935  PRINT "UPROOTS A TREE.": GOTO 7000
  156. 5490 X = I -5
  157. 5500  IF D%(P,X) = 0  THEN 5620
  158. 5510 P = D%(P,X): GOTO 7000
  159. 5620  PRINT "YOU CAN'T GO IN THAT DIRECTION.": GOTO 7000
  160. 5700  IF   NOT X  THEN  PRINT "I ALSO NEED A DIRECTION.": GOTO 1000
  161. 5730  IF X <7  THEN X = X -1: GOTO 5500
  162. 5735  IF X = 8  THEN 10000
  163. 5736  IF X = 7  THEN 11000
  164. 5737  IF X = 57  THEN 12000
  165. 5740  IF X = 99  THEN  PRINT "SORRY...IT'S TOO DANGEROUS.": GOTO 7000
  166. 5745  IF X = 56  AND P = 16  THEN  PRINT "WHAT SHALL I DO WITH IT?": GOTO 1000
  167. 5750  IF X = 12  AND P = 16  THEN 320
  168. 5760  IF X = 13  THEN 310
  169. 5770  IF X = 19  THEN  PRINT "THE ROCK SLIDE IS IMPENETRABLE.": GOTO 7000
  170. 5780  IF X = 20  AND P = 6  THEN P = 7: GOTO 7000
  171. 5790  IF X = 27  THEN 6010
  172. 5800  IF X = 29  THEN  PRINT "ARE YOU CRAZY?!": GOTO 7000
  173. 5810  IF X = 37  AND P = 2  THEN P = 38: GOTO 7000
  174. 5820  IF X = 38  AND P = 23  THEN P = 24: GOTO 7000
  175. 5830  IF X = 39  AND P = 19  THEN P = 21: GOTO 7000
  176. 5840  IF X = 40  AND P = 19  THEN P = 20: GOTO 7000
  177. 5850  IF X = 54  AND P = 13  THEN P = 27: GOTO 7000
  178. 5880  IF X = 59  AND P = 36  THEN 6095
  179. 5890  IF X = 60  AND P = 31  THEN 6107
  180. 5900  IF X = 61  THEN 6110
  181. 5920  IF X = 73  AND P%(28) = P  THEN  PRINT "FANTASTIC! UTTERLY FASCINATING!..OH NO! ...EVERYTHING IS GETTING BLACK--HELP!!": GOSUB 220:P%(28) =  -1:P%(29) = 4:H = H +1:P%(27) =  -2:AX = 0: GOTO 7000
  182. 5930  IF X = 77  THEN 6130
  183. 5950  GOTO 240
  184. 6010  IF GT  THEN P = 11: GOTO 7000
  185. 6011  GOTO 200
  186. 6095  IF VR  THEN P = 37: GOTO 7000
  187. 6096  PRINT "SOMEONE SHOOK THE LADDER, KNOCKING YOU<CTRL-M>TO THE FLOOR.": GOTO 7000
  188. 6107  PRINT "SPINNING, YOU SEE MULTITUDES OF PENGUINSFEVERISHLY BAKING CHERRY PIES. ONE ASKS IF YOU'VE PLAYED 'PIE-MAN'.": GOSUB 220: PRINT "SUDDENLY, YOU'RE BACK IN THE CELLAR.": GOTO 1000
  189. 6110  IF P = 31  THEN 6107
  190. 6111  IF P < >9  AND P < >10  THEN X = 0: GOTO 5700
  191. 6112  IF   NOT DR  THEN 200
  192. 6114  IF P = 9  THEN P = 10: GOTO 7000
  193. 6115 P = 9: GOTO 7000
  194. 6140  IF X = 56  THEN I = 59: GOTO 9400
  195. 6142  IF X < >22  THEN 290
  196. 6145  IF P%(25) < > -2  AND P%(25) < >P  OR T%(25) = 0  THEN 210
  197. 6146  IF P%(24) = P  THEN 3061
  198. 6150  PRINT "THE BROOMSTICK BUCKS VIOLENTLY, BUT YOU ARE FINALLY ABLE TO MASTER IT. IT SOARS HIGH OVER THE WOODS, SHOWING YOU THE":P%(25) =  -1:P = 15: GOSUB 220:H = H -1
  199. 6160  PRINT "HILLS OF TRANSYLVANIA BATHED IN A PALE<CTRL-M>MOONLIGHT. THE BROOM DIVES, CIRCLING<CTRL-M>TWICE AROUND A GLOOMY CASTLE. TO THE": GOSUB 220: PRINT "SOUTH YOU SEE A LAKE EXTENDING FAR<CTRL-M>BEYOND THE FOREST. SUDDENLY THE BROOM"
  200. 6170  PRINT "PLUNGES TOWARD THE LAKE. YOU ARE SHAKEN": GOSUB 220: PRINT "LOOSE AND FALL INTO A LARGE WILLOW ON<CTRL-M>THE SHORE.  THE LAST SOUND YOU HEAR IS<CTRL-M>THE LOUD, CHILLING CACKLE OF A WITCH!": GOSUB 220: GOTO 7000
  201. 6300  IF X = 27  THEN 6370
  202. 6301  IF X < >61  THEN 240
  203. 6310  IF P < >9  AND P < >10  THEN 210
  204. 6315  IF DR  THEN 280
  205. 6320  IF P%(26) =  -2  THEN DR = 1: PRINT "OK.": GOTO 7000
  206. 6330  GOTO 240
  207. 6370  IF P < >5  THEN 210
  208. 6375  IF GT  THEN 280
  209. 6380  IF P%(11) < > -2  THEN 240
  210. 6390 GT = 1: PRINT "OK.": GOTO 7000
  211. 6400  IF X = 27  THEN 6470
  212. 6401  IF X < >61  THEN 240
  213. 6410  IF P < >9  AND P < >10  THEN 210
  214. 6415  IF DR  THEN DR = 0: PRINT "OK.": GOTO 7000
  215. 6417  GOTO 200
  216. 6470  IF P < >5  THEN 210
  217. 6475  IF   NOT GT  THEN 200
  218. 6480  IF P%(11) < > -2  THEN 240
  219. 6490 GT = 0: PRINT "OK.": GOTO 7000
  220. 6500  IF X = 43  THEN 6570
  221. 6510  IF X < >41  THEN  PRINT "YECCHHH!": GOTO 7000
  222. 6530  IF P%(9) < >P  AND P%(9) < > -2  THEN 210
  223. 6534  PRINT "IT TASTED AWFUL.":AX = 0: IF P%(9) =  -2  THEN AX = 1:H = H -1
  224. 6535 P%(9) =  -1: GOTO 7000
  225. 6570  IF P%(32) < >P  AND P%(32) < > -2  THEN 210
  226. 6580  PRINT "OK":AX = 0: IF P%(32) =  -2  THEN AX = 1:H = H -1
  227. 6581 P%(32) =  -1: GOTO 7000
  228. 6600  IF X = 117  THEN 6620
  229. 6605  IF X = 36  THEN 6640
  230. 6610  IF X = 28  THEN  PRINT "TO YOU THAT STUFF IS POISONOUS!": GOTO 7000
  231. 6615  GOTO 230
  232. 6620  IF P < >16  THEN 240
  233. 6625  PRINT "AAH! THAT HITS THE SPOT!": GOTO 7000
  234. 6640  IF P%(1) < > -2  THEN 210
  235. 6665  PRINT "THE ACID BURNS YOUR MOUTH AND YOU<CTRL-M>INSTINCTIVELY SPIT IT OUT."
  236. 6666  GOSUB 220: PRINT "OOPS! THE BOTTLE SLIPPED!<CTRL-M>SMASH!":H = H -1:P%(1) =  -1: GOTO 7000
  237. 6700  IF X = 12  AND P = 16  THEN 320
  238. 6705  IF X = 57  THEN 12000
  239. 6710  IF X = 59  THEN 5880
  240. 6711  IF X < >13  THEN 240
  241. 6712  IF P < >16  THEN 310
  242. 6725  GOTO 320
  243. 7000  IF P%(39) < >P  THEN V =  -1
  244. 7001  IF P%(34) < >P  THEN W =  -1
  245. 7003  IF P < >35  AND P%(5) = 35  THEN P%(5) =  -1:N%(62) = 23:P%(4) =  -1:P%(23) = 35
  246. 7005 TU = TU +1: IF  INT(TU/70) = TU/70  THEN Y = TU/70: GOTO 876
  247. 7015  IF TU -V = 1  THEN  PRINT "YOU FEEL A PINCH ON YOUR NECK, THE ROOM SPINS, AND YOU BLACK OUT...": GOSUB 220: GOTO 30000
  248. 7020  IF TU -W = 1  THEN  PRINT "TOO LATE! THE FURRY FIEND JUST HAD YOU<CTRL-M>FOR DINNER...": GOSUB 220: GOTO 30000
  249. 7021  IF P%(20) <1  THEN 7030
  250. 7022 I = P%(20): IF I = CR  THEN AX = 0
  251. 7023  IF I = 2  THEN I = 17: GOTO 7028
  252. 7024  IF I = 19  THEN I = 2
  253. 7025  IF I = 3  THEN I = 19
  254. 7026  IF I = 17  THEN I = 3
  255. 7027  IF I = 38  OR I = 74  THEN I = I -36
  256. 7028 P%(20) = I: IF I = CR  AND AX  THEN I = 20: GOSUB 8070
  257. 7030  IF TU -R = 20  THEN  PRINT "I THOUGHT I SAW A SHOOTING STAR!":P%(28) = 4:AX = 0: GOTO 7990
  258. 7031  IF P%(39) = P  OR P%(34) = P  THEN 7140
  259. 7040  IF P = 7  THEN 7330
  260. 7050  IF P < >26  OR P%(10) < >26  THEN 7060
  261. 7052 Z =  INT( RND(1) *4) +1: ON Z GOTO 7054,7055,7056
  262. 7053  PRINT "SOMEONE JUST GAVE YOU A HOTFOOT! AAAAH!": GOTO 7990
  263. 7054  PRINT "SOMEONE JUST DUMPED WATER ON YOU!": GOTO 7990
  264. 7055  PRINT "THE GOBLIN JUST GAVE YOU A JUICY BRONX<CTRL-M>CHEER!": GOTO 7990
  265. 7056  PRINT "SOMEONE JUST SET YOUR HAIR ON FIRE! YOU WERE ABLE TO PUT IT OUT, THOUGH.": GOTO 7990
  266. 7060  IF P >26  AND P <38  THEN 7350
  267. 7090  IF WF  THEN 7140
  268. 7100  IF  RND(1) <.67  OR TU <10  THEN 7140
  269. 7125  IF P = 15  OR P = 9  OR P = 10  OR P = 26  OR P = 22  THEN 7990
  270. 7130 W = TU:P%(34) = P: IF CR = P  AND AX  THEN I = 34: GOSUB 8070
  271. 7140  IF  RND(1) >.2  THEN 7990
  272. 7170 Y =  INT( RND(1) *ZZ) +1
  273. 7175  ON Y GOTO 7180,7185,7190,7195,7200,7205,7210,7215,7220,7270,7225
  274. 7180  PRINT "A WITCH'S CACKLE CUTS THROUGH THE STILL AIR OF THE NIGHT.": GOTO 7990
  275. 7185  PRINT "A FEW BATS HOVERED OVER YOU FOR A WHILE,BUT FLEW AWAY.": GOTO 7990
  276. 7190  PRINT "YOU HEAR A WOLF HOWL IN THE DISTANCE.": GOTO 7990
  277. 7195  PRINT "YOU HEAR MOANING NOISES IN THE DISTANCE.": GOTO 7990
  278. 7200  PRINT "A STRANGE, GHOSTLY SHAPE JUST FLOATED<CTRL-M>PAST MOURNFULLY CRYING '";YN$;",": PRINT YN$;"...'": GOTO 7990
  279. 7205  PRINT "YOU HEARD SOME RUSTLING NOISES NEARBY.": GOTO 7990
  280. 7210  PRINT "A ROUGH VOICE SHOUTS 'GET OUT!'": GOTO 7990
  281. 7215  PRINT "HOOOO! HOOOO! (WHO?) - JUST AN OWL.": GOTO 7990
  282. 7220  PRINT "A GRIM CHUCKLE ERUPTS BEHIND YOU.": GOTO 7990
  283. 7225  PRINT "A CAT DARTED BY, FOLLOWED BY THREE<CTRL-M>RAVENOUS-LOOKING MICE.": GOTO 7990
  284. 7270  IF RT%(P) >2  THEN 7990
  285. 7271  PRINT "A GIANT EAGLE SWOOPS DOWN ON YOU, GRASPSYOU IN ITS TALONS, AND TAKES YOU TO<CTRL-M>ANOTHER PART OF THE FOREST.": GOSUB 220
  286. 7272 P =  INT( RND(1) *23) +1: IF RT%(P) >2  OR CR = P  THEN 7272
  287. 7273 P%(34) =  -1: GOTO 7990
  288. 7330  IF  RND(1) <.5  OR P%(24) < >7  OR P < >7  THEN 7990
  289. 7338  PRINT "YOU HEAR A LOUD, HISSING 'MEOW'.": GOTO 7990
  290. 7350  IF P%(32) =  -2  OR VR  THEN 7990
  291. 7355  IF  RND(1) <.2  THEN P%(39) = P:V = TU: IF CR = P  AND AX  THEN I = 39: GOSUB 8070
  292. 7370  GOTO 7990
  293. 7500  IF X = 29  AND P = 38  THEN AX = 0: PRINT "AS YOU LIFT THE LID AN OVERPOWERING<CTRL-M>STENCH HITS YOU...":N%(29) = 19:P%(20) = 74:P%(19) = 38:P%(22) = 38:P%(37) = 38:P%(21) =  -1: GOTO 7000
  294. 7502  IF X = 61  THEN 6310
  295. 7505  IF X = 62  THEN 7530
  296. 7510  IF X = 70  AND P = 37  THEN  PRINT "GIVE UP-THE SARCOPHAGUS IS HERMETICALLY SEALED.": GOTO 7000
  297. 7515  IF X = 72  THEN  PRINT "IT SEEMS BOLTED DOWN SOMEHOW.": GOTO 7000
  298. 7516  IF X < >27  OR P%(13) < >P  THEN 230
  299. 7525  IF GT  THEN 280
  300. 7526  GOTO 200
  301. 7530  IF P < >35  THEN 210
  302. 7534  IF P%(23) = P  THEN N%(62) = 4:P%(4) = P:P%(5) = P: PRINT "OK.":P%(23) =  -1:AX = 0: GOTO 7000
  303. 7535  GOTO 280
  304. 7600  IF X < >29  THEN 240
  305. 7601 N%(34) = 21:P%(37) =  -1:P%(21) = 38:P%(19) =  -1:AX = 0: IF P%(22) = 38  THEN P%(22) =  -1
  306. 7602  GOTO 7000
  307. 7700  IF (X = 63  OR X = 115)  AND P = 4  AND P%(3) =  -2  AND P%(5) =  -2  THEN 7745
  308. 7701  IF X = 26  AND P%(6) =  -2  THEN 7769
  309. 7702  IF X = 28  THEN 7780
  310. 7705  GOTO 290
  311. 7745  PRINT "A STREAM OF WHITE FIRE SHOOTS FROM YOUR<CTRL-M>RING ONTO THE STATUE. GREEN AND WHITE<CTRL-M>FLAMES BURN QUICKLY, ENGULFING ALL THAT": GOSUB 220: PRINT "IS AROUND YOU. SUDDENLY, A RED FIREBALL EMERGES, QUELLING THE WHITE AND GREEN"
  312. 7746  PRINT "FLAMES IN ITS FURY. THE AWKWARD": GOSUB 220: PRINT "SILHOUETTE OF AN ALIEN CREATURE APPEARS<CTRL-M>IN FRONT OF THE FIREBALL. IT STEPS<CTRL-M>FORWARD INTO THE RETURNING DARKNESS.": GOSUB 220: PRINT "'WELL MET, SIR! YOU HAVE FREED ME FROM"
  313. 7747  PRINT "MY ACCURSED PRISON! I AM DEEPLY INDEBTEDTO YOU!' THE CREATURE GRASPS THE RING": GOSUB 220: PRINT "AND CRUSHES IT. THERE IS A VIOLENT<CTRL-M>EXPLOSION. WHEN THE SMOKE CLEARS, STATUEAND ALIEN ARE NOWHERE TO BE SEEN.": GOSUB 220
  314. 7765 P%(5) =  -1:P%(2) =  -1:R = TU:H = H -1:AX = 0: GOTO 7000
  315. 7769  PRINT "A STREAM OF BLINDING LIGHT ESCAPES FROM THE CROSS.": GOSUB 220: IF P%(39) < >P  THEN 7000
  316. 7771  PRINT "THE VAMPIRE SHRIEKS AND DISINTEGRATES<CTRL-M>INTO A PILE OF BURNING DUST.":P%(39) =  -1:VR = 1:AX = 0: GOTO 7000
  317. 7780  IF P%(36) < > -2  THEN 210
  318. 7783 SH = 1: PRINT "OK.": GOTO 7000
  319. 7800  IF X = 69  THEN 7820
  320. 7805  IF X = 102  AND P = 21  THEN  PRINT "IT WOBBLES.": GOTO 7000
  321. 7810  IF X < >25  OR P < >5  THEN 290
  322. 7815  PRINT "YOU FOUND A GRATE BEHIND THE GRAVESTONE.":P%(13) = 5:I = 13: GOTO 270
  323. 7820  IF P < >37  OR P%(14) < >37  THEN 230
  324. 7821  GOSUB 300:I = 15: GOTO 270
  325. 7900  IF PO < >1  OR   NOT SH  OR P < >37  THEN 290
  326. 7915  PRINT "THE DAMSEL STIRS A LITTLE AND FINALLY<CTRL-M>AWAKENS.":T%(38) = 1:P%(38) = P:P%(16) =  -1:N%(71) = 38:AX = 0: GOTO 7000
  327. 7990  IF CR = P  AND AX  THEN 1000
  328. 7995 AX = 1: IF BR = P  THEN 8020
  329. 8000 BR = P:CR = P:O =  PEEK(37) +1: POKE 34,0: POKE 35,13: & : VTAB 1: HOME : POKE 35,LD: HOME : POKE 35,24: PRINT "<CTRL-D>OPENROOMS,L69": PRINT "<CTRL-D>READROOMS,R";P: INPUT L$: PRINT "<CTRL-D>CLOSE": PRINT "YOU ARE ";L$: PRINT "OBVIOUS EXITS: ";: IF D%(P,0) >0  THEN  PRINT "N. ";
  330. 8008  IF D%(P,1) >0  THEN  PRINT " S. ";
  331. 8009  IF D%(P,2) >0  THEN  PRINT " W. ";
  332. 8010  IF D%(P,3) >0  THEN  PRINT " E. ";
  333. 8011  IF D%(P,4) >0  THEN  PRINT " U. ";
  334. 8012  IF D%(P,5) >0  THEN  PRINT " D. ";
  335. 8013  PRINT : PRINT "<-------------------------------------->":LD =  PEEK(37) +1: POKE 34,LD: VTAB O: PRINT "YOU ARE ";L$: PRINT "<CTRL-D>BLOADR";P;",A4608"
  336. 8020  POKE 2560,0: POKE 2561,18: CALL 2608
  337. 8030  FOR I = 1 TO M: IF P%(I) = P  THEN  GOSUB 8070
  338. 8040  NEXT I: GOTO 1000
  339. 8070  PRINT "THERE IS A ";OD$(I): IF I = 10  OR I = 38  THEN BR = 0: PRINT "<CTRL-D>BLOADO";I;",A4608": POKE 2560,0: POKE 2561,18: CALL 2613: RETURN 
  340. 8072  IF CO < >I  THEN CO = I: PRINT "<CTRL-D>BLOADO";I;",A6632"
  341. 8075  POKE 2560,232: POKE 2561,25: CALL 2613: RETURN 
  342. 8500  PRINT "OKAY."
  343. 8510  IF X = 81  AND P%(10) = 26  AND P = 26  THEN  PRINT "THE GOBLIN DROPS THE KEY AND FLEES<CTRL-M>SCREAMING INTO THE DARKNESS...":P%(10) =  -1:P%(11) = P:AX = 0: GOTO 7000
  344. 8540  GOTO 290
  345. 9000  PRINT "YOUR WHISTLE ECHOED EERILY BACK TO YOU.": GOTO 7000
  346. 9400  IF (X = 82  AND I = 54  OR X = 78  AND I = 35  OR I = 59  AND (X = 56  OR X = 82))  AND P = 16  THEN 9420
  347. 9410  GOTO 230
  348. 9420  IF P%(38) < > -2  THEN  PRINT "AFTER A MISERABLE, CHOPPY JOURNEY, THE<CTRL-M>KING'S GUARDS REFUSE TO LET YOU LAND<CTRL-M>WITHOUT THE PRINCESS SABRINA! THEY LET": GOSUB 220: PRINT "YOU CHOOSE BETWEEN THE GUILLOTINE AND<CTRL-M>SAILING BACK. YOU SAIL BACK.": GOSUB 220: GOTO 1000
  349. 9440  PRINT "AFTER A PRECARIOUS FEW MINUTES, THE<CTRL-M>JOURNEY GOES SMOOTHLY. A SOMEWHAT TIRED AND BEWILDERED PRINCESS SABRINA": GOSUB 220: PRINT "GRACIOUSLY THANKS YOU AS YOU RETURN TO<CTRL-M>HER KINGDOM. THE KING IS SUITABLY"
  350. 9445  PRINT "IMPRESSED AND ASKS THAT YOU BE SENT TO": GOSUB 220: PRINT "DEEPEST AFRICA TO SAVE HIS OTHER<CTRL-M>DAUGHTER. THAT EVENING, YOU SNEAK OUT<CTRL-M>IN PEASANT DRESS, PLOTTING YOUR RESCUE": GOSUB 220: PRINT "OF SABRINA FROM THE KING'S CASTLE...<CTRL-M>WELL DONE!"
  351. 9450  GOTO 30040
  352. 9600  PRINT "ISN'T THAT A LITTLE CORNY?": GOTO 7000
  353. 9700  IF P = 15  AND X = 11  THEN  PRINT "'YOU ARE ON THE PROPERTY OF ZIN THE<CTRL-M>WIZARD, WHO LIVES IN A CABIN IN THIS<CTRL-M>FOREST. THE SUN WILL RISE AT FIVE.'": GOTO 7000
  354. 9702  IF X = 25  THEN 1555
  355. 9705  IF X = 24  AND (P%(18) = P  OR P%(18) =  -2)  THEN  PRINT "'SABRINA DIES AT DAWN!'": GOTO 7000
  356. 9710  IF (X = 51  OR X = 49)  AND P = 1  THEN 9760
  357. 9715  IF X < >66  OR P < >9  THEN 240
  358. 9720  PRINT "ALL THE PAGES HAVE BEEN RIPPED OUT BUT<CTRL-M>ONE. IT READS 'MAGIC ELIXIRS-MOST TYPES DEAL WITH THE REMOVAL OF SPELLS CAST ON": GOSUB 220: PRINT "PEOPLE. TO USE AN ELIXIR, SIMPLY WAVE<CTRL-M>THE CONTAINER TO ENERGIZE THE"
  359. 9721  PRINT "INGREDIENTS AND POUR CONTENTS ON THE": GOSUB 220: PRINT "SUBJECT. TO COMPLETE THE SPELL, CLAP<CTRL-M>YOUR HANDS.": GOSUB 220: GOTO 7000
  360. 9760  IF SM  THEN  PRINT "THE WRITING SAYS 'KNOCK HERE'.": GOTO 7000
  361. 9761  PRINT "IT'S COVERED WITH SEDIMENT AND TOO FUZZYTO READ.": GOTO 7000
  362. 9800  IF X < >49  THEN 290
  363. 9820  IF P = 1  THEN  PRINT "POOF!":P = 9: GOTO 7000
  364. 9821  PRINT "HUH?": GOTO 7000
  365. 9900 Z =  INT( RND(1) *7) +1: IF Z < >6  THEN 7175
  366. 9930  PRINT "YOU HEARD NOTHING, WHICH IS ODD IN THIS FOREST.": GOTO 1000
  367. 10000  IF RT%(P) <4  THEN 230
  368. 10010  IF RT%(P) <7  THEN P = P -RT%(P) +3: GOTO 7000
  369. 10012  IF P = 27  THEN P = 13
  370. 10014  IF P = 36  OR P = 11  THEN P = P -6
  371. 10016  IF P = 38  THEN P = 2
  372. 10018  IF P = 15  THEN P = 16
  373. 10019  IF P = 9  OR P = 10  OR P = 22  THEN 240
  374. 10020  GOTO 7000
  375. 11000  IF RT%(P) < >2  THEN 5737
  376. 11005  IF P = 8  THEN 240
  377. 11010  IF P = 23  OR P = 6  THEN P = P +1
  378. 11015  IF P = 13  THEN P = 27
  379. 11020  GOTO 7000
  380. 12000  IF P = 24  THEN P = 25: GOTO 7000
  381. 12002  IF P = 25  OR P = 35  THEN P = P -1: GOTO 7000
  382. 12004  IF P = 30  THEN P = 36: GOTO 7000
  383. 12006  IF P = 36  THEN P = 30: GOTO 7000
  384. 12008  GOTO 210
  385. 25000  INPUT "ARE YOU SURE?";J$
  386. 25010  IF  LEFT$(J$,1) = "Y"  THEN  GOSUB 100: GOSUB 220: INPUT "NAME FOR SAVED GAME : ";J$: PRINT "<CTRL-D>NOMONC,I,O": GOTO 25020
  387. 25012  IF  LEFT$(J$,1) < >"N"  THEN 25000
  388. 25015  GOTO 1000
  389. 25020  PRINT "<CTRL-D>OPEN";J$: PRINT "<CTRL-D>WRITE";J$: PRINT P: PRINT TU: PRINT NZ: FOR I = 1 TO NZ: PRINT N%(I): NEXT : PRINT M: FOR I = 1 TO M: PRINT OD$(I): PRINT P%(I): PRINT T%(I): NEXT 
  390. 25030  PRINT LZ: FOR I = 1 TO LZ: PRINT RT%(I): FOR X = 0 TO 5: PRINT D%(I,X): NEXT : NEXT : PRINT SM: PRINT GT: PRINT SH: PRINT PO: PRINT GN: PRINT DR: PRINT H: PRINT R: PRINT W: PRINT V: PRINT WF: PRINT VR: PRINT ZZ: PRINT YN$: PRINT "<CTRL-D>CLOSE"
  391. 25035  GOSUB 110: GOSUB 220: GOTO 1000
  392. 27000  PRINT "THE SUN BEGINS TO APPEAR ON THE HORIZON.": GOSUB 220: PRINT "YOUR TIME HAS RUN OUT! ";: IF P%(N%(71)) = P  OR P%(N%(71)) =  -2  THEN 27020
  393. 27010  PRINT "YOU HEAR A TERRORFILLED SCREAM. RUNNING TO WHERE IT HAS<CTRL-M>COME FROM YOU FIND THE LIFELESS BODY OF": GOSUB 220: PRINT "PRINCESS SABRINA LYING IN A POOL OF<CTRL-M>BLOOD!": GOTO 30040
  394. 27020  PRINT "SUDDENLY<CTRL-M>SOMETHING HITS YOU. YOU AWAKEN WITH A<CTRL-M>DULL ACHE IN THE BACK OF YOUR HEAD, AND": GOSUB 220: PRINT "TURN TO FIND THE LIFELESS BODY OF<CTRL-M>PRINCESS SABRINA LYING IN A POOL OF<CTRL-M>BLOOD!": GOTO 30040
  395. 30000  PRINT "SO MUCH FOR THAT TRY..."
  396. 30040  PRINT "PRESS ANY KEY TO RESTART THE GAME.": GET J$: PRINT : PRINT "<CTRL-D>PR#6"