home *** CD-ROM | disk | FTP | other *** search
/ Jason Aller Floppy Collection / 106.img / MIRROR2.ZIP / CALC.XTS < prev    next >
Text File  |  1988-12-15  |  12KB  |  397 lines
  1. ;*****************************************************************
  2. ;*         Sample script : Calc version 4              *
  3. ;*  Simple calculator with user-defined number of decimal places *
  4. ;*  available up to maximum of 4 (no floating decimal)           *
  5. ;*  (This version is a sub-script of Point-&-Dial)         *
  6. ;*****************************************************************
  7. abort disable
  8.  
  9. ad c prism
  10. if #= 1 ju checkspace
  11. cl
  12. al 3n : al 3n
  13. me
  14. [12,15][h]PRISM add-in module must be loaded to run this script.[n]
  15. [14,15]Please consult your Mirror III User's Guide for information
  16. [15,15]on the [h]ADdin load[n] command and use of the [h]MIRROR.CFG[n] file.
  17. .
  18. ab
  19.  
  20. LABEL CHECKSPACE
  21. ;  Prism is loaded...check to see if enough SAVESPACE is available.
  22. if (savespace >= 1500) jump all_go
  23. cl
  24. al 3n : al 3n
  25. me
  26. [12,15][h]You need at least 1500 bytes of SAVESCREEN space to run CALC.[n]
  27. [14,15]Please consult your Mirror III User's Guide for information
  28. [15,15]on the [h]ADdin load[n] command and use of the [h]MIRROR.CFG[n] file.
  29. .
  30. ab
  31.  
  32. LABEL ALL_GO
  33. sc l kk :         ;hide command line
  34. sc t
  35. box at 1,1 size 25,80 color "kk" 
  36. background return
  37.  
  38. LABEL DECL
  39. me [10,10]One moment please...
  40. var  real op, total, tens[5]
  41. var  integer l, r, c, z, count, d
  42. var  string ch[2,1], colors[3,2], formt[5,4], pth[67]
  43.  
  44. var  integer mode 
  45. ;     0 = none, 1 = plus, 2 = minus, 3 = times, 4 = divide, 5 = equal
  46.  
  47. jump /r setup
  48. jump /r show_calc
  49. me [22,41][wk] Press [Yk]F1[wk] for help 
  50. jump show_tape
  51.  
  52. LABEL LOOP
  53. ch[2] = ch[1]
  54. LABEL LOOP2
  55. ;    Loop2 is used when keys other than digits & math operators 
  56. ;    are pressed. These other keys are not recorded in ch[2]
  57. z = inkey(-1)
  58. if (z = keyval("esc")) jump exit
  59. sound 1004,10 :             ;    keyclick
  60. ch[1] = upcase(chr(z))
  61.  
  62. l =  instr("0123456789",ch[1])
  63. if (l > 0) jump acc
  64.  
  65. l = inlist(z,13,keyval("f1"),keyval("alt-d"),keyval("alt-c"))
  66. if (l = 1) ch[1] = "="
  67. on l jump equal,help,set_decimal,show_tape
  68.  
  69. l = instr("+-*/PMTD=CS.O",ch[1]) 
  70. on l jump plus,minus,mult,div,plus,minus,mult,div
  71. on (l-8) jump equal,clear,sign_change,point,exit
  72.  
  73. if (z = keyval("up-arrow")) scroll at 6,41 size 14,16 : jump loop2
  74. if (ch[1] = "E") jump cl_entry
  75. ;    An invalid key was pushed. Ignore it.
  76. jump loop2
  77.  
  78. LABEL ACC
  79. ;    Build the current operand
  80. l = l - 1
  81. if (op < 0) l = -1 * l
  82. if (mode = 5) mode = 0 : total = 0
  83. if (count = 0)  op = (op * 10) + l  : ju sayit
  84.  
  85. ;    COUNT <> 0 so we must be entering digits after the decimal point
  86.  
  87. op = op + (l * tens[count])
  88. if (count < 5) count = count + 1
  89. LABEL SAYIT
  90. ;     Display the current operand
  91. say at 3,10; color colors[1]; op:@(formt[d])
  92. jump loop
  93.  
  94. LABEL CLEAR
  95. ;    Flash the CLEAR button & clear the calculator
  96. say at 8,19; color "Ww";"  C  "
  97. for z = 1 to 2
  98. box at 7,18 size 3,7   style 4 color colors[3] hollow
  99. box at 7,18 size 3,7   style 4 color colors[2] hollow
  100. next
  101. say at 8,19; color "Wb";"  C  "
  102.  
  103. say at 3,23; color colors[2]; " "
  104. total = 0
  105. mode = 0
  106. ;    write to tape
  107. scroll up 2 at 6,41 size 14,16
  108. say at 19,43; color colors[2]; total:@(formt[d]); " c"
  109. jump disp_total
  110.  
  111. LABEL CL_ENTRY
  112. ;    Clear current operand, but not operation or total
  113. op = 0
  114. count = 0  :  ;    RESET DECIMAL (NOT ENTERING DIGITS AFTER THE DEC. PT.)   
  115. if (0 < instr(digit+".",ch[2])) say at 3,10; color colors[1]; op:@(formt[d]);
  116. jump loop2
  117.  
  118. LABEL SIGN_CHANGE
  119. ;    change operand's sign, if operand is being entered
  120. if (0 <> instr("+-*/PMTD=",ch[2])) jump loop2
  121. op = op * -1
  122. say at 3,10; color colors[1]; op:@(formt[d]);
  123. jump loop2
  124.  
  125. LABEL POINT
  126. ;    Handles display of decimal point
  127. if (d = 1) jump loop2 :           ;; we are in INTEGER mode. ignore
  128. if (count <> 0) jump loop2      : ;; decimal point was already entered
  129. count = 1 :                 ;; indicates 1st place after dec. 
  130. say at 3,10; color colors[1]; op:@(formt[d])
  131. jump loop2
  132.  
  133. LABEL PLUS
  134. say at 3,23; color colors[2]; "+"
  135. count = 0
  136. if (0 = instr("+-*/PMTD=",ch[2])) jump plus1
  137. ;    Here, An operator was the LAST thing entered 
  138. mode = 1  
  139. scroll at 6,41 size 14,16 
  140. say at 19,43; color colors[2]; ; total:@(formt[d]);" +";
  141. jump loop2
  142. LABEL PLUS1
  143. if (mode = 0) jump no_mode
  144. jump /r calc                 : ;; perform CURRENT operation
  145. say color colors[2]; " +";   : ;; update the tape
  146. mode = 1                     : ;; set NEW current operation
  147. jump disp_total
  148.  
  149. LABEL MINUS
  150. say at 3,23; color colors[2]; "-"
  151. count = 0
  152. if (0 = instr("+-*/PMTD=",ch[2])) jump minus1
  153. ;    Here, An operator was the LAST thing entered 
  154. mode = 2  
  155. scroll at 6,41 size 14,16 
  156. say at 19,43; color colors[2]; ; total:@(formt[d]);" -";
  157. jump loop2
  158. LABEL MINUS1
  159. if (mode = 0) jump no_mode
  160. jump /r calc                 : ;; perform CURRENT operation
  161. say color colors[2]; " -";   : ;; update the tape
  162. mode = 2                     : ;; set NEW current operation
  163. jump disp_total
  164.  
  165. LABEL MULT
  166. say at 3,23; color colors[2]; "x"
  167. count = 0
  168. if (0 = instr("+-*/PMTD=",ch[2])) jump mult1
  169. ;    Here, An operator was the LAST thing entered 
  170. mode = 3  
  171. scroll at 6,41 size 14,16 
  172. say at 19,43; color colors[2]; ; total:@(formt[d]);" x";
  173. jump loop2
  174. LABEL MULT1
  175. if (mode = 0) jump no_mode    
  176. jump /r calc                 : ;; perform CURRENT operation
  177. say color colors[2]; " x";   : ;; update the tape
  178. mode = 3                     : ;; set NEW current operation
  179. jump disp_total
  180.  
  181. LABEL DIV
  182. say at 3,23; color colors[2]; "÷"
  183. count = 0
  184. if (0 = instr("+-*/PMTD=",ch[2])) jump div1
  185. ;    Here, An operator was the LAST thing entered 
  186. mode = 4  
  187. scroll at 6,41 size 14,16 
  188. say at 19,43; color colors[2]; ; total:@(formt[d]);" ÷";
  189. jump loop2
  190. LABEL DIV1
  191. if (mode = 0) jump no_mode
  192. jump /r calc                 : ;; perform CURRENT operation
  193. say color colors[2]; " ÷";   : ;; update the tape
  194. mode = 4                     : ;; set NEW current operation
  195. jump disp_total
  196.  
  197. LABEL NO_MODE
  198. ;    There is no CURRENT operation when the first operator is pressed.
  199. ;    The default operation is PLUS. Add operand to total.
  200. total = op
  201. ;    Set the CURRENT mode
  202. ; 
  203. mode = ((l-1) mod 4) + 1
  204. ;     Update the tape
  205. scroll at 6,41 size 14,16
  206. say at 19,43 ; color colors[2]; op:@(formt[d]); " "; mid("+-x÷",mode,1)
  207. jump disp_total
  208.  
  209. LABEL EQUAL
  210. say at 3,23; color colors[2]; " "   : ;; Erase displayed operator 
  211. if (0 = instr("=+-*/PMTD",ch[2])) jump E1
  212. ;    Last key was an operator, so display TOTAL line on the tape
  213. ;    (sequence was, for example: operand operator = )
  214. scroll at 6,41 size 14,16
  215. say at 19,41; color colors[2]; "T "; total:@(formt[d]);
  216. mode = 5
  217. jump loop  
  218. LABEL E1
  219. ;    Last key was NOT an operator. See if there is a CURRENT operator.
  220. count = 0
  221. if (mode <> 0) jump e2
  222. ;    Here, the user has hit = before entering an operator
  223. total = op 
  224. scroll at 6,41 size 14,16
  225. say at 19,41; color colors[2]; "T "; total:@(formt[d]);
  226. jump disp_total
  227. LABEL E2
  228. ;     Here, = was hit in a "normal" sequence so calculate & display
  229. ;     (i.e. operand1 operator operand2 = )
  230. jump /r calc
  231. say at 19,41; color colors[2]; "T";
  232. say at 3,10; color colors[1]; total:@(formt[d]);
  233. op = 0
  234. mode = 5
  235. jump loop
  236.  
  237. LABEL DISP_TOTAL
  238. ;    Display the total in the Calc display
  239. say at 3,10; color colors[1]; total:@(formt[d]);
  240. if (0 = instr("=+-*/PMTD",ch[2])) op = 0
  241. jump loop
  242.  
  243. LABEL CALC
  244. ;    Perform CURRENT operation and update the tape
  245. scroll at 6,41 size 14,16
  246. say at 19,43 ; color colors[2]; op:@(formt[d])
  247. if (mode = 1) total = total + op : jump calc1
  248. if (mode = 2) total = total - op : jump calc1
  249. if (mode = 3) total = total * op : jump calc1
  250. if (op = 0) jump calc_error
  251. total = total / op
  252. LABEL CALC1
  253. scroll at 6,41 size 14,16
  254. say at 19,41; color colors[2]; "S "; str(total:@(formt[d]));
  255. rturn
  256.  
  257. LABEL CALC_ERROR
  258. ;    Divide by Zero, or attempt to enter 2nd decimal point
  259. al 7n
  260. say at 3,10; color colors[1]; "       ERROR";
  261. say at 19,56; color colors[2]; "E"
  262. ;    Accept only CLEAR
  263. repeat
  264. z = inkey(-1)
  265. until (0 <> instr("Cc",chr(z)))
  266. jump clear
  267.  
  268. LABEL HELP
  269. ;     Display HELP screen, and return to input mode
  270. box at 7,42 size 16,37 style 5 color "rw" save
  271. me
  272. [7,50][Wr]*** CALC  HELP ***  
  273. [09,44][Kw]P[kw]  or  [Kw]+[kw]    add    
  274. [10,44][Kw]M[kw]  or  [Kw]-[kw]    subtract
  275. [11,44][Kw]T[kw]  or  [Kw]*[kw]    multiply 
  276. [12,44][Kw]D[kw]  or  [Kw]/[kw]    divide
  277. [14,44][Kw]O[kw]      calculator off (exit CALC)
  278. [15,44][Kw]S[kw]      change sign of operand
  279. [16,44][Kw]C[kw]      clear calculator
  280. [17,44][Kw]E[kw]      clear entry
  281. [18,44][Kw]Alt-C[kw]  clear calculator & tape
  282. [19,44][Kw]Alt-D[kw]  change # of decimal places
  283. [20,44][Kw][kw]      tape feed
  284. [22,47][Wr]< Press a key to exit Help >
  285. .
  286. ;    Wait for key 
  287. z = inkey(-1)
  288. restore
  289. jump LOOP2
  290.  
  291. LABEL SET_DECIMAL
  292. ;    Allow user to configure # of decimal places displayed
  293. box at 7,42 size 6,37 style 5 color "bw" save
  294. say at 7,45; color "Wb"; "Change Number of Decimal Places"
  295. say at 9,44; color colors[2]; "How many places (0 - 4) ? "
  296. ;    NOTE: The variable 'd' contains the number of decimal places
  297. ;          to be displayed PLUS ONE. This is because 'd' is used as
  298. ;          an array index and CANNOT = 0
  299. z = d-1
  300. input z at 9,70 format 1 color colors[1] only "01234"
  301. d = z + 1
  302. say at 3,28; color colors[2]; "D:"; color colors[1]; z:1
  303. say at 10,44; color colors[2]; "Make this the default (Y/N)?"
  304. ch[1] = "N"
  305. input ch[1] at 10,73 color colors[1] alluc only "YN"
  306. if  (ch[1] = "N") restore : jump loop2
  307. ;    Here we create or update a CALC.CFG file which is to contain
  308. ;    the number of digits to be displayed after the decimal.
  309. open append pth as 1 size 1
  310. seek 1, 0
  311. write line 1, z
  312. close 1
  313. say at 12,45; color "WB"; "Done!"; color "Wb"; "   Press a key..."
  314. z = inkey(50)
  315. restore
  316. jump loop2
  317.  
  318. LABEL SHOW_TAPE
  319. ;    Draw the Tape
  320. box at 3,40 size 18,18 color colors[2] style 2
  321. draw from 5,40 to 5,57 color colors[2] style 2 ends "╠" + "╣"
  322. say at 4,45; color colors[2]; "T A P E"
  323. jump clear
  324.  
  325. LABEL SHOW_CALC
  326. ;    Draw the Calculator
  327. box at 2,5 size 22,30 style 2 color colors[2] 
  328. draw from 4,5 to 4,34 color colors[2] ends "╟╢"
  329. me
  330. [5,9][Bk] P[Ck] R[Gk] I[Yk] S[Rk] M   [Wk]C A L C [kk]
  331. .
  332. say at 3,28; color colors[2]; "D:"; color colors[1]; (d-1):1
  333. box at 10,8 size 3,5 across 3 down 4 xsep 2 ysep 1 style 2 color "kw" hollow
  334. for l = 1 to 3
  335. say at 11,(10 + ((l-1)*6));  color colors[2]; l + 6
  336. say at 14,(10 + ((l-1)*6));  color colors[2]; l + 3
  337. say at 17,(10 + ((l-1)*6));  color colors[2]; l 
  338. say at 20,(10 + ((l-1)*6));  color colors[2]; mid("±0∙",l,1)
  339. next
  340.  
  341. box at 7,28 size 3,3 down 5, ysep 1 style 3 color colors[2] hollow
  342. for l = 1 to 5
  343. say at (8 + ((l-1)*3)),29; color colors[2]; mid("+-x÷=",l,1)
  344. next
  345.  
  346. box at 7,8 size 3,7 across 2 xsep 4 style 4 color colors[2]
  347. say at 8,9; color "Wr"; " O"; color "wr"; "n  "
  348. say at 8,19; color "Wb";"  C  "
  349. rturn
  350.  
  351. LABEL SETUP
  352. ;    Initialize variables & colors
  353. box at 1,1 size 25,80 color "kk" style 0
  354. colors[1] = "ky"
  355. colors[2] = "kw"
  356. colors[3] = "Wk"
  357. d = 1               : ;; default # of digits after decimal is 0
  358. tens[1] = 0.1       : ;; used to enter digits after the decimal
  359. tens[2] = 0.01
  360. tens[3] = 0.001
  361. tens[4] = 0.0001
  362. tens[5] = 0.00001
  363. formt[1] = "12"     : ;; used for current display mode
  364. formt[2] = "12.1"
  365. formt[3] = "12.2"
  366. formt[4] = "12.3"
  367. formt[5] = "12.4"
  368. ;    create path name containing path where calc.xts resides, 
  369. ;    followed by the filename CALC.CFG
  370. pth = strip(value("do"),letter + ".",1) + "CALC.CFG"
  371. if -[@(pth)] rt              : ;; CALC.CFG doesn't exist
  372. ;    CALC.CFG exists. Input & validate the configuration
  373. open input pth as 1 size 1
  374. get 1,1,ch[1]
  375. close 1
  376. if (0 = instr("01234",ch[1])) rt
  377. d = int(ch[1]) + 1
  378. rt
  379.  
  380. LABEL EXIT
  381. for z = 1 to 2
  382. box at 7,8 size 3,7 style 4 color colors[3] hollow
  383. box at 7,8 size 3,7 style 4 color colors[2] hollow
  384. next
  385. say at 8,9; color colors[2]; " O"; color "Kw"; "ff "
  386. LABEL ERROR_LABEL
  387. ;    Here is where execution is transfered to when user presses the
  388. ;    ATtention key (to abort CALC)
  389. say at 25,20; color "Wk"; "Press a key to exit CALC...";
  390. z = inkey(40)
  391. sc l kw
  392. cl
  393. var forget op
  394. LABEL KILL_STACK
  395. rt KILL_STACK
  396. end
  397.