home *** CD-ROM | disk | FTP | other *** search
/ The Glitch Apple Disk Collection / 2014.glitch.apple.collection.zip / indexed / STRIPPKR.DSK / SP1.bas < prev    next >
BASIC Source File  |  2014-09-09  |  20KB  |  384 lines
  1. 4  ONERR  GOTO 9971: REM  12A07W82
  2. 5  PRINT  CHR$(4);"OPEN PLYR": PRINT  CHR$(4);"READ PLYR": INPUT N$: PRINT  CHR$(4);"CLOSE"
  3. 6  TEXT : HOME : VTAB 10: PRINT "REINSERT THE DATA DISK IF NECESSARY     AND PRESS THE SPACE BAR."
  4. 7  IF  PEEK( -16384) = 160  THEN  POKE  -16368,0: HGR : GOTO 11
  5. 8  GOTO 7
  6. 11  PRINT  CHR$(4);"VERIFY";N$
  7. 12  PRINT  CHR$(4);"BLOAD";N$;"1":F = 1: PRINT  CHR$(4);"OPEN";N$: PRINT  CHR$(4);"READ";N$: INPUT S5: INPUT Z5: FOR J = 1 TO 10: INPUT A$(J): NEXT : PRINT  CHR$(4);"CLOSE"
  8. 24 N =  -16384:NN =  -16368: HOME : DIM D(52),A(5),A1(5),A2(14),B(5),B1(5),B2(14),H(15),R(10),M2(14),G(40),T$(20): GOSUB 9950
  9. 32  HGR2 : POKE 232,0: POKE 233,9: SCALE= 1: ROT= 0: HCOLOR= 3: HPLOT 0,152 TO 279,152:P(1) = 5:P(2) = 61:P(3) = 117:P(4) = 173:P(5) = 229: GOTO 200
  10. 40  FOR G = 1 TO  LEN(U$):MM$ =  MID$ (U$,G,1): IF MM$ = "$"  THEN MM$ = "<"
  11. 44  IF MM$ = ","  THEN MM$ = ";"
  12. 45  IF MM$ = " "  THEN G(G) = O: GOTO 48
  13. 46 G(G) =  ASC(MM$) -47
  14. 48  NEXT : FOR G = 1 TO  LEN(U$):X = X +6: IF G(G) = O  THEN 55
  15. 53  IF DX  THEN  XDRAW G(G) AT X,Y: GOTO 55
  16. 54  DRAW G(G) AT X,Y
  17. 55  NEXT :DX = O: RETURN 
  18. 56  HPLOT P(I) +50,165 TO P(I) +50,189: RETURN 
  19. 57  XDRAW 1 AT P(I) +13,189: RETURN 
  20. 58 LFA = LFA -100:FC = FC -1: RETURN 
  21. 59 AMT = AMT -100:CY = CY -1: RETURN 
  22. 60  CALL 592: GOSUB 96: XDRAW 1 AT P(CNT) +13,189:I = CNT: GOSUB 121: GOSUB 105: GOSUB 56: XDRAW A(CNT) AT P(CNT),155: XDRAW A1(CNT) +13 AT P(CNT),169: POKE 233,9: RETURN 
  23. 70  CALL 592: POKE 233,25:I = CNT: GOSUB 105: XDRAW A(I) AT P(I),155: XDRAW A1(I) +13 AT P(I),169: GOSUB 96: GOSUB 121: GOSUB 96: GOSUB 57: ROT= 0: POKE 233,9: GOSUB 56: RETURN 
  24. 75  XDRAW A1(I) +13 AT P(I) +27,167: RETURN 
  25. 76  XDRAW A1(I) +13 AT P(I) +27,179: RETURN 
  26. 77  XDRAW A1(I) +13 AT P(I) +15,167: XDRAW A1(I) +13 AT P(I) +39,167: RETURN 
  27. 78  XDRAW A1(I) +13 AT P(I) +15,179: XDRAW A1(I) +13 AT P(I) +39,179: RETURN 
  28. 80  FOR J = 2 TO 5: FOR JJ = 1 TO 4: IF M(J) =  >M(JJ)  THEN 83
  29. 81 II = M(J):M(J) = M(JJ):M(JJ) = II:II = M1(J):M1(J) = M1(JJ):M1(JJ) = II
  30. 83  NEXT : NEXT : RETURN 
  31. 84  FOR I = 1 TO 5: IF M(I) < >R(8)  AND M(I) < >R(9)  THEN M2(11) = M(I)
  32. 85  NEXT : RETURN 
  33. 86 II = 11: FOR I = 1 TO 5: IF M(I) < >R(9)  THEN M2(II) = M(I):II = II +1
  34. 87  NEXT : FOR I = 12 TO 13: FOR J = 11 TO 12: IF M2(I) <M2(J)  THEN 89
  35. 88 JJ = M2(I):M2(I) = M2(J):M2(J) = JJ
  36. 89  NEXT : NEXT : RETURN 
  37. 90  IF I >25  THEN I = 5
  38. 91  IF I <5  THEN I = 25
  39. 93  GOSUB 9016:X = 72:U$ =  STR$(I): GOSUB 40: RETURN 
  40. 95 CA = O:SY = O:R2 = O: RETURN 
  41. 96  ROT= 48: POKE 233,16: RETURN 
  42. 97 ST = O:D1 = O:R3 = O:CA = O: RETURN 
  43. 98 M2(11) = M(4):M2(12) = M(3):M2(13) = M(2):M2(14) = M(1): RETURN 
  44. 100  POKE 233,25: FOR I = 1 TO 5: CALL 592: XDRAW A(I) AT P(I),155: XDRAW A1(I) +13 AT P(I),169: GOSUB 104: NEXT : POKE 233,9: RETURN 
  45. 104  GOSUB 96: GOSUB 120: GOSUB 56
  46. 105  IF A(I) = 1  THEN  GOTO 75
  47. 106  IF A(I) = 2  THEN  GOSUB 75: GOTO 76
  48. 107  IF A(I) = 3  THEN  GOTO 77
  49. 108  IF A(I) = 4  THEN  GOSUB 77: GOTO 76
  50. 109  IF A(I) = 5  OR A(I) = 7  THEN  GOSUB 77: GOTO 78
  51. 110  IF A(I) = 6  OR A(I) = 8  OR A(I) = 9  THEN  GOSUB 77: GOSUB 76: GOTO 78
  52. 111  IF A(I) = 13  THEN  GOTO 76
  53. 112  RETURN 
  54. 120  GOSUB 57
  55. 121  IF A(I) >9  AND A(I) <13  THEN  XDRAW A(I) -8 AT P(I) +13,189
  56. 130  ROT= O: POKE 233,25: RETURN 
  57. 150  GOSUB 96: FOR I = 1 TO 5: CALL 592: GOSUB 57: HPLOT P(I) +50,164 TO P(I) +50,153: NEXT : ROT= O: POKE 233,9: RETURN 
  58. 160 Q2 =  INT( RND(1) *4.9) *5 +5: GOSUB 9240:R2 = 1: RETURN 
  59. 165 Q2 = 20: IF  RND(1) >.45  THEN Q2 = 25
  60. 166 R2 = 1: GOSUB 9240: RETURN 
  61. 170  FOR I = 11 TO 14: IF A2(I) >B2(I)  THEN 5130
  62. 172  IF A2(I) <B2(I)  THEN 5090
  63. 173  NEXT : GOSUB 9010: GOTO 5190
  64. 180 G = O: FOR I = O TO 4:H(I) = O: NEXT : FOR I = 1 TO 10:R(I) = O: NEXT : RETURN 
  65. 185  FOR I = 1 TO 4: FOR J = O TO 3: IF N(I) =  >N(J)  THEN 188
  66. 186 JJ = N(I):N(I) = N(J):N(J) = JJ
  67. 188  NEXT : NEXT : FOR I = O TO 4: IF N(I) +1 = N(I +1)  THEN CS = CS +1: GOTO 196
  68. 192  IF CS <2  THEN CS = O
  69. 194  IF CS  THEN I = 6
  70. 196  NEXT : RETURN 
  71. 199  HCOLOR= O: FOR J = O TO 4: HPLOT II,144 +J TO JJ,144 +J: NEXT : HCOLOR= 3: RETURN 
  72. 200 M = 400:AMT = 100:MS = O:LFA = 100: CALL 752: CALL 972: HPLOT O,152 TO O,189: GOSUB 150
  73. 210 U$ = "PRESS SPACE BAR":X = 24:Y = 144: GOSUB 40
  74. 211  IF  PEEK(N) < >160  THEN 211
  75. 220  GOSUB 9400: GOSUB 9010
  76. 223 Q = 5:Q1 = O:Q2 = O
  77. 224 T1 = O:CF(1) = O:CF = O:CS = O:WB = O:TEMP = O:COUNT = O:R3 = O:ST = O:SY = O: GOSUB 95
  78. 230 X = 96:U$ = "ANTE $" + STR$(Q): GOSUB 40:AMT = AMT -5:MS = MS +5: GOSUB 9500:LFA = LFA -5:MX = MX +5: GOSUB 8500
  79. 270  FOR I = 1 TO 52:D(I) = I: NEXT : FOR I = 1 TO 5: GOSUB 8100:A(I) = V:A1(I) = S: GOSUB 8100:B(I) = V:B1(I) = S: NEXT 
  80. 272  GOSUB 280: GOTO 400
  81. 280  FOR J = 2 TO 5: FOR JJ = 1 TO 4: IF A(J) =  >A(JJ)  THEN 300
  82. 290 II = A(J):A(J) = A(JJ):A(JJ) = II
  83. 295 II = A1(J):A1(J) = A1(JJ):A1(JJ) = II
  84. 300  NEXT : NEXT : GOSUB 100: RETURN 
  85. 400  GOSUB 4000: GOSUB 6200: IF SY  AND ST  THEN X = 96:U$ = "< ANTE AGAIN <": GOSUB 40:Q = Q +5: FOR CNT = 1 TO 5: GOSUB 70: NEXT : GOSUB 9010: GOTO 224
  86. 430 ST = O: GOSUB 95:R3 = O: IF D1  THEN D1 = O: GOSUB 7000: GOSUB 5090: GOTO 220
  87. 500  IF DR = 2  THEN 9990
  88. 510 JJ = O: GOSUB 4400
  89. 515 X = 24:U$ = "I DREW " + STR$(JJ): GOSUB 40: FOR CNT = 1 TO 5: IF E(CNT) < >99  THEN  GOSUB 70
  90. 535 E(CNT) = O: NEXT : GOSUB 280:CF(1) = O:CF = O:CS = O: FOR I = 1 TO 14:B2(I) = O:M2(I) = O: NEXT : FOR I = 1 TO 5:M(I) = B(I):M1(I) = B1(I): NEXT : GOSUB 1000
  91. 544  FOR I = 1 TO 14:B2(I) = M2(I): NEXT : GOSUB 6215: IF D1  THEN D1 = O: GOSUB 7000: GOSUB 5090: GOTO 220
  92. 547  IF DR = 2  THEN 9990
  93. 550 CF(1) = O:CF = O:CS = O: FOR I = 1 TO 14:A2(I) = O:M2(I) = O: NEXT : FOR I = 1 TO 5:M(I) = A(I):M1(I) = A1(I): NEXT : GOSUB 1000: FOR I = 1 TO 14:A2(I) = M2(I): NEXT : GOSUB 7000: FOR CNT = 1 TO 5: GOSUB 70: NEXT 
  94. 585  GOSUB 9010:X = 24:U$ = "MY HAND": GOSUB 40: FOR J = 1 TO 5:A(J) = B(J):A1(J) = B1(J): NEXT : GOSUB 280: GOSUB 5000: GOTO 220
  95. 1000  GOSUB 180: FOR I = 1 TO 13: FOR J = 1 TO 5: IF M(J) = I  THEN H(G) = H(G) +1:N(G) = I
  96. 1010  NEXT : IF H(G)  THEN G = G +1
  97. 1020  NEXT : FOR I = O TO 4: IF H(I) = 4  THEN R(3) = N(I):M2(3) = N(I)
  98. 1030  IF H(I) = 3  THEN R(7) = N(I):M2(7) = N(I)
  99. 1040  IF H(I) = 2  AND R(9)  THEN R(8) = R(9):M2(8) = R(9)
  100. 1050  IF H(I) = 2  THEN R(9) = N(I):M2(9) = N(I)
  101. 1060  NEXT : IF R(7)  AND R(9)  THEN R(4) = 1:M2(4) = M2(7): RETURN 
  102. 1070  IF R(3)  THEN  RETURN 
  103. 1075  IF R(7)  THEN  RETURN 
  104. 1080  IF R(8)  AND M2(9) >M2(8)  THEN JJ = M2(8):M2(8) = M2(9):M2(9) = JJ: GOSUB 84: RETURN 
  105. 1082  IF R(9)  THEN  GOSUB 86: RETURN 
  106. 1085  GOSUB 185
  107. 1130  FOR I = 1 TO 5: FOR J = 1 TO 5: IF M1(I) = M1(J)  THEN CF = CF +1:CF(1) = M1(I)
  108. 1140  NEXT : IF CF >2  THEN I = 6: GOTO 1160
  109. 1150 CF = O
  110. 1160  NEXT 
  111. 1170  IF CF = 5  AND CS = 4  AND N(4) = 13  THEN R(1) = 13:M2(1) = 13: RETURN 
  112. 1180  IF CF = 5  AND CS = 4  THEN R(2) = N(4):M2(2) = N(4): RETURN 
  113. 1190  IF CF = 5  THEN  GOSUB 80:R(5) = M(5):M2(5) = M(5): GOTO 98
  114. 1200  IF CS = 4  THEN R(6) = N(4):M2(6) = N(4): RETURN 
  115. 1210  GOSUB 80:R(10) = M(5):M2(10) = M(5): GOTO 98
  116. 4000  GOSUB 180: FOR I = 1 TO 13: FOR J = 1 TO 5: IF B(J) = I  THEN H(G) = H(G) +1:N(G) = I
  117. 4010  NEXT : IF H(G)  THEN G = G +1
  118. 4020  NEXT : FOR I = O TO 4: IF H(I) = 4  THEN R(3) = N(I):DR = O
  119. 4030  IF H(I) = 3  THEN R(7) = N(I)
  120. 4040  IF H(I) = 2  AND R(9)  THEN R(8) = R(9)
  121. 4050  IF H(I) = 2  THEN R(9) = N(I)
  122. 4060  NEXT : IF R(7)  AND R(9)  THEN R(4) = 1:DR = O: RETURN 
  123. 4070  IF R(3)  THEN  RETURN 
  124. 4075  IF R(7)  THEN DR = O: RETURN 
  125. 4080  IF R(8)  OR R(9)  THEN DR = 1: RETURN 
  126. 4085  GOSUB 185
  127. 4130  FOR I = 1 TO 5: FOR J = 1 TO 5: IF B1(I) = B1(J)  THEN CF = CF +1:CF(1) = B1(I)
  128. 4140  NEXT : IF CF >2  THEN I = 6: GOTO 4160
  129. 4150 CF = O
  130. 4160  NEXT 
  131. 4170  IF CF = 5  THEN R(5) = 1:DR = O: RETURN 
  132. 4180  IF CF >2  AND CF > = CS +1  THEN R(5) = 1:DR = 1: RETURN 
  133. 4190  IF CS = 4  THEN R(6) = 1:DR = O: RETURN 
  134. 4200  IF CS >1  THEN R(6) = 1:DR = 1: RETURN 
  135. 4210 R(10) = 1:DR = 2: RETURN 
  136. 4400  IF R(1)  OR R(2)  OR R(4)  OR CS = 4  OR CF = 5  THEN  RETURN 
  137. 4402  FOR I = 1 TO 5: IF R(3)  AND B(I) < >R(3)  THEN  GOSUB 4500
  138. 4404  IF R(7)  AND B(I) < >R(7)  THEN  GOSUB 4500
  139. 4406  IF R(8)  AND B(I) < >R(8)  AND B(I) < >R(9)  THEN  GOSUB 4500:I = 6: GOTO 4410
  140. 4407  IF R(8)  THEN 4410
  141. 4408  IF R(9)  AND B(I) < >R(9)  THEN  GOSUB 4500
  142. 4410  NEXT 
  143. 4412  IF R(5)  THEN  FOR I = 1 TO 5: IF B1(I) < >CF(1)  THEN  GOSUB 4500
  144. 4414  IF R(5)  THEN  NEXT : RETURN 
  145. 4416  IF R(6)  AND CS = 2  THEN  GOSUB 4700: RETURN 
  146. 4420  IF R(6)  AND B(1) +1 < >B(2)  THEN I = 1: GOSUB 4500: RETURN 
  147. 4421  IF R(6)  THEN I = 5: GOSUB 4500
  148. 4460  RETURN 
  149. 4500 JJ = JJ +1: GOSUB 8100:B(I) = V:B1(I) = S: RETURN 
  150. 4700  FOR I = O TO 4: IF N(I) +1 = N(I +1)  THEN 4750
  151. 4710  IF I = 1  THEN  GOSUB 4500:I = 2: GOSUB 4500:I = 6: GOTO 4750
  152. 4720  IF I = 2  THEN I = 4: GOSUB 4500:I = 5: GOSUB 4500:I = 6: GOTO 4750
  153. 4730  IF I = 4  THEN I = 1: GOSUB 4500:I = 5: GOSUB 4500
  154. 4750  NEXT : RETURN 
  155. 5000  FOR I = 1 TO 10: IF A2(I) +B2(I) < >O  THEN 5070
  156. 5060  NEXT 
  157. 5070  IF A2(I) = B2(I)  THEN 170
  158. 5080  IF A2(I) >B2(I)  THEN 5130
  159. 5090 X = 96: IF PP  THEN X = 24
  160. 5092  GOSUB 9010:U$ = "MY POT, $" + STR$(K/2 +MS): GOSUB 40:P = O
  161. 5094  IF PP  THEN X = 108:U$ = "I KEEP MY CLOTHES": GOSUB 40:PP = O:FF = O
  162. 5100 M = M +K:AMT = AMT +K +MS -MX: GOSUB 9005: GOSUB 9800: GOSUB 9500:MS = O:MX = O
  163. 5120  FOR CNT = 1 TO 5: GOSUB 70: NEXT : RETURN 
  164. 5130 X = 96: IF P  THEN X = 24
  165. 5132  GOSUB 9010:U$ = "YOUR POT, $" + STR$(K/2 +MX): GOSUB 40
  166. 5134  IF P  THEN X = 120:U$ = "KEEP YOUR CLOTHES": GOSUB 40:P = O
  167. 5140 LFA = LFA +K +MX -MS:MS = O:MX = O: GOSUB 9005: GOSUB 9800: GOSUB 8600: GOSUB 8500: GOSUB 9010
  168. 5145  IF PP  THEN PP = O:FF = O:X = 24:U$ = T$( INT(10 * RND(1) +11)): GOSUB 40
  169. 5146  GOTO 5120
  170. 5190 X = 96:U$ = "WE TIED:  NEW DEAL": GOSUB 40:M = M +K/2: GOTO 5120
  171. 6200  GOSUB 9011:BE =   NOT BE
  172. 6215 T1 = T1 +1
  173. 6220  IF BE  THEN  GOSUB 6300: IF D1 = O  THEN Q = Q +TEMP:TEMP = Q1:Q2 = O
  174. 6222  IF CA = 1  THEN COUNT = O: GOTO 6255
  175. 6223  IF D1  THEN  RETURN 
  176. 6225  IF T1 = 1  THEN  GOSUB 6400: IF DR <2  THEN Q = Q +TEMP:TEMP = Q2:Q1 = O
  177. 6226  IF T1 = 2  THEN  GOSUB 6550: IF DR <2  THEN Q = Q +TEMP:TEMP = Q2:Q1 = O
  178. 6227  IF DR = 2  THEN  RETURN 
  179. 6228  IF CA = 1  THEN COUNT = O: GOTO 6255
  180. 6230  IF BE = O  THEN  GOSUB 6300: IF D1 = O  THEN Q = Q +TEMP:TEMP = Q1:Q2 = O
  181. 6240  IF D1  OR DR = 2  THEN  RETURN 
  182. 6242  IF SY  AND ST  THEN  RETURN 
  183. 6245  IF CA = 1  THEN COUNT = O: GOTO 6255
  184. 6246 COUNT = COUNT +1: IF COUNT < >2  THEN SY = O:ST = O: GOTO 6220
  185. 6247 COUNT = O: GOSUB 9014: IF BE = O  THEN  GOSUB 9210: GOSUB 9005: GOTO 6255
  186. 6248 X = 24:U$ = "LAST BET": GOSUB 40: POKE  -16368,0
  187. 6249  IF  PEEK(N) = 160  AND (U$ = "CALL"  OR U$ = "DROP")  THEN 6254
  188. 6250  IF  PEEK(N) = 149  THEN  GOSUB 9016: POKE NN,O:CNT = CNT +1: IF CNT = 3  THEN CNT = 1
  189. 6251  IF  PEEK(N) = 136  THEN  GOSUB 9016: POKE NN,O:CNT = CNT -1: IF CNT = O  THEN CNT = 2
  190. 6253 X = 78: ON CNT GOTO 7400,7410
  191. 6254  POKE NN,O: IF U$ = "DROP"  THEN D1 = 1: RETURN 
  192. 6255 Q = Q +Q1 +Q2:Q1 = O:TEMP = O:LFA = LFA -Q2:MX = MX +Q2: GOSUB 8500:Q2 = O
  193. 6258  IF T1 = 2  THEN  RETURN 
  194. 6259  GOSUB 9010: POKE NN,O:X = 18:U$ = "V": GOSUB 40:X = 18:CNT = 1
  195. 6261  IF  PEEK(N) = 160  THEN  POKE NN,O: GOTO 6280
  196. 6262  IF  PEEK(N) = 149  THEN  POKE NN,O:CNT = CNT +1: GOTO 6270
  197. 6263  IF  PEEK(N) = 136  THEN  POKE NN,O:CNT = CNT -1: GOTO 6270
  198. 6264  GOTO 6261
  199. 6270  IF CNT = 7  THEN CNT = 1
  200. 6271  IF CNT = O  THEN CNT = 6
  201. 6272 DX = 1: ON CNT GOTO 7350,7350,7350,7350,7350,7360
  202. 6275  GOTO 6261
  203. 6280  POKE NN,O: IF CNT = 6  THEN  GOTO 6290
  204. 6284  IF E(CNT) = 99  THEN  GOSUB 60:E(CNT) = O: GOTO 6261
  205. 6285 E(CNT) = 99: GOSUB 70: GOTO 6261
  206. 6290  GOSUB 9010: FOR I = 1 TO 5: IF E(I) = 99  THEN  GOSUB 8100:A(I) = V:A1(I) = S:WB = WB +1
  207. 6295  NEXT : RETURN 
  208. 6300  GOSUB 9014:X = 24:U$ = "WAGER": GOSUB 40
  209. 6305  GOSUB 97:CNT = 3: POKE NN,O
  210. 6307  IF  PEEK(N) = 160  THEN  POKE NN,O: GOTO 6329
  211. 6309  IF  PEEK(N) = 149  THEN  POKE NN,O:CNT = CNT +1: GOTO 6315
  212. 6310  IF  PEEK(N) = 136  THEN  POKE NN,O:CNT = CNT -1: GOTO 6315
  213. 6311  GOTO 6307
  214. 6315  GOSUB 97: IF CNT = 4  THEN CNT = 1
  215. 6316  IF CNT <1  THEN CNT = 3
  216. 6317  GOSUB 9012
  217. 6318  ON CNT GOSUB 7100,7150,7200
  218. 6320  GOTO 6307
  219. 6329  IF D1  OR ST  THEN  RETURN 
  220. 6331  IF CA = 1  THEN LFA = LFA -Q2:MX = MX +Q2: GOSUB 8500:R2 = O: RETURN 
  221. 6335  IF R3  THEN 6337
  222. 6336  GOTO 6307
  223. 6337  GOSUB 9014:X = 24:U$ = "AMOUNT?": GOSUB 40:I = O
  224. 6340  IF  PEEK(N) = 149  THEN I = I +5: POKE NN,O: GOSUB 90
  225. 6345  IF  PEEK(N) = 136  THEN I = I -5: POKE NN,O: GOSUB 90
  226. 6347  IF  PEEK(N) = 160  THEN  POKE NN,O:Q1 = Q1 +I:LFA = LFA -Q1 -Q2:MX = MX +Q1 +Q2: GOSUB 8500: RETURN 
  227. 6349  GOTO 6340
  228. 6400  GOSUB 95: IF S5 >4  THEN 8900
  229. 6402  IF DR = 3  THEN DR = 2: RETURN 
  230. 6404  IF DR = 2  AND R3 = O  THEN DR = 3: GOTO 9220
  231. 6410  IF DR = 2  THEN  RETURN 
  232. 6415  IF DR = 1  AND  RND(1) >.25  THEN 160
  233. 6420  IF DR = O  THEN 160
  234. 6425  IF R3  THEN 9210
  235. 6430  GOTO 9220
  236. 6550  GOSUB 95: FOR I = 1 TO 10: IF R(I)  THEN KT = I:I = 11
  237. 6552  NEXT : IF S5 = 2  OR S5 = 6  THEN 8300
  238. 6553  IF S5 = 3  OR S5 = 7  THEN 8800
  239. 6560  IF KT <7  THEN 165
  240. 6570  IF R(7)  THEN 160
  241. 6575  IF R(8)  AND  RND(1) >.2  THEN 160
  242. 6595  IF KT = 9  AND  RND(1) >.5  THEN 160
  243. 6600  IF (KT = 8  OR KT = 9)  AND R3  THEN 9210
  244. 6620  IF KT = 10  AND R3  THEN DR = 2: RETURN 
  245. 6630  GOTO 9220
  246. 7000 M = M -Q:K = Q +Q: RETURN 
  247. 7100 U$ = "BET":R3 = 1: IF R2  THEN U$ = "RAISE": GOSUB 7300: RETURN 
  248. 7120  GOSUB 7300: RETURN 
  249. 7150 U$ = "STAY":ST = 1: IF R2  THEN U$ = "CALL":CA = 1:ST = O: GOTO 7300
  250. 7160  GOTO 7300
  251. 7200 U$ = "DROP":D1 = 1: GOTO 7300
  252. 7300 X = 60: GOSUB 40: RETURN 
  253. 7350  GOSUB 40:X = P(CNT) +15:U$ = "V": GOSUB 40:X = P(CNT) +15: GOTO 6261
  254. 7360  GOSUB 40:X = 102:U$ = "FINISHED": GOSUB 40:X = 102: GOTO 6261
  255. 7400 U$ = "CALL": GOSUB 40: GOTO 6249
  256. 7410 U$ = "DROP": GOSUB 40: GOTO 6249
  257. 8100 V =  INT(52 * RND(1) +1): IF D(V) = O  THEN 8100
  258. 8105 D(V) = O:S = 1
  259. 8110  IF V < = 13  THEN  RETURN 
  260. 8130 V = V -13:S = S +1: GOTO 8110
  261. 8300  IF KT <9  AND ST  THEN 165
  262. 8305  IF KT <10  AND ST  THEN 160
  263. 8307  IF ST  THEN 9220
  264. 8309  IF   NOT R3  THEN 8385
  265. 8310  IF MX -MS <20  AND KT <9  THEN 165
  266. 8320  IF MX -MS <20  AND KT = 9  AND R(9) >9  THEN 160
  267. 8330  IF MX -MS <20  AND KT = 9  AND  RND(1) >.2  THEN 9210
  268. 8340  IF MX -MS >15  THEN 8700
  269. 8380  IF Q1 <15  AND DR = 1  THEN 9210
  270. 8382 DR = 2: RETURN 
  271. 8385  IF KT <9  THEN 165
  272. 8386  IF KT = 9  AND  RND(1) >.7  THEN 9220
  273. 8387  IF KT = 9  THEN 160
  274. 8388  GOTO 9220
  275. 8500  IF LFA <0  THEN LFA = LFA +100:FC = FC +1: GOSUB 8510:P = 1
  276. 8505  GOSUB 9019:X = O:U$ =  STR$(LFA): GOSUB 40: RETURN 
  277. 8510  IF FC = 1  THEN U$ = "TOP"
  278. 8520  IF FC = 2  THEN U$ = "PANTS"
  279. 8530  IF FC = 3  THEN U$ = "UNDIES"
  280. 8540  GOSUB 9010:X = 24:U$ = "FOR $100 YOU OFFER YOUR " +U$: GOSUB 40: GOSUB 9005: GOSUB 9010: RETURN 
  281. 8600  IF LFA > = 100  AND FC  THEN  GOSUB 58: IF LFA > = 100  AND FC  THEN  GOTO 58
  282. 8610  RETURN 
  283. 8700  IF KT <8  THEN 165
  284. 8745  IF KT = 8  AND  RND(1) >.3  THEN 160
  285. 8750  IF KT = 8  THEN 9210
  286. 8760  IF KT = 9  AND R(9) >10  AND  RND(1) >.7  THEN 160
  287. 8765  IF KT = 9  AND R(9) >10  THEN 9210
  288. 8770  IF KT = 9  AND  RND(1) >.5  THEN 9210
  289. 8780  GOTO 8380
  290. 8800  IF WB = 1  AND (MX -MS >15)  AND KT >8  AND  RND(1) >.33  THEN DR = 2: RETURN 
  291. 8810  IF WB = 2  AND (MX -MS >15)  AND KT >7  AND  RND(1) >.40  THEN DR = 2: RETURN 
  292. 8820  IF WB = 3  AND KT = 10  AND R3  AND  RND(1) >.15  THEN DR = 2: RETURN 
  293. 8830  IF WB = 3  AND KT = 9  AND R(9) <10  AND  RND(1) >.4  AND (MX -MS >10)  THEN DR = 2: RETURN 
  294. 8840  IF KT <9  THEN 165
  295. 8850  IF KT = 9  AND R(9) >10  THEN 165
  296. 8860  IF KT = 10  AND R3  AND  RND(1) >.5  THEN DR = 2: RETURN 
  297. 8870  IF KT = 10  AND R3  THEN 9210
  298. 8875  IF KT = 10  THEN 9220
  299. 8877  GOTO 160
  300. 8900  FOR I = 1 TO 10: IF R(I)  THEN KT = I:I = 11
  301. 8905  NEXT : IF DR = 1  AND (KT = 5  OR KT = 6)  THEN 8990
  302. 8910  IF DR = 2  OR DR = 3  THEN 6402
  303. 8920  IF DR = O  THEN 165
  304. 8930  GOTO 8300
  305. 8990  IF  RND(1) >.2  AND ST = 1  THEN 165
  306. 8992  IF  RND(1) >.3  AND R3  THEN 160
  307. 8993  IF R3  THEN 9210
  308. 8994  IF R3  THEN DR = 2: RETURN 
  309. 8996  IF  RND(1) <.5  THEN 160
  310. 8997  GOTO 9220
  311. 9005  FOR J = 1 TO 2000: NEXT : RETURN 
  312. 9010 II = 24:JJ = 257: GOTO 199
  313. 9011 II = 96:JJ = 149: GOTO 199
  314. 9012 II = 60:JJ = 96: GOTO 199
  315. 9014 II = 24:JJ = 96: GOTO 199
  316. 9016 II = 78:JJ = 107: GOTO 199
  317. 9017 II = 186:JJ = 251: GOTO 199
  318. 9018 II = 258:JJ = 275: GOTO 199
  319. 9019 II = O:JJ = 23: GOTO 199
  320. 9210 AMT = AMT -Q1:MS = MS +Q1: GOSUB 9500:X = 186: GOSUB 9017:U$ = "I CALL": GOSUB 40:CA = 1: RETURN 
  321. 9220  GOSUB 9017:X = 186:U$ = "I STAY": GOSUB 40:SY = 1: RETURN 
  322. 9240 AMT = AMT -Q1 -Q2:MS = MS +Q1 +Q2: GOSUB 9500:U$ = "I BET ": IF R3  THEN U$ = "I RAISE "
  323. 9242  GOSUB 9017:X = 186:U$ = U$ + STR$(Q2): GOSUB 40: RETURN 
  324. 9250  GOSUB 9017:X = 186:U$ = "I DROP": GOSUB 40: GOSUB 9005: RETURN 
  325. 9400  IF M < -100  AND F < >6  THEN F = 6: GOTO 9480
  326. 9405  IF M > -101  AND M <0  AND F < >5  THEN F = 5: GOTO 9480
  327. 9410  IF M > -1  AND M <100  AND F < >4  THEN F = 4: GOTO 9480
  328. 9420  IF M >99  AND M <200  AND F < >3  THEN F = 3: GOTO 9480
  329. 9430  IF M >199  AND M <300  AND F < >2  THEN F = 2: GOTO 9480
  330. 9435  IF M >299  AND F < >1  THEN F = 1: GOTO 9480
  331. 9460  RETURN 
  332. 9480  IF F >Z5  THEN F = Z5
  333. 9481  IF A$(F) = "SKIN"  THEN  GOSUB 9010:X = 24:U$ = "I LOST EVERYTHING": GOSUB 40: PRINT  CHR$(4);"BLOAD"N$F: PRINT  CHR$(4);"RUN ENDGAME"
  334. 9482  PRINT  CHR$(4);"BLOAD";N$F: CALL 752: CALL 972: RETURN 
  335. 9500  IF AMT <0  THEN PP = 1:AMT = AMT +100:CY = CY +1:FF = FF +1: GOSUB 9600
  336. 9505  GOSUB 9018:X = 252:U$ =  STR$(AMT): GOSUB 40: RETURN 
  337. 9600  GOSUB 9010: IF CY = 1  THEN U$ = A$(F -1 +FF)
  338. 9601  IF CY = 2  THEN U$ = A$(F -1 +FF)
  339. 9602  IF CY = 3  THEN U$ = A$(F -1 +FF)
  340. 9603  IF CY = 4  THEN U$ = A$(F -1 +FF)
  341. 9604  IF CY = 5  THEN U$ = A$(F -1 +FF)
  342. 9610 X = 24:U$ = "$100 PLEASE, I OFFER MY " +U$: GOSUB 40: GOSUB 9005: GOSUB 9010: RETURN 
  343. 9700 AMT = AMT -100: IF CY  AND AMT -100 > = O  THEN  GOSUB 59: IF CY  AND AMT -100 > = O  THEN  GOSUB 59
  344. 9710  GOSUB 9010: RETURN 
  345. 9800  IF AMT > = 100  AND CY  THEN CY = CY -1: GOSUB 9700
  346. 9801  IF FC  THEN  GOSUB 9805: GOSUB 9005: GOSUB 9010
  347. 9802  RETURN 
  348. 9805  GOSUB 9010:X = 24
  349. 9810  IF AMT >400  AND M >500  THEN U$ = "YOU LOST YOUR UNDIES": GOSUB 40: GOTO 9850
  350. 9820  IF AMT >300  AND M >500  THEN CZ = 3: IF CZ >CQ  THEN U$ = "YOU LOST YOUR PANTS": GOSUB 40:CQ = 3: GOSUB 9920: RETURN 
  351. 9825  IF AMT <301  AND M >500  THEN CZ = 2: IF CZ <CQ  THEN U$ = "YOU WON BACK YOUR PANTS": GOSUB 40:CQ = 2: RETURN 
  352. 9830  IF AMT >200  AND M >500  THEN CZ = 1: IF CZ >CQ  THEN U$ = "YOU LOST YOUR TOP": GOSUB 40:CQ = 1: GOSUB 9920: RETURN 
  353. 9835  IF AMT <201  AND M <501  THEN CZ = O: IF CZ <CQ  THEN U$ = "YOU WON BACK YOUR TOP": GOSUB 40:CQ = O: RETURN 
  354. 9840  RETURN 
  355. 9850  GOSUB 9005: GOSUB 9010:X = 24:U$ = "THAT IS ALL I CARE TO SEE": GOSUB 40: GOSUB 9005: GOSUB 9010:X = 24:U$ = "I LL RETIRE WHILE I AM AHEAD": GOSUB 40
  356. 9855  GOSUB 9005: PRINT  CHR$(4);"RUN HELLO"
  357. 9920  GOSUB 9005: GOSUB 9010:X = 24:U$ = T$( INT(10 * RND(1) +1)): GOSUB 40: GOSUB 9005: GOTO 9010
  358. 9950 T$(1) = "I AM LOVING THIS"
  359. 9951 T$(2) = "I AM HOT TONIGHT"
  360. 9952 T$(3) = "YOU LOOK CUTE LIKE THAT"
  361. 9953 T$(4) = "DONT COVER YOURSELF UP"
  362. 9954 T$(5) = "I OWN THE CARDS HONEY"
  363. 9955 T$(11) = "GIVE ME A BREAK"
  364. 9956 T$(12) = "I WANT A NEW DECK OF CARDS"
  365. 9957 T$(13) = "A BAD TRANSISTOR MADE ME BET"
  366. 9958 T$(14) = "CLOSE YOUR EYES HONEY"
  367. 9959 T$(15) = "WHO DO YOU HAVE HELPING YOU"
  368. 9960 T$(6) = "THAT MAKES MY SENSORS OVERHEAT"
  369. 9961 T$(7) = "IS IT GETTING COLD OUT THERE"
  370. 9962 T$(8) = "YOU COULD USE SOME SUN"
  371. 9963 T$(9) = "OOH IF I COULD ONLY DROOL"
  372. 9964 T$(10) = "BE STILL MY HEART"
  373. 9965 T$(16) = "WIPE THAT SMILE OFF YOUR FACE"
  374. 9966 T$(17) = "NEXT HAND WE PLAY WITH MY DECK"
  375. 9967 T$(18) = "COULD YOU TURN YOUR BACK"
  376. 9968 T$(19) = "IM NOT LIKING THIS"
  377. 9969 T$(20) = "I CAN UNDRESS MYSELF THANKS"
  378. 9970  RETURN 
  379. 9971  TEXT : HOME : CALL 640:RR =  PEEK(222): IF RR = 255  THEN  PRINT "MODESTY MODE--PRESS ESCAPE KEY TO RESUME": GOTO 9980
  380. 9972  IF RR = 6  THEN  PRINT "FILE NOT FOUND.  CHANGE DISKS AND 'RESET'":FP
  381. 9973  PRINT "UNKNOWN ERROR.  START ALL OVER.         THE ERROR CODE IS ";RR:FP
  382. 9980  IF  PEEK( -16384) = 155  THEN  POKE  -16304,0: POKE  -16297,0: POKE  -16299,0: RESUME 
  383. 9981  GOTO 9980
  384. 9990  GOSUB 9250: GOSUB 7000: GOSUB 5130: GOSUB 9005: GOTO 220