home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
The Glitch Apple Disk Collection
/
2014.glitch.apple.collection.zip
/
indexed
/
33MASTER.DSK
/
RANDOM.bas
< prev
next >
Wrap
BASIC Source File
|
2014-09-09
|
3KB
|
81 lines
5 PRINT "<CTRL-D>NOMONI,O,C": HOME
10 TEXT :D$ = CHR$(4)
20 LET OP$ = D$ +"OPEN "
30 LET CL$ = D$ +"CLOSE "
40 LET RD$ = D$ +"READ "
50 LET WR$ = D$ +"WRITE "
60 LET FL$ = "APPLE PROMS"
70 PRINT OP$;FL$;",L40"
74 GOSUB 9000
75 GOTO 1000
80 GOSUB 390
90 ON Q GOTO 100,180,480
100 GOSUB 330
110 FOR R = R1 TO R2
120 PRINT RD$;FL$;",R";R
130 INPUT N$,BL,BW,ST
140 PRINT " ";R; TAB( 8);N$; TAB( 24);BL; TAB( 32);ST
150 NEXT R
160 PRINT D$
170 GOTO 310
180 GOSUB 330
190 LET T = 7: FOR R = R1 TO R2:T = T +1
200 PRINT RD$;FL$;",R";R: INPUT N$,BL,BW,ST: PRINT D$
210 VTAB (T): PRINT " ";R; TAB( 8);N$;: HTAB (7): INPUT Q$
220 IF LEN(Q$) >15 THEN 200
230 IF LEN(Q$) < >0 THEN N$ = Q$
250 VTAB (T): HTAB (24): PRINT BL;: HTAB (23): INPUT Q$: IF LEN(Q$) < >0 THEN BL = VAL(Q$)
270 VTAB (T): HTAB (32): PRINT ST;: HTAB (31): INPUT Q$: IF LEN(Q$) >0 THEN ST = VAL(Q$)
280 VTAB (T): PRINT " ";R; TAB( 8);N$; TAB( 24);BL; TAB( 32);ST;" "
290 PRINT WR$;FL$;",R";R: PRINT N$;",";BL;",";BW","ST
294 CALL 768: PRINT
300 PRINT D$: NEXT R
310 VTAB (23): PRINT "PRESS THE RETURN KEY TO CONTINUE.";: GET Q$
320 GOTO 80
330 PRINT : INPUT "PART NUMBER 1-9 (0=ALL) ";Q$
340 PRINT Q$:Q = VAL(Q$): IF (Q <1 OR Q >9) AND Q$ < >"0" THEN PRINT CHR$(7);: GOTO 330
350 LET R1 = Q:R2 = Q: IF Q = 0 THEN R1 = 1:R2 = 9
360 HOME : VTAB (5)
370 PRINT "PART# NAME SIZE IN STOCK ----- ---- ---- -------- "
380 RETURN
390 HOME : PRINT TAB( 12);FL$: VTAB (10)
400 PRINT "COMMAND","NUMBER"
410 PRINT "-------","------"
420 PRINT "LIST"," 1"
430 PRINT "CHANGE"," 2"
440 PRINT "EXIT"," 3"
450 PRINT : INPUT "CHOOSE NUMBER (1 - 3) ";Q$:Q = VAL(Q$)
460 IF Q >0 AND Q <4 THEN RETURN
470 VTAB (15): PRINT CHR$(7);: GOTO 450
480 PRINT CL$;FL$
490 HOME : END
500 REM DEMONSTRATION OF RANDOM ACCESS
1000 DIM A$(9),B(9),C(9),D(9)
1010 HOME : PRINT : PRINT "THIS DEMONSTRATION WILL NOT EXECUTE ON": PRINT "A WRITE-PROTECTED DISKETTE SUCH AS"
1020 PRINT "YOUR DOS SYSTEM MASTER (VERSION 3.3). FOR YOUR CONVENIENCE, PROVISIONS HAVE BEEN MADE TO COPY THIS PROGRAM AND IT'S"
1030 PRINT "DATA TO ANOTHER DISKETTE.": PRINT
1040 INPUT "DO YOU WISH TO DO THIS NOW? (Y OR N) ";Q$: IF Q$ = "N" THEN 480
1050 IF Q$ = "Y" THEN 1070
1060 PRINT : VTAB (9): GOTO 1040
1070 PRINT : PRINT "NOW READING DATA..."
1080 FOR R = 1 TO 9: PRINT RD$;FL$;",R";R
1090 INPUT A$(R),B(R),C(R),D(R)
1100 NEXT R
1110 PRINT CL$;FL$
1120 PRINT CHR$(7): HOME : PRINT : PRINT "INSERT AN INITIALIZED DISKETTE, THEN": PRINT "PRESS THE RETURN KEY TO BEGIN TRANSFER.": INPUT " ";Q$
1130 PRINT OP$;FL$;",L40"
1140 PRINT WR$;FL$;",R0"
1150 PRINT "75": PRINT "DEL 1000,1250": PRINT "SAVE RANDOM": PRINT "HOME": PRINT "RUN"
1160 FOR R = 1 TO 9
1170 PRINT WR$;FL$;",R";R
1180 PRINT A$(R);",";B(R);",";C(R);",";D(R)
1190 NEXT R
1200 PRINT CL$;FL$
1210 HOME : PRINT : PRINT "WHEN THE PROGRAM AND DATA HAVE BEEN": PRINT "FULLY TRANSFERRED, THE PROGRAM WILL": PRINT "BEGIN RUNNING."
1220 PRINT D$;"EXEC ";FL$
1230 REM LINE 75 AND LINES 1000-1250 ARE NOT SAVED
1240 REM RECORD ZERO CONTAINS THE 'SAVE' PROGRAM EXECUTIVE
1250 END
9000 FOR I = 768 TO 775: READ J: POKE I,J: NEXT
9010 RETURN
9100 DATA 169,0,32,237,253,76,142,253