home *** CD-ROM | disk | FTP | other *** search
/ The Glitch Apple Disk Collection / 2014.glitch.apple.collection.zip / indexed / 33MASTER.DSK / ANIMALS.int next >
Text File  |  2014-09-09  |  5KB  |  105 lines
  1. 0 GOTO 1000
  2. 1 REM *************************
  3. 2 REM *                       *
  4. 3 REM *    ANIMALS:           *
  5. 4 REM *   COPYRIGHT 1978 BY   *
  6. 5 REM *  APPLE COMPUTER INC.  *
  7. 6 REM *                       *
  8. 7 REM *************************
  9. 100 CUR=1:REM HERE IS WHERE PROGRAM IS PLAYED
  10. 110 PRINT OP$
  11. 120 PRINT RF$;CUR
  12. 130 INPUT NEW$:IF NEW$(1,1)="!" THEN 500:INPUT RTPTR:INPUT WRNGPTR
  13. 140 REM NOW HAVE QUESTION TO ASK. RTPTR POINTS AT RECORD TO GO TO IF HE ANSWERS YES, WRNGPTR IF HE SAYS NO.
  14. 150 PRINT CL$
  15. 160 PRINT :PRINT NEW$;:INPUT "?",A$:PREV=CUR:IF NOT  LEN(A$) THEN 160:A$=A$(1,1):IF A$#"Y" AND A$#"N" THEN 160
  16. 170 IF A$="Y" THEN CUR=RTPTR:IF A$="N" THEN CUR=WRNGPTR:GOTO 110
  17. 500 REM HAVE REACHED AN ANIMAL ENTRY. IS IT THE RIGHT ONE?
  18. 510 PRINT CL$:AN$="AEIOU":PRINT "IS THE ANIMAL YOU'RE THINKING OF A";:FOR VWL=1 TO 5
  19. 520 IF AN$(VWL,VWL)=NEW$(2,2) THEN PRINT "N";:NEXT VWL:PRINT :PRINT NEW$(2);:INPUT "?",AN$:IF NOT  LEN(AN$) THEN 510
  20. 530 AN$=AN$(1,1):IF AN$#"Y" AND AN$#"N" THEN 510:IF AN$="Y" THEN 800
  21. 540 REM I DON'T KNOW WHAT ANIMAL IT IS, ASK HIM
  22. 550 PRINT :PRINT :PRINT "ALL RIGHT, I GIVE UP. WHAT ANIMAL WERE":PRINT "YOU THINKING OF?";
  23. 560 ANIM$="!":INPUT ANIM$(2)
  24. 570 PRINT :PRINT "PLEASE TYPE A QUESTION THAT WOULD":PRINT "DISTINGUISH BETWEEN A ";NEW$(2):PRINT "AND A ";ANIM$(2);
  25. 580 INPUT ":",Q$:IF Q$( LEN(Q$))="?" THEN Q$=Q$(1, LEN(Q$)-1)
  26. 590 PRINT :PRINT "WHAT WOULD THE CORRECT ANSWER FOR A":PRINT ANIM$(2);" BE?";:INPUT AN$:AN$=AN$(1,1):IF AN$#"Y" AND AN$#"N" THEN 590
  27. 600 PRINT OP$
  28. 610 PRINT RF$;0
  29. 620 REM UPDATE HEADER RECORD.
  30. 630 INPUT CNT,LAST:PRINT WF$;0
  31. 640 CNT=CNT+1:LAST=LAST+2:PRINT CNT;",";LAST:PRINT RF$;PREV
  32. 650 INPUT NEW$:INPUT OLDR:INPUT OLDW:PRINT WF$;PREV
  33. 660 PRINT NEW$:IF A$="N" THEN 670:PRINT LAST-1:PRINT OLDW:GOTO 680
  34. 670 PRINT OLDR:PRINT LAST-1
  35. 680 PRINT WF$;LAST-1
  36. 690 PRINT Q$:IF AN$="Y" THEN 700:PRINT CUR:PRINT LAST:GOTO 710
  37. 700 PRINT LAST:PRINT CUR
  38. 710 PRINT WF$;LAST
  39. 720 PRINT ANIM$:PRINT CL$
  40. 730 PRINT "I NOW KNOW ";CNT;" ANIMALS!<CTRL-G>":GOTO 830
  41. 800 REM  I GOT IT RIGHT!!!
  42. 810 FOR L=1 TO 10:PRINT :NEXT L
  43. 820 PRINT "I GOT IT RIGHT!!!<CTRL-G><CTRL-G><CTRL-G><CTRL-G>"
  44. 830 PRINT :INPUT "WANT TO PLAY AGAIN? ",A$:IF  LEN(A$) THEN IF A$(1,1)="N" THEN END :GOTO 100
  45. 1000 REM ***************************
  46. 1001 REM *                         *
  47. 1002 REM *        ANIMAL:          *
  48. 1003 REM *  PROGRAM THATS LEARNS   *
  49. 1004 REM *  ABOUT VARIOUS ANIMALS  *
  50. 1005 REM *  FROM THE USER.         *
  51. 1006 REM *                         *
  52. 1007 REM *   SYSTEM REQUIREMENTS:  *
  53. 1008 REM *  16K MEMORY, DISK II    *
  54. 1009 REM *                         *
  55. 1010 REM *      R. WIGGINTON       *
  56. 1011 REM *        06/01/78         *
  57. 1012 REM *                         *
  58. 1013 REM *   UPDATED: 1/12/79      *
  59. 1014 REM ***************************
  60. 1020 PRINT "<CTRL-D>NOMON I,O,C"
  61. 1030 TEXT :CALL -936:DIM NEW$(70),ANIM$(70),Q$(70),A$(70),RF$(20),WF$(20),AN$(10),CL$(20),OP$(40)
  62. 1040 RF$="<CTRL-D>READ ANIMALSFILE,R":WF$="<CTRL-D>WRITE ANIMALSFILE,R":CL$="<CTRL-D>CLOSE":OP$="<CTRL-D>OPEN ANIMALSFILE,L80":PRINT OP$
  63. 1041 REM  THE ABOVE STRINGS WERE SET SO THAT WE ONLY NEED TO PRINT A STRING RATHER THAN TYPE THE WHOLE OPERATION. EXAMPLE:
  64. 1042 REM  RATHER THAN PRINT D$;"READ ANIMALSFILE,R" WE PRINT RF$. NOTE THAT THE ",R" IS FOR RANDOM ACCESS INTO FILES.
  65. 1045 PRINT "* WARNING<CTRL-G>: YOUR DISKETTE MAY NOT BE":PRINT "WRITE PROTECTED IN ORDER TO PLAY THIS":PRINT "GAME!"
  66. 1050 VTAB 5:PRINT " **** ANIMAL LEARNING GAME ****":PRINT :PRINT "HAVE YOU EVER PLAYED BEFORE?";:INPUT A$:IF  LEN(A$) THEN IF A$(1,1)="Y" THEN 100
  67. 1060 PRINT :PRINT "INSTRUCTIONS:":PRINT :PRINT "YOU WILL THINK OF AN ANIMAL, AND I WILL":PRINT "TRY TO GUESS WHAT ANIMAL YOU ARE"
  68. 1070 PRINT "THINKING OF.  I WILL DO THIS BY ASKING":PRINT "YOU A SERIES OF QUESTIONS ABOUT YOUR"
  69. 1080 PRINT "ANIMAL, TO WHICH YOU RESPOND EITHER":PRINT "YES OR NO. (ACTUALLY, A SIMPLE 'Y' OR":PRINT "'N' RESPONSE IS SUFFICIENT)"
  70. 1090 PRINT "IF I DO NOT GUESS WHAT YOUR ANIMAL IS,":PRINT "I WILL ASK YOU A FEW QUESTIONS SO THAT"
  71. 1100 PRINT "NEXT TIME I WILL KNOW WHAT YOUR ANIMAL":PRINT "IS.":PRINT 
  72. 1110 PRINT "DO YOU WANT ME TO START LEARNING, OR":PRINT "HAVE YOU TAUGHT ME ANIMALS BEFORE?"
  73. 1111 PRINT "TYPE 'NEWFILE' FOR ME TO FORGET WHAT I":PRINT "HAVE LEARNED UP TO NOW OR IF NO ONE HAS"
  74. 1112 INPUT "TAUGHT ME ANYTHING YET: ",A$:IF A$#"NEWFILE" THEN 100
  75. 1120 PRINT WF$;0
  76. 1130 PRINT "2,4"
  77. 1140 PRINT WF$;1
  78. 1150 PRINT "DOES IT LIVE IN THE WATER":PRINT 2:PRINT 3
  79. 1160 PRINT WF$;2
  80. 1170 PRINT "!FROG"
  81. 1180 PRINT WF$;3
  82. 1190 PRINT "!MOOSE"
  83. 1200 GOTO 100
  84. 2000 REM -----------------------------
  85. 2010 REM    PROGRAM EXPLANATION
  86. 2020 REM -----------------------------
  87. 2030 REM 
  88. 2040 REM  BASICALLY, THIS PROGRAM
  89. 2050 REM  ILLUSTRATES THE USE OF A
  90. 2060 REM  BINARY TREE STRUCTURE. SINCE
  91. 2070 REM  THE ANSWER TO A QUESTION MUST
  92. 2080 REM  EITHER BE A YES OR NO, WE
  93. 2090 REM  WILL TRAVERSE THE TREE EITHER
  94. 2100 REM  LEFT OR RIGHT. IF WE DO NOT
  95. 2110 REM  GUESS THE ANIMAL CORRECTLY,
  96. 2120 REM  WE SIMPLY GET THE NEW ANIMAL
  97. 2130 REM  AND A QUESTION TO DISTINGUISH
  98. 2140 REM  IT FROM OTHER ANIMALS, AND
  99. 2150 REM  UPDATE THE TREE STRUCTURE.
  100. 2160 REM 
  101. 2170 REM  ORIGINAL PROGRAM IDEA:
  102. 2180 REM    WHO KNOWS?
  103. 2190 REM 
  104. 2200 REM  COPYRIGHT 1978 APPLE COMPUTER INC.
  105.