home *** CD-ROM | disk | FTP | other *** search
/ Graphics Programming Black Book (Special Edition) / BlackBook.bin / disk1 / source / chapter47 / l47-4.asm < prev    next >
Assembly Source File  |  1997-06-18  |  4KB  |  93 lines
  1. ; Mode X (320x240, 256 colors) rectangle fill routine. Works on all
  2. ; VGAs. Uses slow approach that selects the plane explicitly for each
  3. ; pixel. Fills up to but not including the column at EndX and the row
  4. ; at EndY. No clipping is performed.
  5. ; Tested with TASM 4.0 by Jim Mischel 12/16/94.
  6. ; C near-callable as:
  7. ;
  8. ;    void FillRectangleX(int StartX, int StartY, int EndX, int EndY,
  9. ;       unsigned int PageBase, int Color);
  10.  
  11. SC_INDEX equ    03c4h   ;Sequence Controller Index
  12. MAP_MASK equ    02h     ;index in SC of Map Mask register
  13. SCREEN_SEG equ  0a000h  ;segment of display memory in mode X
  14. SCREEN_WIDTH equ 80     ;width of screen in bytes from one scan line
  15.                         ; to the next
  16. parms   struc
  17.         dw      2 dup (?) ;pushed BP and return address
  18. StartX  dw      ?       ;X coordinate of upper left corner of rect
  19. StartY  dw      ?       ;Y coordinate of upper left corner of rect
  20. EndX    dw      ?       ;X coordinate of lower right corner of rect
  21.                         ; (the row at EndX is not filled)
  22. EndY    dw      ?       ;Y coordinate of lower right corner of rect
  23.                         ; (the column at EndY is not filled)
  24. PageBase dw     ?       ;base offset in display memory of page in
  25.                         ; which to fill rectangle
  26. Color   dw      ?       ;color in which to draw pixel
  27. parms   ends
  28.  
  29.         .model  small
  30.         .code
  31.         public  _FillRectangleX
  32. _FillRectangleX proc    near
  33.         push    bp      ;preserve caller's stack frame
  34.         mov     bp,sp   ;point to local stack frame
  35.         push    si      ;preserve caller's register variables
  36.         push    di
  37.  
  38.         mov     ax,SCREEN_WIDTH
  39.         mul     [bp+StartY] ;offset in page of top rectangle scan line
  40.         mov     di,[bp+StartX]
  41.         shr     di,1
  42.         shr     di,1    ;X/4 = offset of first rectangle pixel in scan
  43.                         ; line
  44.         add     di,ax   ;offset of first rectangle pixel in page
  45.         add     di,[bp+PageBase] ;offset of first rectangle pixel in
  46.                         ; display memory
  47.         mov     ax,SCREEN_SEG
  48.         mov     es,ax   ;point ES:DI to the first rectangle pixel's
  49.                         ; address
  50.         mov     dx,SC_INDEX ;set the Sequence Controller Index to
  51.         mov     al,MAP_MASK ; point to the Map Mask register
  52.         out     dx,al
  53.         inc     dx      ;point DX to the SC Data register
  54.         mov     cl,byte ptr [bp+StartX]
  55.         and     cl,011b ;CL = first rectangle pixel's plane
  56.         mov     al,01h
  57.         shl     al,cl   ;set only the bit for the pixel's plane to 1
  58.         mov     ah,byte ptr [bp+Color] ;color with which to fill
  59.         mov     bx,[bp+EndY]
  60.         sub     bx,[bp+StartY]  ;BX = height of rectangle
  61.         jle     FillDone        ;skip if 0 or negative height
  62.         mov     si,[bp+EndX]
  63.         sub     si,[bp+StartX]  ;CX = width of rectangle
  64.         jle     FillDone        ;skip if 0 or negative width
  65. FillRowsLoop:
  66.         push    ax      ;remember the plane mask for the left edge
  67.         push    di      ;remember the start offset of the scan line
  68.         mov     cx,si   ;set count of pixels in this scan line
  69. FillScanLineLoop:
  70.         out     dx,al   ;set the plane for this pixel
  71.         mov     es:[di],ah ;draw the pixel
  72.         shl     al,1    ;adjust the plane mask for the next pixel's
  73.         and     al,01111b ; bit, modulo 4
  74.         jnz     AddressSet ;advance address if we turned over from
  75.         inc     di      ; plane 3 to plane 0
  76.         mov     al,00001b ;set plane mask bit for plane 0
  77. AddressSet:
  78.         loop    FillScanLineLoop
  79.         pop     di      ;retrieve the start offset of the scan line
  80.         add     di,SCREEN_WIDTH ;point to the start of the next scan
  81.                         ; line of the rectangle
  82.         pop     ax      ;retrieve the plane mask for the left edge
  83.         dec     bx      ;count down scan lines
  84.         jnz     FillRowsLoop
  85. FillDone:
  86.         pop     di      ;restore caller's register variables
  87.         pop     si
  88.         pop     bp      ;restore caller's stack frame
  89.         ret
  90. _FillRectangleX endp
  91.         end
  92.  
  93.