home *** CD-ROM | disk | FTP | other *** search
/ Fujiology Archive / fujiology_archive_v1_0.iso / !MAGS / GENIE / JULNEWS.ZIP / HATCHER.BAS (.txt) next >
Encoding:
GW-BASIC  |  1995-07-09  |  2.6 KB  |  42 lines
  1. 10  'HATCHER.BAS - REF. COOPER/COMPLETE BOOK OF MODERN HANDGUNNING, P. 83
  2. 20  'PROGRAMMED BY JOHN L. MARSHALL, EL PASO TEXAS, NRA LIFE MEMBER
  3. 30  CLS
  4. 40  PRINT "This program finds the relative stopping power and f.p.e. for pistol bullets"
  5. 50  PRINT "for bullets at velocities under 1800 f.p.s. (Gen. Julian Hatcher's scale)."
  6. 60  PRINT "Final index figure is relative only (COMPARISON: .45 ACP HARDBALL = ";:COLOR 0,7:PRINT "59.21182";:COLOR 7,0:PRINT ")."
  7. 70  PRINT "                                                          (F.P.E. = 335.1612)"
  8. 80  LINE INPUT "GIVE THE CARTRIDGE'S SPECIFIC NAME:          ",C$
  9. 90  INPUT "GIVE THE BULLET WEIGHT IN GRAINS:            ",W
  10. 100  INPUT "GIVE THE VELOCITY OF THE BULLET IN F.P.S. :  ",V
  11. 110  IF V=>1800 THEN BEEP:PRINT "SORRY. VELOCITY TOO HIGH FOR THIS PURPOSE.":INPUT "PLEASE PRESS 'ENTER' TO START OVER.",A$:GOTO 10
  12. 120  PRINT "CROSS SECTIONAL AREAS IN SQUARE INCHES: "
  13. 130  PRINT "     .22       =  .039       ---        .41           = .127"
  14. 140  PRINT "     .25       =  .049       ---        .44-40        = .143"
  15. 150  PRINT "     .30       =  .075       ---        .44 SPEC/MAG  = .146"
  16. 160  PRINT "     .32       =  .076       ---        .45 AUTO      = .159"
  17. 170  PRINT "     .357/9MM  =  .102       ---        .45 COLT      = .163"
  18. 180  INPUT "GIVE CROSS SECTIONAL AREA AS ABOVE: ",CS
  19. 190  IF CS <0.039 OR CS >0.163 THEN BEEP:PRINT "ANSWER OUTSIDE PARAMETERS.  DO AGAIN, PLEASE.":LOCATE 14,37:PRINT "        ":LOCATE 14,1:GOTO 180
  20. 200  W=W/7000:M=W/32.16:MOM=M*V:R=MOM*CS
  21. 210  'WEIGHT IN LBS = WEIGHT IN GRAINS DIVIDED BY 7000 (THERE ARE 7000 GRAINS TO THE LB.
  22. 220  'MASS (M) = WEIGHT IN LBS DIVIDED BY THE CONSTANT OF GRAVITY (32.16)
  23. 230  'MOMENTUM (MOM) IS MASS TIMES VELOCITY
  24. 240  LOCATE 15,15:PRINT "                                  ":LOCATE 15,1
  25. 250  PRINT "SHAPE FACTORS:"
  26. 260  PRINT "  Lead round nose     1000   Lead blunt point 1050   (Expandable HP) 1300"
  27. 270  PRINT "  Jacketed round nose  900   Semi-flat point  1100   (Jacketed FP)   1100"
  28. 280  PRINT "  Semi-wadcutter (K)  1250   Wadcutter        1250   (Glaser SS)     1800"
  29. 290  LOCATE 19,59:PRINT "(Estimated)":LOCATE 19,1
  30. 300  PRINT:INPUT "GIVE SHAPE FACTOR AS ABOVE: ",SF
  31. 310  IF SF <900 OR SF >1800 THEN BEEP:PRINT "SORRY.  YOUR ANSWER WAS OUTSIDE ACCEPTABLE PARAMETERS.  PLEASE TRY AGAIN.":LOCATE 19,1:GOTO 300
  32. 320  HAT=(R*SF)/2
  33. 330  FPE = (M*(V*V))/2
  34. 340  LOCATE 21,1:PRINT "                                                                           ";
  35. 350  PRINT:COLOR 1,0:PRINT "HATCHER RELATIVE STOPPING POWER INDEX:";:COLOR 7,0:PRINT " ";:COLOR 0,7:PRINT HAT;:COLOR 7,0:PRINT "     FT/LBS ENERGY: ";FPE
  36. 360  C=HAT/59.2118:D$ = "##.##"
  37. 370  IF C<1 THEN PRINT "                                       (THIS IS ";:PRINT USING D$;C;:PRINT " OF THE .45 AUTO'S INDEX)"
  38. 380  IF C=>1 THEN PRINT "                                    (THIS IS ";:PRINT USING D$;C;:PRINT " TIMES THE .45 AUTO'S INDEX)"
  39. 390  INPUT "DO AGAIN? (Y/N) ",A$
  40. 400  IF A$ = "Y" OR A$ = "y" THEN GOTO 30
  41. 410  SYSTEM
  42.