Frozen Fish 2: PC/frozenfish_august_1995.bin/bbs/d03xx/d0300.lha/TACL/JungleSource/CaveRooms2

Text File | 1989-12-25 | 5KB | 272 lines

ROOM Hall_of_the_Priests

DEFAULT
 N Sacred_Chamber
 W Water_Passage
ENDDEFAULT

CODE
 IF Hall_of_the_Priests NOT VISITED THEN
  T This must be the room that ancient priests took coffee breaks in
  T between sacrifices.  There is an exit to the west and to the north
  T is the Sacred Chamber.
  IMAGE Hall_of_the_Priests Priest_Bend
  SHOW Priest_Bend
 ELSE
  T Hall of the Priests.
 ENDIF
ENDCODE

ENDROOM
*
*
*
ROOM Water_Passage

DEFAULT
 S Waterway
 E Hall_of_the_Priests
 W Pit_Passage
ENDDEFAULT

CODE
 IF Water_Passage NOT VISITED THEN
  T An underground river enters this passage from a small hole to the
  T south and follows it in a riverbed on the south side of the passage.
  T you are free to walk on the north side.
  IMAGE Water_Passage Water_Pass
  SHOW Water_Pass
 ELSE
  T Water Passage.
 ENDIF
 PLACEOBJ Water Water_Passage
ENDCODE

ENDROOM
*
*
*
ROOM Waterway

CODE
 T You crouch down and try to enter the waterway.  Since the current is so
 T strong, the only way you are able to do so is to brace your arms and
 T legs against the opposite sides of the narrow passage.  You get about
 T 5 meters in when you lose your grip.  Your clothes catch on a rock and
 T you are drowned.
 CALL BuyTheFarm
ENDCODE

ENDROOM
*
*
*
ROOM Pit_Passage

DEFAULT
 E Water_Passage
 W Connecting_Tunnel
ENDDEFAULT

CODE
 IF InPitPass = 0 THEN
  EQU InPitPass 1
  T You swim back across the pit.
 ENDIF
 IF Pit_Passage NOT VISITED THEN
  T You are in an east-west passage with a pit across the north side
  T and a riverbed surging down the south side.
  IF PitFull = 0 THEN          * show the right image
   SHOW Pit1
  ELSE
   IF Log IN Pit_Passage THEN
    SHOW Pit2
   ELSE
    SHOW Pit3
   ENDIF
  ENDIF
 ELSE
  T Pit Passage.
 ENDIF
 EQU InConnTunn 0
 PLACEOBJ Water Pit_Passage

 IF PitFull = 0 THEN          * set the right image
  IMAGE Pit_Passage Pit1
 ELSE
  IF Log IN Pit_Passage THEN
   IMAGE Pit_Passage Pit2
  ELSE
   IMAGE Pit_Passage Pit3
  ENDIF
 ENDIF
ENDCODE

ENDROOM
*
*
*
ROOM Connecting_Tunnel

DEFAULT
 N Sloping_Passage
 E Pit_Passage
ENDDEFAULT

CODE
 IF CrossedWater = 0 THEN
  T You can't seem to get across the pit.
  GO Pit_Passage
 ELSE
  EQU InPitPass 0
  PLACEOBJ Water Connecting_Tunnel
  IF InConnTunn = 0 THEN
   T You swim across the water.
   EQU InConnTunn 1
  ENDIF
  IF Connecting_Tunnel NOT VISITED THEN
   T You are at a bend in the passage; it goes east and north.  The river
   T swirls into a whirlpool here and disappears into the floor.
   IMAGE Connecting_Tunnel Water_Bend
   SHOW Water_Bend
  ELSE
   T Connecting Tunnel.
  ENDIF
 ENDIF
 PLACEOBJ Water Connecting_Tunnel
ENDCODE

ENDROOM
*
*
*
ROOM Sloping_Passage

DEFAULT
 S Connecting_Tunnel
ENDDEFAULT

CODE
 IF Sloping_Passage NOT VISITED THEN
  T You are in a passage that slopes down sharply to theánorth.
  IF Lever NOT Pulled THEN
   T The path disappears underwater about ten feet in front of you.
   IMAGE Sloping_Passage Sloping_1
   SHOW Sloping_1
   PLACEOBJ Water Sloping_Passage
  ELSE
   DIRECTIONS Sloping_Passage S N
   LINK Sloping_Passage N Split_Passage
   IMAGE Sloping_Passage Sloping_2
   SHOW Sloping_2
  ENDIF
 ELSE
  T Sloping Passage.
 ENDIF
ENDCODE

ENDROOM
*
*
*
ROOM Split_Passage

DEFAULT
 S  Sloping_Passage
 N  Rubble_Crawl
 NE Break_Down_Rocks
 NW Cobble_Crawl
ENDDEFAULT

CODE
 IF Split_Passage NOT VISITED THEN
  T The passage levels out but continues to the north as three possible
  T passages;  one to the northwest, one due north, and one to the
  T northeast.
  IMAGE Split_Passage 3_Way
  SHOW 3_Way
 ELSE
  T Split Passage.
 ENDIF
ENDCODE

ENDROOM
*
*
*
ROOM Rubble_Crawl

DEFAULT
 S Split_Passage
ENDDEFAULT

CODE
 IF Rubble_Crawl NOT VISITED THEN
  T You are in a low crawlway that ends in a wall of loose rocks.
  IMAGE Rubble_Crawl Rock_Crawl_1
  SHOW Rock_Crawl_1
 ELSE
  T Rubble Crawl.
 ENDIF
ENDCODE

ENDROOM
*
*
*
ROOM Break_Down_Rocks

DEFAULT
 SW Split_Passage
ENDDEFAULT

CODE
 IF Break_Down_Rocks NOT VISITED THEN
  T You find yourself in a narrow crevice which ends in a wall of broken
  T and fractured rocks.
  IMAGE Break_Down_Rocks Rock_Crawl_1
  SHOW Rock_Crawl_1
 ELSE
  T Break-Down Rocks.
 ENDIF
ENDCODE

ENDROOM
*
*
*
ROOM Cobble_Crawl

ATTRIB
 Dug
ENDATTRIB

DEFAULT
 SE Split_Passage
ENDDEFAULT

CODE
 IF InCaverns = 0 THEN
  T Your eyes slowly adject to the darkness.
  EQU InCaverns 1
 ENDIF
 IF Cobble_Crawl NOT VISITED THEN
  IF Cobble_Crawl IS Dug THEN
   T This cramped grotto exits to the north.
   IMAGE Cobble_Crawl Rock_Crawl_2
   SHOW Rock_Crawl_2
  ELSE
   T This cramped grotto dead-ends in a wall of stones.
   IMAGE Cobble_Crawl Rock_Crawl_1
   SHOW Rock_Crawl_1
  ENDIF
 ELSE
  T Cobble Crawl.
 ENDIF
ENDCODE

ENDROOM
*
* ----- END OF FILE
*