home *** CD-ROM | disk | FTP | other *** search
/ The Glitch Apple Disk Collection / 2014.glitch.apple.collection.zip / indexed / ABM.DSK / ADJUST.bas < prev    next >
BASIC Source File  |  2014-09-09  |  3KB  |  96 lines
  1. 1  PRINT "<CTRL-D>NOMON C,I,O"
  2. 5  DIM P(4,4)
  3. 10  TEXT : HOME 
  4. 40  VTAB 8: PRINT "            ABM GAME CONTROL": PRINT "              ADJUSTMENT"
  5. 50  VTAB 16: PRINT "    COPYRIGHT 1980, MUSE SOFTWARE": PRINT "        ALL RIGHTS RESERVED"
  6. 55  PRINT "<CTRL-D>BLOAD BKUP.CONTROLS"
  7. 60  VTAB 23: PRINT "        PRESS A KEY TO BEGIN "
  8. 70  GET A$
  9. 80  HOME 
  10. 90  VTAB 8: PRINT "   THIS PROGRAM ADJUSTS THE CONTROL": PRINT 
  11. 100  PRINT "SECTIONS OF THE ABM GAME PROGRAM TO": PRINT 
  12. 110  PRINT "MATCH YOUR GAME CONTROLLER.": PRINT 
  13. 130  PRINT "  MOVE THE GAME CONTROLLER AS THOUGH": PRINT 
  14. 140  PRINT "YOU WERE CONTROLLING YOUR TARGET": PRINT 
  15. 150  PRINT "MARKER AS THE ADJUSTER DIRECTS YOU."
  16. 170  VTAB 23: PRINT "         PRESS A KEY TO GO ON.": GET A$
  17. 180  HOME 
  18. 190  PRINT "MOVE YOUR GAME": PRINT "CONTROLS TO": PRINT "THE UPPER LEFT": PRINT "THEN PRESS A KEY."
  19. 200  GET A$:R = 1: GOSUB 5000
  20. 210  HOME 
  21. 220  PRINT "                        MOVE YOUR GAME": PRINT "                           CONTROLS TO "
  22. 230  PRINT "                       THE UPPER RIGHT ": PRINT "                     THEN PRESS A KEY. "
  23. 240  GET A$:R = 2: GOSUB 5000
  24. 250  HOME : VTAB 16
  25. 260  PRINT "MOVE YOUR GAME": PRINT "CONTROLS TO": PRINT "THE LOWER LEFT": PRINT "THEN PRESS A KEY.
  26. 270  GET A$:R = 3: GOSUB 5000
  27. 280  HOME : VTAB 16
  28. 290  PRINT "                        MOVE YOUR GAME ": PRINT "                           CONTROLS TO "
  29. 300  PRINT "                       THE LOWER RIGHT ": PRINT "                     THEN PRESS A KEY. "
  30. 310  GET A$:R = 4: GOSUB 5000
  31. 320  HOME 
  32. 330 PA = 1:PB = 2:PC = 3:PD = 4: GOSUB 6000
  33. 338 HP = PP
  34. 340  POKE 781,PP -1
  35. 345  POKE 787,PQ
  36. 350 PA = 1:PB = 3:PC = 2:PD = 4: GOSUB 6000
  37. 360  POKE 790,PP -1
  38. 362 VP = PP
  39. 365  POKE 796,PQ
  40. 370  HOME 
  41. 380 R = 1: GOSUB 7000
  42. 390  VTAB 16: PRINT "   PRESS THE BUTTON THAT FIRES": PRINT "   THE OUTER AND CENTER MISSILES."
  43. 395  VTAB 20: PRINT "OUTER             CENTER         OUTER"
  44. 400 R = 2: GOSUB 8000
  45. 410  POKE 801,PP -1: POKE 813,128 -PQ
  46. 411  HOME : VTAB 13: PRINT "     LET UP ON IT!"
  47. 412 R = 2: GOSUB 7000
  48. 413 PP = 0
  49. 414  FOR Q = 1 TO 3
  50. 415  IF P(Q,2) = P(Q,1)  THEN 417
  51. 416 PP = Q
  52. 417  NEXT Q
  53. 418  IF PP >0  THEN 411
  54. 420  HOME 
  55. 429  HOME 
  56. 430  VTAB 16: PRINT "    NOW PRESS THE BUTTON THAT"
  57. 440  PRINT "    FIRES THE INNER MISSILES."
  58. 445  VTAB 20: PRINT "        INNER            INNER"
  59. 450 R = 3: GOSUB 8000
  60. 460  POKE 827,PP -1: POKE 839,128 -PQ
  61. 461 IM = PP
  62. 470  HOME : VTAB 16: PRINT "        OKAY, LET GO.": PRINT "      THE GAME IS STARTING!"
  63. 490  PRINT "<CTRL-D>BSAVE CONTROLS,A$300,L$60"
  64. 500  PRINT "<CTRL-D>BRUNABM"
  65. 1000  HOME : VTAB 10
  66. 1010  PRINT "          THERE IS A PROBLEM."
  67. 1020  PRINT 
  68. 1030  PRINT "  YOU MOVED ONLY ONE GAME PADDLE.": PRINT 
  69. 1040  PRINT "  YOU NEED TWO PADDLES OR A JOYSTICK": PRINT 
  70. 1050  PRINT "  TO PLAY THIS GAME!"
  71. 1060  VTAB 23: PRINT "    PRESS A KEY TO START OVER.": GET A$
  72. 1070  GOTO 180
  73. 4098 OM = PP
  74. 5000  REM 
  75. 5005  FOR Q = 1 TO 4:P(Q,R) =  PDL(Q -1): NEXT Q
  76. 5020  RETURN 
  77. 6000 PP = 0
  78. 6005 MX = 0
  79. 6010  FOR Q = 1 TO 4
  80. 6020 DI = P(Q,PA) +P(Q,PC) -(P(Q,PB) +P(Q,PD))
  81. 6030  IF  ABS(DI) < =  ABS(MX)  THEN 6050
  82. 6040 MX = DI:PP = Q
  83. 6050  NEXT Q
  84. 6060 PQ = 0: IF MX >0  THEN PQ = 255: RETURN 
  85. 6070  RETURN 
  86. 7000  FOR Q = 1 TO 3
  87. 7020 P(Q,R) = 0
  88. 7030  IF  PEEK(Q -16288) >127  THEN P(Q,R) = 128
  89. 7040  NEXT Q
  90. 7050  RETURN 
  91. 8000  GOSUB 7000:PP = 0:PQ = 0
  92. 8010  FOR Q = 1 TO 3: IF P(Q,R) = P(Q,1)  THEN 8030
  93. 8020 PP = Q:PQ = P(Q,R)
  94. 8030  NEXT Q
  95. 8040  IF PP = 0  THEN 8000
  96. 8050  RETURN