home *** CD-ROM | disk | FTP | other *** search
/ Gold Fish 3 / goldfish_volume_3.bin / files / dev / obero / oberon / projectoberonsrc / edit.mod (.txt) < prev    next >
Encoding:
Oberon Text  |  1994-11-16  |  20.9 KB  |  499 lines
  1. Syntax10.Scn.Fnt
  2. Syntax10i.Scn.Fnt
  3. Syntax12.Scn.Fnt
  4. Syntax10b.Scn.Fnt
  5. MODULE Edit;    (** CAS/MH/HM 27.4.1994 / NW 15.11.94 **)
  6.     IMPORT
  7.         Modules, Oberon, Display, Viewers, MenuViewers, Fonts, Printer,
  8.         Texts, TextFrames, ParcElems, TextPrinter;
  9.     CONST
  10.         Menu = "^Edit.Menu.Text System.Close  System.Copy  System.Grow  Edit.Search  Edit.Replace  Edit.Parcs  Edit.Store ";
  11.         OptionChar = "/";
  12.         mm = TextFrames.mm; Unit = TextPrinter.Unit;
  13.         Scale = mm DIV 10;    (*unit of user setable attributes is 1/10 mm*)
  14.         headerX = 15 * mm DIV Unit;
  15.         headerW = 165 * mm DIV Unit;
  16.         bodyX = 15 * mm DIV Unit; bodyY = 15 * mm DIV Unit;
  17.         bodyW = 165 * mm DIV Unit;
  18.         MaxPat = 128;
  19.         CR = 0DX;
  20.         R: Texts.Reader;
  21.         W: Texts.Writer;
  22.         mnam: ARRAY 12*3 + 1 OF CHAR;
  23.         find: RECORD
  24.             time, len: LONGINT;
  25.             buf: ARRAY MaxPat OF CHAR
  26.         END;
  27.         repl: RECORD
  28.             time: LONGINT;
  29.             buf: Texts.Buffer
  30.         END;
  31.     PROCEDURE Ch (ch: CHAR);
  32.     BEGIN Texts.Write(W, ch); Texts.Append(Oberon.Log, W.buf)
  33.     END Ch;
  34.     PROCEDURE Str (s: ARRAY OF CHAR);
  35.     BEGIN Texts.WriteString(W, s); Texts.Append(Oberon.Log, W.buf)
  36.     END Str;
  37.     PROCEDURE Int (n: LONGINT);
  38.     BEGIN Texts.Write(W, " "); Texts.WriteInt(W, n, 0); Texts.Append(Oberon.Log, W.buf)
  39.     END Int;
  40.     PROCEDURE Ln;
  41.     BEGIN Texts.WriteLn(W); Texts.Append(Oberon.Log, W.buf)
  42.     END Ln;
  43.     PROCEDURE Min (x, y: LONGINT): LONGINT;
  44.     BEGIN
  45.         IF x < y THEN RETURN x ELSE RETURN y END
  46.     END Min;
  47.     PROCEDURE AppendNum (VAR s: ARRAY OF CHAR; VAR i: INTEGER; n: LONGINT);
  48.         VAR j: INTEGER; digits: ARRAY 16 OF CHAR;
  49.     BEGIN j := 0;
  50.         REPEAT digits[j] := CHR(n MOD 10 + 30H); INC(j); n := n DIV 10 UNTIL n = 0;
  51.         REPEAT DEC(j); s[i] := digits[j]; INC(i) UNTIL j = 0;
  52.         s[i] := 0X
  53.     END AppendNum;
  54.     PROCEDURE AppendDate (VAR s: ARRAY OF CHAR);    (*s := s & "   (dd mmm yy)"*)
  55.         VAR time, date: LONGINT; i, j, k, m: INTEGER;
  56.     BEGIN Oberon.GetClock(time, date); i := 0;
  57.         WHILE s[i] # 0X DO INC(i) END;
  58.         s[i] := " "; s[i + 1] := " "; s[i + 2] := " "; s[i + 3] := "("; INC(i, 4);
  59.         AppendNum(s, i, date MOD 20H); s[i] := " "; INC(i);
  60.         m := SHORT((date DIV 20H) MOD 10H); k := m * 3; j := k - 3;
  61.         REPEAT s[i] := mnam[j]; INC(i); INC(j) UNTIL j = k;
  62.         s[i] := " "; INC(i); AppendNum(s, i, (date DIV 200H) MOD 100);
  63.         s[i] := ")"; s[i + 1] := 0X
  64.     END AppendDate;
  65.     PROCEDURE ShowAliens (t: Texts.Text);
  66.         VAR R: Texts.Reader; identify: Texts.IdentifyMsg;
  67.     BEGIN
  68.         Texts.OpenReader(R, t, 0); Texts.ReadElem(R);
  69.         WHILE ~R.eot DO identify.mod[31] := 0X; R.elem.handle(R.elem, identify);
  70.             IF identify.mod[31] = 1X THEN Ln; Str("pos"); Int(Texts.Pos(R) - 1);
  71.                 Str("  unknown element allocator: "); Str(identify.mod); Ch("."); Str(identify.proc)
  72.             END;
  73.             Texts.ReadElem(R)
  74.         END;
  75.         IF W.buf.len > 0 THEN Ln; Texts.Append(Oberon.Log, W.buf) END
  76.     END ShowAliens;
  77.     (* view support *)
  78.     PROCEDURE ShowPos (F: TextFrames.Frame; pos: LONGINT);
  79.         VAR beg, end, delta: LONGINT;
  80.     BEGIN delta := 200;
  81.         LOOP beg := F.org; end := TextFrames.Pos(F, F.X + F.W, F.Y);
  82.             IF (beg <= pos) & (pos < end) OR (delta = 0) THEN EXIT END;
  83.             TextFrames.Show(F, pos - delta); delta := delta DIV 2
  84.         END
  85.     END ShowPos;
  86.     PROCEDURE SetCaret (F: TextFrames.Frame; pos: LONGINT);
  87.     BEGIN Oberon.PassFocus(Viewers.This(F.X, F.Y)); TextFrames.SetCaret(F, pos)
  88.     END SetCaret;
  89.     PROCEDURE NewView (name: ARRAY OF CHAR; class: INTEGER;
  90.             T: Texts.Text; org: LONGINT): TextFrames.Frame;
  91.         VAR V: MenuViewers.Viewer; F, M: TextFrames.Frame; i, x, y: INTEGER;
  92.     BEGIN
  93.         IF class = Texts.String THEN i := 0;
  94.             WHILE name[i] # 0X DO INC(i) END;
  95.             name[i] := 22X; INC(i); name[i] := 0X;
  96.             WHILE i >= 0 DO name[i+1] := name[i]; DEC(i) END;
  97.             name[0] := 22X
  98.         END;
  99.         F := TextFrames.NewText(T, org);
  100.         Oberon.AllocateUserViewer(Oberon.Mouse.X, x, y);
  101.         M := TextFrames.NewMenu(name, Menu);
  102.         V := MenuViewers.New(M, F, TextFrames.menuH, x, y);
  103.         ShowPos(F, org); RETURN F
  104.     END NewView;
  105.     (* search & replace *)
  106.     PROCEDURE Find (T: Texts.Text; beg: LONGINT; VAR end: LONGINT);
  107.         VAR i, j, b, e: INTEGER; ch: CHAR; ref: ARRAY MaxPat OF CHAR;    (*ref [b..e) is readback buffer*)
  108.     BEGIN
  109.         Texts.OpenReader(R, T, beg); Texts.Read(R, ch); i := 0; ref[0] := ch; j := 0; b := 0; e := 1;
  110.         WHILE ~R.eot & (i < find.len) DO
  111.             IF (find.buf[i] = ch)
  112.                 OR (find.buf[i] = 0FFX)
  113.                     & ((ch < "0") OR (ch > "9") & (ch < "A") OR (ch > "Z") & (ch < "a") OR (ch > "z"))
  114.                         THEN INC(i); j := (j + 1) MOD MaxPat
  115.             ELSE i := 0; b := (b + 1) MOD MaxPat; j := b
  116.             END;
  117.             IF j # e THEN ch := ref[j]
  118.             ELSE Texts.Read(R, ch); ref[j] := ch; e := (e + 1) MOD MaxPat; INC(beg);
  119.             END
  120.         END;
  121.         IF i = find.len THEN end := beg ELSE end := -1 END
  122.     END Find;
  123.     PROCEDURE Check (T: Texts.Text; beg: LONGINT): BOOLEAN;
  124.         VAR ch: CHAR; i: INTEGER;
  125.     BEGIN i := 0;
  126.         IF (beg >= 0) & (find.len > 0) THEN Texts.OpenReader(R, T, beg); Texts.Read(R, ch);
  127.             WHILE ~R.eot & (i < find.len) & (ch = find.buf[i]) DO Texts.Read(R, ch); INC(i) END;
  128.         END;
  129.         RETURN i = find.len
  130.     END Check;
  131.     PROCEDURE SetReplBuf;
  132.         VAR T: Texts.Text; beg, end, time: LONGINT;
  133.     BEGIN Oberon.GetSelection(T, beg, end, time);
  134.         IF time > repl.time THEN repl.time := time;
  135.             Texts.OpenBuf(repl.buf); Texts.Save(T, beg, end, repl.buf)
  136.         END
  137.     END SetReplBuf;
  138.     PROCEDURE Subst (T: Texts.Text; beg: LONGINT; VAR end: LONGINT);
  139.     BEGIN Texts.Delete(T, beg, beg + find.len);
  140.         IF repl.buf.len > 0 THEN end := beg + repl.buf.len;
  141.             Texts.Insert(T, beg, repl.buf); Texts.Save(T, beg, end, repl.buf)
  142.         END
  143.     END Subst;
  144.     (* arguments *)
  145.     PROCEDURE MarkedFrame (): TextFrames.Frame;
  146.         VAR V: Viewers.Viewer;
  147.     BEGIN V := Oberon.MarkedViewer();
  148.         IF (V # NIL) & (V IS MenuViewers.Viewer) & (V.dsc.next IS TextFrames.Frame) THEN
  149.             RETURN V.dsc.next(TextFrames.Frame)
  150.         ELSE RETURN NIL
  151.         END
  152.     END MarkedFrame;
  153.     PROCEDURE FocusFrame (): TextFrames.Frame;
  154.         VAR V: Viewers.Viewer; f: Display.Frame;
  155.     BEGIN V := Oberon.FocusViewer;
  156.         IF (V # NIL) & (V IS MenuViewers.Viewer) & (V.dsc # NIL) THEN f := V.dsc.next;
  157.             IF (f # NIL) & (f IS TextFrames.Frame) THEN RETURN f(TextFrames.Frame) ELSE RETURN NIL END
  158.         ELSE RETURN NIL
  159.         END
  160.     END FocusFrame;
  161.     PROCEDURE TargetFrame (): TextFrames.Frame;    (*body frame or focus frame*)
  162.         VAR f: Display.Frame;
  163.     BEGIN
  164.         IF Oberon.Par.vwr.dsc = Oberon.Par.frame THEN f := Oberon.Par.frame.next;
  165.             IF (f # NIL) & (f IS TextFrames.Frame) THEN RETURN f(TextFrames.Frame) ELSE RETURN NIL END
  166.         ELSE RETURN FocusFrame()
  167.         END
  168.     END TargetFrame;
  169.     PROCEDURE GetMainArg (VAR S: Texts.Scanner; VAR end: LONGINT); (*takes recent selection if ^*)
  170.         VAR text: Texts.Text; beg, time: LONGINT;
  171.     BEGIN Texts.Scan(S); end := MAX(LONGINT);
  172.         IF (S.class = Texts.Char) & (S.c = "^") THEN Oberon.GetSelection(text, beg, end, time);
  173.             IF time >= 0 THEN Texts.OpenScanner(S, text, beg); Texts.Scan(S) END
  174.         END;
  175.         IF S.line # 0 THEN S.class := Texts.Inval END
  176.     END GetMainArg;
  177.     PROCEDURE GetArg (VAR S: Texts.Scanner);
  178.         (*takes selection in command frame if ^*)
  179.         VAR F: TextFrames.Frame;
  180.     BEGIN
  181.         Texts.OpenScanner(S, Oberon.Par.text, Oberon.Par.pos); Texts.Scan(S);
  182.         IF (S.class = Texts.Char) & (S.c = "^") THEN F := Oberon.Par.frame(TextFrames.Frame);
  183.             IF F.hasSel THEN 
  184.                 Texts.OpenScanner(S, F.text, F.selbeg.pos); Texts.Scan(S); F.time := 0;
  185.             END
  186.         END
  187.     END GetArg;
  188.     PROCEDURE Change (sel: SET);
  189.         VAR S: Texts.Scanner; fnt: Fonts.Font; text: Texts.Text; beg, end, time: LONGINT; col, off: SHORTINT;
  190.     BEGIN GetArg(S); Oberon.GetSelection(text, beg, end, time);
  191.         IF time >= 0 THEN
  192.             IF (sel = {0}) & (S.class = Texts.Name) THEN fnt := Fonts.This(S.s)
  193.             ELSIF (sel = {1}) & (S.class = Texts.Int) & (0 <= S.i) & (S.i < 16) THEN col := SHORT(SHORT(S.i))
  194.             ELSIF (sel = {2}) & (S.class = Texts.Int) & (-128 <= S.i) & (S.i < 128) THEN off := SHORT(SHORT(S.i))
  195.             ELSE sel := {}
  196.             END;
  197.             IF sel # {} THEN Texts.ChangeLooks(text, beg, end, sel, fnt, col, off) END
  198.         END
  199.     END Change;
  200.     (* commands *)
  201.     PROCEDURE Locate*;
  202.         VAR S: Texts.Scanner; F: TextFrames.Frame; text: Texts.Text; beg, end, time: LONGINT;
  203.     BEGIN F := MarkedFrame(); Oberon.GetSelection(text, beg, end, time);
  204.         IF time > 0 THEN Texts.OpenScanner(S, text, beg); Texts.Scan(S);
  205.             WHILE (S.class # Texts.Int) & (S.line = 0) & ~S.eot DO Texts.Scan(S) END;
  206.             IF (F # NIL) & (S.class = Texts.Int) & (S.line = 0) THEN ShowPos(F, S.i); SetCaret(F, S.i) END
  207.         END;
  208.     END Locate;
  209.     PROCEDURE Search*;
  210.         VAR F: TextFrames.Frame; T: Texts.Text; i, beg, end, time: LONGINT;
  211.     BEGIN Oberon.GetSelection(T, beg, end, time); F := TargetFrame();
  212.         IF time > find.time THEN find.time := time; find.len := Min(end - beg, MaxPat);
  213.             Texts.OpenReader(R, T, beg); i := 0;
  214.             REPEAT Texts.Read(R, find.buf[i]); INC(i) UNTIL i = find.len
  215.         END;
  216.         IF F # NIL THEN
  217.             IF F.hasCar THEN beg := F.carloc.pos ELSE beg := 0 END;
  218.             Find(F.text, beg, end);
  219.             IF end >= 0 THEN ShowPos(F, end); SetCaret(F, end)
  220.             ELSE TextFrames.RemoveCaret(F)
  221.             END;
  222.             TextFrames.RemoveSelection(F)
  223.         END
  224.     END Search;
  225.     PROCEDURE Show*;
  226.         VAR S: Texts.Scanner; F: TextFrames.Frame; text: Texts.Text;
  227.             i, j, beg, end, time: LONGINT;
  228.             name: ARRAY Modules.ModNameLen + 4 OF CHAR;
  229.     BEGIN text := Oberon.Par.text; beg := Oberon.Par.pos; end := Oberon.Par.text.len; time := Oberon.Time();
  230.         Texts.OpenScanner(S, text, beg); Texts.Scan(S);
  231.         IF (S.class = Texts.Char) & (S.c = "^") OR (S.line > 0) THEN Oberon.GetSelection(text, beg, end, time);
  232.             IF time >= 0 THEN Texts.OpenScanner(S, text, beg); Texts.Scan(S) END
  233.         END;
  234.         IF (time >= 0) & (S.class = Texts.Name) THEN i := 0;
  235.             WHILE (S.s[i] # 0X) & (S.s[i] # ".") DO name[i] := S.s[i]; INC(i) END;
  236.             IF i < Modules.ModNameLen THEN
  237.                 name[i] := "."; name[i+1] := "M"; name[i+2] := "o"; name[i+3] := "d"; name[i+4] := 0X;
  238.                 find.len := 0; j := i + 1; 
  239.                 WHILE S.s[j] # 0X DO find.buf[find.len] := S.s[j]; INC(find.len); INC(j) END;
  240.                 find.buf[find.len] := 0FFX; INC(find.len);
  241.                 find.time := time;
  242.                 text := TextFrames.Text(name);
  243.                 Find(text, 0, end); IF end < 0 THEN end := 0 END;
  244.                 F := NewView(name, Texts.Name, text, end);
  245.                 IF end > 0 THEN SetCaret(F, end) END
  246.             END
  247.         END
  248.     END Show;
  249.     PROCEDURE Recall*;
  250.         VAR B: Texts.Buffer; copyover: Oberon.CopyOverMsg;
  251.     BEGIN Texts.Recall(B);
  252.         IF B # NIL THEN copyover.beg := 0; copyover.end := B.len;
  253.             copyover.text := TextFrames.Text(""); Texts.Append(copyover.text, B);
  254.             Oberon.FocusViewer.handle(Oberon.FocusViewer, copyover)
  255.         END
  256.     END Recall;
  257.     PROCEDURE ClearReplaceBuffer*;
  258.     BEGIN Texts.OpenBuf(repl.buf)
  259.     END ClearReplaceBuffer;
  260.     PROCEDURE Replace*;
  261.         VAR F: TextFrames.Frame; T: Texts.Text; beg, end: LONGINT;
  262.     BEGIN F := TargetFrame(); SetReplBuf;
  263.         IF (F # NIL) & F.hasCar THEN T := F.text; end := F.carloc.pos; beg := end - find.len;
  264.             TextFrames.RemoveSelection(F);
  265.             IF Check(T, beg) THEN Subst(T, beg, end) END;
  266.             Find(T, end, beg);
  267.             IF beg >= 0 THEN ShowPos(F, beg); SetCaret(F, beg)
  268.             ELSE TextFrames.RemoveCaret(F)
  269.             END
  270.         END
  271.     END Replace;
  272.     PROCEDURE ReplaceAll*;
  273.         VAR F: TextFrames.Frame; T: Texts.Text; beg, end: LONGINT;
  274.     BEGIN F := TargetFrame(); SetReplBuf;
  275.         IF (F # NIL) & F.hasCar THEN T := F.text; end := F.carloc.pos; beg := end - find.len;
  276.             TextFrames.RemoveSelection(F);
  277.             IF Check(T, beg) THEN Subst(T, beg, end) END;
  278.             LOOP Find(T, end, beg);
  279.                 IF beg < 0 THEN EXIT END;
  280.                 Subst(T, beg - find.len, end)
  281.             END
  282.         END
  283.     END ReplaceAll;
  284.     PROCEDURE ChangeFont*;
  285.     BEGIN Change({0})
  286.     END ChangeFont;
  287.     PROCEDURE ChangeColor*;
  288.     BEGIN Change({1})
  289.     END ChangeColor;
  290.     PROCEDURE ChangeOffset*;
  291.     BEGIN Change({2})
  292.     END ChangeOffset;
  293.     PROCEDURE ChangeBackgroundColor*;
  294.         VAR F: TextFrames.Frame; m: MenuViewers.ModifyMsg; S: Texts.Scanner; H: INTEGER;
  295.     BEGIN F := MarkedFrame();
  296.         IF F # NIL THEN GetArg(S);
  297.             IF S.class = Texts.Int THEN
  298.                 F.col := SHORT(SHORT(S.i)); m.id := MenuViewers.extend; m.Y := F.Y; H := F.H;
  299.                 m.H := 0; F.handle(F, m); (*suspend*)
  300.                 m.H := H; F.handle(F, m) (*extend*)
  301.             END
  302.         END
  303.     END ChangeBackgroundColor;
  304.     PROCEDURE InsertParc*;
  305.         VAR copy: Texts.CopyMsg; insert: TextFrames.InsertElemMsg;
  306.     BEGIN
  307.         TextFrames.defParc.handle(TextFrames.defParc, copy); insert.e := copy.e;
  308.         Oberon.FocusViewer.handle(Oberon.FocusViewer, insert)
  309.     END InsertParc;
  310.     PROCEDURE Parcs*;
  311.         VAR S: Texts.Scanner; V: Viewers.Viewer; F: TextFrames.Frame; um: TextFrames.UpdateMsg;
  312.             end: LONGINT; R: Texts.Reader;
  313.     BEGIN
  314.         IF Oberon.Par.frame # Oberon.Par.vwr.dsc THEN Texts.OpenScanner(S, Oberon.Par.text, Oberon.Par.pos);
  315.             Texts.Scan(S);
  316.             IF (S.class = Texts.Char) & (S.line = 0) & (S.c = "*") THEN V := Oberon.MarkedViewer() ELSE V := NIL END
  317.         ELSE V := Oberon.Par.vwr
  318.         END;
  319.         IF (V # NIL) & (V IS MenuViewers.Viewer) & (V.dsc.next IS TextFrames.Frame) THEN
  320.             F := V.dsc.next(TextFrames.Frame); F.showsParcs := ~ F.showsParcs;
  321.             Texts.OpenReader(R, F.text, F.org); Texts.ReadElem(R); end := TextFrames.Pos(F, F.X + F.W, F.Y);
  322.             WHILE (Texts.Pos(R) <= end) & (R.elem # NIL) & ~(R.elem IS TextFrames.Parc) DO Texts.ReadElem(R) END;
  323.             IF (R.elem # NIL) & (R.elem IS TextFrames.Parc) & (Texts.Pos(R) <= end) THEN
  324.                 um.id := Texts.replace; um.text := F.text; um.end := end;
  325.                 um.beg := Texts.Pos(R)-1;
  326.                 F.handle(F, um)
  327.             END
  328.         END
  329.     END Parcs;
  330.     PROCEDURE Open*;
  331.         VAR S: Texts.Scanner; F: TextFrames.Frame; end: LONGINT;
  332.     BEGIN Texts.OpenScanner(S, Oberon.Par.text, Oberon.Par.pos); GetMainArg(S, end);
  333.         IF (S.class = Texts.Name) OR (S.class = Texts.String) THEN
  334.             F := NewView(S.s, S.class, TextFrames.Text(S.s), 0);
  335.             ShowAliens(F.text)
  336.         END
  337.     END Open;
  338.     PROCEDURE Store*;
  339.         VAR S: Texts.Scanner; R: Texts.Reader; V: Viewers.Viewer; T: Texts.Text; ch: CHAR;
  340.     BEGIN V := NIL;
  341.         IF Oberon.Par.frame = Oberon.Par.vwr.dsc THEN V := Oberon.Par.vwr
  342.         ELSIF Oberon.Pointer.on THEN  V := Oberon.MarkedViewer()
  343.         END;
  344.         IF (V # NIL) & (V IS MenuViewers.Viewer) & (V.dsc IS TextFrames.Frame) & (V.dsc.next IS TextFrames.Frame) THEN
  345.             Texts.OpenScanner(S, V.dsc(TextFrames.Frame).text, 0); Texts.Scan(S);
  346.             IF (S.class = Texts.Name) OR (S.class = Texts.String) THEN
  347.                 Str("Edit.Store "); Str(S.s); T := V.dsc.next(TextFrames.Frame).text;
  348.                 Texts.Close(T, S.s); Int(T.len); Ln;
  349.                 T := V.dsc(TextFrames.Frame).text;
  350.                 Texts.OpenReader(R, T, T.len - 1); Texts.Read(R, ch);
  351.                 IF ch = "!" THEN Texts.Delete(T, T.len - 1, T.len) END
  352.             END
  353.         END
  354.     END Store;
  355.     PROCEDURE Set*;
  356.         VAR S: Texts.Scanner; R: Texts.Reader; text: Texts.Text; P: TextFrames.Parc;
  357.             msg: ParcElems.StateMsg; pos, beg, end, time: LONGINT;
  358.     BEGIN GetArg(S); Oberon.GetSelection(text, beg, end, time);
  359.         IF time >= 0 THEN Texts.OpenReader(R, text, beg); 
  360.             REPEAT Texts.ReadElem(R); pos := Texts.Pos(R);
  361.                 IF ~R.eot & (pos <= end) & (R.elem IS TextFrames.Parc) THEN
  362.                     msg.id := ParcElems.set; msg.pos := pos - 1; msg.frame := NIL; msg.par := S; msg.log := Oberon.Log;
  363.                     P := R.elem(TextFrames.Parc); P.handle(P, msg);
  364.                 END
  365.             UNTIL R.eot OR (pos > end)
  366.         ELSE Str("Edit.Set failed (no parc selected)"); Ln
  367.         END
  368.     END Set;
  369.     PROCEDURE Get*;
  370.         VAR S: Texts.Scanner; R: Texts.Reader; text: Texts.Text; P: TextFrames.Parc; pos, beg, end, time: LONGINT;
  371.             msg: ParcElems.StateMsg;
  372.     BEGIN GetArg(S); Oberon.GetSelection(text, beg, end, time);
  373.         IF time >= 0 THEN
  374.             Texts.OpenReader(R, text, beg); Texts.ReadElem(R); pos := Texts.Pos(R);
  375.             IF ~R.eot & (pos <= end) & (R.elem IS TextFrames.Parc) THEN
  376.                 Str("Edit.Set ^ ");
  377.                 msg.id := ParcElems.get; msg.pos := pos - 1; msg.frame := NIL; msg.par := S; msg.log := Oberon.Log;
  378.                 P := R.elem(TextFrames.Parc); P.handle(P, msg)
  379.             ELSE Str("Edit.Get failed (no parc selected)")
  380.             END
  381.         ELSE Str("Edit.Get failed (no parc selected)")
  382.         END;
  383.     END Get;
  384.     PROCEDURE Print*;
  385.         VAR S, S1: Texts.Scanner; V: Viewers.Viewer; F: TextFrames.Frame; end: LONGINT; draft: BOOLEAN;
  386.         PROCEDURE PrintText(VAR S: Texts.Scanner; T: Texts.Text; name: ARRAY OF CHAR; draft: BOOLEAN);
  387.             CONST headerLen = 128;
  388.             VAR pos, len: LONGINT; ch: CHAR;
  389.                 hx, hy, hw, bx, by, bw, bh, i, k: INTEGER;
  390.                 nofcopies, pno, first, last, arab: INTEGER;
  391.                 fnt: Fonts.Font; label, labelfirst, alt: BOOLEAN;
  392.                 header: ARRAY headerLen OF CHAR;
  393.         BEGIN hx := headerX; hw := headerW;
  394.             hy := SHORT((LONG(Printer.PageHeight) * Unit - 17 * mm) DIV Unit);
  395.             bx := bodyX; by := bodyY; bw := bodyW;
  396.             bh := SHORT((LONG(Printer.PageHeight) * Unit - 37 * mm) DIV Unit);
  397.             nofcopies := 1; pno := 0; first := 0; last := 10000; arab := 1;
  398.             label := TRUE; labelfirst := TRUE; alt := FALSE;
  399.             header[0] := 0X; fnt := Fonts.Default;
  400.             Texts.Scan(S);
  401.             WHILE (S.class = Texts.Char) & (S.c = OptionChar) DO
  402.                 Texts.Scan(S);
  403.                 IF S.class = Texts.Name THEN ch := CAP(S.s[0]);
  404.                     IF ch # "H" THEN Texts.Scan(S) END;
  405.                     IF ch = "A" THEN alt := TRUE
  406.                     ELSIF (ch = "C") & (S.class = Texts.Int) & (1 <= S.i) & (S.i < 10) THEN nofcopies := SHORT(S.i); Texts.Scan(S)
  407.                     ELSIF (ch = "F") & (S.class = Texts.Name) THEN fnt := Fonts.This(S.s); Texts.Scan(S)
  408.                     ELSIF ch = "H" THEN
  409.                         REPEAT Texts.Read(S, ch) UNTIL (ch > " ") OR S.eot;
  410.                         IF ch = 22X THEN i := 0; (* read string *)
  411.                             REPEAT Texts.Read(S, ch); header[i] := ch; INC(i) UNTIL (ch = 22X) OR (ch = CR);
  412.                             header[i-1] := 0X; Texts.Read(S, ch);
  413.                             (*COPY(S.s, header); Texts.Scan(S)*)
  414.                         ELSE COPY(name, header); AppendDate(header)
  415.                         END;
  416.                         S.nextCh := ch; Texts.Scan(S);
  417.                     ELSIF ch = "M" THEN    (*margin options*)
  418.                         IF S.class = Texts.Name THEN ch := CAP(S.s[0]); Texts.Scan(S); i := 0;
  419.                             WHILE (S.class = Texts.Int) & (0 <= S.i) DO
  420.                                 k := SHORT(S.i * Scale DIV TextPrinter.Unit); INC(i); Texts.Scan(S);
  421.                                 IF ch = "H" THEN
  422.                                     IF i = 1 THEN hx := k ELSIF i = 2 THEN hy := k ELSIF i = 3 THEN hw := k END
  423.                                 ELSIF ch = "B" THEN
  424.                                     IF i = 1 THEN bx := k ELSIF i = 2 THEN by := k
  425.                                     ELSIF i = 3 THEN bw := k ELSIF i = 4 THEN bh := k
  426.                                     END
  427.                                 END
  428.                             END
  429.                         END
  430.                     ELSIF ch = "P" THEN    (*page numbering options*)
  431.                         IF (S.class = Texts.Int) & (0 <= S.i) THEN pno := SHORT(S.i); first := pno; Texts.Scan(S)
  432.                         ELSIF S.class = Texts.Name THEN ch := CAP(S.s[0]); Texts.Scan(S);
  433.                             IF ch = "F" THEN labelfirst := FALSE
  434.                             ELSIF ch = "N" THEN label := FALSE
  435.                             ELSIF ch = "R" THEN arab := -1;
  436.                                 IF first = 0 THEN pno := 1; first := 1 END
  437.                             END
  438.                         END
  439.                     ELSIF (ch = "S") & (S.class = Texts.Int) & (0 <= S.i) THEN first := SHORT(S.i); Texts.Scan(S);
  440.                         IF (S.class = Texts.Int) & (0 <= S.i) THEN last := SHORT(S.i); Texts.Scan(S) ELSE last := first END
  441.                     END
  442.                 END
  443.             END;
  444.             Ch(" "); Str(name); Int(nofcopies); Ch(" ");
  445.             IF draft THEN TextPrinter.PrintDraft(T, name, nofcopies)
  446.             ELSE pos := 0; len := T.len;
  447.                 WHILE (pos < len) & (pno <= last) & (Printer.res = 0) DO
  448.                     IF (first <= pno) & label & labelfirst THEN
  449.                         TextPrinter.PlaceHeader(hx, hy, hw, arab*pno, fnt, header, alt)
  450.                     END;
  451.                     TextPrinter.PlaceBody(bx, by, bw, bh, T, pos, pno, (first <= pno) & (pno <= last));
  452.                     IF first <= pno THEN Printer.Page(nofcopies); Ch(".") ELSE Ch("'") END;
  453.                     INC(pno); labelfirst := TRUE
  454.                 END
  455.             END;
  456.             Ln
  457.         END PrintText;
  458.     BEGIN Str("Edit.Print "); Texts.OpenScanner(S, Oberon.Par.text, Oberon.Par.pos); Texts.Scan(S);
  459.         IF ((S.class = Texts.Name) OR (S.class = Texts.String)) & (S.line = 0) THEN Str(S.s);
  460.             Printer.Open(S.s, Oberon.User, Oberon.Password); TextPrinter.InitFonts;
  461.             IF Printer.res = 0 THEN GetMainArg(S, end);
  462.                 IF (S.class = Texts.Char) & (S.c = "%") THEN draft := TRUE; Texts.Scan(S) ELSE draft := FALSE END;
  463.                 IF Oberon.Par.frame = Oberon.Par.vwr.dsc THEN
  464.                     F := Oberon.Par.frame(TextFrames.Frame);
  465.                     IF (F.next # NIL) & (F.next IS TextFrames.Frame) THEN
  466.                         Texts.OpenScanner(S1, F.text, 0); Texts.Scan(S1);
  467.                         PrintText(S, F.next(TextFrames.Frame).text, S1.s, draft)
  468.                     END
  469.                 ELSIF (S.class = Texts.Char) & (S.c = "*") THEN V := Oberon.MarkedViewer();
  470.                     IF (V IS MenuViewers.Viewer) & (V.dsc.next IS TextFrames.Frame) THEN
  471.                         Texts.OpenScanner(S1, V.dsc(TextFrames.Frame).text, 0); Texts.Scan(S1);
  472.                         IF S1.class # Texts.Name THEN S1.s[0] := "*"; S1.s[1] := 0X END;
  473.                         PrintText(S, V.dsc.next(TextFrames.Frame).text, S1.s, draft)
  474.                     ELSE Str(" failed (bad * marker)"); Ln
  475.                     END
  476.                 ELSIF S.class = Texts.Name THEN
  477.                     REPEAT PrintText(S, TextFrames.Text(S.s), S.s, draft)
  478.                     UNTIL S.eot OR (S.class # Texts.Name) OR (Texts.Pos(S) > end)
  479.                 ELSE Ln
  480.                 END;
  481.                 Printer.Close
  482.             ELSE Str(" failed (");
  483.                 IF Printer.res = 1 THEN Str("no such printer)")
  484.                 ELSIF Printer.res = 2 THEN Str("no link)")
  485.                 ELSIF Printer.res = 3 THEN Str("printer not ready)")
  486.                 ELSIF Printer.res = 4 THEN Str("no permission)")
  487.                 ELSE Str("res ="); Int(Printer.res); Str(" ?)")
  488.                 END;
  489.                 Ln
  490.             END
  491.         ELSE Str("failed (no printer specified)"); Ln
  492.         END
  493.     END Print;
  494. BEGIN Texts.OpenWriter(W);
  495.     mnam := "JanFebMarAprMayJunJulAugSepOctNovDec";
  496.     find.time := -1; find.len := 0;
  497.     repl.time := -1; NEW(repl.buf); Texts.OpenBuf(repl.buf)
  498. END Edit.
  499.