home *** CD-ROM | disk | FTP | other *** search
/ The Glitch Apple Disk Collection / 2014.glitch.apple.collection.zip / indexed / TEXTADV.DSK / DUKEDOM.bas < prev    next >
BASIC Source File  |  2014-09-09  |  14KB  |  217 lines
  1. 1000  TEXT : HOME 
  2. 1001  DEF  FN X(Y) =  RND(1) *(1 +F3% -( -F3%)) +( -F3%) +R(Y)
  3. 1002  GOSUB 20000
  4. 1010  GOTO 1620
  5. 1030  DIM P(8),L(3),G(10),S(6),U(6),R(8),P$(8),L$(3),G$(10)
  6. 1050 Q3% =  RND(1) *(1 +Q2% -Q1%) +Q1%: IF Q3% >5  THEN G0% = Q3% +Q3%/2
  7. 1055  IF Q3% <5  THEN G0% = Q3%
  8. 1060  RETURN 
  9. 1330  INPUT " ";V$:V$ =  LEFT$(V$,1): IF  LEN(V$) = 0  THEN V$ = "N"
  10. 1331  IF  ABS( VAL(V$)) >95  THEN V$ =  CHR$( ABS( VAL(V$) -32))
  11. 1332  IF V$ = "N"  OR V$ = "Y"  THEN  RETURN 
  12. 1333  PRINT "PLEASE ANSWER YES OR NO: ";: GOTO 1330
  13. 1335  IF  ABS( VAL(V$)) >95  THEN V$ =  CHR$( ABS( VAL(V$) -32))
  14. 1430  INPUT " ";V$:V =  INT( VAL(V$)): IF V > = 0  THEN  RETURN 
  15. 1432  PRINT "PLEASE ENTER A NON-NEGATIVE NUMBER: ";: GOTO 1430
  16. 1530  PRINT "BUT YOU DON'T HAVE ENOUGH GRAIN": PRINT "YOU HAVE ";G;" HL. OF GRAIN LEFT,": IF X1 > = 4  THEN  PRINT "ENOUGH TO BUY  "; INT(G/X1)" HA. OF LAND"
  17. 1531  PRINT "ENOUGH TO PLANT "; INT(G/2);" HA. OF LAND": RETURN 
  18. 1550  PRINT "BUT YOU DON'T HAVE ENOUGH LAND ": PRINT "YOU ONLY HAVE  ";L;"  HA. OF LAND LEFT ": RETURN 
  19. 1570 : PRINT "BUT YOU DON'T HAVE ENOUGH PEASANTS": PRINT "YOUR PEASANTS CAN ONLY PLANT  ";4 *P"  HA. OF LAND": RETURN 
  20. 1620  PRINT : PRINT "D U K E D O M ": PRINT "DO YOU WANT INSTRUCTIONS ? ";: GOSUB 1330: IF V$ = "N"  THEN 2050
  21. 1690  HOME : PRINT "FOR INSTRUCTIONS ON THE GAME PLEASE     READ CREATIVE COMPUTING, FEB. 1980 FOR  THE LONG EXPLANATION OF THE HISTORICAL  SITUATION BEHIND THE GAME."
  22. 1691  PRINT : PRINT "THE MOST IMPORTANT THING TO KNOW AT     THIS POINT IS THE AMOUNT OF GRAIN       NECESSARY TO FEED THE PEASANTS. 14 HL.  PER PEASANT IS ADEQUATE.   "
  23. 1692  PRINT "13 HL. PER PEASANT WILL CAUSE SOME      HUNGER AND DECREASE FIGHTING ABILITY.   AT 12 HL. PER, SOME WILL STARVE AND IT  WILL CREATE RESENTMENT."
  24. 1693  PRINT "BY OVER FEEDING THE PEASANTS (UP TO 18) YOU WILL INCREASE THEIR GOOD WILL FOR   YOU AND THEY WILL FIGHT BETTER FOR YOU  IN THE COMING SPRING."
  25. 1694  PRINT "GOOD LUCK"
  26. 1700  INPUT " ";V$
  27. 2050 F3% = 2:M = 1.3: REM   M IS CHANGED FROM 1.95..THIS CHANGE ALLOWS GREATER L(3) SPOILS OF WAR    
  28. 2051 M = 1.95
  29. 2100  PRINT "DO YOU WISH TO SKIP THE DETAILED REPORTS AT THE END OF EACH YEAR? ";: GOSUB 1330:R$ = V$
  30. 2180  READ Y%,C1,U1,U2,K%,D,P,L,G
  31. 2190  FOR I = 1 TO 8: READ P(I): NEXT : FOR I = 1 TO 3: READ L(I): NEXT : FOR I = 1 TO 10: READ G(I): NEXT : FOR I = 1 TO 6: READ S(I): NEXT 
  32. 2192  FOR I = 1 TO 8: READ P$(I): NEXT : FOR I = 1 TO 3: READ L$(I): NEXT : FOR I = 1 TO 10: READ G$(I): NEXT 
  33. 2200  RESTORE 
  34. 2210  DATA   0,3.95,0,0,0,0,100,600 ,4177,96,0,0,0,0,0,-4,8,600, 0,0,5193,-1344,0,-768,0,0,0, 1516,-120,-300,216,200,184,0   ,0,0   
  35. 2270 Q1% = 4:Q2% = 7: GOSUB 1050:R(1) = G0%:Q2% = 8: GOSUB 1050:R(2) = G0%:Q2% = 6: GOSUB 1050:R(3) = G0%:Q1% = 3:Q2% = 8: GOSUB 1050:R(4) = G0%:Q1% = 5: GOSUB 1050:R(5) = G0%:Q1% = 3:Q2% = 6: GOSUB 1050:R(6) = G0%
  36. 2271 Q2% = 8: GOSUB 1050:R(7) = G0%:Q1% = 4: GOSUB 1050:R(8) = G0%
  37. 2460  PRINT "YEAR ";Y%;" PEASANTS "; INT(P);" LAND ";L;" GRAIN ";G: PRINT 
  38. 2500  IF R$ = "Y"  THEN 2810
  39. 2501  PRINT "YIELD = ";C;" HL/HA."
  40. 2510  FOR J1 = 1 TO 8: IF P(J1) < >0  OR J1 = 1  THEN  PRINT P$(J1); TAB( 20); INT(P(J1))
  41. 2520  NEXT J1
  42. 2530  PRINT "PEASANTS AT END "; TAB( 20); INT(P)
  43. 2600  FOR J1 = 1 TO 3: IF L(J1) < >0  OR J1 = 1  THEN  PRINT L$(J1); TAB( 20); INT(L(J1))
  44. 2610  NEXT J1: PRINT "LAND AT END "; TAB( 20); INT(L)
  45. 2690  PRINT "100%  80%   60%   40%   20%  DEPL"
  46. 2691  PRINT "-----------------------------------"
  47. 2692  FOR J1 = 1 TO 6: IF J1 = 1  THEN GG =  -5
  48. 2693 GG = GG +6: HTAB GG: PRINT  INT(S(J1));: NEXT :
  49. 2694  PRINT 
  50. 2720  FOR J1 = 1 TO 10: IF G(J1) < >0  OR J1 = 1  THEN  PRINT G$(J1); TAB( 20); INT(G(J1))
  51. 2730  NEXT J1: PRINT "GRAIN AT END"; TAB( 20);G:
  52. 2800  IF Y% < = 0  THEN  PRINT "(CROP DAMAGE DUE TO SEVEN YEAR LOCUSTS)"
  53. 2810 Y% = Y% +1: FOR I = 1 TO 8:P(I) = 0: NEXT : FOR I = 1 TO 3:L(I) = 0: NEXT : FOR I = 1 TO 10:G(I) = 0: NEXT 
  54. 2815 P(1) = P:L(1) = L:G(1) = G
  55. 2816  PRINT 
  56. 2980  IF P > = 33  THEN 3040
  57. 2981  PRINT "YOU HAVE SO FEW PEASANT LEFT THAT "
  58. 3000  PRINT "THE HIGH KING HAS ABOLISHED YOUR DUCAL  RIGHT ": GOSUB 24040: GOTO 30000
  59. 3040  IF L > = 199  THEN 3070
  60. 3050  PRINT "YOU HAVE SO LITTLE LAND LEFT THAT ";: GOTO 3100
  61. 3070  IF U1 >88  OR U2 >99  THEN 3100
  62. 3071  IF G > = 429  THEN 3130
  63. 3100  PRINT "THE PEASANTS TIRE OF WAR AND STARVATION": PRINT "YOU ARE DEPOSED": PRINT : GOTO 30000
  64. 3130  IF Y% >45  AND K% = 0  THEN  PRINT "YOU HAVE REACHED THE AGE OF MANDATORY   RETIREMENT": GOTO 30000
  65. 3170 U1 = 0: IF K% >0  THEN  PRINT "THE KING DEMANDS TWICE TH ROYAL TAX IN  THE HOPE OF PROVOKING WAR. WILL YOU PAY";: GOSUB 1330:K% = 2: IF V$ = "N"  THEN K% =  -1
  66. 3270  PRINT "GRAIN FOR FOOD = ";: GOSUB 1430:V = V *P: IF V >G  THEN  GOSUB 1530: GOTO 3270
  67. 3271  IF V = 0  THEN 3270
  68. 3350  IF V/P <11  AND V <G -100  THEN  PRINT "PEASANTS DEMONSTRATE BEFORE THE CASTLE  WITH SHARPENED SCYTHES":U1 = U1 +3: GOTO 3270
  69. 3410 G(2) =  -V:G = G +G(2)
  70. 3440 X1 = V/P: IF X1 <13  THEN  PRINT "SOME PEASANTS HAVE STARVED DURING THE   WINTER":P(2) =  - INT(P -V/13):P = P +P(2)
  71. 3490 X1 = X1 -14:X1 =  -X1 *(X1 < = 4) -4 *(X1 >4)::U1 = U1 -3 *P(2) -2 *X1: IF V1 >88  THEN 3100
  72. 3491  IF P <33  THEN 2980
  73. 3580 C = C1:
  74. 3582 X1 =  INT(2 *C + FN X(1) -5)
  75. 3585 X1 =  -X1 *(X1 > = 4) -4 *(X1 <4)
  76. 3589 X1 =  -X1
  77. 3640  PRINT "LAND TO BUY AT ";X1;" HL./HA.= ";: GOSUB 1430:G(3) =  -V *X1: IF  -G(3) >G  THEN  GOSUB 1530: GOTO 3640
  78. 3700 L(2) = V:S(3) = S(3) +V: IF V >0  THEN 4020
  79. 3701 X2 = S(1) +S(2) +S(3)
  80. 3740  FOR J1 = 1 TO 3:X1 = X1 -1: PRINT "LAND TO SELL AT ";X1;" HL./HA. = ";: GOSUB 1430: IF V >X2  THEN  PRINT "BUT YOU ONLY HAVE "X2;" HA. OF GOOD LAND": GOTO 3840
  81. 3810 G(3) = V *X1: IF G(3) < = 4000  THEN 3870
  82. 3811  PRINT "NO BUYERS HAVE THAT MUCH GRAIN--SELL    LESS"
  83. 3840  NEXT J1: PRINT "BUYERS HAVE LOST INTEREST":V = 0:G(3) = 0
  84. 3870 L(2) =  -V
  85. 3880  FOR J1 = 3 TO 1  STEP  -1: IF V < = S(J1)  THEN 4010
  86. 3881 V = V -S(J1):S(J1) = 0: NEXT J1
  87. 3882  REM  LOOP SHOULD NEVER EXIT HERE    
  88. 3960  PRINT "LAND SELLING LOOP ERROR ": END 
  89. 4010 S(J1) = S(J1) -V
  90. 4020 L = L +L(2): IF L <10  THEN 3040
  91. 4021  IF L(2) <0  AND X1 <4  THEN G(3) =  INT(G(3)/2): PRINT "THE HIGH KING APPROPRIATES HALF YOUR    EARNINGS AS PUNISHMENT FOR SELLING AT   JUST A LOW PRICE!!"
  92. 4090 G = G +G(3)
  93. 4130  IF K% < > -2  THEN 4350
  94. 4131  PRINT "THE KING'S ARMY IS ABOUT TO ATTACK YOUR DUCHY":X1 =  INT(G/100): PRINT "AT 100 HL EACH (PAYMENT IN ADVANCE)"
  95. 4170  PRINT "YOU HAVE HIRED ";X1;" FOREIGN MERCENARIES": IF 8 *X1 +P >2399  THEN 4220
  96. 4190  PRINT "THE PLACEMENT OF YOUR HEAD ATOP THE     CASTLE GATE SIGNIFIES THAT ";: GOTO 3000
  97. 4220  PRINT "WIPE THE BLOOD FROM THE CROWN--YOU ARE  NOW HIGH KING!": PRINT "A NEARBY MONARCHY THREATENS WAR": PRINT "HOW MANY......": GOSUB 24040: GOTO 32767
  98. 4349  PRINT "TOTAL LAND THAT PEASANTS CAN PLANT";4 *P
  99. 4350  PRINT "TOTAL LAND PEASANTS CAN PLANT  "; INT(4 *P): PRINT "**LAND TO PLANT = ";: GOSUB 1430: IF V >L  THEN  GOSUB 1550: GOTO 4350
  100. 4360  IF V >4 *P  THEN  GOSUB 1570: GOTO 4350
  101. 4430 G(4) =  -2 *V: IF  -G(4) >G  THEN  GOSUB 1530: GOTO 4350
  102. 4470 G(8) = V:G = G +G(4)
  103. 4500  FOR I = 1 TO 6:U(I) = 0: NEXT 
  104. 4510  FOR J1 = 1 TO 6: IF V < = S(J1)  THEN 4620
  105. 4511 V = V -S(J1):U(J1) = S(J1):S(J1) = 0: NEXT J1
  106. 4600  PRINT "LAND TABLE UPDATING ERROR": END 
  107. 4620 U(J1) = V:S(J1) = S(J1) -V:S(1) = S(1) +S(2):S(2) = 0
  108. 4660  FOR J1 = 3 TO 6:S(J1 -2) = S(J1 -2) +S(J1):S(J1) = 0: NEXT J1
  109. 4700  FOR J1 = 1 TO 5:S(J1 +1) = S(J1 +1) +U(J1): NEXT :S(6) = S(6) +U(6)
  110. 4710  HOME 
  111. 4770 C =  FN X(2) +3
  112. 4775  IF  INT(Y%/7) *7 = Y%  THEN  PRINT "SEVEN YEAR LOCUSTS":C = C/2
  113. 4830 X1 = 0: FOR J1 = 1 TO 5:X1 = X1 +U(J1) *(1.2 -.2 *J1): NEXT J1: IF G(8) = 0  THEN C1 = 0:C = 0:
  114. 4831  IF G(8) < >0  THEN C1 =  INT((C *(X1/G(8))) *100)/100:C = C1
  115. 4920  PRINT "YIELD = ";C;" HL./HA.":X1 =  FN X(3) +3
  116. 4921  IF X1 <9  THEN  GOTO 5190
  117. 4922  IF X1 > = 9  THEN G(5) =  - INT((X1 *G)/83):G = G +G(5)
  118. 4990  PRINT "RATS INFEST THE GRAINERY": IF P <67  OR K% =  -1  THEN 5190
  119. 4991 X1 =  INT( FN X(4))
  120. 4992  IF X1 <P/30  THEN 5190
  121. 5060  PRINT "THE HIGH KING REQUIRES ";X1;" PEASANTS": PRINT "FOR HIS ESTATES AND MINES. WILL YOU     SUPPLY THEM (YES) OR PAY ";X1 *100: PRINT "HL. OF GRAIN INSTEAD (NO) ?": GOSUB 1330: IF V$ = "N"  THEN G(10) =  -100 *X1:G = G +G(10): GOTO 5190
  122. 5140 P(3) =  -X1:P = P +P(3)
  123. 5180  GOTO 5230
  124. 5188  GOTO 5240
  125. 5190  REM  ADDITION ON MAGIC ITEMS
  126. 5193  IF P <50  OR G <2000  OR L <300  THEN  PRINT "WHERE IS MERLIN WHEN I NEED HIM??":CH =  RND(1) *100: IF CH >70  THEN 5195
  127. 5194  GOTO 5230
  128. 5195  HOME : GOSUB 24040: VTAB 4: PRINT "TODAY IS YOUR LUCKY DAY.....": VTAB 10: PRINT "YOU HAVE JUST DISCOVERED MERLIN THE     MAGICIAN YOUR OLD FRIEND.  HE SEES THE  TERRIBLE SHAPE YOUR DUCHY IS IN AND HE  OFFERS YOU ONE OF THESE GIFTS:"
  129. 5197  PRINT : PRINT "(1) 50 EXTRA PEASANTS                   (2) 200 MORE HA. OF LAND                (3) 4000 MORE HL. OF GRAIN ": PRINT : PRINT "WHICH DO YOU CHOSE?": GET AN$:ANS =  VAL(AN$): IF ANS = 0  OR ANS >3  THEN 5197:
  130. 5199  IF ANS = 1  THEN P = P +50
  131. 5200  IF ANS = 2  THEN S(1) = S(1) +200:L = L +200:
  132. 5202  IF ANS = 3  THEN G = G +4000
  133. 5204  GOTO 5230
  134. 5220  REM 
  135. 5230  IF K% =  -1  THEN  PRINT "THE HIGH KING CALLS FOR PEASANT LEVIES  AND HIRES MANY FOREIGN MERCENARIES":K% =  -2: GOTO 6340
  136. 5240 X1 =  INT(20 -1.5 *C): IF K% < >0  OR P < = 109  OR 17 *(L -400) +G < = 10600  THEN 5350
  137. 5241  PRINT "THE HIGH KING GROWS UNEASY AND MAY BE   SUBSIDIZING WARS AGAINST YOU.":X1 = X1 +2:X2 = Y% +5: GOSUB 24000: GOTO 5380
  138. 5350 X2 = 0
  139. 5380 X3 =  FN X(5): IF X3 >X1  THEN 6340
  140. 5381  PRINT "A NEARBY DUKE THREATENS WAR ";:X2 =  INT(X2 +85 +18 + FN X(6)): GOSUB 20020
  141. 5440 X4 =  INT(1.2 -U1/16):X5 =  INT(P *X4) +13: PRINT "WILL YOU ATTACK FIRST ? ";: GOSUB 1330: IF V$ = "N"  THEN 5590
  142. 5441  IF X2 >X5  THEN 5540
  143. 5442  PRINT "PEACE NEGOTIATIONS WERE SUCCESSFUL"
  144. 5510 P(4) =  -X1 -1:X2 = 0: GOTO 5570
  145. 5540  PRINT "FIRST STRIKE FAILED-YOU NEED            PROFESSIONALS":P(4) =  -X3 -X1 -2:X2 = X2 +3 *P(4)
  146. 5570 P = P +P(4)
  147. 5571  IF X2 <1  THEN U1 = U1 -2 *P(4) -3 *P(5): GOTO 6340
  148. 5590  PRINT "HOW MANY MERCENARIES WILL YOU HIRE      AT 40 HL. EACH = ";: GOSUB 1430:
  149. 5640 X2 =  INT(X2 *M):X5 =  INT(P *X4) +7 *V +13:X6 = X2 -4 *V - INT(.25 *X5):X2 = X5 -X2:L(3) =  INT(.8 *X2): IF  -L(3) >.67 *L  THEN  PRINT "YOU HAVE BEEN OVERRUN AND HAVE LOST THE ENTIRE DUKEDOME": GOTO 4190
  150. 5720 X1 = L(3)
  151. 5730  FOR J1 = 1 TO 3:X3 =  INT(X1/(4 -J1)): IF  -X3 < = S(J1)  THEN X5 = X3
  152. 5731  IF  -X3 >S(J1)  THEN X5 =  -S(J1)
  153. 5790 S(J1) = S(J1) +X5:X1 = X1 -X5: NEXT J1
  154. 5820  FOR J1 = 4 TO 6: IF  -X1 < = S(J1)  THEN X5 = X1
  155. 5821  IF  -X1 >S(J1)  THEN X5 =  -S(J1)
  156. 5870 S(J1) = S(J1) +X5:X1 = X1 -X5
  157. 5871  NEXT J1
  158. 5900  IF L(3) <399  THEN 6010
  159. 5910  PRINT "YOU HAVE OVERRUN THE ENEMY AND ANNEXED  HIS ENTIRE DUKEDOM":G(7) = 10000:G = G +G(7):X6 =  -47:X4 = .55: GOSUB 24050: IF K% >0  THEN 6130
  160. 5970 K% = 1: PRINT "THE KING FEARS FOR HIS THRONE AND MAY   BE PLANNING DIRECT ACTION": GOSUB 24040: GOTO 6130
  161. 6010  IF X2 > = 0  THEN  PRINT "YOU HAVE WON THE WAR":X4 = .67:G(7) =  INT(20 *L(3)):G = G +G(7): GOTO 6090: REM   THIS HAS BEEN CHANGED TO INCREASE FRUITS OF WAR  
  162. 6070  PRINT "YOU HAVE LOST THE WAR":X4 = G(8)/L
  163. 6090  IF X6 < = 9  THEN X6 = 0
  164. 6091  IF X6 >9  THEN X6 =  INT(X6/10)
  165. 6130 X6 =  -X6 *(X6 < = P) -P *(X6 >P):P(4) =  -(P(4) -X6):P = P +X6:G(8) = G(8) + INT(X4 *L(3)):X6 = 40 *V
  166. 6131  IF X6 < = G  THEN G(6) =  -X6: GOTO 6250
  167. 6132  IF X6 >G  THEN G(6) =  -G
  168. 6133 P(5) =  INT((X6 -G)/7) -1: PRINT "THERE ISN'T ENOUGH GRAIN TO PAY THE     MERCENARIES!!!!"
  169. 6250 G = G +G(6):P(5) =  -P(5) *( -P(5) < = P) +P *( -P(5) >P):P = P +P(5):L = L +L(3):U1 = U1 -2 *P(4) -3 *P(5)
  170. 6255 P(5) =  INT(P(5)):P =  INT(P)
  171. 6340 X1 =  FN X(7):X1 =  INT(X1): REM  BELONG?:P(6)= 0   
  172. 6341  IF X1 >2  THEN 6500
  173. 6342  IF X1 < >1  THEN 6440
  174. 6343  IF D >0  THEN 6500
  175. 6344  PRINT "THE BLACK PLAGUE HAS STRUCK THE AREA":D = 13:X2 = 3: GOSUB 23000
  176. 6430 P(6) =  - INT(P/X2):P = P +P(6): GOTO 6500
  177. 6440  PRINT "A POX EPIDEMIC HAS BROKEN OUT":X2 = X1 +5:P(6) =  - INT(P/X2):P = P +P(6)
  178. 6500 X1 =  FN X(8) +4
  179. 6501 X1 =  -X1 *(P(5) = 0) -4.5 *(P(5) < >0):P(8) =  - INT(P/X1):P(7) =  INT(.3 -P/22):P = P +P(7) +P(8):D = D -1
  180. 6600 G(8) =  INT(C *G(8)):G = G +G(8):X1 = G(8) -4000
  181. 6601 G(9) =  -(X1 < = 0) + INT(.1 *X1) *(X1 >0):G(9) =  -(G(9) +120):G = G +G(9)
  182. 6670  IF K% <0  THEN 6790
  183. 6671 X1 =  INT(L/2)
  184. 6710  IF K% > = 2  THEN X1 = X1 * -2
  185. 6713  IF K% <2  THEN X1 = X1 * -1
  186. 6720  IF  -X1 >G  THEN  PRINT "YOU HAVE INSUFFICIENT GRAIN TO PAY THE  ROYAL TAX": GOTO 3000
  187. 6740 G(10) = X1:G = G +X1
  188. 6790 U2 =  INT(U2 *.85) +U1: GOSUB 24030: GOTO 2270
  189. 7000  DATA  "PEASANTS AT START","STARVATIONS","KING'S LEVY", "WAR CASULTIES", "LOOTING VICTIMS","DISEASE VICTIMS","NATURAL DEATHS","BIRTHS"
  190. 7100  DATA  "LAND AT START", "BOUGHT/SOLD", "FRUITS OF WAR"
  191. 7200  DATA  "GRAIN AT START","USED FOR FOOD","LAND DEALS","SEEDINGS", "RAT LOSSES", "MERCENARY HIRE", "FRUITS OF WAR", "CROP YIELD", "CASTLE EXPENSE","ROYAL TAX"
  192. 20000  POKE 770,173: POKE 771,48: POKE 772,192: POKE 773,136: POKE 774,208: POKE 775,5: POKE 776,206: POKE 777,1: POKE 778,3
  193. 20010  POKE 779,240: POKE 780,9: POKE 781,202: POKE 782,208: POKE 783,245: POKE 784,174: POKE 785,0: POKE 786,3: POKE 787,76: POKE 788,2: POKE 789,3: POKE 790,96: POKE 791,0: POKE 792,0: RETURN 
  194. 20020 K = 10
  195. 20030  FOR J = 1 TO 10
  196. 20040 H = 50
  197. 20050  FOR X = 1 TO 5
  198. 20060 H = H +1
  199. 20070  POKE 768,H: POKE 769,K: CALL 770
  200. 20080  POKE 768,50: POKE 769,9: CALL 770
  201. 20090  NEXT : NEXT 
  202. 20100  RETURN 
  203. 23000  FOR J = 1 TO 10
  204. 23010 H = 255
  205. 23020  FOR X = 1 TO 5
  206. 23030 H = H -10
  207. 23040  POKE 768,H: POKE 769,10: CALL 770
  208. 23050  NEXT : NEXT 
  209. 23060  RETURN 
  210. 24000  FOR K = 1 TO 8: FOR X = 1 TO 4: IF X <2  THEN I = 75:
  211. 24010  IF X >2  THEN I = 149
  212. 24020 J = 8: POKE 768,I: POKE 769,J: CALL 770: NEXT X: NEXT K: RETURN 
  213. 24030 J = 100:I = 15: FOR K = 1 TO 10: POKE 768,J: POKE 769,I: CALL 770: NEXT K: RETURN 
  214. 24040  FOR X = 1 TO 5:I = 120:J = 75: POKE 768,I: POKE 769,J: CALL 770:I = 140: POKE 768,I: POKE 769,J: CALL 770: NEXT X: RETURN 
  215. 24050  FOR X = 1 TO 10:I = 60:J = 10: POKE 768,I: POKE 769,J: CALL 770:I = 90: POKE 768,I: POKE 769,J: CALL 770: NEXT X: RETURN 
  216. 30000  PRINT : PRINT "DO YOU WISH TO TRY ANOTHER GAME ? ";: GOSUB 1330: IF V$ = "Y"  THEN 2180
  217. 32767  END