home *** CD-ROM | disk | FTP | other *** search
/ Chestnut's Multimedia Mania / MM_MANIA.ISO / midi / cmtcmu / timdif.asm < prev    next >
Assembly Source File  |  1990-06-28  |  14KB  |  417 lines
  1. ;version 1 released 6-10-86 
  2.     title timdif - real time at different than clock rate 
  3. debug=-1 ;set to -1 to turn on debugging code 
  4. ;written by Aaron Wohl 
  5. ;       for Roger Dannerberg 
  6. ;        at The Center for the Arts and technolagy 
  7. ;           Carnegie Mellon University 
  8. ;        5000 Forbes Ave 
  9. ;        Pittsburgh, PA 15xxx 
  10. ; 
  11. ;change log: 
  12. ; Jun 10 86 avw      - release version 1 
  13. ; Jun 04 86 avw      - create from wohl's personal timer.asm 
  14. ; 
  15. ;this module provides a 32bit timer that counts at a rate different than 
  16. ;the ~54ms time provided by the bios.  It is currently configured to 
  17. ;count in 10ms tics. 
  18. ; 
  19. ;The idea is to do subtractions and keep a remainder instead of dividing 
  20. ;the bios and timer chip time to save divide or multiply instructions. 
  21. ;This is probably only a good idea if the rate you want is near the 
  22. ;bios rate. 
  23. ; 
  24. ;things to do: 
  25. ; change dodiv to be alot smarter and faster.  it currently loops 
  26. ; subtracting divr from rem, instead subtract 3*divr and see if there 
  27. ; is a borrow and go from there.  this will decrease the maximum divide time. 
  28.   
  29. ;************************************************************************ 
  30. ;*                                    * 
  31. ;*    Module interface specifications                    * 
  32. ;*                                    * 
  33. ;************************************************************************ 
  34. ; ibm_time - this routine is the reason this module exists, it returns the 
  35. ;       current time in 10ms tics. 
  36. ;     note:ibm_time() may not be called with interupts disabled 
  37. ;usage: unsigned long i,ibm_time(); i=ibm_time(); 
  38. ; 
  39. ; cletime - stop our timer.  crash the system if timer not currently running. 
  40. ;usage: cletime(); 
  41. ; 
  42. ; settime - zero our timer and start counting.  crash the system if our timer 
  43. ;       is already running. 
  44. ;       if debbuging, also zero the value gettic() returns (see gettic) 
  45. ;usage: settime(); 
  46. ; 
  47. ; overall usage: 
  48. ;  a) call settime() to start the timer 
  49. ;  b) call ibm_time() as many times as you like to get the time. 
  50. ;  c) call cletime() to stop timing 
  51. ;  d) exit the program, or if you like, goto step a) 
  52.   
  53. ;************************************************************************ 
  54. ;*                                    * 
  55. ;*    Module debug interface specifications                * 
  56. ;*                                    * 
  57. ;************************************************************************ 
  58. ; gettic - return high precision (8253 counter 0) reading from when 
  59. ;       the latest interupt happened.  latest meaning the most late, the 
  60. ;       interupt delayed for the longest time. usefull for debugging to see 
  61. ;       if someone is leaving the interups off for too long. 
  62. ;     note:we must be called with debug on for gettic to function, always 
  63. ;       returns zero otherwise 
  64. ; usage: int i,getic(); i=gettic(); 
  65. ; 
  66. ; getbtim - return the 32bit bios time (it counts in ~54ms tics). 
  67. ;        usefull for debugging.  since the rest of this module runs 
  68. ;        off the same clock, this time (when converted to 10ms ticks) 
  69. ;        should never be more then 6 (10ms) ticks different. 
  70. ;usage: unsigned long i,getbtim(); i=getbtim(); 
  71. ; 
  72.   
  73. ;************************************************************************ 
  74. ;*                                    * 
  75. ;*    Timeing constants, linkages, libraries                * 
  76. ;*                                    * 
  77. ;************************************************************************ 
  78.  
  79. divr    equ 3054545        ;divider for 11931.81667 to get 10ms 
  80. divlow    equ 09bd1h        ;low word of divr 
  81. divhig    equ 0002eh        ;high word of divr 
  82.  
  83.     include macsym.lib    ;control constructs 
  84.     include prcsym.lib    ;procedure data declarators 
  85.     cmods_            ;set linkage mode to c small model 
  86.  
  87.   
  88. ;************************************************************************ 
  89. ;*                                    * 
  90. ;*    data global to timdif                        * 
  91. ;*                                    * 
  92. ;************************************************************************ 
  93.  
  94. ;define memory location of timer interupt vector 
  95. ivec    segment at 0 
  96.     org    8h*4 
  97. timvec    label word 
  98. ivec    ends 
  99.  
  100.     dseg timdat 
  101.     if debug 
  102. tictim    dw 0            ;remeber when ticks happen 
  103.     endif 
  104.  
  105. ;remainder from previous divisions as a 32 bit number low byte to high byte 
  106. ;also, used to remember part of current second already used 
  107. rem    label dword 
  108. rem0w    label word        ;a few names for things since we 
  109. rem0b    db 0            ; sometimes do byte operations and sometimes 
  110. rem1w    label word        ; do word operations 
  111. rem1b    db 0 
  112. rem2w    label word 
  113. rem2b    db 0 
  114. rem3b    db 0 
  115.  
  116. now    label dword            ;current time in our units 
  117. now0w    dw 0                ;for returning result to user 
  118. now2w    dw 0 
  119.     endds 
  120.  
  121.   
  122.     pseg prog 
  123. ;************************************************************************ 
  124. ;*                                    * 
  125. ;*    dodiv - divide bx(low word) ax(high word)            * 
  126. ;*        by tivr                            * 
  127. ;*        result in cx, remainder in ax,bx 
  128. ;*                                    * 
  129. ;*                                    * 
  130. ;************************************************************************ 
  131.  
  132. ;do divide 
  133. dodiv    proc near 
  134.     mov cx,0        ;initilize result of division 
  135.     do_ 
  136.      inc cx            ;divide happend one more time 
  137.      sub bx,divlow 
  138.      sbb ax,divhig 
  139.      jnc top_        ;loop till we borrow 
  140.     od_ 
  141.     dec cx            ;correct for going once to many times 
  142.     add bx,divlow        ;undo last subtract 
  143.     adc ax,divhig 
  144.     ret 
  145. dodiv    endp 
  146.   
  147. ;************************************************************************ 
  148. ;*                                    * 
  149. ;*    Timer routine to piggy back on bios timer interupt        * 
  150. ;*    data addressed by cs for interupt routine            * 
  151. ;*                                    * 
  152. ;************************************************************************ 
  153.  
  154. romwd    label word        ;word address of rom tim 
  155. romtim    dd ?            ;rom timer interupt address 
  156. timds    dw ?            ;data segment for timer routines 
  157.   
  158. ;************************************************************************ 
  159. ;*                                    * 
  160. ;*    Macro to read time into ax                    * 
  161. ;*    This is not a routine to save the subroutine call overhead    * 
  162. ;*                                    * 
  163. ;************************************************************************ 
  164. timprt    equ 040h        ;timer 0 port 
  165. timcmd    equ (timprt+3)        ;timer control port 
  166. latcmd    equ 000h        ;command to latch a time, timer 0 
  167. modcmd    equ 034h        ;set to mode 2 instead of mode 3 
  168.   
  169. ;************************************************************************ 
  170. ;*                                    * 
  171. ;*    Routine to return to user, when the latest timer tick happened    * 
  172. ;*                                    * 
  173. ;************************************************************************ 
  174.     public gettic 
  175.     prcent gettic 
  176.     if debug 
  177.       mov ax,tictim 
  178.     else 
  179.       xor ax,ax 
  180.     endif 
  181.     prcexi gettic        ;return the tic time to lattice c 
  182.   
  183. ;************************************************************************ 
  184. ;*                                    * 
  185. ;*    Routine for returning the current bios time            * 
  186. ;*    getbtim - return a 32bit time in our bios tics            * 
  187. ;*    only used to check our accuracy                    * 
  188. ;*                                    * 
  189. ;************************************************************************ 
  190.     public getbtim 
  191.     prcent getbtim,,,<,ds> 
  192.     mov ax,040h        ;address of rom data 
  193.     mov ds,ax 
  194.     cli 
  195.     mov bx,ds:[06ch]    ;get high and low words of the time 
  196.     mov ax,ds:[06eh] 
  197.     sti 
  198.     prcexi getbtim        ;return the time to lattice c 
  199.   
  200. ;read a latched time into cx cl=low, cx=high 
  201. REDTIM    macro 
  202.     mov al,latcmd        ;latch a timer 
  203.     out timcmd,al        ;send command to 8153 
  204.     in al,timprt        ;get low byte of time 
  205.     mov cl,al        ;save it 
  206.     in al,timprt        ;get high byte of the time 
  207.     mov ch,al 
  208.     neg cx 
  209.     endm 
  210.  
  211.   
  212. ;************************************************************************ 
  213. ;*                                    * 
  214. ;*    Routine for returning the current time                * 
  215. ;*    ibm_time - return a 32bit time in our units            * 
  216. ;*                                    * 
  217. ;************************************************************************ 
  218.     public ibm_time 
  219.     prcent ibm_time 
  220.  
  221.     do_ 
  222.      push es        ;free up es to point to 
  223.      mov ax,040h        ;address of rom data 
  224.      mov es,ax 
  225.      cli 
  226.      REDTIM            ;read timer into ax 
  227.      sti            ;do next instruction, then ints on 
  228.      mov bx,es:[06ch]    ;(interupts off here, see sti def) get time 
  229.      cli 
  230.      cmp bx,es:[06ch]    ;time change? set z flag if ok 
  231.      pop es 
  232.      jnz top_        ;if time changed then counter is wrong 
  233.     od_ 
  234. ;note: interupts are off when exiting the loop! so that now doesn't 
  235. ;      get bashed on by the timer interupt code while we are updating it 
  236. ;note: the 8253 timer counts down, so ax has the negative of the part of 
  237. ;      the tick 
  238.     mov bx,rem0w        ;get low word of remainder 
  239.     mov ax,rem2w        ;get high word 
  240.     add bh,cl 
  241.     adc al,ch 
  242.     adc ah,0 
  243.  
  244.     call dodiv        ;fixup now to be correct 
  245.  
  246.     add cx,now0w        ;get now plus part of tick 
  247.     mov ax,0 
  248.     adc ax,now2w 
  249.     sti            ;done, allow interupts now 
  250.     mov bx,cx        ;put low bits where lattice c wants them 
  251.     prcexi ibm_time         ;return bx,ax (current time) 
  252.   
  253. ;************************************************************************ 
  254. ;*                                    * 
  255. ;*    Routine for stopping our timer                    * 
  256. ;*    cletime - stop timer remove patch into bios timer        * 
  257. ;*                                    * 
  258. ;************************************************************************ 
  259.  
  260. ;clear the timer interupt routine 
  261.     public cletime 
  262.     prcent cletime,,,<,ds> 
  263.     assume ds:ivec        ;address current vectors 
  264.     mov ax,ivec 
  265.     mov ds,ax 
  266.      
  267.     cli 
  268.     mov ax,romwd 
  269.     mov timvec,ax        ;restore original interupt vector 
  270.     mov ax,romwd[2] 
  271.     mov timvec[2],ax 
  272.     sti 
  273.      
  274.     assume ds:dgroup 
  275.     prcexi cletime 
  276.  ;************************************************************************ 
  277. ;*                                    * 
  278. ;*    Routine for starting our timer                    * 
  279. ;*    settime - zero now (time starts from zero), also patch into    * 
  280. ;*         bios timer interupt so we can call timint on each    * 
  281. ;*         timer tick                        * 
  282. ;*                                    * 
  283. ;************************************************************************ 
  284.  
  285.     public settime 
  286.     prcent settime,,,<,ds> 
  287.  
  288.     xor ax,ax        ;get a zero 
  289.     if debug 
  290.      mov tictim,ax        ;clear latest tick time 
  291.     endif 
  292.     mov now0w,ax        ;clear now 
  293.     mov now2w,ax 
  294.     mov rem0w,ax        ;clear remainder 
  295.         mov rem2w,ax 
  296.  
  297. ;change the timer to mode 2 (rate generator ) so we can see what part of the 
  298. ;current tick we are in.  the rom sets it to mode 3 (square wave).  mode 3 
  299. ;counts by two then twidiles the counter output line.  thus if read the 
  300. ;timer you can't tell which half of the tick you are in.  mode 2 counts 
  301. ;by one then gives a one clock pulse tick, which is just fine with 
  302. ;the 8259 interupt controller chip. 
  303.     mov al,034h        ;set timer mode 
  304.     cli            ;lets not mess with the time interupt routine 
  305.     out timcmd,al 
  306.     xor al,al        ;something to send to timer for time 
  307.     out timprt,al        ;after setting mode need to send a time 
  308.     out timprt,al        ;to restart the timer 
  309.     sti 
  310.  
  311.     mov ax,ds        ;save stack segment 
  312.     mov timds,ax 
  313.  
  314.     assume ds:ivec        ;address current vectors 
  315.     mov ax,ivec 
  316.     mov ds,ax 
  317.      
  318.     mov ax,timvec        ;save original interupt vector 
  319.     mov romwd,ax 
  320.     mov ax,timvec[2] 
  321.     mov romwd[2],ax 
  322.  
  323.     mov ax,cs        ;get new code segment 
  324.     mov bx,offset timint    ;code routine 
  325.     cli 
  326.     mov timvec,bx        ;set new timer offset 
  327.     mov timvec[2],ax    ;set new timer segment 
  328.     sti 
  329.  
  330.     assume ds:dgroup 
  331.     prcexi settime 
  332.   
  333. ;************************************************************************ 
  334. ;*                                    * 
  335. ;*    More timer routine to piggy back on bios timer interupt        * 
  336. ;*    This page has the code that gets called by the hardware        * 
  337. ;*    Instead of the bios code                    * 
  338. ;*    It saves AX,BX,CX,DS then falls into the next page of code    * 
  339. ;*    on the users stack.                        * 
  340. ;*                                    * 
  341. ;************************************************************************ 
  342.  
  343. ;new timer interupt 
  344.     public timint;for debugging only 
  345. timint    proc far 
  346.     assume ds:nothing,es:nothing,ss:nothing    ;we know nothing, nothing 
  347. ;note: it is safe to use 5 stack levels in a timer routine since the 
  348. ;      bios interupt we replace does.  (save 4 regs, allowing one stack 
  349. ;      level left for the call to dodiv) 
  350.     push ax 
  351.     push bx 
  352.     push cx 
  353.     push ds 
  354.     mov ax,timds        ;set new ss and sp 
  355.     mov ds,ax        ;set ds for user routine 
  356.     assume ds:dgroup,ss:dgroup 
  357.   
  358. ;************************************************************************ 
  359. ;*                                    * 
  360. ;*    More timer routine to piggy back on bios timer interupt        * 
  361. ;*    We take care of keeping our time up to date            * 
  362. ;*                                    * 
  363. ;*    Debugging code, remember what part of a tick interupts happen    * 
  364. ;*                                    * 
  365. ;************************************************************************ 
  366.     if debug 
  367.       REDTIM        ;see when it is 
  368.       cmp tictim,cx        ;later than before? 
  369.       ifskp_ nc        ;remember time if yes 
  370.        mov tictim,cx    ;remember it 
  371.       endif_ 
  372.     endif 
  373.   
  374. ;************************************************************************ 
  375. ;*                                    * 
  376. ;*    More timer routine to piggy back on bios timer interupt        * 
  377. ;*    We take care of keeping our time up to date            * 
  378. ;*                                    * 
  379. ;************************************************************************ 
  380.  
  381. ;get number to divide 
  382.     mov bx,rem0w        ;get low word of remainder 
  383.     mov ax,rem2w        ;get high word 
  384.     inc ah            ;one more tick has passed 
  385.  
  386.     call dodiv        ;update now accordingly 
  387.  
  388. ;put back current remainder 
  389.     mov rem0w,bx 
  390.     mov rem2w,ax 
  391.  
  392. ;add result into now 
  393.     add now0w,cx        ;move the time forward 
  394.     ifskp_ nc        ;carry out of low word? 
  395.      inc now2w        ;had a carry, propagate it 
  396.     endif_ 
  397.   
  398. ;************************************************************************ 
  399. ;*                                    * 
  400. ;*    NOTE: execution runs into this page from above (save call/ret)    * 
  401. ;*    More timer routine to piggy back on bios timer interupt        * 
  402. ;*    This page restores AX,BX,CX,DS,SS,SP then jumps to the normal    * 
  403. ;*    bios code.                            * 
  404. ;*                                    * 
  405. ;************************************************************************ 
  406.  
  407.     assume ds:nothing,ss:nothing 
  408.     pop ds 
  409.     pop cx 
  410.     pop bx 
  411.     pop ax 
  412.     jmp romtim 
  413. timint    endp 
  414.  
  415.     endps 
  416.     end 
  417.