The Glitch Apple Disk Collection/2014.glitch.apple.collection.zip/indexed/AUDEX.DSK/EXCERPT-A-SOUND.bas

BASIC Source File | 2014-09-09 | 15KB | 414 lines

0  ONERR  GOTO 0
1  FOR E = 952 TO 975: READ H: POKE E,H: NEXT : FOR E = 1010 TO 1012: READ H: POKE E,H: NEXT
2  DATA  32,234,3,162,2,173,0,224,201,76,240,7,202,157,128,192,16,243,2,162,20,76,18,212,184,3,166
3  PRINT  CHR$(4);"BRUNINSTALL &LOMEM": &  LOMEM: 16384
10  HIMEM: 29183
15  DIM AS(255)
20 NS = 0:AS(1) = 29184
25 BUF = 30332
30 AUDIO = 37375
35  PRINT  CHR$(4);"BLOAD AUDIO OPCODES"
98  ONERR  GOTO 100
99  GOTO 1000
100  CALL 54915:ER =  PEEK(222): IF ER = 255  OR ER = 20  THEN  GOTO 1000
110  HOME : TEXT
140  IF ER = 0  OR ER >15  THEN J = 53856 +ER +(ER = 255) * -1: GOTO 160
150 J = 43377 + PEEK(43583 +ER)
160 K =  PEEK(J): PRINT  CHR$(K);: IF K <192  THEN J = J +1: GOTO 160
170  PRINT : PRINT "PRESS ANY KEY": WAIT  -16384,128: POKE 49168,0: GOTO 1000
998 :
999 :
1000 : REM
1010  TEXT : GOSUB 1200: GOSUB 1280: GOSUB 2000: GOSUB 1300: GOTO 3000
1098 :
1099 :
1100  REM
1105  GOSUB 1200: GOSUB 2000: GOSUB 1300: RETURN
1110 :
1115 :
1200  REM
1205  HOME : GOSUB 1230: VTAB 17: GOSUB 1235: PRINT "CURSOR FLASHES BY OPTION.": PRINT "SPACE BAR MOVES CURSOR.": PRINT "RETURN KEY ACTIVATES OPTION.": RETURN
1210  PRINT "MENU"
1215  PRINT "('EXCERPT-A-SOUND' PROGRAM)
1220  RETURN
1225 :
1230  PRINT "=====AUDEX: EXCERPT-A-SOUND PROGRAM=====": INVERSE : PRINT "    COPYRIGHT 1982 BY SIRIUS SOFTWARE   ": NORMAL : RETURN
1235  NORMAL : INVERSE : GOSUB 1240: NORMAL : RETURN
1240  PRINT "                                        ": RETURN
1245  PRINT "CURSOR FLASHES BY OPTION."
1250  PRINT "SPACE BAR MOVES CURSOR."
1255  PRINT "RETURN KEY ACTIVATES OPTION."
1260  VTAB 1
1265  RETURN
1270 :
1275 :
1280  REM
1285 SF = 1:SL = 2:SET = 1:VT = 5
1290 :
1295 :
1300  REM
1305  VTAB VT: INVERSE : FLASH : PRINT " ": NORMAL : RETURN
1310 :
1315 :
1325  NORMAL : INVERSE : PRINT "                                        "
1330  NORMAL : RETURN
1335 :
1340 :
2000  REM
2001  GOSUB 2100: VTAB 5: ON SET GOTO 2011,2021,2030,2040
2011  PRINT " INSTRUCTIONS": PRINT
2012  PRINT " LOAD AUDIO FROM CASSETTE": PRINT
2013  PRINT " SAVE 'RAW' AUDIO ON DISK": PRINT
2014  PRINT " DISPLAY AND EXCERPT SOUND PULSES": PRINT
2015  PRINT " SAVE EXCERPTED SOUNDS ON DISK": PRINT
2016  GOTO 2200
2017  PRINT " QUIT"
2018  RETURN
2021  PRINT " INSTRUCTIONS": PRINT
2022  PRINT " LOAD 'RAW' AUDIO FROM DISK": PRINT
2023  PRINT " RUN HELLO": PRINT
2024  PRINT " RUN DRAW-A-SOUND": PRINT
2025  PRINT " RUN BUILD-A-SOUND": PRINT
2026  GOTO 2200
2098 :
2099 :
2100  REM
2110  FOR I = 5 TO 15  STEP 2: VTAB I
2120  PRINT "                                        ": NEXT I: RETURN
2200  PRINT " LIST OTHER OPTIONS": RETURN
2998 :
2999 :
3000  REM
3010 RET = 141:SPACE = 160:KBD = 49152:KSTROBE = 49168
3098 :
3099 :
3100  REM
3110  GOSUB 9000
3120  IF X = 160  THEN  GOSUB 3200: GOTO 3100
3130  IF X = 141  THEN  GOSUB 3300: GOTO 3100
3140  GOTO 3100
3198 :
3199 :
3200  REM
3210  VTAB VT: PRINT " "
3220 VT = VT +2: IF VT >15  THEN VT = 5
3230  VTAB VT
3240  INVERSE : FLASH
3250  PRINT " ": NORMAL
3260  RETURN
3298 :
3299 :
3300  REM
3310 OPT = (VT -3)/2
3320  ON SET GOTO 3321,3322,3323,3324
3321  ON OPT GOSUB 11000,5000,5120,6000,6420,3400: GOSUB 1100: RETURN
3322  ON OPT GOSUB 11000,5100,4005,4010,4015,3400: GOSUB 1100: RETURN
3398 :
3399 :
3400  REM
3410 SET = SET +1: IF SET >SL  THEN SET = SF
3420  RETURN
3430  GOSUB 6655: RETURN
3498 :
3499 :
3505  IF NS < >0  THEN  GOSUB 6420
3510  HOME : POKE 103,1: POKE 104,8: END
3598 :
3599 :
3700  RETURN
3998 :
3999 :
4005  GOSUB 4100: POKE 103,1: POKE 104,8: PRINT  CHR$(4);"RUN HELLO"
4010  GOSUB 4100: POKE 103,1: POKE 104,8: PRINT  CHR$(4);"RUN DRAW-A-SOUND"
4015  GOSUB 4100: POKE 103,1: POKE 104,8: PRINT  CHR$(4);"RUN BUILD-A-SOUND"
4100  IF NS < >0  THEN  HOME : VTAB 10: PRINT "EXCERPT BUFFER MUST BE SAVED FIRST.": GOSUB 9030: GOSUB 6420
4105  HOME : VTAB 10: PRINT "INSERT PROGRAM DISK.": GOSUB 9030: HOME : VTAB 10: PRINT "LOADING. PLEASE WAIT.": RETURN
4998 :
4999 :
5000  REM
5005  HOME : VTAB 10: PRINT "CONNECT AND PREPARE CASSETTE RECORDER.": GOSUB 9030: HOME :: VTAB 10: GOSUB 10004
5006  IF  PEEK(49152) = 193  THEN  RETURN
5010  HOME : VTAB 10: PRINT "AUDIO INPUT COMPLETE.": PRINT : PRINT "TURN TAPE RECORDER OFF.": GOSUB 9030
5015  HOME : VTAB 8: PRINT "PRESS RETURN KEY TO HEAR WHOLE RECORD.": PRINT : PRINT "PRESS SPACE BAR TO HEAR DATA PAGES IN   SEQUENCE.": PRINT : PRINT "PRESS ESCAPE KEY TO RETURN TO MENU."
5020  GOSUB 9000
5025  IF X = 160  THEN  GOSUB 5055: GOTO 5015
5030  IF X = 141  THEN  GOSUB 5080: GOTO 5015
5035  IF X = 155  THEN  RETURN
5040  GOTO 5020
5045 :
5050 :
5055  REM
5060  HOME
5065  FOR I = 0 TO 27: POKE 255,145 -I: POKE 253,144 -I: VTAB 10: PRINT "PAGE ";I +1: CALL 37786: NEXT I: RETURN
5070 :
5075 :
5080  REM
5085  GOSUB 10006: RETURN
5090 :
5095 :
5100  REM
5101  GOSUB 9185
5105  HOME : VTAB 10: INPUT "ENTER NAME OF AUDIO FILE TO BE LOADED.  (TYPE IN AND HIT RETURN.)               ";A$
5106  HOME : VTAB 10: PRINT "READY TO LOAD RAW AUDIO DATA.": PRINT "FILENAME WILL BE: ";A$: GOSUB 9210
5107  PRINT  CHR$(4);"BLOAD";A$: GOTO 5015
5110 :
5115 :
5120  REM
5121  GOSUB 9185
5125  HOME : VTAB 10: INPUT "ENTER FILE NAME.                        (TYPE IN AND HIT RETURN)                ";A$: PRINT  CHR$(4);"BSAVE";A$;",A30208,L7168": RETURN
5126  HOME : VTAB 10: PRINT "READY TO SAVE RAW AUDIO DATA.": PRINT "FILENAME WILL BE: ";A$: GOSUB 9210
5127  PRINT  CHR$(4);"BSAVE";A$;",A30208,L7168": RETURN
6000  REM
6005 P = 1:L = 10:N = 1: GOSUB 6500:JMODE = 1
6010  GOSUB 9000
6015  IF X = 136  THEN  GOSUB 6105: GOTO 6010
6020  IF X = 149  THEN  GOSUB 6140: GOTO 6010
6025  IF X = 208  THEN  GOSUB 6175: GOTO 6010
6030  IF X = 204  THEN  GOSUB 6205: GOTO 6010
6035  IF X = 211  THEN  GOSUB 6235: GOTO 6010
6040  IF X = 178  THEN  GOSUB 6265: GOTO 6010
6045  IF X = 193  THEN  TEXT : GOSUB 5055: GOSUB 6865: GOTO 6010
6050  IF X = 200  THEN  GOSUB 6285: GOTO 6010
6055  IF X = 197  THEN  GOSUB 6335: GOTO 6010
6056  IF X = 210  THEN  GOSUB 6310: GOTO 6010
6060  IF X = 203  THEN  GOSUB 6380: GOTO 6010
6065  IF X = 155  THEN  GOSUB 6085: GOTO 6010
6070  GOTO 6010
6075 :
6080 :
6085  REM
6090  TEXT : POP : RETURN
6095 :
6100 :
6105  REM
6110  IF JMODE = 1  THEN  GOSUB 6475
6115  IF JMODE = 2  THEN  GOTO 6730
6120  IF JMODE = 3  THEN  GOTO 6810
6125  RETURN
6130 :
6135 :
6140  REM
6145  IF JMODE = 1  THEN  GOTO 6525
6150  IF JMODE = 2  THEN  GOTO 6685
6155  IF JMODE = 3  THEN  GOTO 6775
6160  RETURN
6165 :
6170 :
6175  REM
6180 JMODE = 2
6185  TEXT : HOME : VTAB 10: PRINT "ENTER A VALUE (1 TO 128) FOR POSITION.": GOSUB 9050: IF X <1  OR X >128  THEN  GOSUB 6865: RETURN
6190  GOSUB 6570:P = X: GOSUB 6550: GOSUB 6865: RETURN
6195 :
6200 :
6205  REM
6210 JMODE = 3
6215  TEXT : HOME : VTAB 10: PRINT "ENTER DESIRED EXCERPT LENGTH (1 TO 255).": GOSUB 9050: IF X <1  OR X >255  THEN  GOSUB 6865: RETURN
6220  GOSUB 6590:L = X: GOSUB 6550: GOSUB 6865: RETURN
6225 :
6230 :
6235  REM
6240 JMODE = 1
6245  TEXT : HOME : VTAB 10: PRINT "ENTER DESIRED SCREEN NO. (0.5 THRU 28).": GOSUB 9050: IF X <.5  OR X >28  THEN  GOSUB 6865: RETURN
6250 N =  INT(2 *X): GOSUB 6500: RETURN
6255 :
6260 :
6265  REM
6270 AD = BUF: POKE BUF,255:NR = 1: GOSUB 10002: RETURN
6275 :
6280 :
6285  REM
6290 AD = BUF +P -1:X =  PEEK(AD): POKE AD,L:NR = 1
6295  GOSUB 10002: POKE AD,X: RETURN
6300 :
6305 :
6310  REM
6315 AD = BUF +P -1:X =  PEEK(AD): POKE AD,L:NR = 50
6320  GOSUB 10002: POKE AD,X: RETURN
6325 :
6330 :
6335  REM
6340  TEXT : HOME : PRINT "EXCERPTING": POKE AS(NS +1),L
6345  FOR I = 1 TO L: POKE AS(NS +1) +I, PEEK(BUF +P -1 +I): NEXT I: POKE AS(NS +1) +L +1,0
6350 NS = NS +1:AS(NS +1) = AS(NS) +L +1
6355  IF AS(NS +1) >BUF  THEN  TEXT : GOSUB 6420
6360  TEXT : HOME : VTAB 10: PRINT "EXCERPTED AS SOUND ";NS: GOSUB 9030: GOSUB 6865
6365  RETURN
6370 :
6375 :
6380  REM
6385  TEXT : HOME : GOSUB 1230: VTAB 4: PRINT "KEY     FUNCTION": PRINT
6390  PRINT "P       ENTER POSITION OF EXCERPT": PRINT "L       ENTER LENGTH OF EXCERPT": PRINT "S       ENTER SCREEN NO. (0.5 THRU 28)  <--     DECREASE VALUE LAST SET (P,L,S) -->     INCREASE VALUE LAST SET (P,L,S)": PRINT
6395  PRINT "H       HEAR TARGETED PULSES": PRINT "R       HEAR TARGETED PULSES REPEATED": PRINT
6400  PRINT "2       HEAR PAGE (TWO SCREENS)": PRINT "A       HEAR ALL PAGES": PRINT : PRINT "E       EXCERPT TARGETED PULSES INTO            SOUNDSET FILE ": PRINT
6405  PRINT : PRINT "ESC     RETURN TO MAIN MENU": GOSUB 9030: GOSUB 6865: RETURN
6410 :
6415 :
6420  REM
6421  IF NS = 0  THEN  RETURN
6425  GOSUB 9165
6430  PRINT  CHR$(4);"BLOAD SETCOUNT":SC =  PEEK(255): PRINT  CHR$(4);"BSAVE SOUNDSET";SC +1;",A";AS(1);",L";AS(NS +1) +1 -AS(1):SC = SC +1: POKE 255,SC: PRINT  CHR$(4);"BSAVE SETCOUNT,A255,L1"
6432  HOME : TEXT : VTAB 10: PRINT "SAVED AS SOUNDSET";SC: GOSUB 9030
6435 FS = 0:NS = 0:AS(1) = 29184: RETURN
6440 :
6445 :
6450 :
6455 :
6465 :
6470 ::
6475  REM
6480  IF N = 1  THEN  RETURN
6485 N = N -1: GOTO 6500
6490 :
6495 :
6500  REM
6505 A = AUDIO -128 *(N -1): HOME : HGR
6510  FOR I = 0 TO 127:X =  PEEK(A -I): HCOLOR= 3 *(X < >0): HPLOT 11,I +16 TO 10 +X,I +16: POKE BUF +I,X: NEXT I: FOR I = 128 TO 384: POKE BUF +I, PEEK(A -I): NEXT I: HCOLOR= 3: GOSUB 6645: GOSUB 6845: GOSUB 6550: RETURN
6515 :
6520 :
6525  REM
6530  IF N = 56  THEN  RETURN
6535 N = N +1: GOTO 6500
6540 :
6545 :
6550  REM
6555  HCOLOR= 3: GOSUB 6610: GOSUB 6630: RETURN
6560 :
6565 :
6570  REM
6575  HCOLOR= 0: GOSUB 6610: GOSUB 6630: RETURN
6580 :
6585 :
6590  REM
6595  HCOLOR= 0: GOSUB 6630: RETURN
6600 :
6605 :
6610  REM
6615  HPLOT 9,P +15 TO 0,P +15 TO 0,P +12 TO 7,P +15: RETURN
6620 :
6625 :
6630  REM
6635  IF P +L -1 >128  THEN  RETURN
6640  HPLOT 9,P +L +14 TO 0,P +L +14 TO 0,P +L +17 TO 7,P +L +14: RETURN
6645  REM
6650  HOME
6655  VTAB 21: PRINT "SCREEN NO. = ";N/2
6660  VTAB 22: HTAB 1: PRINT "POSITION = ";P;: HTAB 21: PRINT "LENGTH = ";L
6665  RETURN
6670  PRINT "                                        ": RETURN
6675 :
6680 :
6685  REM
6690  GOSUB 6570
6695 P = P +1: IF P >128  THEN P = 1: GOSUB 6525: GOTO 6710
6700  GOSUB 6550: GOSUB 6885
6705  FOR I = 1 TO 100: NEXT I
6710  IF  PEEK(KBD) <128  THEN  GOTO 6685
6715  POKE KSTROBE,0: RETURN
6720 :
6725 :
6730  REM
6735  GOSUB 6570
6740 P = P -1: IF P <1  THEN P = 128: GOSUB 6475: GOTO 6755
6745  GOSUB 6550: GOSUB 6885
6750  FOR I = 1 TO 100: NEXT I
6755  IF  PEEK(KBD) <128  THEN  GOTO 6730
6760  POKE KSTROBE,0: RETURN
6765 :
6770 :
6775  REM
6780  IF L = 255  THEN  GOTO 6795
6785  GOSUB 6590:L = L +1: GOSUB 6550: GOSUB 6905
6790  IF  PEEK(KBD) <128  THEN  GOTO 6775
6795  POKE KSTROBE,0: RETURN
6800 :
6805 :
6810  REM
6815  IF L = 1  THEN  GOTO 6830
6820  GOSUB 6590:L = L -1: GOSUB 6550: GOSUB 6905
6825  IF  PEEK(KBD) <128  THEN  GOTO 6810
6830  POKE KSTROBE,0: RETURN
6835 :
6840 :
6845  REM
6850 A$ = "(PRESS K KEY FOR KEY FUNCTION NOTES.)   ": FOR I = 1 TO 40: POKE 1999 +I, ASC( MID$ (A$,I,1)) +128: NEXT I: RETURN
6855 :
6860 :
6865  REM
6870  HOME : POKE 49239,0: POKE 49232,0: GOSUB 6645: GOSUB 6845: RETURN
6875 :
6880 :
6885  REM
6890  VTAB 22: HTAB 12: PRINT "   ";: HTAB 12: PRINT P: RETURN
6895 :
6900 :
6905  REM
6910  VTAB 22: HTAB 30: PRINT "   ";: HTAB 30: PRINT L: RETURN
6915 :
6920 :
9000  REM
9005  POKE 49168,0
9010 X =  PEEK(49154): IF X <128  THEN  GOTO 9010
9015  POKE 49168,0: RETURN
9020 :
9025 :
9030  REM
9035  VTAB 23: PRINT "(PRESS ANY KEY TO CONTINUE.)": GOSUB 9000: RETURN
9040 :
9045 :
9050  REM
9055  INPUT "(TYPE IN VALUE AND HIT RETURN.)";X: RETURN
9065  FOR I = 1 TO AS(SX +1) -AS(SX) -1: POKE ADDRESS +I, PEEK(AS(SX) +I):P(I) =  PEEK(ADDRESS +I): NEXT I:N =  PEEK(AS(SX)): POKE ADDRESS,N:NM = N: RETURN
9070 :
9075 :
9085 X = N +1 -(AS(SX +1) -AS(SX))
9090  FOR I = AS(NS +1) TO AS(SX +1)  STEP  -1: POKE I +X, PEEK(I): NEXT I
9095  FOR I = 0 TO N: POKE AS(SX) +I, PEEK(ADDRESS +I): NEXT I
9100  GOSUB 9115: RETURN
9105 :
9110 :
9115  REM
9120 NS = 1:AS(1) = 29184
9125 AS(NS +1) = 1 +AS(NS) + PEEK(AS(NS)): IF  PEEK(AS(NS +1)) < >0  THEN NS = NS +1: GOTO 9125
9130  RETURN
9135 :
9140 :
9150  HOME : VTAB 10: PRINT "THERE ARE ";NS;" EXISTING SOUNDS NOW,": PRINT "NUMBERED 1 TO ";NS;".": RETURN
9155 :
9160 :
9165  REM
9170  HOME : VTAB 10: PRINT "INSERT STORAGE DISK.": GOSUB 9030: RETURN
9175 :
9180 :
9185  REM
9190  GOSUB 9165: PRINT  CHR$(4);"CATALOG": GOSUB 9030: GOTO 9210
9195  RETURN
9200 :
9205 :
9210  REM
9215  PRINT : PRINT "HIT RETURN TO PROCEED.": PRINT : PRINT "HIT ANY OTHER TO RECONSIDER.": GOSUB 9000: IF X < >141  THEN  POP : RETURN
9220  RETURN
10001  GOTO 10009
10002  GOSUB 10008: POKE 254,PL: POKE 255,PH: POKE 253,NR: CALL 37889: RETURN
10003  GOSUB 10008: POKE 254,PL: POKE 255,PH: CALL 37478: RETURN
10004  GOSUB 10008: PRINT "TAPE WILL PLAY THROUGH SPEAKER.": PRINT "'T' KEY TRIGGERS DATA INPUT": PRINT "'A' KEY ABORTS WITHOUT DATA INPUT": POKE 255,145: POKE 253,117: CALL 37632: HOME : RETURN
10005  POKE 255,145: POKE 253,117: CALL 37675: RETURN
10006  POKE 255,145: POKE 253,117: CALL 37786: RETURN
10007  POKE 254,ML: POKE 255,MH: POKE 252,NL: POKE 253,NH: CALL 37376: RETURN
10008 PH =  INT(AD/256):PL = AD -256 *PH: RETURN
10009 :
11000  REM
11005  HOME
11010  PRINT "WITH THIS PROGRAM YOU CAN LOAD AUDIO    FROM A TAPE RECORDER INTO MEMORY. ONCE  IN MEMORY, THE 'RAW' AUDIO MAY BE SAVED ON DISK AND RELOADED LATER."
11015  PRINT
11020  PRINT "EXCERPTING GROUPS OF SOUND PULSES FROM  RAW AUDIO INTO A SOUNDSET FILE ALLOWS   YOU TO MODIFY THE GROUPS OF PULSES LATERWITH DRAW-A-SOUND AND CONNECT THEM IN   ANY ORDER WITH BUILD-A-SOUND. RAW AUDIO"
11025  PRINT "OFTEN CONTAINS REPETETIVE PATTERNS OF   PULSES.": PRINT
11030  PRINT "WHEN LOADING AUDIO FROM A CASSETTE, YOU SHOULD BE ABLE TO HEAR THE TAPE THROUGH THE COMPUTER'S SPEAKER. ADJUST YOUR TAPERECORDER AS NEEDED. SOUND WILL NEVER BE PERFECT. WHILE AUDIO IS BEING STORED IN MEMORY THE SPEAKER IS QUIET."
11035  GOSUB 9030: HOME
11040  PRINT "RAW AUDIO IS DIVIDED IN MEMORY INTO 28  256-BYTE PAGES. 128 SOUND PULSES, HALF  OF A PAGE, CAN BE DISPLAYED AT ONCE.    SCREENS OF DISPLAYED DATA ARE NUMBERED  0.5, 1, 1.5, , , ,27.5, 28."
11044  PRINT : PRINT "A CURSOR MARKS THE FIRST PULSE TARGETED FOR EXCERPTION AND ANOTHER CURSOR MARKS"
11045  PRINT "THE END OF THE EXCERPT. THE 'END' CURSORMAY MOVE OFF SCREEN. BY CHANGING THE    HALF-PAGE DISPLAYED, THE POSITION OF THE'START' CURSOR, AND THE LENGTH OF THE   TARGETED PATTERN YOU CAN HEAR AND/OR"
11050  PRINT "EXCERPT ANY GROUP OF PULSES (UP TO 255) ANYWHERE IN THE 7K-BYTES OF AUDIO DATA."
11055  GOSUB 9030: RETURN
11100  REM    <CTRL-G>COPYRIGHT 1982
11110  REM BY SIRIUS SOFTWARE,INC
11120  REM ALL RIGHTS RESERVED