home *** CD-ROM | disk | FTP | other *** search
/ The Glitch Apple Disk Collection / 2014.glitch.apple.collection.zip / indexed / 33MASTER.DSK / COPY.int < prev    next >
Text File  |  2014-09-09  |  3KB  |  54 lines
  1. 10 TEXT 
  2. 20 REM **************************
  3. 30 REM *       DISK COPY        *
  4. 40 REM *   COPYRIGHT 1980 BY    *
  5. 50 REM *  APPLE COMPUTER INC.   *
  6. 60 REM *                        *
  7. 70 REM **************************
  8. 90 PRINT "<CTRL-D>BLOAD COPY.OBJ0":REM A$2C0
  9. 100 DIM DK$(20)
  10. 110 DIM I$(40):CALL -936:PRINT "   APPLE DISKETTE DUPLICATION PROGRAM":PRINT :PRINT 
  11. 120 CALL 704:CS= PEEK (718)/16
  12. 130  POKE 715, PEEK (205)+1:REM BUFSTART
  13. 140  POKE 716, PEEK (203)-1:REM BUFEND
  14. 150 I$=" ORIGINAL":N=CS:A=718:GOSUB 430:MS=N:N= PEEK (720):GOSUB 440:MD=N:A=717
  15. 160 I$="DUPLICATE":N=MS:GOSUB 430:SS=N:N=3-MD:GOSUB 440:SD=N
  16. 170 FT=0
  17. 180 VTAB 5:TAB 24:PRINT "       ":VTAB 8:TAB 24:PRINT "          "
  18. 190 CALL 704: POKE 717,SS*16: POKE 718,MS*16: POKE 719,SD: POKE 720,MD
  19. 200 VTAB 17: POKE 34,16
  20. 210 CALL -936
  21. 220 PRINT "-- PRESS 'RETURN' KEY TO BEGIN COPY --";:INPUT I$
  22. 225 CALL -936
  23. 230 DK$=" ORIGINAL":GOSUB 480:REM GET ORIG DISK
  24. 240 VTAB 5:TAB 24: POKE 50,63:PRINT "READING": POKE 50,255
  25. 250 CALL 707:REM  READ A HUNK
  26. 260 IF  PEEK (713)=2 THEN 390:REM ERROR!
  27. 270 VTAB 5:TAB 24:PRINT "       "
  28. 280 IF  PEEK (713)=1 THEN 400
  29. 290 IF FT THEN 330:REM NOT FIRST RD
  30. 300 DK$="DUPLICATE":GOSUB 480:REM GET DUP DISK
  31. 310 VTAB 8:TAB 24: POKE 50,63:PRINT "FORMATTING": POKE 50,255
  32. 320 PRINT "<CTRL-D>INIT XXX,S";SS;",D";SD;",V"; PEEK (714):FT=1:GOTO 340
  33. 330 DK$="DUPLICATE":GOSUB 480:REM GET DUP DISK
  34. 340 VTAB 8:TAB 24: POKE 50,63:PRINT "WRITING";: POKE 50,255:PRINT "    ";
  35. 350 CALL 710:REM  WRITE A HUNK
  36. 360 VTAB 8:TAB 24:PRINT "       "
  37. 370 IF  PEEK (713)#2 THEN 230
  38. 380 VTAB 18: POKE 50,63:PRINT "****** UNABLE TO WRITE ******<CTRL-G><CTRL-G>":GOTO 400
  39. 390 VTAB 18: POKE 50,63:PRINT "****** UNABLE TO READ ******<CTRL-G><CTRL-G>"
  40. 400 VTAB 19: POKE 50,255: POKE -16368,0:PRINT :INPUT "DO YOU WISH TO MAKE ANOTHER COPY?",I$:IF  LEN(I$)=0 THEN 420:IF I$(1,1)="Y" THEN 170
  41. 410 IF I$(1,1)#"N" THEN 400
  42. 420 TEXT :END 
  43. 430 PRINT :GOSUB 470:PRINT N;: POKE 50,255:TAB 1:PRINT I$;"  SLOT: ";:L=1:H=7:GOSUB 450: POKE A,N*16:RETURN 
  44. 440 GOSUB 470:PRINT N;: POKE 50,255:TAB 4:PRINT "       DRIVE: ";:L=1:H=2:GOSUB 450:RETURN 
  45. 450 K= PEEK (-16384):IF K<128 THEN 450: POKE -16368,0:IF K=141 THEN 460:K=K-176:IF K<L OR K>H THEN 450:N=K
  46. 460 TAB 20:PRINT N;"                  ":RETURN 
  47. 470  POKE 50,63:TAB 22:PRINT "DEFAULT = ";: POKE ( PEEK (41)*256+ PEEK (40)+14),96:RETURN 
  48. 480 IF MS#SS THEN RETURN 
  49. 490 IF MD#SD THEN RETURN 
  50. 500 CALL -936:IF DK$(1,1)="D" THEN PRINT 
  51. 510 PRINT "INSERT ";DK$;" DISK AND PRESS RETURN";:INPUT DK$
  52. 520 CALL -936
  53. 530 RETURN 
  54.