home *** CD-ROM | disk | FTP | other *** search
/ Gold Fish 3 / goldfish_volume_3.bin / files / dev / obero / oberon / projectoberonsrc / textframes.mod (.txt) < prev    next >
Encoding:
Oberon Text  |  1994-11-16  |  57.5 KB  |  1,246 lines
  1. Syntax10.Scn.Fnt
  2. Syntax10i.Scn.Fnt
  3. Syntax10b.Scn.Fnt
  4. Syntax8.Scn.Fnt
  5. Syntax12.Scn.Fnt
  6. MODULE TextFrames;    (** CAS/MH/HM 20.4.94/NW 12.11.94 **)
  7.     IMPORT Modules, Input, Display, Files, Fonts, Viewers, Oberon, MenuViewers, Texts;
  8.     CONST
  9.         (** update message IDs **)
  10.             replace* = 0; insert* = 1; delete* = 2;
  11.         (** units **)
  12.             mm* = 36000;  Unit* = 10000;
  13.         (** parc options **)
  14.             gridAdj* = 0;  leftAdj* = 1;  rightAdj* = 2;  pageBreak* = 3;    twoColumns* = 4;
  15.         (** maximum number of TAB stops in Parc **)
  16.             MaxTabs* = 32;
  17.         AdjMask = {leftAdj, rightAdj};
  18.         TAB = 9X; LF = 0AX; CR = 0DX; DEL = 7FX; BRK = 0ACX; ShiftBRK = 0ADX; CRSL = 0C4X; CRSR = 0C3X;
  19.         AdjustSpan = 30; MinTabWidth = 3 * mm; StdTabWidth = 4 * mm;
  20.         rightKey = 0; middleKey = 1; leftKey = 2; cancel = {rightKey, middleKey, leftKey};
  21.     TYPE
  22.         Parc* = POINTER TO ParcDesc;
  23.         ParcDesc* = RECORD (Texts.ElemDesc)
  24.             left*: LONGINT;    (** distance from (F.X + F.left); in units **)
  25.             first*: LONGINT;    (** first line indentation from P.left; in units **)
  26.             width*: LONGINT;    (** parc width; in units **)
  27.             lead*: LONGINT;    (** distance to previous line; in units **)
  28.             lsp*: LONGINT;    (** line spacing of text after P; in units **)
  29.             dsr*: LONGINT;    (** descender of text after P; in units **)
  30.             opts*: SET;
  31.             nofTabs*: INTEGER;
  32.             tab*: ARRAY MaxTabs OF LONGINT    (** in units **)
  33.         END;
  34.         TextLine = POINTER TO TextLineDesc;
  35.         Location* = RECORD
  36.             org*, pos*: LONGINT;
  37.             x*, y*, dx*, dy*: INTEGER;
  38.             line: TextLine
  39.         END;
  40.         TextLineDesc = RECORD
  41.             next: TextLine;
  42.             eot: BOOLEAN;                (* contains end of text *)    
  43.             indent: LONGINT;                (* line indentation in units *)
  44.             w, h, dsr: INTEGER;            (* bounding box clipped to frame (w including indent) *)
  45.             w0, nob: INTEGER;            (* unclipped width (including indent), number of contained blanks: nob > 0 if text line wraps around *)
  46.             org, len, span: LONGINT;    (* len ... characters w/o; span ... w/ trailing CR or white space, if any *)
  47.             P: Parc;                            (* last parc before this text line *)
  48.             pbeg: LONGINT                (* position of P *)
  49.         END;
  50.         Frame* = POINTER TO FrameDesc;
  51.         FrameDesc* = RECORD (Display.FrameDesc)
  52.             text*: Texts.Text;
  53.             org*: LONGINT;
  54.             col*, left*, right*, top*, bot*: INTEGER;
  55.             markH*: INTEGER;    (** position of tick mark in scroll bar (< 0 => no tick mark) **)
  56.             barW*: INTEGER;    (** scroll bar width **)
  57.             time*: LONGINT;    (** selection time **)
  58.             hasCar*, hasSel*, showsParcs*: BOOLEAN;    (** caret/selection present; parcs visible **)
  59.             carloc*, selbeg*, selend*: Location;
  60.             focus*: Display.Frame;    (** frame of nested element if this element contains the focus **)
  61.             trailer: TextLine    (* ring with trailer and header *)
  62.         END;
  63.         DisplayMsg* = RECORD (Texts.ElemMsg)
  64.             prepare*: BOOLEAN;
  65.             fnt*: Fonts.Font;
  66.             col*: SHORTINT;
  67.             pos*: LONGINT;    (** position in host text **)
  68.             frame*: Display.Frame;    (** ~prepare => host frame **)
  69.             X0*, Y0*: INTEGER;    (** ~prepare => receiver origin in screen space **)
  70.             indent*: LONGINT;    (** prepare => width already consumed in line, in units **)
  71.             elemFrame*: Display.Frame    (** optional return parameter **)
  72.         END;
  73.         TrackMsg* = RECORD (Texts.ElemMsg)
  74.             X*, Y*: INTEGER;
  75.             keys*: SET;
  76.             fnt*: Fonts.Font;
  77.             col*: SHORTINT;
  78.             pos*: LONGINT;    (** position in host text **)
  79.             frame*: Display.Frame;    (** host frame **)
  80.             X0*, Y0*: INTEGER    (** receiver origin in screen space **)
  81.         END;
  82.         FocusMsg* = RECORD (Texts.ElemMsg)
  83.             focus*: BOOLEAN;    (** whether to focus or to defocus **)
  84.             elemFrame*: Display.Frame;    (** focus/defocus target **)
  85.             frame*: Display.Frame    (** host frame **)
  86.         END;
  87.         NotifyMsg* = RECORD (Display.FrameMsg)
  88.             frame*: Display.Frame    (** host frame **)
  89.         END;
  90.         UpdateMsg* = RECORD (Display.FrameMsg)
  91.             id*: INTEGER;
  92.             text*: Texts.Text;
  93.             beg*, end*: LONGINT
  94.         END;
  95.         InsertElemMsg* = RECORD (Display.FrameMsg)
  96.             e*: Texts.Elem
  97.         END;
  98.         SelectMsg = RECORD (Display.FrameMsg)
  99.             text: Texts.Text;
  100.             beg, end: LONGINT;
  101.             time: LONGINT
  102.         END;
  103.         menuH*, barW*, left*, right*, top*, bot*: INTEGER;
  104.         defParc*: Parc;
  105.         (*shared globals => get rid off in a later version?*)
  106.         W, W0: Texts.Writer;
  107.         B: Texts.Buffer;
  108.         P: Parc;
  109.         pbeg: LONGINT;    (*inv T[pbeg] = P*)
  110.         R: Texts.Reader;
  111.         nextCh: CHAR;    (*inv Base(R) = T => T[Pos(R)-1] = nextCh]*)
  112.         par: Oberon.ParList;
  113.         neutralize: Oberon.ControlMsg;
  114.     PROCEDURE Min (x, y: INTEGER): INTEGER;
  115.     BEGIN IF x < y THEN RETURN x ELSE RETURN y END
  116.     END Min;
  117.     PROCEDURE Max (x, y: INTEGER): INTEGER;
  118.     BEGIN IF x > y THEN RETURN x ELSE RETURN y END
  119.     END Max;
  120.     PROCEDURE MarkMenu (F: Frame);
  121.         VAR R: Texts.Reader; V: Viewers.Viewer; T: Texts.Text; ch: CHAR;
  122.     BEGIN V := Viewers.This(F.X, F.Y);
  123.         IF (V IS MenuViewers.Viewer) & (V.dsc IS Frame) & (F # V.dsc) THEN
  124.             T := V.dsc(Frame).text;
  125.             IF T.len > 0 THEN Texts.OpenReader(R, T, T.len - 1); Texts.Read(R, ch) ELSE ch := 0X END;
  126.             IF ch # "!" THEN Texts.Write(W0, "!"); Texts.Append(T, W0.buf) END
  127.         END
  128.     END MarkMenu;
  129.     (* Element Subframes *)
  130.     PROCEDURE InvertBorder (F: Display.Frame);
  131.     BEGIN
  132.         Display.ReplPattern(Display.white, Display.grey1, F.X-1, F.Y-1, F.W+2, 1, Display.invert);
  133.         Display.ReplPattern(Display.white, Display.grey1, F.X-1, F.Y+F.H, F.W+2, 1, Display.invert);
  134.         Display.ReplPattern(Display.white, Display.grey1, F.X-1, F.Y, 1, F.H, Display.invert);
  135.         Display.ReplPattern(Display.white, Display.grey1, F.X+F.W, F.Y, 1, F.H, Display.invert)
  136.     END InvertBorder;
  137.     PROCEDURE InvalSubFrames (F: Frame; x, y, w, h: INTEGER);    (* removes and suspends all subframes partly in (x, y, w, h) *)
  138.         VAR p, f: Display.Frame; msg: MenuViewers.ModifyMsg;
  139.     BEGIN
  140.         IF (w > 0) & (h > 0) THEN f := F.dsc;
  141.             IF f # NIL THEN p := f; f := p.next END;
  142.             WHILE f # NIL DO
  143.                 IF (f.X < x + w) & (f.X + f.W > x) & (f.Y < y + h) & (f.Y + f.H > y) THEN p.next := f.next;
  144.                     msg.id := MenuViewers.reduce; msg.dY := 0; msg.Y := f.Y; msg.H := 0;
  145.                     f.handle(f, msg)
  146.                 ELSE p := f
  147.                 END;
  148.                 f := p.next
  149.             END;
  150.             f := F.dsc;
  151.             IF (f # NIL) & (f.X < x + w) & (f.X + f.W > x) & (f.Y < y + h) & (f.Y + f.H > y) THEN F.dsc := F.dsc.next;
  152.                 msg.id := MenuViewers.reduce; msg.dY := 0; msg.Y := f.Y; msg.H := 0;
  153.                 f.handle(f, msg)
  154.             END
  155.         END
  156.     END InvalSubFrames;
  157.     PROCEDURE ShiftSubFrames (F: Frame; oldY, newY, h: INTEGER);    (* shift (F.X, oldY, F.W, h) to (F.X, newY, F.W, h) *)
  158.         VAR f: Display.Frame; msg: MenuViewers.ModifyMsg;
  159.     BEGIN
  160.         IF oldY > newY THEN InvalSubFrames(F, F.X, newY, F.W, oldY - newY)
  161.         ELSE InvalSubFrames(F, F.X, oldY + h, F.W, newY - oldY)
  162.         END;
  163.         f := F.dsc;
  164.         WHILE f # NIL DO
  165.             IF (f.Y < oldY + h) & (f.Y + f.H > oldY) THEN INC(f.Y, newY - oldY);
  166.                 msg.id := MenuViewers.reduce; msg.dY := 0; msg.Y := f.Y; msg.H := f.H;
  167.                 f.handle(f, msg)
  168.             END;
  169.             f := f.next
  170.         END
  171.     END ShiftSubFrames;
  172.     PROCEDURE NotifySubFrames (F: Frame; VAR msg: Display.FrameMsg);
  173.         VAR p, f: Display.Frame;
  174.     BEGIN f := F.dsc;
  175.         IF msg IS NotifyMsg THEN msg(NotifyMsg).frame := F END;
  176.         WHILE f # NIL DO p := f; f := f.next; p.handle(p, msg) END
  177.     END NotifySubFrames;
  178.     (* Display Primitives *)
  179.     PROCEDURE DrawCursor (x, y: INTEGER);
  180.     BEGIN Oberon.DrawCursor(Oberon.Mouse, Oberon.Arrow, x, y)
  181.     END DrawCursor;
  182.     PROCEDURE TrackMouse (VAR x, y: INTEGER; VAR keys, keysum: SET);
  183.     BEGIN Input.Mouse(keys, x, y); keysum := keysum + keys; DrawCursor(x, y)
  184.     END TrackMouse;
  185.     PROCEDURE EraseRect (F: Frame; x, y, w, h: INTEGER);
  186.     BEGIN Display.ReplConst(F.col, x, y, w, h, Display.replace); InvalSubFrames(F, x, y, w, h)
  187.     END EraseRect;
  188.     PROCEDURE Erase (F: Frame; x, y, w, h: INTEGER);    (*RemoveMarks optimization*)
  189.     BEGIN
  190.         IF h > 0 THEN Oberon.RemoveMarks(x, y, w, h); EraseRect(F, x, y, w, h) END
  191.     END Erase;
  192.     PROCEDURE Shift (F: Frame; oldY, newY, h: INTEGER);    (*RemoveMarks optimization*)
  193.     BEGIN
  194.         IF (oldY # newY) & (h > 0) THEN
  195.             Oberon.RemoveMarks(F.X + F.left, Min(oldY, newY), F.W - F.left, Max(oldY, newY) + h);
  196.             Display.CopyBlock(F.X + F.left, oldY, F.W - F.left, h, F.X + F.left, newY, Display.replace);
  197.             ShiftSubFrames(F, oldY, newY, h)
  198.         END
  199.     END Shift;
  200.     PROCEDURE InvertCaret (F: Frame);
  201.         VAR loc: Location; bot: INTEGER;
  202.     BEGIN loc := F.carloc; bot := loc.y + loc.line.dsr - 6;
  203.         Display.CopyPatternC(F, Display.white, Display.hook, loc.x, bot, Display.invert)
  204.     END InvertCaret;
  205.     PROCEDURE InvertRect (F: Frame; x, y, w, h: INTEGER);    (*clips to right and bottom frame margin*)
  206.     BEGIN
  207.         IF x + w > F.X + F.W - F.right THEN w := F.X + F.W - F.right - x END;
  208.         IF y >= F.Y + F.bot THEN Display.ReplConst(Display.white, x, y, w, h, Display.invert) END
  209.     END InvertRect;
  210.     PROCEDURE InvertSelection (F: Frame; beg, end: Location);
  211.         VAR t: TextLine; ex, rx, w, py: INTEGER;
  212.     BEGIN
  213.         rx := F.X + F.W - F.right; t := end.line;
  214.         IF t.eot OR (end.pos <= t.org + t.len) THEN ex := end.x ELSE ex := rx END;
  215.         IF beg.line = end.line THEN InvertRect(F, beg.x, beg.y, ex - beg.x, beg.line.h)
  216.         ELSE t := beg.line; py := beg.y; w := F.W - F.left - F.right;
  217.             InvertRect(F, beg.x, py, rx - beg.x, t.h); t := t.next; DEC(py, t.h);
  218.             WHILE t # end.line DO InvertRect(F, F.X + F.left, py, w, t.h); t := t.next; DEC(py, t.h) END;
  219.             InvertRect(F, F.X + F.left, py, ex - (F.X + F.left), t.h)
  220.         END
  221.     END InvertSelection;
  222.     PROCEDURE CoordToPos (F: Frame; mh: INTEGER): LONGINT;
  223.         VAR h: INTEGER;
  224.     BEGIN h := F.H - 1;
  225.         IF h > 0 THEN RETURN (h - mh) * F.text.len DIV h ELSE RETURN 0 END
  226.     END CoordToPos;
  227.     PROCEDURE ShowBar (F: Frame; botH, topH: INTEGER);
  228.     BEGIN
  229.         IF (F.left > F.barW) & (F.barW > 0) THEN
  230.             Display.ReplConst(Display.white, F.X + F.barW - 1, F.Y + botH, 1, topH - botH, Display.replace)
  231.         END
  232.     END ShowBar;
  233.     PROCEDURE Tick (F: Frame);
  234.     BEGIN
  235.         IF (0 <= F.markH) & (F.markH < F.H) & (F.left > F.barW) & (F.barW > 6) & (F.H > 2) THEN
  236.             Display.ReplConst(Display.white, F.X + 1, F.Y + F.markH, F.barW - 6, 2, Display.invert)
  237.         END
  238.     END Tick;
  239.     PROCEDURE ShowTick (F: Frame);    (* removes global marks as needed *)
  240.         VAR h, mh: INTEGER; len: LONGINT;
  241.     BEGIN
  242.         h := F.H - 2; len := F.text.len;
  243.         IF len > 0 THEN mh := SHORT(h - h * F.org DIV len) ELSE mh := h END;
  244.         IF F.markH # mh THEN Oberon.RemoveMarks(F.X, F.Y, F.barW, F.H);
  245.             Tick(F); F.markH := mh; Tick(F)
  246.         END
  247.     END ShowTick;
  248.     PROCEDURE Mark* (F: Frame; mark: INTEGER);
  249.     BEGIN
  250.         Erase(F, F.X, F.Y, F.barW - 1, F.H); F.markH := -1;
  251.         IF (mark < 0) & (F.H >= 16) THEN
  252.             Display.CopyPattern(Display.white, Display.downArrow, F.X, F.Y, Display.invert)
  253.         ELSIF mark > 0 THEN
  254.             ShowTick(F)
  255.         END
  256.     END Mark;
  257.     (** Parcs **)
  258.     PROCEDURE ParcBefore* (T: Texts.Text; pos: LONGINT; VAR P: Parc; VAR beg: LONGINT);
  259.         VAR R: Texts.Reader;
  260.     BEGIN Texts.OpenReader(R, T, pos + 1);
  261.         REPEAT Texts.ReadPrevElem(R) UNTIL R.eot OR (R.elem IS Parc);
  262.         IF R.eot THEN P := defParc; beg := -1 ELSE P := R.elem(Parc); beg := Texts.Pos(R) END
  263.     END ParcBefore;
  264.     PROCEDURE InitDefParc;
  265.     BEGIN
  266.         IF Modules.ThisMod("ParcElems") = NIL THEN HALT(99) END
  267.         (* side effect: body of ParcElems initialises defParc *)
  268.     END InitDefParc;
  269.     (* Screen Metrics *)
  270.     PROCEDURE Tab (dw: INTEGER; VAR dx: INTEGER);    (*P set*)
  271.         (* dw = line width from left margin to caret (in pixels); dx = distance from caret to next tab stop (in pixels) *)
  272.         VAR i, n: INTEGER; w: LONGINT;
  273.     BEGIN
  274.         i := 0; n := P.nofTabs; w := LONG(dw) * Unit + MinTabWidth;
  275.         IF dw < 0 THEN dx := -dw
  276.         ELSE
  277.             WHILE (i < n) & (P.tab[i] < w) DO INC(i) END;
  278.             IF i < n THEN dx := SHORT((P.tab[i] - LONG(dw) * Unit) DIV Unit)
  279.             ELSE dx := StdTabWidth DIV Unit
  280.             END
  281.         END
  282.     END Tab;
  283.     PROCEDURE MeasureSpecial (dw: INTEGER; VAR dx, x, y, w, h: INTEGER);
  284.         (* returns metrics of nextCh (nextCh <= " "); sends prepare message to elements; P, R, nextCh set *)
  285.         VAR e: Texts.Elem; pat: Display.Pattern; msg: DisplayMsg;
  286.     BEGIN
  287.         IF nextCh = " " THEN Display.GetChar(R.fnt.raster, nextCh, dx, x, y, w, h, pat);
  288.             x := 0; y := 0; w := dx; h := 0
  289.         ELSIF nextCh = TAB THEN Tab(dw, dx); x := 0; y := 0; w := dx; h := 0
  290.         ELSIF R.elem # NIL THEN e := R.elem;
  291.             msg.prepare := TRUE; msg.indent := LONG(dw) * Unit;
  292.             msg.fnt := R.fnt; msg.col := R.col; msg.pos := Texts.Pos(R)-1;
  293.             msg.Y0 := -SHORT(P.dsr DIV Unit);    (*<<< 18-Nov-91*)
  294.             e.handle(e, msg);
  295.             w := SHORT(e.W DIV Unit);
  296.             dx := w; x := 0; y := msg.Y0; h := SHORT(e.H DIV Unit)    (*<<< 18-Nov-91*)
  297.         ELSE Display.GetChar(R.fnt.raster, nextCh, dx, x, y, w, h, pat)
  298.         END
  299.     END MeasureSpecial;
  300.     PROCEDURE GetSpecial (F: Frame; VAR n: INTEGER; cn, ddx, dw: INTEGER; VAR dx, x, y, w, h: INTEGER);
  301.         (* returns metrics of nextCh (nextCh <= " "); no prepare message to elements; extends blanks for block adjust *)
  302.         (* cn ... add 1 pixel to first cn blanks (block adjust); ddx ... add ddx pixels to every blank (block adjust) *)
  303.         (*P, R, nextCh set*)
  304.         VAR e: Texts.Elem; pat: Display.Pattern;
  305.     BEGIN
  306.         IF nextCh = " " THEN Display.GetChar(R.fnt.raster, nextCh, dx, x, y, w, h, pat);
  307.             x := 0; y := 0; INC(dx, ddx); INC(n); IF n <= cn THEN INC(dx) END;    (*space correction for block adjustment*)
  308.             w := dx; h := 0
  309.         ELSIF nextCh = TAB THEN Tab(dw, dx); x := 0; y := 0; w := dx; h := 0
  310.         ELSIF R.elem # NIL THEN e := R.elem;
  311.             IF (e IS Parc) & (P.W = 9999 * Unit) THEN (* P gets this value in prepare message *)
  312.                 w := Min(SHORT((P.width + P.left) DIV Unit), F.W - F.right - F.left);
  313.                 e.W := LONG(w) * Unit
  314.             ELSE w := SHORT(e.W DIV Unit)
  315.             END;
  316.             dx := w; x := 0; y := -SHORT(P.dsr DIV Unit); h := SHORT(e.H DIV Unit)
  317.         ELSE Display.GetChar(R.fnt.raster, nextCh, dx, x, y, w, h, pat)
  318.         END
  319.     END GetSpecial;
  320.     PROCEDURE NextLine (T: Texts.Text; VAR org: LONGINT);    (*R, nextCh set; org = Texts.Pos(R)-1*)
  321.         VAR pat: Display.Pattern; pos, bk, d: LONGINT; width, tw, dx, x, y, w, h: INTEGER;
  322.             R1: Texts.Reader; peekCh: CHAR; indent: INTEGER;
  323.     BEGIN
  324.         tw := 0; dx := 0; w := 0; bk := -999;    (* bk = pos of last seperator *)
  325.         pos := org; ParcBefore(T, pos, P, pbeg); width := SHORT(P.width DIV Unit);
  326.         indent := 0;
  327.         IF org > 0 THEN Texts.OpenReader(R1, T, org - 1); Texts.Read(R1, peekCh);
  328.             IF (peekCh = CR) OR (R1.elem # NIL) & (R1.elem IS Parc) THEN indent := SHORT(P.first DIV Unit) END;
  329.         END;
  330.         INC(tw, indent);
  331.         LOOP INC(pos);    (*inv pos = Texts.Pos(R), ~R.eof => nextCh = text[pos-1]*)
  332.             IF R.eot OR (nextCh = CR) THEN EXIT END;
  333.             INC(tw, dx);
  334.             IF nextCh <= " " THEN MeasureSpecial(tw, dx, x, y, w, h)
  335.             ELSE Display.GetChar(R.fnt.raster, nextCh, dx, x, y, w, h, pat)
  336.             END;
  337.             IF tw + x + w > width THEN d := pos - bk;
  338.                 IF (d < AdjustSpan) & (nextCh > " ") THEN pos := bk
  339.                 ELSIF ((nextCh > " ") OR (nextCh = Texts.ElemChar)) & (pos > org + 1) THEN DEC(pos)
  340.                 END;
  341.                 Texts.OpenReader(R, T, pos); Texts.Read(R, nextCh);
  342.                 EXIT
  343.             END;
  344.             IF (nextCh <= " ") & (nextCh # Texts.ElemChar) THEN bk := pos END;
  345.             Texts.Read(R, nextCh)
  346.         END;
  347.         org := pos
  348.     END NextLine;
  349.     PROCEDURE BegOfLine (T: Texts.Text; VAR pos: LONGINT; adjust: BOOLEAN);
  350.         (* returns origin of line containing pos *)
  351.         VAR p, org: LONGINT;
  352.     BEGIN
  353.         IF pos <= 0 THEN pos := 0
  354.         ELSE
  355.             IF pos <= T.len THEN org := pos ELSE org := T.len END;
  356.             LOOP    (*search backwards for CR*)
  357.                 IF org = 0 THEN EXIT END;
  358.                 Texts.OpenReader(R, T, org - 1); Texts.Read(R, nextCh);
  359.                 IF nextCh = CR THEN EXIT END;
  360.                 DEC(org)
  361.             END;
  362.             IF adjust THEN    (*search forward for actual line origin*)
  363.                 Texts.OpenReader(R, T, org); Texts.Read(R, nextCh); p := org;
  364.                 REPEAT org := p; NextLine(T, p) UNTIL (p > pos) OR R.eot
  365.             END;
  366.             pos := org
  367.         END
  368.     END BegOfLine;
  369.     PROCEDURE AdjustMetrics (F: Frame; t: TextLine; VAR pw, tw, ddx, cn: INTEGER);    (*t.org set*)
  370.         (* pw ... x-coord of first char in line (in pixels); tw ... width of text line; ddx, cn ... see GetSpecial *)
  371.     BEGIN
  372.         P := t.P; pbeg := t.pbeg;
  373.         pw := F.left; tw := t.w; ddx := 0; cn := 0;
  374.         IF t.pbeg # t.org THEN
  375.             INC(pw, SHORT((P.left + t.indent) DIV Unit));
  376.             IF leftAdj IN P.opts THEN
  377.                 IF (rightAdj IN P.opts) & (t.nob > 0) THEN
  378.                     tw := SHORT(P.width DIV Unit); ddx := (tw - t.w0) DIV t.nob; cn := (tw - t.w0) MOD t.nob
  379.                 END
  380.             ELSIF rightAdj IN P.opts THEN INC(pw, SHORT(P.width DIV Unit) - t.w0)
  381.             ELSE (*center*) INC(pw, (SHORT(P.width DIV Unit) - t.w0) DIV 2)
  382.             END;
  383.             DEC(tw, SHORT(t.indent DIV Unit));
  384.         END
  385.     END AdjustMetrics;
  386.     (* Screen Placement *)
  387.     PROCEDURE DrawSpecial (F: Frame; px, py, x, y: INTEGER);    (*R, nextCh set*)
  388.         VAR e: Texts.Elem; pat: Display.Pattern; dx, w, h: INTEGER; msg: DisplayMsg;
  389.     BEGIN
  390.         IF (nextCh = TAB) OR (nextCh = CR) THEN (*skip*)
  391.         ELSIF R.elem # NIL THEN e := R.elem;
  392.             IF ~(e IS Parc) OR F.showsParcs THEN
  393.                 msg.prepare := FALSE; msg.fnt := R.fnt; msg.col := R.col; msg.pos := Texts.Pos(R) - 1;
  394.                 msg.frame := F; msg.X0 := px + x; msg.Y0 := py + y; msg.elemFrame := NIL;
  395.                 e.handle(e, msg);
  396.                 IF msg.elemFrame # NIL THEN msg.elemFrame.next := F.dsc; F.dsc := msg.elemFrame END;
  397.             ELSIF pageBreak IN e(Parc).opts THEN (*(e IS Parc) & ~F.showsParcs*)
  398.                 Display.ReplPattern(Display.white, Display.grey1, px + x, py, SHORT(e.W DIV Unit), 1, Display.replace)
  399.             END
  400.         ELSE Display.GetChar(R.fnt.raster, nextCh, dx, x, y, w, h, pat);
  401.             Display.CopyPattern(R.col, pat, px + x, py + y, Display.invert)
  402.         END;
  403.     END DrawSpecial;
  404.     PROCEDURE ShowLine (F: Frame; t: TextLine; left, right, py: INTEGER);
  405.         VAR pat: Display.Pattern; i: LONGINT; n, cn, lm, px, pw, tw, ddx, dx, x, y, w, h: INTEGER;
  406.     BEGIN
  407.         (* lm ... left parc margin in screen coord; pw ...  x of first char in frame coord *)
  408.         Texts.OpenReader(R, F.text, t.org); AdjustMetrics(F, t, pw, tw, ddx, cn);
  409.         lm := F.X + F.left + SHORT(P.left DIV Unit); px := F.X + pw; INC(py, t.dsr); i := 0; n := 0;
  410.         WHILE i < t.len DO Texts.Read(R, nextCh);
  411.             IF nextCh <= " " THEN GetSpecial(F, n, cn, ddx, px - lm, dx, x, y, w, h)
  412.             ELSE Display.GetChar(R.fnt.raster, nextCh, dx, x, y, w, h, pat)
  413.             END;
  414.             INC(y, R.fnt.height * R.voff DIV 64);
  415.             IF px + x + w <= right THEN
  416.                 IF px + x >= left THEN
  417.                     IF nextCh <= " " THEN DrawSpecial(F, px, py, x, y)
  418.                     ELSE Display.CopyPattern(R.col, pat, px + x, py + y, Display.invert)
  419.                     END
  420.                 END;
  421.                 INC(px, dx); INC(i)
  422.             ELSE i := t.len
  423.             END
  424.         END
  425.     END ShowLine;
  426.     PROCEDURE ShowLines (F: Frame; botH, topH: INTEGER; erase: BOOLEAN);
  427.         VAR t: TextLine; ph: INTEGER;
  428.     BEGIN
  429.         t := F.trailer.next; ph := F.H - F.top;
  430.         WHILE (t # F.trailer) & (ph - t.h >= topH) DO DEC(ph, t.h); t := t.next END;
  431.         WHILE (t # F.trailer) & (ph - t.h >= botH) DO DEC(ph, t.h);
  432.             IF erase THEN Erase(F, F.X + F.left, F.Y + ph, F.W - F.right - F.left, t.h) END;
  433.             ShowLine(F, t, F.X + F.left, F.X + F.W - F.right, F.Y + ph); t := t.next
  434.         END
  435.     END ShowLines;
  436.     (* Screen Casting *)
  437.     PROCEDURE MeasureLine (F: Frame; maxW: INTEGER; t: TextLine);    (* R, nextCh set *)
  438.         VAR pat: Display.Pattern; len, bklen, d: LONGINT; eol: BOOLEAN;
  439.             nob, bknob, width, minY, bkminY, maxY, bkmaxY, tw, bktw, lsp, dsr, dx, x, y, w, h: INTEGER;
  440.             R1: Texts.Reader; peekCh: CHAR;
  441.             (* bk* ... backup for last blank *)
  442.     BEGIN
  443.         len := 0; nob := 0; bklen := -999; tw := 0; dx := 0; minY := 0; maxY := 0;
  444.         ParcBefore(F.text, t.org, P, pbeg);
  445.         lsp := SHORT(P.lsp DIV Unit); dsr := SHORT(P.dsr DIV Unit); width := SHORT(P.width DIV Unit);
  446.         t.indent := 0;
  447.         IF t.org > 0 THEN Texts.OpenReader(R1, F.text, t.org - 1); Texts.Read(R1, peekCh);
  448.             IF (peekCh = CR) OR (R1.elem # NIL) & (R1.elem IS Parc) THEN t.indent := P.first END;
  449.         END;
  450.         INC(tw, SHORT(t.indent DIV Unit));
  451.         LOOP
  452.             IF R.eot OR (nextCh = CR) THEN nob := 0; eol := ~R.eot; EXIT END;
  453.             IF nextCh <= " " THEN MeasureSpecial(tw, dx, x, y, w, h)
  454.             ELSE Display.GetChar(R.fnt.raster, nextCh, dx, x, y, w, h, pat)
  455.             END;
  456.             IF tw + x + w > width THEN d := len - bklen;
  457.                 IF (d < AdjustSpan) & (nextCh > " ") THEN eol := TRUE;
  458.                     Texts.OpenReader(R, F.text, Texts.Pos(R) - d);
  459.                     nob := bknob; len := bklen; tw := bktw; minY := bkminY; maxY := bkmaxY
  460.                 ELSIF len = 0 THEN    (* force at least one character on each line *)
  461.                     INC(len); INC(y, R.fnt.height * R.voff DIV 64); minY := Min(minY, y); maxY := Max(maxY, y + h);
  462.                     Texts.Read(R, nextCh); eol := FALSE; tw := maxW
  463.                 ELSE eol := (nextCh <= " ") & (nextCh # Texts.ElemChar)
  464.                 END;
  465.                 EXIT
  466.             END;
  467.             IF (nextCh <= " ") & (nextCh # Texts.ElemChar) THEN
  468.                 bknob := nob; bklen := len; bktw := tw; bkminY := minY; bkmaxY := maxY;
  469.                 IF nextCh = " " THEN INC(nob) END
  470.             END;
  471.             INC(len); INC(tw, dx); INC(y, R.fnt.height * R.voff DIV 64);
  472.             IF y < minY THEN minY := y END;
  473.             IF y + h > maxY THEN maxY := y + h END;
  474.             Texts.Read(R, nextCh)
  475.         END;
  476.         IF ~F.showsParcs & (pbeg = t.org) THEN dsr := 0; t.h := SHORT(P.lead DIV Unit) + 1
  477.         ELSIF gridAdj IN P.opts THEN
  478.             WHILE dsr < -minY DO INC(dsr, lsp) END;
  479.             t.h := Max(lsp, dsr + maxY); INC(t.h, (-t.h) MOD lsp)
  480.         ELSE dsr := Max(dsr, -minY); t.h := Max(lsp, dsr + maxY)
  481.         END;
  482.         t.len := len; t.w0 := tw; t.w := Min(tw, maxW); t.dsr := dsr; t.nob := nob; t.eot := R.eot; t.P := P; t.pbeg := pbeg;
  483.         IF eol THEN Texts.Read(R, nextCh); t.span := len + 1 ELSE t.span := len END
  484.     END MeasureLine;
  485.     PROCEDURE MeasureLines (F: Frame; org: LONGINT; VAR trailer: TextLine);
  486.         VAR s, t: TextLine; ph: INTEGER;
  487.     BEGIN
  488.         NEW(trailer); s := trailer;
  489.         Texts.OpenReader(R, F.text, org); Texts.Read(R, nextCh); ph := F.H - F.top;
  490.         LOOP NEW(t); t.org := org; MeasureLine(F, F.W - F.left - F.right, t);
  491.             IF ph - t.h < F.bot THEN EXIT END;
  492.             s.next := t; s := t; INC(org, s.span); DEC(ph, s.h);
  493.             IF R.eot THEN EXIT END
  494.         END;
  495.         s.next := trailer; trailer.eot := TRUE; trailer.org := org; (* start of first invisible line *) trailer.len := 0; trailer.w := 0;
  496.         trailer.h := SHORT(defParc.lsp DIV Unit); trailer.P := P (* P set by MeasureLine *) ; trailer.pbeg := pbeg
  497.     END MeasureLines;
  498.     (** Locators **)
  499.     PROCEDURE LocateLineTop (F: Frame; trailer: TextLine; org: LONGINT; VAR loc: Location);
  500.         VAR t: TextLine; ph: INTEGER;
  501.     BEGIN
  502.         ph := F.H - F.top; t := trailer.next;
  503.         WHILE (t # trailer) & (t.org # org) DO DEC(ph, t.h); t := t.next END;
  504.         loc.org := org; loc.line := t; loc.y := F.Y + ph
  505.     END LocateLineTop;
  506.     PROCEDURE Width (F: Frame; t: TextLine; pos: LONGINT; VAR pw, dx, dy: INTEGER);
  507.         VAR pat: Display.Pattern; i: LONGINT; n, mw, lm, tw, ddx, cn, x, y, w, h: INTEGER;
  508.     BEGIN
  509.         AdjustMetrics(F, t, pw, tw, ddx, cn); dy := 0; lm := F.left + SHORT(P.left DIV Unit);
  510.         IF t # F.trailer THEN Texts.OpenReader(R, F.text, t.org); Texts.Read(R, nextCh);
  511.             i := 0; n := 0; DEC(pos, t.org); dx := 0; mw := F.W - F.right;
  512.             WHILE ~R.eot & (i < t.len) & (i <= pos) & (pw + dx <= mw) DO
  513.                 (* i ... pos of nextCh; dx ... width of char before nextCh; pw ... line width up to pos (or up to right margin) *)
  514.                 INC(i); INC(pw, dx);
  515.                 IF nextCh <= " " THEN GetSpecial(F, n, cn, ddx, pw - lm, dx, x, y, w, h)
  516.                 ELSE Display.GetChar(R.fnt.raster, nextCh, dx, x, y, w, h, pat)
  517.                 END;
  518.                 dy := R.fnt.height * R.voff DIV 64;
  519.                 Texts.Read(R, nextCh)
  520.             END;
  521.             IF (i <= pos) & (pw + dx <= mw) THEN INC(i); INC(pw, dx) END
  522.         ELSE dx := 4
  523.         END
  524.     END Width;
  525.     PROCEDURE LocatePos* (F: Frame; pos: LONGINT; VAR loc: Location);    (* loc.dx = dx of char at pos *)
  526.         VAR t: TextLine; pw, dx, dy: INTEGER;
  527.     BEGIN
  528.         IF pos < F.org THEN pos := F.org; t := F.trailer.next
  529.         ELSIF pos < F.trailer.org THEN t := F.trailer;
  530.             WHILE (t.next # F.trailer) & (t.next.org <= pos) DO t := t.next END
  531.         ELSE pos := F.trailer.org; t := F.trailer.next;
  532.             WHILE ~t.eot DO t := t.next END
  533.         END;
  534.         Width(F, t, pos, pw, dx, dy); LocateLineTop(F, F.trailer, t.org, loc); DEC(loc.y, loc.line.h);
  535.         loc.org := t.org; loc.pos := pos; loc.x := F.X + pw; loc.dx := dx; loc.dy := dy; loc.line := t
  536.     END LocatePos;
  537.     PROCEDURE LocateLine* (F: Frame; y: INTEGER; VAR loc: Location);
  538.         (* loc.x = line start; loc.y = line bottom; loc.dx = line width *)
  539.         VAR t: TextLine; h, ph, pw, tw, ddx, cn: INTEGER;
  540.     BEGIN
  541.         t := F.trailer.next; h := y - F.Y; ph := F.H - F.top - t.h;
  542.         WHILE ~t.eot & (ph - t.next.h >= F.bot) & (ph > h) DO t := t.next; DEC(ph, t.h) END;
  543.         AdjustMetrics(F, t, pw, tw, ddx, cn);
  544.         IF pw >= F.W - F.right THEN pw := F.W - F.right - 4 END;
  545.         loc.org := t.org; loc.pos := loc.org; loc.x := F.X + pw; loc.y := F.Y + ph; loc.dx := tw; loc.dy := 0; loc.line := t
  546.     END LocateLine;
  547.     PROCEDURE LocateChar* (F: Frame; x, y: INTEGER; VAR loc: Location);
  548.         VAR t: TextLine; pat: Display.Pattern; i: LONGINT; n, w, lm, pw, tw, ddx, cn, dx, xc, yc, wc, hc: INTEGER;
  549.     BEGIN
  550.         LocateLine(F, y, loc); t := loc.line; w := x - F.X; AdjustMetrics(F, t, pw, tw, ddx, cn);
  551.         lm := F.left + SHORT(P.left DIV Unit);
  552.         IF (t # F.trailer) & (w > pw) THEN Texts.OpenReader(R, F.text, t.org);
  553.             i := 0; n := 0; dx := 0; nextCh := 0X;
  554.             WHILE (i < t.len) & (pw + dx < w) DO
  555.                 (* i = pos after nextCh; dx = width of nextCh; pw = line width without nextCh *)
  556.                 Texts.Read(R, nextCh); INC(i); INC(pw, dx);
  557.                 IF nextCh <= " " THEN GetSpecial(F, n, cn, ddx, pw - lm, dx, xc, yc, wc, hc)
  558.                 ELSE Display.GetChar(R.fnt.raster, nextCh, dx, xc, yc, wc, hc, pat)
  559.                 END
  560.             END;
  561.             IF pw + dx < w THEN INC(i); INC(pw, dx); R.elem := NIL END;
  562.             INC(loc.pos, i - 1); loc.x := F.X + pw;
  563.             IF i < t.len THEN loc.dx := dx; loc.dy := R.fnt.height * R.voff DIV 64 ELSE loc.dx := 4 END
  564.         ELSE loc.dx := 4; R.elem := NIL
  565.         END
  566.     END LocateChar;
  567.     PROCEDURE LocateWord* (F: Frame; x, y: INTEGER; VAR loc: Location);
  568.         VAR t: TextLine; pos, i: LONGINT; px, rx: INTEGER; pat: Display.Pattern; dx, xc, yc, wc, hc: INTEGER;
  569.     BEGIN
  570.         LocateChar(F, x, y, loc); pos := loc.pos + 1;
  571.         REPEAT DEC(pos); Texts.OpenReader(R, F.text, pos); Texts.Read(R, nextCh)
  572.         UNTIL (pos < loc.org) OR (nextCh > " ");
  573.         INC(pos);
  574.         REPEAT DEC(pos); Texts.OpenReader(R, F.text, pos); Texts.Read(R, nextCh)
  575.         UNTIL (pos < loc.org) OR (nextCh <= " ");
  576.         LocatePos(F, pos + 1, loc); t := loc.line; i := loc.pos - loc.org;
  577.         IF i < t.len THEN px := loc.x; rx := F.X + F.W - F.right;
  578.             Texts.OpenReader(R, F.text, loc.pos); dx := 0; wc := 0; nextCh := "x";
  579.             WHILE (i < t.len) & (nextCh > " ") & (px + dx < rx) DO
  580.                 Texts.Read(R, nextCh); INC(i); INC(px, dx);
  581.                 Display.GetChar(R.fnt.raster, nextCh, dx, xc, yc, wc, hc, pat)
  582.             END;
  583.             IF (nextCh > " ") & (px + dx < rx) THEN INC(i); INC(px, dx) END;
  584.             loc.dx := px - loc.x
  585.         ELSE loc.dx := 0
  586.         END
  587.     END LocateWord;
  588.     PROCEDURE Pos* (F: Frame; x, y: INTEGER): LONGINT;
  589.         VAR loc: Location;
  590.     BEGIN LocateChar(F, x, y, loc); RETURN loc.pos
  591.     END Pos;
  592.     PROCEDURE ThisSubFrame (F: Frame; x, y: INTEGER): Display.Frame;
  593.         VAR f: Display.Frame;
  594.     BEGIN f := F.dsc;
  595.         WHILE (f # NIL) & ((x < f.X) OR (x >= f.X + f.W) OR (y < f.Y) OR (y >= f.Y + f.H)) DO f := f.next END;
  596.         RETURN f
  597.     END ThisSubFrame;
  598.     (** Caret & Selection **)
  599.     PROCEDURE PassSubFocus (F: Frame; f: Display.Frame);
  600.         (* pass focus from F.focus to f (f is also an element frame in F) *)
  601.         VAR loc: Location; f1: Display.Frame; ctrl: Oberon.ControlMsg; focus: FocusMsg;
  602.     BEGIN
  603.         IF F.focus # NIL THEN f1 := F.focus;
  604.             ctrl.id := Oberon.defocus; f1.handle(f1, ctrl);
  605.             LocateChar(F, f1.X + 1, f1.Y + 1, loc);
  606.             InvertBorder(f1); F.focus := NIL;
  607.             IF R.elem # NIL THEN
  608.                 focus.focus := FALSE; focus.elemFrame := f1; focus.frame := F; R.elem.handle(R.elem, focus)
  609.             END
  610.         END;
  611.         IF f # NIL THEN
  612.             LocateChar(F, f.X + 1, f.Y + 1, loc);    (* side effect: set R to element *)
  613.             focus.focus := TRUE; focus.elemFrame := f; focus.frame := F; R.elem.handle(R.elem, focus);
  614.             InvertBorder(f)
  615.         END;
  616.         F.focus := f
  617.     END PassSubFocus;
  618.     PROCEDURE RemoveSelection* (F: Frame);
  619.     BEGIN
  620.         IF F.hasSel THEN InvertSelection(F, F.selbeg, F.selend); F.hasSel := FALSE END
  621.     END RemoveSelection;
  622.     PROCEDURE SetSelection* (F: Frame; beg, end: LONGINT);    (** forces range to visible bounds **)
  623.         VAR loc: Location;
  624.     BEGIN
  625.         IF end > F.text.len THEN end := F.text.len END;
  626.         IF end > beg THEN
  627.             IF F.hasSel & (F.selbeg.pos = beg) THEN
  628.                 IF (F.selend.pos < end) & (F.selend.pos < F.trailer.org) THEN
  629.                     LocatePos(F, F.selend.pos, loc); LocatePos(F, end, F.selend); InvertSelection(F, loc, F.selend)
  630.                 ELSIF end < F.selend.pos THEN
  631.                     LocatePos(F, end, loc); InvertSelection(F, loc, F.selend); LocatePos(F, end, F.selend)
  632.                 END
  633.             ELSE RemoveSelection(F); PassSubFocus(F, NIL);
  634.                 LocatePos(F, beg, F.selbeg); LocatePos(F, end, F.selend); InvertSelection(F, F.selbeg, F.selend)
  635.             END;
  636.             F.hasSel := TRUE; F.time := Oberon.Time()
  637.         END
  638.     END SetSelection;
  639.     PROCEDURE RemoveCaret* (F: Frame);
  640.         VAR msg: Oberon.ControlMsg;
  641.     BEGIN
  642.         IF F.focus # NIL THEN msg.id := Oberon.defocus; F.focus.handle(F.focus, msg) END;
  643.         IF F.hasCar THEN InvertCaret(F); F.hasCar := FALSE END
  644.     END RemoveCaret;
  645.     PROCEDURE SetCaret* (F: Frame; pos: LONGINT);    (** only done if within visible bounds **)
  646.     BEGIN
  647.         IF ~F.hasCar OR (F.carloc.pos # pos) THEN RemoveCaret(F); PassSubFocus(F, NIL);
  648.             LocatePos(F, pos, F.carloc);
  649.             IF F.carloc.x <= F.X + F.W - F.right THEN InvertCaret(F); F.hasCar := TRUE END
  650.         END
  651.     END SetCaret;
  652.     (** Display Range **)
  653.     PROCEDURE Complete (F: Frame; trailer: TextLine; s: TextLine; org: LONGINT; ph: INTEGER);
  654.         VAR u: TextLine;
  655.     BEGIN
  656.         IF ph > F.bot THEN    (*try to add new lines to the bottom*)
  657.             Texts.OpenReader(R, F.text, org); Texts.Read(R, nextCh);
  658.             LOOP
  659.                 IF R.eot THEN EXIT END;
  660.                 NEW(u); u.org := org; MeasureLine(F, F.W - F.left - F.right, u);
  661.                 IF ph - u.h < F.bot THEN EXIT END;
  662.                 s.next := u; s := s.next; DEC(ph, s.h); INC(org, s.span)
  663.             END
  664.         END;
  665.         s.next := trailer; trailer.eot := TRUE; trailer.org := org; trailer.len := 0; trailer.w := 0;
  666.         trailer.h := SHORT(defParc.lsp DIV Unit); trailer.P := P; trailer.pbeg := pbeg
  667.     END Complete;
  668.     PROCEDURE ShowFrom (F: Frame; pos: LONGINT);    (* removes global marks as needed and neutralizes F *)
  669.         VAR new, s: TextLine; beg, end: Location; org: LONGINT; ph, y0, dy: INTEGER;
  670.     BEGIN
  671.         F.handle(F, neutralize);
  672.         IF (F.trailer # NIL) & (F.org < pos) & (pos < F.trailer.org) THEN    (* shift up and extend to the bottom *)
  673.             LocateLineTop(F, F.trailer, pos, beg); LocateLineTop(F, F.trailer, F.trailer.org, end);
  674.             dy := (F.Y + F.H - F.top) - beg.y; Shift(F, end.y, end.y + dy, beg.y - end.y);
  675.             Erase(F, F.X + F.left, end.y, F.W - F.left, dy);
  676.             s := F.trailer.next; WHILE s.org # pos DO s := s.next END;
  677.             F.trailer.next := s; org := s.org + s.span; ph := F.H - F.top - s.h;
  678.             WHILE s.next # F.trailer DO s := s.next; org := org + s.span; ph := ph - s.h END;
  679.             Complete(F, F.trailer, s, org, ph); F.org := pos; ShowLines(F, F.bot, end.y + dy - F.Y, FALSE)
  680.         ELSIF (F.trailer = NIL) OR (pos # F.org) THEN
  681.             MeasureLines(F, pos, new);
  682.             IF (F.trailer # NIL) & (pos < F.org) & (F.org <= new.org) THEN    (* shift down and extend to the top *)
  683.                 LocateLineTop(F, new, F.org, beg); LocateLineTop(F, new, new.org, end);
  684.                 y0 := F.Y + F.H - F.top; Shift(F, y0 - (beg.y - end.y), end.y, beg.y - end.y);
  685.                 Erase(F, F.X + F.left, beg.y, F.W - F.left, y0 - beg.y);
  686.                 Erase(F, F.X + F.left, F.Y + F.bot, F.W - F.left, end.y - (F.Y + F.bot));
  687.                 F.org := pos; F.trailer := new; ShowLines(F, beg.y - F.Y, F.H - F.top, FALSE)
  688.             ELSE    (* full redisplay *)
  689.                 IF F.trailer = NIL THEN Erase(F, F.X, F.Y, F.W, F.H); ShowBar(F, 0, F.H); F.markH := -1
  690.                 ELSE Erase(F, F.X + F.left, F.Y + F.bot, F.W - F.left, F.H - F.bot - F.top)
  691.                 END;
  692.                 F.org := pos; F.trailer := new; ShowLines(F, F.bot, F.H - F.top, FALSE)
  693.             END
  694.         END;
  695.         ShowTick(F)
  696.     END ShowFrom;
  697.     PROCEDURE Show* (F: Frame; pos: LONGINT);    (** removes global marks as needed and neutralizes F **)
  698.     BEGIN BegOfLine(F.text, pos, TRUE); ShowFrom(F, pos)
  699.     END Show;
  700.     PROCEDURE Resize (F: Frame; x, y, w, h: INTEGER);
  701.         VAR oldY, oldH, dh, ph: INTEGER; t: TextLine;
  702.     BEGIN
  703.         IF (w = 0) OR (h = 0) THEN InvalSubFrames(F, F.X, F.Y, F.W, F.H);
  704.             F.X := x; F.Y := y; F.W := w; F.H := h; F.trailer := NIL
  705.         ELSIF (F.trailer # NIL) & (x = F.X) & (w = F.W) THEN
  706.             oldY := F.Y; oldH := F.H; Tick(F); F.markH := -1; F.Y := y; F.H := h;
  707.             IF h > oldH THEN dh := h - oldH;    (* extend *)
  708.                 IF y + h # oldY + oldH THEN
  709.                     Display.CopyBlock(x, oldY, w, oldH, x, y + dh, Display.replace);
  710.                     ShiftSubFrames(F, oldY, y + dh, oldH)
  711.                 END;
  712.                 EraseRect(F, x, y, w, dh); ShowBar(F, 0, dh);
  713.                 t := F.trailer; ph := F.H - F.top;
  714.                 WHILE t.next # F.trailer DO t := t.next; ph := ph - t.h END;
  715.                 Complete(F, F.trailer, t, F.trailer.org, ph); ShowLines(F, F.bot, ph, FALSE)
  716.             ELSE dh := oldH - h;    (* reduce *)
  717.                 IF y + h # oldY + oldH THEN
  718.                     Display.CopyBlock(x, oldY + dh, w, h, x, y, Display.replace);
  719.                     ShiftSubFrames(F, oldY + dh, y, h)
  720.                 END;
  721.                 t := F.trailer; ph := F.H - F.top;
  722.                 WHILE (t.next # F.trailer) & (ph - t.next.h >= F.bot) DO t := t.next; DEC(ph, t.h) END;
  723.                 IF t = F.trailer THEN t.org := F.org; t.span := 0 END;
  724.                 Complete(F, F.trailer, t, t.org + t.span, ph);
  725.                 EraseRect(F, x + F.left, y, w - F.left, ph);
  726.                 InvalSubFrames(F, x, oldY, w, y - oldY); InvalSubFrames(F, x, y + h, w, dh - (y - oldY))
  727.             END;
  728.             ShowTick(F)
  729.         ELSE F.X := x; F.Y := y; F.W := w; F.H := h; F.trailer := NIL; Show(F, F.org)
  730.         END
  731.     END Resize;
  732.     (** Contents Update **)
  733.     PROCEDURE Update (F: Frame; VAR msg: UpdateMsg);    (** removes global marks as needed **)
  734.         VAR t: TextLine; org, d, Fbeg, Fend: LONGINT;
  735.             foc: Display.Frame; beg, end: LONGINT; ch: CHAR; r: Texts.Reader; loc: Location;
  736.         PROCEDURE Begin (VAR beg: LONGINT; VAR org0: LONGINT; VAR q: TextLine);
  737.             (* org0 = origin of first affected line; beg = pos of first modified character; q = first affected line (if line origin has not moved).*)
  738.             (* q = NIL => beg = org0; q # NIL => first (beg-org0) characters of q need not be redrawn *)
  739.             VAR trailer, t: TextLine;
  740.         BEGIN
  741.             trailer := F.trailer; t := trailer;
  742.             WHILE (t.next # trailer) & (beg >= t.next.org + t.next.span) & ~t.next.eot DO t := t.next END;
  743.             q := t.next;
  744.             IF (t # trailer) & (q # trailer) & (beg <= q.org + q.span) THEN
  745.                 Texts.OpenReader(R, F.text, t.org); Texts.Read(R, nextCh); org0 := t.org; NextLine(F.text, org0)
  746.             ELSE org0 := beg; BegOfLine(F.text, org0, TRUE)
  747.             END;
  748.             IF org0 # q.org THEN
  749.                 IF t = trailer THEN org0 := q.org ELSE org0 := t.org END;
  750.                 beg := org0; q := NIL
  751.             END
  752.         END Begin;
  753.         PROCEDURE Adjust (end, delta: LONGINT);
  754.             (* H1 = top of synchronization line in old frame *)
  755.             (* h0 = top of line that was modified *)
  756.             (* h1 = top of block in new frame that could be reused *)
  757.             (* h2 = bottom of last line in new frame *)
  758.             (* h1 - h2 = height of block that could be reused *)
  759.             VAR new, old, s, t, u, p, q: TextLine; bot: Location;
  760.                 org, org0, beg: LONGINT; ph, h0, h1, H1, h2, lm, dx, dy: INTEGER;
  761.         BEGIN
  762.             q := NIL; LocateLineTop(F, F.trailer, F.trailer.org, bot);
  763.             IF msg.beg < F.org THEN org0 := F.org; beg := org0 ELSE beg := msg.beg; Begin(beg, org0, q) END;
  764.             NEW(new); s := new; old := F.trailer; t := old; org := F.org; ph := F.H - F.top;
  765.             WHILE (t.next # old) & (t.next.org # org0) DO t := t.next;    (*transfer unchanged prefix*)
  766.                 s.next := t; s := t; DEC(ph, s.h); INC(org, s.span)
  767.             END;
  768.             h0 := ph; H1 := h0; t := t.next; p := s;
  769.             Texts.OpenReader(R, F.text, org); Texts.Read(R, nextCh);    (*rebuild at least one line descriptor*)
  770.             LOOP NEW(u); u.org := org; MeasureLine(F, F.W - F.left - F.right, u);
  771.                 IF ph - u.h < F.bot THEN h1 := ph; h2 := h1; EXIT END;
  772.                 s.next := u; s := s.next; DEC(ph, s.h); INC(org, s.span);
  773.                 IF R.eot THEN h1 := ph; h2 := h1; EXIT END;
  774.                 IF org > end THEN
  775.                     WHILE (t # old) & (org > t.org + delta) DO DEC(H1, t.h); t := t.next END;
  776.                     IF (org = t.org + delta) & (P = t.P) THEN h1 := ph;    (*resynchronized*)
  777.                         WHILE (t # old) & (ph - t.h >= F.bot) DO    (*transfer unchanged suffix*)
  778.                             s.next := t; s := t; s.org := org; ParcBefore(F.text, s.org, s.P, s.pbeg);
  779.                             DEC(ph, s.h); INC(org, s.span); t := t.next
  780.                         END;
  781.                         h2 := ph; EXIT
  782.                     END
  783.                 END
  784.             END;
  785.             Shift(F, F.Y + H1 - (h1 - h2), F.Y + h2, h1 - h2);
  786.             Complete(F, new, s, org, ph); F.trailer := new; t := p.next;
  787.             IF (q # NIL) & (t # F.trailer) & (q.h = t.h) & (q.dsr = t.dsr) & (q.org = t.org) & (q.P = t.P) & (end <= t.org + t.span) THEN
  788.                 P := t.P; pbeg := t.pbeg;
  789.                 IF (P.opts * AdjMask = {leftAdj}) OR (P.opts * AdjMask = AdjMask) & (q.nob = 0) & (t.nob = 0) THEN
  790.                     Width(F, t, beg, lm, dx, dy);    (*preserve prefix of first affected line*)
  791.                     DEC(h0, t.h); Erase(F, F.X + lm, F.Y + h0, F.W - lm, t.h);
  792.                     ShowLine(F, t, F.X + lm, F.X + F.W - F.right, F.Y + h0)
  793.                 END
  794.             END;
  795.             ShowLines(F, h1, h0, TRUE);
  796.             Erase(F, F.X + F.left, bot.y, F.W - F.left, h2 - (bot.y - F.Y)); ShowLines(F, F.bot, h2, FALSE)
  797.         END Adjust;
  798.     BEGIN
  799.         foc := F.focus; beg := msg.beg; end := msg.end; 
  800.         F.handle(F, neutralize); MarkMenu(F); Fbeg := F.org; Fend := F.trailer.org;
  801.         IF (msg.id = Texts.insert) & (msg.beg < F.org) THEN t := F.trailer; d := msg.end - msg.beg; INC(F.org, d);
  802.             REPEAT INC(t.org, d); t := t.next UNTIL t = F.trailer
  803.         ELSIF msg.id = Texts.delete THEN
  804.             IF msg.end <= F.org THEN t := F.trailer; d := msg.end - msg.beg; DEC(F.org, d);
  805.                 REPEAT DEC(t.org, d); t := t.next UNTIL t = F.trailer
  806.             ELSIF msg.beg < F.org THEN F.org := msg.beg
  807.             END
  808.         END;
  809.         org := F.org;
  810.         IF msg.beg <= Fbeg + AdjustSpan THEN BegOfLine(F.text, org, TRUE) END;
  811.         ParcBefore(F.text, org, P, d);
  812.         IF (org # F.org) OR (P # F.trailer.next.P) THEN
  813.             F.trailer := NIL; Show(F, F.org)
  814.         ELSIF (msg.end > Fbeg) & (msg.beg < Fend + AdjustSpan) THEN
  815.             IF msg.id = Texts.replace THEN Adjust(msg.end, 0);
  816.                 (* refocus element if necessary *)
  817.                 IF (foc # NIL) & (end-beg = 1) THEN
  818.                     Texts.OpenReader(r, F.text, beg); Texts.Read(r, ch);
  819.                     IF r.elem # NIL THEN
  820.                         LocatePos(F, beg, loc); foc := ThisSubFrame(F, loc.x, loc.y); PassSubFocus(F, foc);
  821.                     END
  822.                 END
  823.             ELSIF msg.id = Texts.insert THEN Adjust(msg.end, msg.end - msg.beg)
  824.             ELSIF msg.id = Texts.delete THEN Adjust(msg.beg, msg.beg - msg.end)
  825.             END
  826.         END;
  827.         ShowTick(F)
  828.     END Update;
  829.     (** User Interface **)
  830.     PROCEDURE Back (F: Frame; dY: INTEGER; (*inout*) VAR org: LONGINT);    (* mh 10.10.92 *)
  831.         (* computes new org such that old org is (at most) dY pixels below new org *)
  832.         VAR H: INTEGER; oldOrg: LONGINT;
  833.         PROCEDURE TotalHeight (org1, org2: LONGINT): INTEGER;
  834.             (* measures total height of text-lines starting at org1 and ending at the line before the line containing org2 *) 
  835.             VAR h: INTEGER; line: TextLine;
  836.         BEGIN
  837.             Texts.OpenReader(R, F.text, org1); Texts.Read(R, nextCh); NEW(line); h := 0;
  838.             LOOP line.org := org1;
  839.                 MeasureLine(F, F.W - F.left - F.right, line); INC(org1, line.span);
  840.                 IF Texts.Pos(R)-1 > org2 THEN EXIT END;
  841.                 INC(h, line.h);
  842.                 IF R.eot THEN EXIT END;
  843.             END;
  844.             RETURN h
  845.         END TotalHeight;
  846.         PROCEDURE Forward (h: INTEGER);
  847.             (* increase org by n text-lines such that the sum of the n line-heights > h *)
  848.             VAR line: TextLine;
  849.         BEGIN
  850.             Texts.OpenReader(R, F.text, org); Texts.Read(R, nextCh); NEW(line);
  851.             WHILE h > 0 DO line.org := org;
  852.                 MeasureLine(F, F.W - F.left - F.right, line); INC(org, line.span); DEC(h, line.h);
  853.             END;
  854.             org := Texts.Pos(R)-1;
  855.         END Forward;
  856.     BEGIN H := 0;
  857.         LOOP oldOrg := org;
  858.             IF org = 0 THEN EXIT END;
  859.             DEC(org, 800); BegOfLine(F.text, org, FALSE);
  860.             INC(H, TotalHeight(org, oldOrg));
  861.             IF H > dY THEN EXIT END;
  862.         END;
  863.         Forward(H - dY);
  864.     END Back;
  865.     PROCEDURE TrackLine* (F: Frame; VAR x, y: INTEGER; VAR org: LONGINT; VAR keysum: SET);
  866.         VAR keys: SET; new, old: Location;
  867.     BEGIN
  868.         LocateLine(F, y, old); InvertRect(F, old.x, old.y, old.dx + 4, 2); keysum := {};
  869.         REPEAT TrackMouse(x, y, keys, keysum); LocateLine(F, y, new);
  870.             IF new.org # old.org THEN
  871.                 InvertRect(F, new.x, new.y, new.dx + 4, 2); InvertRect(F, old.x, old.y, old.dx + 4, 2); old := new
  872.             END
  873.         UNTIL keys = {};
  874.         InvertRect(F, new.x, new.y, new.dx + 4, 2); org := new.org
  875.     END TrackLine;
  876.     PROCEDURE TrackWord* (F: Frame; VAR x, y: INTEGER; VAR pos: LONGINT; VAR keysum: SET);
  877.         VAR keys: SET; new, old: Location;
  878.     BEGIN 
  879.         LocateWord(F, x, y, old); InvertRect(F, old.x, old.y, old.dx, 2); keysum := {};
  880.         REPEAT TrackMouse(x, y, keys, keysum); LocateWord(F, x, y, new);
  881.             IF new.pos # old.pos THEN
  882.                 InvertRect(F, new.x, new.y, new.dx, 2); InvertRect(F, old.x, old.y, old.dx, 2); old := new
  883.             END
  884.         UNTIL keys = {};
  885.         InvertRect(F, new.x, new.y, new.dx, 2); pos := new.pos
  886.     END TrackWord;
  887.     PROCEDURE TrackCaret* (F: Frame; VAR x, y: INTEGER; VAR keysum: SET);
  888.         VAR keys: SET;
  889.     BEGIN keysum := {};
  890.         REPEAT TrackMouse(x, y, keys, keysum); SetCaret(F, Pos(F, x, y)) UNTIL keys = {}
  891.     END TrackCaret;
  892.     PROCEDURE TrackSelection* (F: Frame; VAR x, y: INTEGER; VAR keysum: SET);
  893.         VAR keys: SET; pos: LONGINT; V: Viewers.Viewer; f: Frame;
  894.     BEGIN
  895.         V := Viewers.This(F.X, F.Y); V := V.next(Viewers.Viewer);
  896.         IF (V.dsc # NIL) & (V.dsc.next # NIL) & (V.dsc.next IS Frame) THEN f := V.dsc.next(Frame);
  897.             IF f.hasSel & (f.text = F.text) THEN
  898.                 IF (f.selbeg.pos < f.trailer.org) & (f.org < f.selend.pos) & (f.selbeg.pos <= Pos(F, x, y)) THEN
  899.                     SetSelection(F, f.selbeg.pos, Pos(F, x, y) + 1)
  900.                 ELSE RemoveSelection(f); f := NIL
  901.                 END
  902.             ELSE f := NIL
  903.             END
  904.         ELSE f := NIL
  905.         END;
  906.         IF f = NIL THEN
  907.             IF F.hasSel & (F.selbeg.pos + 1 = F.selend.pos) & (Pos(F, x, y) = F.selbeg.pos) THEN
  908.                 SetSelection(F, F.selbeg.org, Pos(F, x, y) + 1)
  909.             ELSE SetSelection(F, Pos(F, x, y), Pos(F, x, y) + 1)
  910.             END
  911.         END;
  912.         keysum := {};
  913.         REPEAT TrackMouse(x, y, keys, keysum);
  914.             IF F.hasSel THEN
  915.                 pos := Pos(F, x, Min(y, F.selbeg.y)) + 1;
  916.                 IF pos <= F.selbeg.pos THEN pos := F.selbeg.pos + 1 END;
  917.                 SetSelection(F, F.selbeg.pos, pos);
  918.                 IF f # NIL THEN SetSelection(f, f.selbeg.pos, pos); f.selend.pos := F.selend.pos END
  919.             ELSE SetSelection(F, Pos(F, x, y), Pos(F, x, y) + 1)
  920.             END
  921.         UNTIL keys = {};
  922.         IF f # NIL THEN F.selbeg.pos := f.selbeg.pos END
  923.     END TrackSelection;
  924.     PROCEDURE Call (F: Frame; pos: LONGINT; keysum: SET);
  925.         VAR S: Texts.Scanner; res, i, j: INTEGER;
  926.     BEGIN Texts.OpenScanner(S, F.text, pos); Texts.Scan(S);
  927.         IF (S.class = Texts.Name) & (S.line = 0) THEN i := 0;
  928.             WHILE (i < S.len) & (S.s[i] # ".") DO INC(i) END;
  929.             j := i + 1;
  930.             WHILE (j < S.len) & (S.s[j] # ".") DO INC(j) END;
  931.             IF (j >= S.len) & (S.s[i] = ".") OR (rightKey IN keysum) THEN
  932.                 par.vwr := Viewers.This(F.X, F.Y);
  933.                 IF rightKey IN keysum THEN S.s:="Edit.Open"; par.pos := pos ELSE par.pos := pos + S.len END;
  934.                 par.frame := F; par.text := F.text; Oberon.Call(S.s, par, keysum = {middleKey, leftKey}, res);
  935.                 IF res > 0 THEN
  936.                     Texts.WriteString(W0, "Call error: "); Texts.WriteString(W0, Modules.importing);
  937.                     IF res = 1 THEN Texts.WriteString(W0, " not found")
  938.                     ELSIF res = 2 THEN Texts.WriteString(W0, " not an obj-file")
  939.                     ELSIF res = 3 THEN Texts.WriteString(W0, " imports ");
  940.                         Texts.WriteString(W0, Modules.imported); Texts.WriteString(W0, " with bad key");
  941.                     ELSIF res = 4 THEN Texts.WriteString(W0, " corrupted obj file")
  942.                     ELSIF res = 6 THEN Texts.WriteString(W0, " has too many imports")
  943.                     ELSIF res = 7 THEN Texts.WriteString(W0, " not enough space")
  944.                     END
  945.                 ELSIF res < 0 THEN
  946.                     INC(i); WHILE i < S.len DO Texts.Write(W0, S.s[i]); INC(i) END;
  947.                     Texts.WriteString(W0, " not found")
  948.                 END ;
  949.                 IF res # 0 THEN Texts.WriteLn(W0); Texts.Append(Oberon.Log, W0.buf) END
  950.             END
  951.         END
  952.     END Call;
  953.     PROCEDURE PickAttributes (VAR W: Texts.Writer; T: Texts.Text; pos: LONGINT; font: Fonts.Font; col, voff: SHORTINT);
  954.         VAR R: Texts.Reader; ch: CHAR;
  955.     BEGIN
  956.         IF T.len > 0 THEN
  957.             IF pos > 0 THEN Texts.OpenReader(R, T, pos-1); Texts.Read(R, ch)
  958.             ELSE Texts.OpenReader(R, T, 0); Texts.Read(R, ch)
  959.             END;
  960.             Texts.SetFont(W, R.fnt); Texts.SetColor(W, R.col); Texts.SetOffset(W, R.voff);
  961.         ELSE Texts.SetFont(W, font); Texts.SetColor(W, col); Texts.SetOffset(W, voff)
  962.         END
  963.     END PickAttributes;
  964.     PROCEDURE ShiftBlock (F: Frame; delta: INTEGER);    (* shift selected lines to left or right *)
  965.         VAR text: Texts.Text; pos, beg, end, time: LONGINT; select: SelectMsg; ch: CHAR;
  966.     BEGIN
  967.         Oberon.GetSelection(text, beg, end, time);
  968.         IF (time >= 0) & (text = F.text) THEN BegOfLine(F.text, beg, FALSE); pos := beg;
  969.             WHILE pos < end DO Texts.OpenReader(R, F.text, pos); Texts.Read(R, ch);
  970.                 WHILE (R.elem # NIL) & (R.elem IS Parc) & (pos < end) DO Texts.Read(R, ch); INC(pos) END;
  971.                 IF pos < end THEN
  972.                     IF delta < 0 THEN
  973.                         IF (ch <= " ") & (ch # CR) & (ch # Texts.ElemChar) THEN
  974.                             Texts.Delete(F.text, pos, pos + 1); DEC(end)
  975.                         END
  976.                     ELSE
  977.                         PickAttributes(W, text, pos, Oberon.CurFnt, Oberon.CurCol, Oberon.CurOff);
  978.                         IF (ch <= " ") & (ch # CR) & (ch # Texts.ElemChar) THEN Texts.Write(W, ch)    (* first char extension *)
  979.                         ELSE Texts.Write(W, TAB)
  980.                         END;
  981.                         Texts.Insert(F.text, pos, W.buf); INC(end); INC(pos)
  982.                     END;
  983.                     Texts.OpenReader(R, F.text, pos);
  984.                     REPEAT Texts.Read(R, ch) UNTIL R.eot OR (ch = CR);
  985.                     pos := Texts.Pos(R)
  986.                 END
  987.             END;
  988.             select.text := F.text; select.beg := beg; select.end := pos; select.time := Oberon.Time();
  989.             Viewers.Broadcast(select)
  990.         END
  991.     END ShiftBlock;
  992.     PROCEDURE Write (F: Frame; ch: CHAR; fnt: Fonts.Font; col, voff: SHORTINT);
  993.         VAR loc: Location; parc: Parc; org, pos, pbeg: LONGINT; i: INTEGER; ch0: CHAR;
  994.             buf: ARRAY 32 OF CHAR;
  995.             copy: Texts.CopyMsg; input: Oberon.InputMsg;
  996.         PROCEDURE Visible(ch: CHAR): BOOLEAN;
  997.             VAR pat: Display.Pattern; dx, x, y, w, h: INTEGER;
  998.         BEGIN Display.GetChar(W.fnt.raster, ch, dx, x, y, w, h, pat); RETURN dx > 0
  999.         END Visible;
  1000.         PROCEDURE InsertBuffer;
  1001.             VAR i, j: INTEGER; ch: CHAR;
  1002.         BEGIN i := 0; j := 0; ch := buf[i];
  1003.             WHILE ch # 0X DO
  1004.                 IF (ch = TAB) OR (ch = CR) OR (ch = " ") OR Visible(ch) THEN Texts.Write(W, ch); INC(j) END;
  1005.                 INC(i); ch := buf[i]
  1006.             END; 
  1007.             IF j > 0 THEN Texts.Insert(F.text, pos, W.buf); INC(pos, LONG(j)) END
  1008.         END InsertBuffer;
  1009.         PROCEDURE Flush;
  1010.             VAR ch: CHAR;
  1011.         BEGIN
  1012.             WHILE Input.Available() > 0 DO Input.Read(ch) END
  1013.         END Flush;
  1014.     BEGIN
  1015.         IF F.hasSel & (ch = CRSL) THEN ShiftBlock(F, -1)
  1016.         ELSIF F.hasSel & (ch = CRSR) THEN ShiftBlock(F, 1)
  1017.         ELSIF F.hasCar THEN pos := F.carloc.pos;
  1018.             IF (ch = DEL) & (pos > F.org) THEN DEC(pos); Texts.Delete(F.text, pos, pos + 1); Flush
  1019.             ELSIF (ch = CRSL) & (pos > 0) THEN DEC(pos)
  1020.             ELSIF (ch = CRSR) & (pos < F.text.len) THEN INC(pos)
  1021.             ELSIF (ch = BRK) OR (ch = ShiftBRK) THEN
  1022.                 ParcBefore(F.text, pos, P, pbeg); P.handle(P, copy); parc := copy.e(Parc);
  1023.                 IF ch = BRK THEN EXCL(parc.opts, pageBreak) ELSE INCL(parc.opts, pageBreak) END;
  1024.                 PickAttributes(W, F.text, pos, fnt, col, voff);
  1025.                 Texts.WriteElem(W, parc); Texts.Insert(F.text, pos, W.buf); INC(pos)
  1026.             ELSIF (ch = TAB) OR (ch = LF) OR (ch = CR) OR (ch >= " ") THEN
  1027.                 PickAttributes(W, F.text, pos, fnt, col, voff);
  1028.                 IF ch = LF THEN buf[0] := CR; i := 1; org := F.carloc.org; BegOfLine(F.text, org, FALSE);
  1029.                     Texts.OpenReader(R, F.text, org);
  1030.                     REPEAT Texts.Read(R, ch) UNTIL (R.elem = NIL) OR ~(R.elem IS Parc);
  1031.                     WHILE (Texts.Pos(R) <= pos) & (ch <= " ") & (ch # Texts.ElemChar) & (i < 31) DO
  1032.                         buf[i] := ch; INC(i); Texts.Read(R, ch)
  1033.                     END
  1034.                 ELSE buf[0] := ch; i := 1
  1035.                 END;
  1036.                 WHILE (Input.Available() > 0) & (i < 31) & (ch >= " ") & (ch < DEL) DO Input.Read(buf[i]); INC(i) END;
  1037.                 buf[i] := 0X; InsertBuffer
  1038.             END;
  1039.             IF pos < F.org THEN Show(F, F.org - 1)
  1040.             ELSIF pos < F.text.len THEN org := -1;
  1041.                 WHILE (pos >= F.trailer.org) & (pos > F.org) DO
  1042.                     org := F.trailer.next.next.org; IF org = F.org THEN INC(org) END;
  1043.                     ShowFrom(F, org); Flush
  1044.                 END
  1045.             ELSE LocatePos(F, pos, loc); LocateChar(F, loc.x + 1, loc.y, loc);
  1046.                 IF pos # loc.pos THEN Show(F, F.trailer.next.next.org); Flush END
  1047.             END;
  1048.             SetCaret(F, pos)
  1049.         ELSIF F.focus # NIL THEN input.id := Oberon.consume; input.ch := ch;
  1050.             input.fnt := fnt; input.col := col; input.voff := voff; F.focus.handle(F.focus, input)
  1051.         END
  1052.     END Write;
  1053.     PROCEDURE TouchElem (F: Frame; VAR x, y: INTEGER; VAR keysum: SET);
  1054.         VAR loc: Location; e: Texts.Elem; pbeg: LONGINT; y0: INTEGER;
  1055.             track: TrackMsg;
  1056.     BEGIN
  1057.         LocateChar(F, x, y, loc); e := R.elem;
  1058.         IF (e # NIL) & (loc.x + e.W DIV Unit <= F.X + F.W - F.right) THEN
  1059.             ParcBefore(F.text, loc.pos, P, pbeg); y0 := loc.y + loc.line.dsr - SHORT(P.dsr DIV Unit) + loc.dy;
  1060.             IF (loc.x <= x) & (x < loc.x + e.W DIV Unit) & (keysum= {middleKey}) THEN
  1061.                 track.X := x; track.Y := y; track.keys := keysum;
  1062.                 track.fnt := R.fnt; track.col := R.col; track.pos := Texts.Pos(R) - 1;
  1063.                 track.frame := F; track.X0 := loc.x; track.Y0 := y0;
  1064.                 e.handle(e, track); keysum := {}
  1065.             END
  1066.         END
  1067.     END TouchElem;
  1068.     PROCEDURE Edit (F: Frame; x, y: INTEGER; keysum: SET);
  1069.         VAR ef: Display.Frame; text: Texts.Text; beg, end, time, pos: LONGINT; keys: SET; ch: CHAR;
  1070.             loc: Location; delta: INTEGER; copyover: Oberon.CopyOverMsg; input: Oberon.InputMsg;
  1071.     BEGIN
  1072.         IF x < F.X + F.barW THEN pos := F.org;    (* scroll bar *)
  1073.             IF leftKey IN keysum THEN TrackLine(F, x, y, pos, keysum)
  1074.             ELSIF rightKey IN keysum THEN TrackLine(F, x, y, pos, keysum); LocateLine(F, y, loc);
  1075.                 pos := F.org; delta := loc.y - (F.Y + F.bot); Back(F, delta, pos)
  1076.             ELSIF middleKey IN keysum THEN
  1077.                 REPEAT TrackMouse(x, y, keys, keysum) UNTIL keys = {};
  1078.                 IF keysum = {middleKey, leftKey} THEN pos := F.text.len; (*BegOfLine(F.text, pos, TRUE);*)
  1079.                     Back(F, F.H - F.bot - F.top - 30 (*heuristic*), pos);
  1080.                 ELSIF keysum = {middleKey, rightKey} THEN pos := 0
  1081.                 ELSIF (F.Y <= y) & (y <= F.Y + F.H) THEN pos := CoordToPos(F, y - F.Y); BegOfLine(F.text, pos, TRUE)
  1082.                 END
  1083.             ELSE DrawCursor(x, y); keysum := cancel
  1084.             END;
  1085.             IF keysum # cancel THEN ShowFrom(F, pos) END
  1086.         ELSE    (* text area *)
  1087.             ef := ThisSubFrame(F, x, y);
  1088.             IF ef # NIL THEN    (* within sub-frame *)
  1089.                 IF (F.focus # ef) & (keysum = {leftKey}) THEN
  1090.                     REPEAT TrackMouse(x, y, keys, keysum) UNTIL keys = {};
  1091.                     IF keysum = {leftKey} THEN RemoveSelection(F); RemoveCaret(F); PassSubFocus(F, ef); RETURN END
  1092.                 ELSIF F.focus = ef THEN input.id := Oberon.track; input.keys := keysum; input.X := x; input.Y := y;
  1093.                     ef.handle(ef, input); RETURN
  1094.                 END
  1095.             END;
  1096.             IF keysum # {} THEN TouchElem(F, x, y, keysum) END;
  1097.             IF leftKey IN keysum THEN Oberon.PassFocus(Viewers.This(F.X, F.Y)); TrackCaret(F, x, y, keysum);
  1098.                 IF (keysum = {leftKey, middleKey}) & F.hasCar THEN Oberon.GetSelection(text, beg, end, time);
  1099.                     IF time >= 0 THEN Texts.Save(text, beg, end, B);
  1100.                         Texts.Insert(F.text, F.carloc.pos, B); SetCaret(F, F.carloc.pos + (end - beg))
  1101.                     END
  1102.                 ELSIF (keysum = {leftKey, rightKey}) & F.hasCar & (F.carloc.pos < F.text.len) THEN
  1103.                     Oberon.GetSelection(text, beg, end, time);
  1104.                     IF time >= 0 THEN Texts.OpenReader(R, F.text, F.carloc.pos); Texts.Read(R, ch);
  1105.                         Texts.ChangeLooks(text, beg, end, {0, 1, 2}, R.fnt, R.col, R.voff)
  1106.                     END
  1107.                 END
  1108.             ELSIF middleKey IN keysum THEN TrackWord(F, x, y, pos, keysum);
  1109.                 IF keysum # cancel THEN Call(F, pos, keysum) END
  1110.             ELSIF rightKey IN keysum THEN TrackSelection(F, x, y, keysum);
  1111.                 IF (keysum = {rightKey, middleKey}) & F.hasSel THEN
  1112.                     copyover.text := F.text; copyover.beg := F.selbeg.pos; copyover.end := F.selend.pos;
  1113.                     Oberon.FocusViewer.handle(Oberon.FocusViewer, copyover)
  1114.                 ELSIF (keysum = {rightKey, leftKey}) & F.hasSel THEN Oberon.PassFocus(Viewers.This(F.X, F.Y));
  1115.                     Texts.Delete(F.text, F.selbeg.pos, F.selend.pos); SetCaret(F, F.selbeg.pos)
  1116.                 END
  1117.             ELSE DrawCursor(x, y)
  1118.             END
  1119.         END
  1120.     END Edit;
  1121.     (** General **)
  1122.     PROCEDURE Copy (SF, DF: Frame);
  1123.     BEGIN
  1124.         DF.handle := SF.handle; DF.text := SF.text; DF.org := SF.org;
  1125.         DF.col := SF.col; DF.left := SF.left; DF.right := SF.right; DF.top := SF.top; DF.bot := SF.bot;
  1126.         DF.barW := SF.barW; DF.hasCar := FALSE; DF.hasSel := FALSE; DF.showsParcs := SF.showsParcs;
  1127.         DF.focus := NIL; DF.trailer := NIL
  1128.     END Copy;
  1129.     PROCEDURE Handle* (f: Display.Frame; VAR msg: Display.FrameMsg);
  1130.         VAR F, F1: Frame; pos: LONGINT;
  1131.     BEGIN F := f(Frame);
  1132.         IF msg IS Oberon.InputMsg THEN
  1133.             WITH msg: Oberon.InputMsg DO
  1134.                 IF msg.id = Oberon.consume THEN Write(F, msg.ch, msg.fnt, msg.col, msg.voff)
  1135.                 ELSIF msg.id = Oberon.track THEN Edit(F, msg.X, msg.Y, msg.keys)
  1136.                 END
  1137.             END
  1138.         ELSIF msg IS Oberon.ControlMsg THEN
  1139.             WITH msg: Oberon.ControlMsg DO
  1140.                 IF msg.id = Oberon.defocus THEN RemoveCaret(F)
  1141.                 ELSIF msg.id = Oberon.neutralize THEN
  1142.                     RemoveCaret(F); RemoveSelection(F); PassSubFocus(F, NIL); NotifySubFrames(F, msg)
  1143.                 ELSE NotifySubFrames(F, msg)
  1144.                 END
  1145.             END
  1146.         ELSIF msg IS Oberon.CopyMsg THEN
  1147.             WITH msg: Oberon.CopyMsg DO
  1148.                 IF msg.F = NIL THEN NEW(F1); msg.F := F1 END;
  1149.                 Copy(F, msg.F(Frame))
  1150.             END
  1151.         ELSIF msg IS UpdateMsg THEN NotifySubFrames(F, msg);
  1152.             WITH msg: UpdateMsg DO
  1153.                 IF msg.text = F.text THEN Update(F, msg) END
  1154.             END
  1155.         ELSIF msg IS InsertElemMsg THEN
  1156.             IF F.hasCar THEN pos := F.carloc.pos;
  1157.                 PickAttributes(W, F.text, pos, Oberon.CurFnt, Oberon.CurCol, Oberon.CurOff);
  1158.                 Texts.WriteElem(W, msg(InsertElemMsg).e);
  1159.                 Texts.Insert(F.text, pos, W.buf);
  1160.                 SetCaret(F, pos + 1)
  1161.             END
  1162.         ELSIF msg IS Oberon.SelectionMsg THEN NotifySubFrames(F, msg);
  1163.             WITH msg: Oberon.SelectionMsg DO
  1164.                 IF F.hasSel & (F.time > msg.time) THEN
  1165.                     msg.text := F.text; msg.beg := F.selbeg.pos; msg.end := F.selend.pos; msg.time := F.time
  1166.                 END
  1167.             END
  1168.         ELSIF msg IS Oberon.CopyOverMsg THEN NotifySubFrames(F, msg);
  1169.             WITH msg: Oberon.CopyOverMsg DO
  1170.                 IF F.hasCar THEN Texts.Save(msg.text, msg.beg, msg.end, B);
  1171.                     Texts.Insert(F.text, F.carloc.pos, B); SetCaret(F, F.carloc.pos + (msg.end - msg.beg))
  1172.                 END
  1173.             END
  1174.         ELSIF msg IS MenuViewers.ModifyMsg THEN
  1175.             WITH msg: MenuViewers.ModifyMsg DO
  1176.                 F.handle(F, neutralize); Resize(F, F.X, msg.Y, F.W, msg.H)
  1177.             END
  1178.         ELSIF msg IS SelectMsg THEN NotifySubFrames(F, msg);
  1179.             WITH msg: SelectMsg DO
  1180.                 IF (msg.text = F.text) & ~F.hasSel THEN Oberon.RemoveMarks(F.X, F.Y, F.W, F.H);
  1181.                     F.handle(F, neutralize);
  1182.                     SetSelection(F, msg.beg, msg.end); F.time := msg.time;
  1183.                     IF F.hasSel THEN F.selbeg.pos := msg.beg; F.selend.pos := msg.end END
  1184.                 END
  1185.             END
  1186.         ELSE NotifySubFrames(F, msg)
  1187.         END
  1188.     END Handle;
  1189.     PROCEDURE Open* (F: Frame; T: Texts.Text; pos: LONGINT);
  1190.     BEGIN
  1191.         F.handle := Handle; F.text := T; F.org := pos; F.col := Display.black;
  1192.         F.left := left; F.right := right; F.top := top; F.bot := bot;
  1193.         F.barW := barW; F.hasCar := FALSE; F.hasSel := FALSE; F.showsParcs := FALSE; F.trailer := NIL
  1194.     END Open;
  1195.     PROCEDURE NotifyDisplay* (T: Texts.Text; op: INTEGER; beg, end: LONGINT);
  1196.         VAR msg: UpdateMsg;
  1197.     BEGIN
  1198.         msg.text := T; msg.id := op; msg.beg := beg; msg.end := end; Viewers.Broadcast(msg)
  1199.     END NotifyDisplay;
  1200.     PROCEDURE Text* (name: ARRAY OF CHAR): Texts.Text;
  1201.         VAR text: Texts.Text;
  1202.     BEGIN
  1203.         NEW(text); Texts.Open(text, name); text.notify := NotifyDisplay; RETURN text
  1204.     END Text;
  1205.     PROCEDURE NewText* (T: Texts.Text; pos: LONGINT): Frame;
  1206.         VAR frame: Frame;
  1207.     BEGIN
  1208.         NEW(frame); Open(frame, T, pos);
  1209.         RETURN frame
  1210.     END NewText;
  1211.     PROCEDURE NewMenu* (name, commands: ARRAY OF CHAR): Frame;
  1212.         VAR T, T1: Texts.Text;
  1213.             buf: Texts.Buffer;
  1214.             frame: Frame;
  1215.             fn: ARRAY 32 OF CHAR;
  1216.             i: INTEGER;
  1217.     BEGIN i := 0; T := Text("");
  1218.         Texts.WriteString(W0, name); Texts.WriteString(W0, " | "); Texts.Append(T, W0.buf);
  1219.         IF commands[0] = "^" THEN
  1220.             WHILE commands[i+1] > " " DO fn[i] := commands[i+1]; INC(i) END ;
  1221.             fn[i] := 0X;
  1222.             IF Files.Old(fn) = NIL THEN
  1223.                 IF commands[i+1] = " " THEN INC(i, 2);
  1224.                     WHILE commands[i] > 0X DO Texts.Write(W0, commands[i]); INC(i) END ;
  1225.                     Texts.Append(T, W0.buf)
  1226.                 END
  1227.             ELSE NEW(T1); Texts.Open(T1, fn);
  1228.                 NEW(buf); Texts.OpenBuf(buf); Texts.Save(T1, 0, T1.len, buf); Texts.Append(T, buf)
  1229.             END
  1230.         ELSE Texts.WriteString(W0, commands); Texts.Append(T, W0.buf)
  1231.         END;
  1232.         NEW(frame); Open(frame, T, 0);
  1233.         frame.col := Display.white; frame.left := 6; frame.top := 0; frame.bot := 0; frame.barW := 0;
  1234.         RETURN frame
  1235.     END NewMenu;
  1236. BEGIN
  1237.     Texts.OpenWriter(W); Texts.OpenWriter(W0);
  1238.     Texts.SetFont(W0, Fonts.Default); Texts.SetColor(W0, Display.white); Texts.SetOffset(W0, 0);
  1239.     neutralize.id := Oberon.neutralize;
  1240.     NEW(par);
  1241.     NEW(B); Texts.OpenBuf(B);
  1242.     menuH := Fonts.Default.height + 2;
  1243.     barW := 14; left := barW + 6; right := 8; top := 6; bot := 6;
  1244.     InitDefParc
  1245. END TextFrames.
  1246.