home *** CD-ROM | disk | FTP | other *** search
/ The Glitch Apple Disk Collection / 2014.glitch.apple.collection.zip / indexed / FLASHCOM.DSK / SIEVE.int < prev   
Text File  |  2014-09-09  |  1KB  |  40 lines
  1. 10 SIZE=8190
  2. 20 DIM FLAGS(8191):GOSUB 5000
  3. 30 CALL -936:VTAB 10:TAB 10:PRINT "SIEVE OF ERATOSTHENES":TAB 8:PRINT MSG$
  4. 35 PRINT :TAB 10:PRINT "( COUNTING PRIMES NOW )";
  5. 40 COUNT=0
  6. 50 FOR I=0 TO SIZE
  7. 60 FLAGS(I)=1
  8. 70 NEXT I
  9. 80 FOR I=0 TO SIZE
  10. 90 IF FLAGS(I)=0 THEN 170
  11. 100 PRIME=I+I+3
  12. 110 K=I+PRIME
  13. 120 IF K>SIZE THEN 160
  14. 130 FLAGS(K)=0
  15. 140 K=K+PRIME
  16. 150 GOTO 120
  17. 160 COUNT=COUNT+1
  18. 170 NEXT I
  19. 175 TAB 10:PRINT "                          ";:TAB 10
  20. 180 PRINT COUNT,"PRIMES<CTRL-G><CTRL-G><CTRL-G><CTRL-G><CTRL-G><CTRL-G><CTRL-G>"
  21. 999 END 
  22. 5000 DIM QWE(2),MSG$(200):MSG$="SLOW INTEGER BASIC VERSION"
  23. 5010 QWE=1:QWE(0)=2:IF QWE=2 THEN 5999
  24. 5020 MSG$="FLASH!  COMPILED  VERSION"
  25. 5999 RETURN 
  26. 10000 REM THIS PROGRAM IMPLIMENTS THE
  27. 10010 REM SIEVE OF ERATOSTHENES TO
  28. 10020 REM COMPUTE ALL PRIME NUMBERS
  29. 10030 REM FROM 3 TO 16000.
  30. 10040 REM 
  31. 10050 REM TAKEN FROM BYTE SEPT. 1981.
  32. 10060 REM 
  33. 10070 REM RUNS IN 19.7 SEC. UNDER
  34. 10071 REM FLASH!
  35. 10072 REM 
  36. 10080 REM RUNS IN 238.0 SEC. UNDER
  37. 10090 REM INTEGER BASIC INTERPRETER.
  38. 10100 REM 
  39. 10110 REM SPEED UP OF 12.1 TIMES.
  40.