home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Shareware Gold 1
/
The_Golden_ROM_Series_-_Shareware_Gold_Volume_1_Number_11_-_SK_89-301_-_1989.iso
/
LIB022
/
HST17.SCR
< prev
next >
Wrap
Text File
|
1988-01-01
|
30KB
|
1,204 lines
STRING QMBS WAIT1 FUNC MENU
ASSIGN WAIT1 "6000"
GOTO FIRST
CONTINUE:
WHEN
GOTOXY 19,24
DISPLAY "Press (Enter) to return to function menu......"
FLUSH ALL
GOTOXY 1,1
GET 1 1
GETFUNC:
PUTSCR
GETSCR
FLUSH ALL
GOTOXY 57,19
GET FUNC 2
IF "$FUNC" = "1" ROMLEVEL
IF "$FUNC" = "2" CKSUM
IF "$FUNC" = "3" RAMTEST
IF "$FUNC" = "4" CURSET
IF "$FUNC" = "5" NRAM
IF "$FUNC" = "6" INTCLOCK
IF "$FUNC" = "7" DISPFONE
IF "$FUNC" = "8" BASHELP
IF "$FUNC" = "9" EXTHELP
IF "$FUNC" = "10" DIALHELP
IF "$FUNC" = "11" SREGHELP
IF "$FUNC" = "12" SWITHELP
IF "$FUNC" = "13" INTEST
IF "$FUNC" = "14" ANLOOP
IF "$FUNC" = "15" FREQTEST
IF "$FUNC" = "16" DATAMODE
IF "$FUNC" = "17" SETDEF
IF "$FUNC" = "18" WRTNRAM
IF "$FUNC" = "19" FONEDIAL
IF "$FUNC" = "20" LINKDIAG
IF "$FUNC" = "AD" ADVANCED
IF "$FUNC" = "QM" QMDMDEF
IF "$FUNC" = "PC" PCBDEF
IF "$FUNC" = "99" GETOUT
IF "$FUNC" > "49" CKMENU
BEEP 400
GOTO GETFUNC
CKMENU:
IF "$MENU" = "2" ADVFUNC
BEEP 400
GOTO GETFUNC
ADVFUNC:
IF "$FUNC" = "50" DISCOMP
IF "$FUNC" = "51" AUTOCOMP
IF "$FUNC" = "52" ENACOMP
IF "$FUNC" = "53" S15REG
IF "$FUNC" = "54" NEWRATE
IF "$FUNC" = "55" MODINQ
IF "$FUNC" = "98" MAINMENU
BEEP 400
GOTO GETFUNC
MAINMENU:
PUTSCR
ASSIGN MENU "1"
GOTO GETFUNC
TOOLONG:
CLRSCR
NOTE DATA NOT RECEIVED AFTER SPECIFIED TIMEOUT - ERROR
PAUSE 3000
GETOUT:
CLRSCR
GOTOXY 1,1
DISPLAYLN "USR HST SERVICE SCRIPT - EXIT"
DISPLAYLN " "
DISPLAYLN "The COM port has been set to 2400-N-8-1 by this script."
DISPLAYLN "The parameters you had set before invoking the script may"
DISPLAYLN "have been different. Use the Alt-P command to restore the"
DISPLAYLN "desired communications parameters before going back online."
DISPLAYLN " "
DISPLAYLN "Thanks for using HST17 and QModem. Have a nice day."
DISPLAYLN " "
DISPLAYLN "Press <Enter> to return to Qmodem"
GET 0 1
PUTSCR
PUTSCR
PUTSCR
EXIT
TURNOFF ECHO
EXIT
FONEDIAL:
CLRSCR
DISPLAYLN "(T) for tone, (P) for pulse dialing and (Enter)..."
GOTOXY 1,3
GET 0 1
IF "$0" = "T" TONE
IF "$0" = "P" PULSE
BEEP 450
GOTO FONEDIAL
TONE:
ASSIGN 0 "ATDT"
GOTO DIALER
PULSE:
ASSIGN 0 "ATDP"
DIALER:
GOTOXY 1,6
DISPLAYLN "Type desired telephone number and (Enter)"
GOTOXY 1,8
GET 1 25
GOTOXY 1,10
HANGUP
DISPLAYLN "Dialing and exitting script......."
SEND "$0$1{"
GOTO GETOUT
ROMLEVEL:
CLRSCR
DISPLAYLN "USR HST ROM LEVEL DISPLAY -- ATI0"
SEND "ATI0{"
TIMEOUT 10 TOOLONG
WAITFOR "OK"
GOTO CONTINUE
CKSUM:
CLRSCR
DISPLAYLN "USR HST MEMORY CHECKSUM (ROM) DISPLAY -- ATI1"
SEND "ATI1{"
TIMEOUT 10 TOOLONG
WAITFOR "OK"
GOTO CONTINUE
RAMTEST:
CLRSCR
DISPLAYLN "USR HST RAM MEMORY TEST -- ATI2"
SEND "ATI2{"
TIMEOUT 10 TOOLONG
WAITFOR "OK"
GOTO CONTINUE
CURSET:
CLRSCR
DISPLAYLN "USR HST CURRENT MODEM SETTINGS -- ATI4"
SEND "ATI4{"
TIMEOUT 10 TOOLONG
WAITFOR "HOOK"
TIMEOUT 10 TOOLONG
WAITFOR "OK"
GOTO CONTINUE
NRAM:
CLRSCR
DISPLAYLN "USR HST NON-VOLATILE RAM SETTINGS -- ATI5"
SEND "ATI5{"
TIMEOUT 10 TOOLONG
WAITFOR "OK"
GOTO CONTINUE
LINKDIAG:
CLRSCR
DISPLAYLN "USR HST lINK DIAGNOSTICS DISPLAY -- ATI6"
SEND "ATI6{
TIMEOUT 40 TOOLONG
WAITFOR "OK"
GOTO CONTINUE
INTCLOCK:
CLRSCR
DISPLAYLN "USR HST INTERNAL CLOCK DISPLAY -- ATI3"
DISPLAYLN "Current modem clock value is:"
SEND "ATI3{"
TIMEOUT 10 TOOLONG
WAITFOR "OK"
DISPLAYLN " "
DISPLAYLN "Do you wish to set the modem clock (Y/N) "
GET 0 1
IF "$0" = "Y" SETCLOCK
GOTO CONTINUE
SETCLOCK:
CLRSCR
DISPLAYLN "USR HST INTERNAL CLOCK SETTING"
GOTOXY 1,3
DISPLAYLN "OPTION 1: Synchronize to system clock"
DISPLAYLN "OPTION 2: Specify your own clock value"
ASKCLOCK:
GOTOXY 1,6
DISPLAY "Type 1 or 2 and (Enter): "
GET 0 1
IF "$0" = "1" SYSCLOCK
IF "$0" = "2" USRCLOCK
BEEP 450
GOTO ASKCLOCK
SYSCLOCK:
CLRSCR
DISPLAYLN "SYNCHRONIZING MODEM CLOCK TO SYSTEM CLOCK"
GOTOXY 1,3
DISPLAYLN "Current system clock is $TIME"
TIMEOUT 10 TOOLONG
SEND "ATK1{"
WAITFOR "OK"
DISPLAYLN " "
ASSIGN 0 "K1"
TIMEOUT 10 TOOLONG
SEND "ATI3=$TIME$0{"
WAITFOR "OK"
SHOWTIME:
GOTOXY 1,12
DISPLAYLN "Modem Internal clock value is now:"
SEND "ATI3{"
TIMEOUT 10 TOOLONG
WAITFOR "OK"
GOTO CONTINUE
USRCLOCK:
CLRSCR
DISPLAYLN "MANUAL SETTING OF USR HST INTERNAL CLOCK"
GOTOXY 1,3
DISPLAYLN "WARNING: The script does not validate the clock value;"
DISPLAYLN " an incorrect clock value will return an error."
GOTOXY 1,7
DISPLAY "Type a clock value in HH:MM:SS format and (Enter): "
GET 1 8
ASSIGN 0 "K1"
DISPLAYLN " "
SEND "ATK1{"
TIMEOUT 10 TOOLONG
WAITFOR "OK"
SEND "ATI3=$1$0{"
TIMEOUT 10 TOOLONG
WAITFOR "OK"
GOTO SHOWTIME
SETSREG:
CLRSCR
DISPLAYLN "SET HST S-REGISTER(S)"
TIMEOUT 10 TOOLONG
SEND "ATS$${"
WAITFOR "OK"
ASKREG:
GOTOXY 1,18
DISPLAYLN "Enter register you want to set (0-13,16-17,19-23): "
DISPLAYLN "---or press (Enter) to return to abort--"
GOTOXY 55,18
GET 1 2
IF "$1" = "" CONTINUE
IF "$1" > "23" BADREG
IF "$1" = "14" BADREG
IF "$1" = "15" BADREG
IF "$1" = "18" BADREG
GOTO DISPREG
BADREG:
BEEP 400
GOTO ASKREG
DISPREG:
CLRSCR
DISPLAYLN "Current value of register S$1:"
SEND "ATS$1?{"
TIMEOUT 10 TOOLONG
WAITFOR "OK"
ASKSET:
GOTOXY 1,8
DISPLAYLN "Type new S$1 register value or (Enter) to leave as is: "
GET 0 3
IF "$0" = "" CONTINUE
IF "$0" < "0" BADSET
IF "$0" > "255" BADSET
SEND "ATS$1=$0{"
TIMEOUT 10 TOOLONG
WAITFOR "OK"
GOTOXY 1,15
DISPLAYLN "New S$1 register value returned by modem is:"
SEND "ATS$1?{"
TIMEOUT 10 TOOLONG
WAITFOR "OK"
GOTO CONTINUE
BADSET:
BEEP 400
GOTO ASKSET
SETDEF:
CLRSCR
DISPLAYLN "Resetting the NRAM defaults may erase changes made to the modem"
DISPLAYLN "operational parameters or S-Registers if these changes were not"
DISPLAYLN "copied to NRAM."
DISPLAYLN "Do you wish to continue (Y/N): "
GOTOXY 31,4
GET 0 1
IF "$0" = "Y" RESETDEF
IF "$0" = "N" CONTINUE
BEEP 400
GOTO SETDEF
RESETDEF:
SEND "ATZ{"
TIMEOUT 10 TOOLONG
WAITFOR "OK"
GOTO CONTINUE
BASHELP:
CLRSCR
SEND "AT$${"
TIMEOUT 10 TOOLONG
WAITFOR "HOOK"
WAITFOR "HOOK"
WAITFOR "OK"
GOTO CONTINUE
EXTHELP:
CLRSCR
SEND "AT&$${"
TIMEOUT 30 TOOLONG
WAITFOR "OK"
GOTO CONTINUE
DIALHELP:
CLRSCR
SEND "ATD$${"
TIMEOUT 30 TOOLONG
WAITFOR"HOOK"
WAITFOR "OK"
GOTO CONTINUE
SREGHELP:
CLRSCR
SEND "ATS$${"
TIMEOUT 30 TOOLONG
WAITFOR "OK"
GOTO CONTINUE
SWITHELP:
CLRSCR
DISPLAYLN "HST DIP SWITCH HELP SCREEN"
DISPLAYLN " "
DISPLAYLN " ▄ ▄ "
DISPLAYLN " ┌──────┐┌─┬─┬─┬─┬─┬─┬─┬─┬─┬─┐"
DISPLAYLN " UP│██████││ │█│ │█│ │ │█│ │ │█│ FACTORY"
DISPLAYLN " DN│ ││█│ │█│ │█│█│ │█│█│ │ SETTINGS"
DISPLAYLN " └──────┘└─┴─┴─┴─┴─┴─┴─┴─┴─┴─┘"
DISPLAYLN " ▀ ▀ 1 2 3 4 5 6 7 8 9 10"
DISPLAYLN " "
NOTE Sw# Description Sw# Description
NOTE ------------------------------------------------------------------------
NOTE 1...Data Terminal Ready Override 6...Carrier Detect Override
NOTE UP=DTR Normal DN=DTR always ON UP=Pin 8 DN=Always ON
NOTE 2...Verbal/Numeric Result Codes 7...Single/Multiple Phone
NOTE UP=Verbal DN=Numeric UP=Single DN=Multiple
NOTE 3...Result Code Display 8...Command Set Recognition
NOTE UP=No Display DN=Display UP=Dumb Mode DN=Smart Mode
NOTE 4...Command Mode Local Echo 9...Normal Mode Escape Code op.
NOTE UP=Echo DN=No Echo UP=Hang Up DN=Keep Connect
NOTE 5...Auto Answer 10...Power-on Software Defaults
NOTE UP=AA 1st ring DN=No AA UP=Use NRAM DN=Use ROM
NOTE
NOTE Quad Switch: Send/Receive UP=Pin2 Xmit/Pin3 Rcv DN=Pin2 Rcv/Pin3 Xmit
GOTO CONTINUE
DISPFONE:
CLRSCR
DISPLAYLN "RAM-STORED NUMBERS (BLANK INDICATES NO NUMBER STORED)"
GOTOXY 1,3
FLUSH ALL
SEND "AT&Z0?{"
GETX 0 36 "^M"
;DISPLAY "[$0]"
GETX 0 36 "^M"
;DISPLAY "[$0]"
GETX 0 36 "^M"
;DISPLAY "[$0]"
GETX 0 36 "^M"
;DISPLAY "[$0]"
GETX 9 36 "^M"
;DISPLAY "[$9]"
GETX 9 36 "^M"
;DISPLAY "[$9]"
DISPLAYLN " "
FLUSH ALL
DELAY 800
SEND "AT&Z1?{"
GETX 1 36 "^M"
;DISPLAY "[$1]"
GETX 1 36 "^M"
;DISPLAY "[$1]"
GETX 1 36 "^M"
;DISPLAY "[$1]"
GETX 1 36 "^M"
;DISPLAY "[$1]"
GETX 9 36 "^M"
;DISPLAY "[$9]"
GETX 9 36 "^M"
;DISPLAY "[$9]"
DISPLAYLN " "
FLUSH ALL
DELAY 800
SEND "AT&Z2?{"
GETX 2 36 "^M"
;DISPLAY "[$2]"
GETX 2 36 "^M"
;DISPLAY "[$2]"
GETX 2 36 "^M"
;DISPLAY "[$2]"
GETX 2 36 "^M"
;DISPLAY "[$2]"
GETX 9 36 "^M"
;DISPLAY "[$9]"
GETX 9 36 "^M"
;DISPLAY "[$9]"
DISPLAYLN " "
FLUSH ALL
DELAY 800
SEND "AT&Z3?{"
GETX 3 36 "^M"
;DISPLAY "[$3]"
GETX 3 36 "^M"
;DISPLAY "[$3]"
GETX 3 36 "^M"
;DISPLAY "[$3]"
GETX 3 36 "^M"
;DISPLAY "[$3]"
GETX 9 36 "^M"
;DISPLAY "[$9]"
GETX 9 36 "^M"
;DISPLAY "[$9]"
DISPLAYLN " "
DISPLAYLN "NUMBER 0: $0"
DISPLAYLN "NUMBER 1: $1"
DISPLAYLN "NUMBER 2: $2"
DISPLAYLN "NUMBER 3: $3"
ASKNUM:
GOTOXY 1,16
DISPLAY "Number to change (0-3) or (Enter) to leave unchanged: "
GOTOXY 54,16
GET 0 1
IF "$0" = "" CONTINUE
IF "$0" < "0" ASKNUM
IF "$0" > "3" ASKNUM
GOTOXY 1,18
DISPLAY "Enter new number (36 pos.max.) ...................................."
GOTOXY 32,18
GET 1 36
SEND "AT&Z$0=$1{"
GOTOXY 1,22
DISPLAYLN "New number has been stored in RAM at position $0"
DELAY 2000
GOTO DISPFONE
WRTNRAM:
CLRSCR
DISPLAYLN "WRITING CHANGES TO NRAM MAY CHANGE YOUR POWER-UP MODEM DEFAULTS."
ASKREW:
GOTOXY 1,3
DISPLAYLN "Do you wish to continue (Y/N): "
GOTOXY 31,3
GET 0 1
IF "$0" = "Y" REWRTRAM
IF "$0" = "N" CONTINUE
BEEP 400
GOTO ASKREW
REWRTRAM:
SEND "AT&W{"
TIMEOUT 10 TOOLONG
WAITFOR "OK"
GOTO NRAM
INTEST:
CLRSCR
DISPLAYLN "PC/MODEM INTERFACE TEST: If the Modem/PC Interface is functional,"
DISPLAYLN "the modem will respond with 'OK'..."
PAUSE $WAIT1
SEND "AT{"
TIMEOUT 10 TOOLONG
WAITFOR "OK"
GOTO CONTINUE
ANLOOP:
CLRSCR
DISPLAYLN "ANALOG LOOPBACK SELF-TEST OF THE HST MODEM: The HST will"
DISPLAYLN "modulate and demodulate its own internal test pattern and return"
DISPLAYLN "the pattern to the screen. The first step, upon success, will"
DISPLAYLN "display 'CONNECT 2400'. The second step will display 'NO CARRIER'"
DISPLAYLN " "
SEND "AT&M0S16=5D{"
TIMEOUT 20 TOOLONG
WAITFOR "CONNECT 2400"
PAUSE 3000
SEND "X"
TIMEOUT 20 TOOLONG
WAITFOR "NO CARRIER"
DISPLAYLN " "
SEND "AT&M4S16=0{"
TIMEOUT 20 TOOLONG
WAITFOR "OK"
GOTO CONTINUE
FREQTEST:
CLRSCR
DISPLAYLN "EXERCISING THE ANSWER FREQUENCY OF THE HST. In a stand-alone mode,"
DISPLAYLN "the modem will return a 'NO CARRIER' response to this command."
SEND "AT&MOS16=5A{"
TIMEOUT 20 TOOLONG
WAITFOR "NO CARRIER"
DISPLAYLN " "
SEND "AT&M4S16=0{"
TIMEOUT 20 TOOLONG
WAITFOR "OK"
GOTO CONTINUE
DATAMODE:
CLRSCR
DISPLAYLN "RESET STANDARD HST DATA MODE. This function will reset the HST"
DISPLAYLN "modem error control and data mode defaults for normal operation."
DISPLAYLN " "
SEND "AT&M4S16=0{"
TIMEOUT 20 TOOLONG
WAITFOR "OK"
GOTO CONTINUE
PCBDEF:
ASSIGN QMBS "1"
CLRSCR
FLUSH ALL
DISPLAYLN "MODEM SWITCH SETTINGS FOR PCBOARD 12.X HOST OPERATIONS"
DISPLAYLN " "
DISPLAYLN " ▄ ▄ "
DISPLAYLN " ┌──────┐┌─┬─┬─┬─┬─┬─┬─┬─┬─┬─┐"
DISPLAYLN " UP│██████││█│█│ │ │█│█│█│ │█│█│"
DISPLAYLN " DN│ ││ │ │█│█│ │ │ │█│ │ │"
DISPLAYLN " └──────┘└─┴─┴─┴─┴─┴─┴─┴─┴─┴─┘"
DISPLAYLN " ▀ ▀ 1 2 3 4 5 6 7 8 9 10"
DISPLAYLN " "
DISPLAYLN "NOTE: Switch 7 setting may be changed if you are running"
DISPLAYLN " a multi-phone operation"
DISPLAYLN " "
DISPLAYLN "Press <Enter> to continue with other modem parameters"
GET 1 1
CLRSCR
DISPLAYLN "This function will set all modem operational parameters and"
DISPLAYLN "S-Registers to their optimum values for 19200 bps operation"
DISPLAYLN "when using PCBoard 12.x software. The settings implemented"
DISPLAYLN "via this option are consistent with the HST settings used by"
DISPLAYLN "Clark Development's PCBMODEM program."
GOTO REJOIN
QMDMDEF:
ASSIGN QMBS "0"
FLUSH ALL
CLRSCR
DISPLAYLN "MODEM SWITCH SETTINGS FOR QMODEM 3.1X ORIGINATE OPERATIONS"
DISPLAYLN " "
DISPLAYLN " ▄ ▄ "
DISPLAYLN " ┌──────┐┌─┬─┬─┬─┬─┬─┬─┬─┬─┬─┐"
DISPLAYLN " UP│██████││ │█│ │ │ │█│█│ │ │█│"
DISPLAYLN " DN│ ││█│ │█│█│█│ │ │█│█│ │"
DISPLAYLN " └──────┘└─┴─┴─┴─┴─┴─┴─┴─┴─┴─┘"
DISPLAYLN " ▀ ▀ 1 2 3 4 5 6 7 8 9 10"
DISPLAYLN " "
DISPLAYLN "Press <Enter> to continue with other modem parameters"
GET 1 1
CLRSCR
DISPLAYLN "This function will set all modem operational parameters and"
DISPLAYLN "S-Registers to their optimum values for 19200 bps operation"
DISPLAYLN "when using Qmodem SST 3.1A in originate mode when communicating"
DISPLAYLN "with PCBoard 12.x HST-equipped Bulletin Board Systems."
REJOIN:
DISPLAYLN " "
DISPLAYLN "You May chose the 'FAST' method which will set all parameters"
DISPLAYLN "at once without any accompanying display, or the 'SLOW' method"
DISPLAYLN "which walks you throught the process one parameter at a time."
DISPLAYLN "The SLOW method may take a couple minutes to complete."
DISPLAYLN " "
DISPLAY "Type 'F' for FAST method, 'S' for SLOW, (null) to abort"
ASKFAST1:
GOTOXY 1,13
GET 0 1
IF "$0" = "" CONTINUE
IF "$0" = "F" FASTSET1
IF "$0" = "S" SLOWSET1
BEEP 400
GOTO ASKFAST1
SLOWSET1:
CLRSCR
DISPLAYLN "SET TRANSMITTER ENABLED : ATC1"
SEND "ATC1{"
TIMEOUT 10 TOOLONG
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "SET COMMAND MODE ECHO OFF: ATE0"
SEND "ATE0{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "SET LOCAL ECHO OFF AFTER CONNECT: ATF1"
SEND "ATF1{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
IF "$QMBS" = "1" SETM0
DISPLAYLN "SET SPEAKER ON UNTIL CARRIER ESTABLISHED: ATM1"
SEND "ATM1{"
WAITFOR "OK"
PAUSE 1500
GOTO SETQ
SETM0:
DISPLAYLN "DISABLE SPEAKER: ATM0"
SEND "ATM0{"
WAITFOR "OK"
PAUSE 1500
SETQ:
CLRSCR
DISPLAYLN "SET QUIET MODE OFF-RESULT CODES DISPLAYED: ATQ0"
SEND "ATQ0{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "SET RESULTS TO VERBAL MODE: ATV1"
SEND "ATV1{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "SET EXTENDED RESULT CODE OPTION: ATX6"
SEND "ATX6{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "SET U.S. ANSWER SEQUENCE DEFAULT: ATB1"
SEND "ATB1{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "EXTENDED FUNCTION-ENABLE ARQ RESULT CODE: AT&A1"
SEND "AT&A1{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "EXTENDED FUNCTION-FIX DTE RATE: AT&B1"
SEND "AT&B1{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "EXTENDED FUNCTION-XMIT DATA CTS HARDWARE/SOFTWARE FLOW CONTROL: AT&H3"
SEND "AT&H3{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "EXTENDED FUNCTION-RCV DATA FLOW CONTROL DISABLED: AT&I0"
SEND "AT&I0{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "EXTENDED FUNCTION-ERROR CONTROL MODE NORMAL/ARQ: AT&M4"
SEND "AT&M4{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "EXTENDED FUNCTION-DATA RATE SET TO NORMAL LINK OPERATIONS: AT&N0"
SEND "AT&N0{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "EXTENDED FUNCTION-SET PULSE DIAL MAKE/BREAK RATIO TO U.S.: AT&P0"
SEND "AT&P0{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "EXTENDED FUNCTION-RCV DATA FLOW CONTROL->PASS ON RTS HIGH: AT&R2"
SEND "AT&R2{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "EXTENDED FUNCTION-MODEM CONTROLS DATA SET READY LINE: AT&S1"
SEND "AT&S1{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "EXTENDED FUNCTION-SEND DESTRUCTIVE, EXPEDITED BREAKS: AT&Y1"
SEND "AT&Y1{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "S-REGISTER- SET ZERO RINGS BEFORE AUTO ANSWER: ATS0=0"
SEND "ATS0=0{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "S-REGISTER- SET INCOMING RING COUNT TO ZERO: ATS1=0"
SEND "ATS1=0{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
IF "$QMBS" = "1" SETS2
DISPLAYLN "S-REGISTER- SET ASCII ESCAPE CODE DEFAULT TO '+': ATS2=43"
SEND "ATS2=43{"
WAITFOR "OK"
PAUSE 1500
GOTO SETS3
SETS2:
DISPLAYLN "S-REGISTER- SET ASCII ESCAPE CODE DEFAULT TO X'FF': ATS2=255"
SEND "ATS2=255{"
WAITFOR "OK"
PAUSE 1500
SETS3:
CLRSCR
DISPLAYLN "S-REGISTER- SET ASCII CARRIAGE RETURN TO 13: ATS3=13"
SEND "ATS3=13{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "S-REGISTER- SET ASCII LINE FEED TO 10: ATS4=10"
SEND "ATS4=10{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "S-REGISTER- SET ASCII BACKSPACE TO 8: ATS5=8"
SEND "ATS5=8{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "S-REGISTER- SET #SECONDS MODEM WAITS BEFORE DIALING T0 2: ATS6=2"
SEND "ATS6=2{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "S-REGISTER- SET #SECONDS MODEM WAITS FOR CARRIER TO 30: ATS7=30"
SEND "ATS7=30{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "S-REGISTER- SET DURATION OF PAUSE (,) TO 2/10TH SECOND: ATS8=2"
SEND "ATS8=2{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "S-REGISTER- REQUIRED DURATION OF REMOTE CARRIER 6/10TH SEC: ATS9=6"
SEND "ATS9=6{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "S-REGISTER- HANG UP 7/10TH SEC AFTER LOSS OF CARRIER: ATS10=7"
SEND "ATS10=7{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "S-REGISTER- TOUCH-TONE DURATION AND SPACING IS 70 MILLISECS: ATS11=70"
SEND "ATS11=70{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "S-REGISTER- ESCAPE CODE SEQUENCE GUARD TIME IS 50 MICSSECS: ATS12=50"
SEND "ATS12=50{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "S-REGISTER- SET BIT-MAPPED REGISTER TO ZERO: ATS13=0"
SEND "ATS13=0{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "S-REGISTER- SET SELF-TEST REGISTER TO DATA MODE (NO TEST): ATS16=0"
SEND "ATS16=0{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "S-REGISTER- SET ARQ LINK DISCONNECT REASON REGISTER TO ZERO: ATS17=0"
SEND "ATS17=0{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
IF "$QMBS" = "1" SETS20
DISPLAYLN "S-REGISTER- SET INACTIVITY TIMER TO ZERO (NO AUTO HANGUP): ATS19=0"
SEND "ATS19=0{"
WAITFOR "OK"
PAUSE 1500
GOTO SETS20
SETS20:
DISPLAYLN "S-REGISTER- SET INACTIVITY TIMER TO FIVE MINUTE AUTO HANGUP: ATS19=5"
SEND "ATS19=5{"
WAITFOR "OK"
PAUSE 1500
SETS20:
CLRSCR
DISPLAYLN "S-REGISTER- SET NP CARRIER REASON CODE REGISTER TO ZERO: ATS20=0"
SEND "ATS20=0{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "S-REGISTER- SET LENGTH OF BREAKS TO 100 MILLISECONDS: ATS21=10"
SEND "ATS21=10{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "S-REGISTER- SET ASCII VALUE OF XON TO 17: ATS22=17"
SEND "ATS22=17{"
WAITFOR "OK"
PAUSE 1500
CLRSCR
DISPLAYLN "S-REGISTER- SET ASCII VALUE OF XOFF TO 19: ATS23=19"
SEND "ATS23=19{"
WAITFOR "OK"
PAUSE 1500
GOTO WRITEPARMS
FASTSET1:
CLRSCR
IF "$QMBS" = "1" FASTSET2
DISPLAYLN "SENDING QMODEM SETUP PARAMETERS TO HST MODEM......."
DISPLAYLN " "
SEND "AT C1 E0 F1 M1 Q0 V1 X7 B1{"
TIMEOUT 10 TOOLONG
WAITFOR "OK"
SEND "AT &A1 &B1 &G0 &H1 &I0 &M4 &N0 &P0 &R2 &S1 &Y1{"
WAITFOR "OK"
SEND "AT S0=0 S1=0 S2=43 S3=13 S4=10 S5=8 S6=2 S7=60 S8=2{"
WAITFOR "OK"
SEND "AT S9=6 S10=7 S11=70 S12=50 S13=0 S16=0 S17=0{"
WAITFOR "OK"
SEND "AT S19=0 S20=0 S21=10 S22=17 S23=19{"
WAITFOR "OK"
PAUSE 1500
GOTO WRITEPARMS
FASTSET2:
DISPLAYLN "SENDING PCB SETUP PARAMETERS TO HST MODEM......."
DISPLAYLN " "
SEND "AT C1 E0 F1 M0 Q0 V1 X7 B1{"
TIMEOUT 10 TOOLONG
WAITFOR "OK"
SEND "AT &A1 &B1 &G0 &H3 &I0 &M4 &N0 &P0 &R2 &S1 &Y1{"
WAITFOR "OK"
SEND "AT S0=0 S1=0 S2=255 S3=13 S4=10 S5=8 S6=2 S7=30 S8=2{"
WAITFOR "OK"
SEND "AT S9=6 S10=7 S11=70 S12=50 S13=0 S16=0 S17=0{"
WAITFOR "OK"
SEND "AT S19=5 S20=0 S21=10 S22=17 S23=19{"
WAITFOR "OK"
PAUSE 1500
GOTO WRITEPARMS
WRITEPARMS:
CLRSCR
DISPLAYLN "ALL DEFAULTS HAVE BEEN SET...."
DISPLAYLN " "
DISPLAYLN "Y to write defaults to NRAM"
DISPLAYLN "N to abort"
ASKDEFYN:
GOTOXY 1,5
DISPLAYLN "Type Y/N and (Enter) "
GOTOXY 22,5
GET 1 1
IF "$1" = "Y" WRITEDEF
IF "$1" = "N" CONTINUE
BEEP 400
GOTO ASKDEFYN
WRITEDEF:
SEND "AT&W{"
TIMEOUT 10 TOOLONG
WAITFOR "OK"
CLRSCR
DISPLAYLN "If you changed switch settings 2,3,4,5 OR 9, a hardware reset"
DISPLAYLN "must be performed for the new switch settings to go into effect."
DISPLAYLN "(hardware reset can be done now or later via power-off/power-on)."
DISPLAYLN " "
DISPLAY "Do you wish a hardware reset to be performed now (Y/N): "
ASKRESET:
GET 1 1
IF "$1" = "Y" RESET
IF "$1" = "N" CONTINUE
BEEP 400
GOTO ASKRESET
RESET:
CLRSCR
DISPLAYLN "RESETTING HARDWARE TO NRAM AND NEW SWITCH SETTINGS"
SEND "ATZ{"
TIMEOUT 10 TOOLONG
WAITFOR "OK"
GOTO CONTINUE
DISCOMP:
CLRSCR
DISPLAYLN "DISABLE MNP LEVEL 5 DATA COMPRESSION - AT&K0"
SEND "AT&K0{"
TIMEOUT 10 TOOLONG
WAITFOR "OK"
GOTO CONTINUE
AUTOCOMP:
CLRSCR
DISPLAYLN "AUTO ENABLE/DISABLE MNP LEVEL 5 DATA COMPRESSION - AT&K1"
SEND "AT&K1{"
TIMEOUT 10 TOOLONG
WAITFOR "OK"
GOTO CONTINUE
ENACOMP:
CLRSCR
DISPLAYLN "FORCE ENABLE MNP LEVEL 5 DATA COMPRESSION - AT&K2"
SEND "AT&K2{"
TIMEOUT 10 TOOLONG
WAITFOR "OK"
GOTO CONTINUE
S15REG:
CLRSCR
DISPLAYLN "ROM LEVEL 964 - S-REGISTER 15 SETTINGS"
DISPLAYLN "S-register 15 controls many of the level 964 ROM features. Each bit"
DISPLAYLN "in the register controls a modem feature or function, as shown below"
DISPLAYLN "The corresponding bit value precedes each feature description."
DISPLAYLN "To select a feature, add its bit value to the total and store the"
DISPLAYLN "the total in the register. The max S15 value is 91 (64+16+8+2+1)."
DISPLAYLN " "
DISPLAYLN "Bit value 1: disable high-frequency equalization if it causes"
DISPLAYLN " problems on shorter-link calls"
DISPLAYLN "Bit value 2: disable 7200/4800bps online fallback"
DISPLAYLN "Bit value 4: Reserved"
DISPLAYLN "Bit value 8: use 128-byte buffer in non-MNP operation"
DISPLAYLN "Bit Value 16: disable MNP Service Class (Level 4). Retransmitting"
DISPLAYLN " the larger level 4 data blocks may be a problem when"
DISPLAYLN " you expect a great number of errors during a call."
DISPLAYLN "Bit Value 32: Reserved"
DISPLAYLN "Bit Value 64: Turn this bit on if you are unable to connect with a"
DISPLAYLN " 'MNP-compatible' modem at 2400bps. Certain MNP modems"
DISPLAYLN " are not fully compatible with the Microcom standard."
DISPLAYLN "Bit Value 128: Reserved"
DISPLAYLN " "
DISPLAYLN "Do you wish to change the value of S-register 15 (Y/N)?"
GET 0 1
IF "$0" = "Y" SETS15
GOTO CONTINUE
SETS15:
GOTOXY 1,22
DISPLAYLN "New total bit value for S-register 15 (0-91) or <Enter> to abort: "
GOTOXY 67,22
GET 1 2
IF "$1" = "" CONTINUE
IF "$1" < "0" BADS15
IF "$1" > "91" BADS15
CLRSCR
DISPLAYLN "SETTING NEW S-REGISTER 15 VALUE - ATS15=$1"
DISPLAYLN " "
SEND "ATS15=$1{"
TIMEOUT 10 TOOLONG
WAITFOR "OK"
GOTO CONTINUE
NEWRATE:
CLRSCR
DISPLAYLN "MODEM LINK RATE SETTINGS - AT&Nx"
DISPLAYLN " "
DISPLAYLN "This command allows you to set the modem LINK rate (the data rate "
DISPLAYLN "on the modem-modem connection) to a FIXED value between 300cps and"
DISPLAYLN "9600cps. Normally, the default (&N0) allows the modem to adapt its"
DISPLAYLN "rate to that of the receiving modem. Forcing a fixed link rate "
DISPLAYLN "will cause your modem to disconnect if the other modem is not set "
DISPLAYLN "at the same rate. Unless you have a need for this feature, use of "
DISPLAYLN "the default value is recommended."
DISPLAYLN " "
ASKRATE:
DISPLAYLN "Do you want to change the modem's link rate setting (Y/N): "
GOTOXY 59,11
GET 1 1
IF "$1" = "Y" CHGRATE
IF "$1" = "N" CONTINUE
BEEP 400
GOTO ASKRATE
CHGRATE:
CLRSCR
DISPLAYLN "CHANGE LINK RATE SETTING - AT&Nx"
DISPLAYLN " "
DISPLAYLN "0=set link rate to DEFAULT - AUTO SPEED DETECT"
DISPLAYLN "1=set link rate to 300bps"
DISPLAYLN "2=set link rate to 1200bps"
DISPLAYLN "3=set link rate to 2400bps"
DISPLAYLN "4=set link rate to 4800bps"
DISPLAYLN "5=set link rate to 7200bps"
DISPLAYLN "6=set link rate to 9600bps"
ASKRATE2:
GOTOXY 1,11
DISPLAYLN "Enter new link rate value (0-6) or <Enter> to abort: "
GOTOXY 53,11
GET 1 1
IF "$1" = "" CONTINUE
IF "$1" = "0" SETZERO
IF "$1" = "1" SET300
IF "$1" = "2" SET1200
IF "$1" = "3" SET2400
IF "$1" = "4" SET4800
IF "$1" = "5" SET7200
IF "$1" = "6" SET9600
BEEP 400
GOTO ASKRATE2
SETZERO:
ASSIGN 9 "AUTO"
GOTO SETLRATE
SET300:
ASSIGN 9 "300"
GOTO SETLRATE
SET1200:
ASSIGN 9 "1200"
GOTO SETLRATE
SET2400:
ASSIGN 9 "2400"
GOTO SETLRATE
SET4800:
ASSIGN 9 "4800"
GOTO SETLRATE
SET7200:
ASSIGN 9 "7200"
GOTO SETLRATE
SET9600:
ASSIGN 9 "9600"
SETLRATE:
CLRSCR
DISPLAYLN "SETTING NEW LINK RATE TO $9 BPS - AT&N$1"
DISPLAYLN " "
SEND "AT&N$1{"
TIMEOUT 10 TOOLONG
WAITFOR "OK"
GOTO CONTINUE
MODINQ:
CLRSCR
DISPLAYLN "MODEM CONFIGURATION INQUIRY SCREEN - ATI7"
DISPLAYLN " "
SEND "ATI7{"
TIMEOUT 30 TOOLONG
WAITFOR "OK"
GOTO CONTINUE
FIRST:
FLUSH ALL
GETSCR
CLRSCR
ASSIGN 5 000
IF $ONLINE NOGOOD
TIMEOUT 10 NOTUSR
WHEN "961" ROM961
WHEN "963" ROM963
WHEN "964" ROM964
FLUSH ALL
SEND "ATI0{"
WAITFOR "OK"
CLRSCR
GOTO USROK
NOTUSR:
CLRSCR
DISPLAYLN "Sorry, your modem is not a USRobotics Courier HST or"
DISPLAYLN "the ROM level is higher than 964 or lower than 961."
DISPLAYLN "HST Service Script aborted."
PAUSE 2000
GOTO GETOUT
ROM961:
ASSIGN 5 961
GOTO USROK
ROM963:
ASSIGN 5 963
GOTO USROK
ROM964:
ASSIGN 5 964
GOTO USROK
NORESP:
CLRSCR
DISPLAYLN "WAITFOR timeout: expected response not received after 20 seconds"
DISPLAYLN "Script aborted...."
GOTO GETOUT
USROK:
TIMEOUT 10 TOOLONG
WAITFOR "OK"
IF "$5" = "000" NOTUSR
WHEN
SETCOMM CJLM
SEND "AT&B0{"
WAITFOR "OK"
TURNOFF ECHO
TURNOFF LINEFEED
TURNON ECHO
CLRSCR
STARTER:
WINDOW 1 1 80 24
WRTSCR:
CLRSCR
NOTE ┌────────────────────────────────────────────┐
NOTE ╒═════════════╡ USR COURIER HST MODEM SERVICE SCRIPT v 1.7 ╞═════════════╕
NOTE │ └────────────────────────────────────────────┘ │
NOTE │ 1. Display HST ROM Level 13. Check Modem-PC Interface │
NOTE │ 2. Display HST Memory Checksum 14. Self-Test: Analog Loopback │
NOTE │ 3. HST RAM Test 15. Self-Test: Answer Frequency │
NOTE │ 4. Display HST RAM Settings 16. Self-Test: Reset Data Mode │
NOTE │ 5. Display HST NRAM Settings 17. Reset Modem to NRAM Default │
NOTE │ 6. Display/Set Internal TOD Clock 18. Copy RAM Settings to NRAM │
NOTE │ 7. Display/Store Internal Phone #s 19. Dial a number & exit │
NOTE │ 8. Display Basic Command Help 20. Link Diagnostics display │
NOTE │ 9. Display Extended Command Help │
NOTE │ 10. Display Dial Command Help │
NOTE │ 11. Display S-Register Help QM. Set Qmodem 3.1 defaults │
NOTE │ 12. Display Modem Switch Help PC. Set PCboard 12.x defaults │
NOTE │ 99. EXIT │
NOTE ╞════════════════════════════════════════════════════════════════════════╡
NOTE │ │
NOTE │ Type desired function code and (Enter): __ │
NOTE │ ┌──────────┐ ┌────────────────────┐ │
NOTE ╘═╡ DPM 1988 ╞═══════════════════════════════════╡ HST ROM Level: ╞══╛
NOTE └──────────┘ └────────────────────┘
GOTOXY 70,21
DISPLAY "$5"
IF "$5" < "964" NOADV
GOTOXY 45,13
DISPLAY "AD. Advanced Functions"
NOADV:
GETSCR
ASSIGN MENU "1"
GOTO GETFUNC
NOGOOD:
CLRSCR
NOTE This Script MUST be run OFFLINE (while in terminal mode)
NOTE Script aborted due to above error.
EXIT
ADVANCED:
CLRSCR
IF "$5" >= "964" ADVOK
NOTE Your USR HST Modem is at ROM level $5.
NOTE Advanced functions require ROM level 964 or higher.
NOTE
NOTE Press <Enter> to return to menu.....
GOTO CONTINUE
ADVOK:
WINDOW 1 1 80 24
CLRSCR
NOTE ┌────────────────────────────────────────────┐
NOTE ╒═════════════╡ USR COURIER HST MODEM - ADVANCED FUNCTIONS ╞═════════════╕
NOTE │ └────────────────────────────────────────────┘ │
NOTE │ 50. Disable data compression │
NOTE │ 51. Auto enable/disable compression │
NOTE │ 52. Enable data compression │
NOTE │ 53. S15 register settings │
NOTE │ 54. Set modem-to-modem link rate │
NOTE │ 55. Modem configuration inquiry │
NOTE │ │
NOTE │ 98. Return to Main Menu │
NOTE │ 99. EXIT │
NOTE │ │
NOTE │ │
NOTE │ │
NOTE │ │
NOTE ╞════════════════════════════════════════════════════════════════════════╡
NOTE │ │
NOTE │ Type desired function code and (Enter): __ │
NOTE │ ┌──────────┐ ┌────────────────────┐ │
NOTE ╘═╡ DPM 1988 ╞═══════════════════════════════════╡ HST ROM Level: ╞══╛
NOTE └──────────┘ └────────────────────┘
GOTOXY 70,21
DISPLAY "$5"
GETSCR
ASSIGN MENU "2"
GOTO GETFUNC