home *** CD-ROM | disk | FTP | other *** search
/ The Glitch Apple Disk Collection / 2014.glitch.apple.collection.zip / indexed / 33MASTER.DSK / RANDOM.bas < prev    next >
BASIC Source File  |  2014-09-09  |  3KB  |  81 lines
  1. 5  PRINT "<CTRL-D>NOMONI,O,C": HOME 
  2. 10  TEXT :D$ =  CHR$(4)
  3. 20  LET OP$ = D$ +"OPEN "
  4. 30  LET CL$ = D$ +"CLOSE "
  5. 40  LET RD$ = D$ +"READ "
  6. 50  LET WR$ = D$ +"WRITE "
  7. 60  LET FL$ = "APPLE PROMS"
  8. 70  PRINT OP$;FL$;",L40"
  9. 74  GOSUB 9000
  10. 75  GOTO 1000
  11. 80  GOSUB 390
  12. 90  ON Q GOTO 100,180,480
  13. 100  GOSUB 330
  14. 110  FOR R = R1 TO R2
  15. 120  PRINT RD$;FL$;",R";R
  16. 130  INPUT N$,BL,BW,ST
  17. 140  PRINT "  ";R; TAB( 8);N$; TAB( 24);BL; TAB( 32);ST
  18. 150  NEXT R
  19. 160  PRINT D$
  20. 170  GOTO 310
  21. 180  GOSUB 330
  22. 190  LET T = 7: FOR R = R1 TO R2:T = T +1
  23. 200  PRINT RD$;FL$;",R";R: INPUT N$,BL,BW,ST: PRINT D$
  24. 210  VTAB (T): PRINT "  ";R; TAB( 8);N$;: HTAB (7): INPUT Q$
  25. 220  IF  LEN(Q$) >15  THEN 200
  26. 230  IF  LEN(Q$) < >0  THEN N$ = Q$
  27. 250  VTAB (T): HTAB (24): PRINT BL;: HTAB (23): INPUT Q$: IF  LEN(Q$) < >0  THEN BL =  VAL(Q$)
  28. 270  VTAB (T): HTAB (32): PRINT ST;: HTAB (31): INPUT Q$: IF  LEN(Q$) >0  THEN ST =  VAL(Q$)
  29. 280  VTAB (T): PRINT "  ";R; TAB( 8);N$; TAB( 24);BL; TAB( 32);ST;"  "
  30. 290  PRINT WR$;FL$;",R";R: PRINT N$;",";BL;",";BW","ST
  31. 294  CALL 768: PRINT 
  32. 300  PRINT D$: NEXT R
  33. 310  VTAB (23): PRINT "PRESS THE RETURN KEY TO CONTINUE.";: GET Q$
  34. 320  GOTO 80
  35. 330  PRINT : INPUT "PART NUMBER 1-9 (0=ALL) ";Q$
  36. 340  PRINT Q$:Q =  VAL(Q$): IF (Q <1  OR Q >9)  AND Q$ < >"0"  THEN  PRINT  CHR$(7);: GOTO 330
  37. 350  LET R1 = Q:R2 = Q: IF Q = 0  THEN R1 = 1:R2 = 9
  38. 360  HOME : VTAB (5)
  39. 370  PRINT "PART#  NAME            SIZE    IN STOCK -----  ----            ----    -------- "
  40. 380  RETURN 
  41. 390  HOME : PRINT  TAB( 12);FL$: VTAB (10)
  42. 400  PRINT "COMMAND","NUMBER"
  43. 410  PRINT "-------","------"
  44. 420  PRINT "LIST","  1"
  45. 430  PRINT "CHANGE","  2"
  46. 440  PRINT "EXIT","  3"
  47. 450  PRINT : INPUT "CHOOSE NUMBER (1 - 3) ";Q$:Q =  VAL(Q$)
  48. 460  IF Q >0  AND Q <4  THEN  RETURN 
  49. 470  VTAB (15): PRINT  CHR$(7);: GOTO 450
  50. 480  PRINT CL$;FL$
  51. 490  HOME : END 
  52. 500  REM DEMONSTRATION OF RANDOM ACCESS
  53. 1000  DIM A$(9),B(9),C(9),D(9)
  54. 1010  HOME : PRINT : PRINT "THIS DEMONSTRATION WILL NOT EXECUTE ON": PRINT "A WRITE-PROTECTED DISKETTE SUCH AS"
  55. 1020  PRINT "YOUR DOS SYSTEM MASTER (VERSION 3.3).   FOR YOUR CONVENIENCE, PROVISIONS HAVE   BEEN MADE TO COPY THIS PROGRAM AND IT'S"
  56. 1030  PRINT "DATA TO ANOTHER DISKETTE.": PRINT 
  57. 1040  INPUT "DO YOU WISH TO DO THIS NOW? (Y OR N) ";Q$: IF Q$ = "N"  THEN 480
  58. 1050  IF Q$ = "Y"  THEN 1070
  59. 1060  PRINT : VTAB (9): GOTO 1040
  60. 1070  PRINT : PRINT "NOW READING DATA..."
  61. 1080  FOR R = 1 TO 9: PRINT RD$;FL$;",R";R
  62. 1090  INPUT A$(R),B(R),C(R),D(R)
  63. 1100  NEXT R
  64. 1110  PRINT CL$;FL$
  65. 1120  PRINT  CHR$(7): HOME : PRINT : PRINT "INSERT AN INITIALIZED DISKETTE, THEN": PRINT "PRESS THE RETURN KEY TO BEGIN TRANSFER.": INPUT " ";Q$
  66. 1130  PRINT OP$;FL$;",L40"
  67. 1140  PRINT WR$;FL$;",R0"
  68. 1150  PRINT "75": PRINT "DEL 1000,1250": PRINT "SAVE RANDOM": PRINT "HOME": PRINT "RUN"
  69. 1160  FOR R = 1 TO 9
  70. 1170  PRINT WR$;FL$;",R";R
  71. 1180  PRINT A$(R);",";B(R);",";C(R);",";D(R)
  72. 1190  NEXT R
  73. 1200  PRINT CL$;FL$
  74. 1210  HOME : PRINT : PRINT "WHEN THE PROGRAM AND DATA HAVE BEEN": PRINT "FULLY TRANSFERRED, THE PROGRAM WILL": PRINT "BEGIN RUNNING."
  75. 1220  PRINT D$;"EXEC ";FL$
  76. 1230  REM  LINE 75 AND LINES 1000-1250 ARE NOT SAVED
  77. 1240  REM  RECORD ZERO CONTAINS THE 'SAVE' PROGRAM EXECUTIVE
  78. 1250  END 
  79. 9000  FOR I = 768 TO 775: READ J: POKE I,J: NEXT 
  80. 9010  RETURN 
  81. 9100  DATA 169,0,32,237,253,76,142,253