home *** CD-ROM | disk | FTP | other *** search
/ Frozen Fish 1: Amiga / FrozenFish-Apr94.iso / bbs / alib / d5xx / d568 / schoonschip.lha / Schoonschip / SDocsAMI.LZH / SDocsAMI / WWb.e < prev   
Text File  |  1991-06-14  |  25KB  |  795 lines
  1. C Example of a gauge field theory.
  2.   Lagrangian.
  3.  
  4. BLOCK VERT{}
  5. S N,N_,M,m
  6. F VE4,VE3,PROP
  7. I al=N, be=N, ga=N, de=N, la=N, ka=N
  8. I l1=3,l2=3,l2=3,l3=3,l4=3,l5=3,l6=3,l7=3,l8=3,l9=3
  9. V p,k,pp,kp,q,qs,qt,qu
  10.  
  11. C F=fi triplet, W=vector boson triplet, Z=Higgs, X=FP ghost triplet.
  12.  
  13. T TAP: F,U,W,Z
  14. T TFE: X
  15. T THI: Z=1:1,U=1:1
  16. Antilist TAP
  17.  
  18. X DEDE(al,be,ga,de)=2.*D(al,be)*D(ga,de) - D(al,de)*D(be,ga)
  19.                      - D(al,ga)*D(be,de)
  20. G 1
  21. X FF(l1,al,l2,be;p)  = NOM(p,M)*D(l1,l2)
  22. X WW(l1,al,l2,be;p)  = NOM(p,M)*D(al,be)*D(l1,l2)
  23. X X_X(l1,al,l2,be;p) = NOM(p,M)*D(l1,l2)
  24.  
  25. X WWW(l1,al,k,l2,be,p,l3,ga,q) =
  26.  -i*Epf(l1,l2,l3)*D(al,ga)*(k(be)-q(be))
  27.  -i*Epf(l1,l2,l3)*D(be,ga)*(q(al)-p(al))
  28.  -i*Epf(l1,l2,l3)*D(al,be)*(p(ga)-k(ga))
  29.  
  30. X FFW(l2,be,p,l3,ga,q,l1,al,k) = 0.5*i*Epf(l1,l2,l3)*p(al)
  31.                 -0.5*i*Epf(l1,l2,l3)*q(al)
  32.  
  33. X WWWW(l1,al,k,l2,be,p,l3,ga,q,l4,de,pp) =
  34.    -D(l4,l2)*D(l1,l3)*DEDE(al,ga,be,de)+D(l4,l1)*D(l3,l2)*DEDE(al,ga,be,de)
  35.    -D(l4,l3)*D(l2,l1)*DEDE(al,be,ga,de)+D(l4,l1)*D(l2,l3)*DEDE(al,be,ga,de)
  36. X FFWW(l3,ga,k,l4,de,p,l1,al,q,l2,be,pp) = - 0.5*D(l1,l2)*D(l3,l4)*D(al,be)
  37. X FFFF(l1,al,k,l2,be,p,l3,ga,q,l4,de,pp) =
  38.     - 0.25*m^2/M^2*D(l1,l2)*D(l3,l4)
  39.     - 0.25*m^2/M^2*D(l1,l3)*D(l2,l4)
  40.     - 0.25*m^2/M^2*D(l1,l4)*D(l2,l3)
  41.  
  42. X WX_X(l1,al,k,l2,be,p,l3,ga,q) = i*Epf(l1,l2,l3)*p(al)
  43. X FX_X(l1,al,k,l2,be,p,l3,ga,q) = 0.5*M*Epf(l1,l2,l3)
  44.  
  45. G 2
  46. X ZZ(l1,al,l2,be;p)  = NOM(p,m)
  47.  
  48. X FWZ(l2,be,p,l1,al,k,l3,ga,q) = 0.5*i*D(l1,l2)*p(al)
  49.                 -0.5*i*D(l1,l2)*q(al)
  50. X WWZ(l1,al,k,l2,be,p,l3,ga,q) = - M*D(l1,l2)*D(al,be)
  51. X FFZ(l1,al,k,l2,be,p,l3,ga,q) = - 0.5*m^2/M*D(l1,l2)
  52. X ZZZ(l1,al,k,l2,be,p,l3,ga,q) = - 1.5*m^2/M
  53.  
  54. X WWZZ(l1,al,k,l2,be,p,l3,ga,q,l4,de,pp) = - 0.5*D(l1,l2)*D(al,be)
  55. X FFZZ(l1,al,k,l2,be,p,l3,ga,q,l4,de,pp) = - 0.25*m^2/M^2*D(l1,l2)
  56. X ZZZZ(l1,al,k,l2,be,p,l3,ga,q,l4,de,pp) = - 0.75*m^2/M^2
  57.  
  58. X X_XZ(l1,al,k,l2,be,p,l3,ga,q) = - 0.5*M*D(l1,l2)
  59.  
  60. G 3
  61. C Tadpole counterterm.
  62.  
  63. X NNZ(l1,al,k,l2,be,p,l3,ga,q) = - M*m^2*Et
  64.  
  65. C Self-energy counter terms.
  66.  
  67. X NWW(l1,al,k,l2,be,p,l3,ga,q) = - {2*M^2*Ew + 2*M^2*E1 - 2*pDq*Ew}
  68.  * D(l2,l3)*D(be,ga) - 2*p(be)*q(ga)*D(l2,l3)*Ew
  69. X FFN(l2,be,p,l3,ga,q,l1,al,k) = 2*pDq*Eh*D(l2,l3) - 1/2*m^2*Et*D(l2,l3)
  70. X FNW(l2,be,p,l1,al,k,l3,ga,q) = M*(Ew+Eh+E1)*D(l2,l3)*i*p(ga)
  71. X NZZ(l1,al,k,l2,be,p,l3,ga,q) = m^2*{-2*Eh-1/2*Et+2*E2-2*E1} + 2*pDq*Eh
  72.  
  73. G 4
  74. C Three point counter terms.
  75.  
  76. X WWWK = Eg+3*Ew
  77. X FFWK = Eg+Ew+2*Eh
  78. X FWZK = Eg+Ew+2*Eh
  79. X WWZK = Eg+2*Ew+Eh+E1
  80. X FFZK = Eg+3*Eh-2*E2+E1
  81. X ZZZK = Eg+3*Eh-2*E2+E1
  82.  
  83. C Four-point counter terms.
  84.  
  85. X WWWWK = 2*Eg+4*Ew
  86. X FFWWK = 2*Eg+2*Ew+2*Eh
  87. X FFFFK = 2*Eg+4*Eh-2*E2
  88. X WWZZK = 2*Eg+2*Ew+2*Eh
  89. X FFZZK = 2*Eg+4*Eh-2*E2
  90. X ZZZZK = 2*Eg+4*Eh-2*E2
  91.  
  92. G 5
  93. C New Higgs-like particle...
  94.   Mass: as Higgs, i.e. m.
  95.   Coupling: - 1/4* gu * U^2 * { (Z+2M/g)^2 + Fi^2 }
  96.   Choice: gu = g^2 * m^2/4/M^2*gu
  97.  
  98. Gotoif 2,_Sw0=0
  99. X UU(l1,al,l2,be;p)  = NOM(p,M)
  100. Goto 3
  101. @2
  102. X UU(l1,al,l2,be;p)  = NOM(p,m)
  103. @3
  104.  
  105. X UUZ(l1,al,k,l2,be,p,l3,ga,q) = - 0.5*m^2/M*gu
  106. X FFUU(l1,al,k,l2,be,p,l3,ga,q,l4,de,pp) = - 0.25*m^2/M^2*D(l1,l2)*gu
  107. X UUZZ(l1,al,k,l2,be,p,l3,ga,q,l4,de,pp) = - 0.25*m^2/M^2*gu
  108.  
  109. G
  110. ENDBLOCK
  111.  
  112. BLOCK FOUR{}
  113. C Four point topologies, including reducible graphs and tadpole types.
  114.   Call: 
  115.      VIER("A,a,al,k,"B,b,p,p,"C,c,pp,pp,"D,d,kp,kp)
  116.  
  117.   The result needs additional contributions, obtained by crossing, as
  118.   shown here:
  119.  
  120.    + VIER("A,a,al,k,"C,c,ga,pp,"B,b,be,p,"D,d,de,kp)
  121.    + VIER("A,a,al,k,"B,b,be,p,"D,d,de,kp,"C,c,ga,pp)
  122.  
  123. Id,VIER(K1~,a~,al~,k~,K2~,b~,be~,p~,K3~,c~,ga~,pp~,K4~,d~,de~,kp~)=
  124.  
  125.      Reduc(K1,a,al,k,K2,b,be,p,K3,c,ga,pp,K4,d,de,kp)
  126.  
  127.    + Redup(K1,a,al,k,K2,b,be,p,K3,c,ga,pp,K4,d,de,kp)
  128.  
  129.    + Tadp(K1,a,al,k,K2,b,be,p,K3,c,ga,pp,K4,d,de,kp)
  130.  
  131.    + DS(K1;J4;-J1;TAP,(
  132.      DS(K2;J1;-J2;TAP,(
  133.      DS(K3;J2;-J3;TAP,(
  134.     A0*VIE(K1,a,al,k,K2,b,be,p,K3,c,ga,pp,K4,d,de,kp,J1,J2,J3,J4)
  135.      * DC("F,TFE,-1,J1,J2,J3,J4) ))) )))
  136.  
  137.     + DS(K1;K3;J7;-J5;TAP,(
  138.      DS(K2;J5;-J6;TAP,(DC("F,TFE,-1,J5,J6,J7)*
  139.     A1*VIE1(K1,a,al,k,K2,b,be,p,K3,c,ga,pp,K4,d,de,kp,J5,J6,J7) )) ))
  140.  
  141.    + DS(K2;K4;J8;-J9;TAP,(
  142.      DS(K1;JA;-J8;TAP,(DC("F,TFE,-1,J8,J9,JA)*
  143.     A2*VIE2(K1,a,al,k,K2,b,be,p,K3,c,ga,pp,K4,d,de,kp,J8,J9,JA) )) ))
  144.  
  145.    + DS(K1;K3;J0;-JB;Sym;J0;-JB;TAP,(DC("F,TFE,-1,J0,JB)*
  146.     A3*VIE3(K1,a,al,k,K2,b,be,p,K3,c,ga,pp,K4,d,de,kp,JB,J0) ) )
  147.  
  148. Id, VIE(K1~,a~,al~,k~,K2~,b~,be~,p~,
  149.     K3~,c~,ga~,pp~,K4~,d~,de~,kp~,J1~,J2~,J3~,J4~)=
  150.    VE3(K1,J4,-J1,*,a,al,k,*,l8,m8,q3,*,l1,m1,-q)*
  151.    VE3(K2,J1,-J2,*,b,be,p,*,l2,m0,q,*,l3,m3,-q1)*
  152.    VE3(K3,J2,-J3,*,c,ga,pp,*,l4,m4,q1,*,l5,m5,-q2)*
  153.    VE3(K4,J3,-J4,*,d,de,kp,*,l6,m6,q2,*,l7,m7,-q3)*
  154.    PROP(J1,-J1,*,l1,m1,q,*,l2,m0,-q)*
  155.    PROP(J2,-J2,*,l3,m3,q1,*,l4,m4,-q1)*
  156.    PROP(J3,-J3,*,l5,m5,q2,*,l6,m6,-q2)*
  157.    PROP(J4,-J4,*,l7,m7,q3,*,l8,m8,-q3)
  158.  
  159. Al,VIE1(K1~,a~,al~,k~,K2~,b~,be~,p~,
  160.     K3~,c~,ga~,pp~,K4~,d~,de~,kp~,J1~,J2~,J3~)=
  161.    VE4(K1,K3,J3,-J1,*,a,al,k,*,c,ga,pp,*,l6,m6,q4,*,l1,m1,-q)*
  162.    VE3(K2,J1,-J2,*,b,be,p,*,l2,m0,q,*,l3,m3,-q1)*
  163.    VE3(K4,J2,-J3,*,d,de,kp,*,l4,m4,q1,*,l5,m5,-q4)*
  164.    PROP(J1,-J1,*,l1,m1,q,*,l2,m0,-q)*
  165.    PROP(J2,-J2,*,l3,m3,q1,*,l4,m4,-q1)*
  166.    PROP(J3,-J3,*,l5,m5,q4,*,l6,m6,-q4)
  167.  
  168. Al,VIE2(K1~,a~,al~,k~,K2~,b~,be~,p~,
  169.     K3~,c~,ga~,pp~,K4~,d~,de~,kp~,J1~,J2~,J3~)=
  170.    VE4(K2,K4,J1,-J2,*,b,be,p,*,d,de,kp,*,l2,m0,q,*,l3,m3,-q4)*
  171.    VE3(K1,J3,-J1,*,a,al,k,*,l6,m6,q3,*,l1,m1,-q)*
  172.    VE3(K3,J2,-J3,*,c,ga,pp,*,l4,m4,q4,*,l5,m5,-q3)*
  173.    PROP(J1,-J1,*,l1,m1,q,*,l2,m0,-q)*
  174.    PROP(J2,-J2,*,l3,m3,q4,*,l4,m4,-q4)*
  175.    PROP(J3,-J3,*,l5,m5,q3,*,l6,m6,-q3)
  176.  
  177. Al,VIE3(K1~,a~,al~,k~,K2~,b~,be~,p~,
  178.     K3~,c~,ga~,pp~,K4~,d~,de~,kp~,J1~,J2~)=
  179.    VE4(K1,K3,J2,-J1,*,a,al,k,*,c,ga,pp,*,l4,m4,q4,*,l1,m1,-q)*
  180.    VE4(K2,K4,J1,-J2,*,b,be,p,*,d,de,kp,*,l2,m0,q,*,l3,m3,-q4)*
  181.    PROP(J1,-J1,*,l1,m1,q,*,l2,m0,-q)*
  182.    PROP(J2,-J2,*,l3,m3,q4,*,l4,m4,-q4)
  183.  
  184. Al,Reduc(K1~,a~,al~,k~,K2~,b~,be~,p~,K3~,c~,ga~,pp~,K4~,d~,de~,kp~) =
  185.      DS(K2;K4;J4;TAP,(DS(-J4;J1;-J2;TAP,(
  186.      DS(K1;J3;-J1;TAP,(
  187.      DC("F,TFE,-1,J1,J2,J3)*R1(J4,J4)*
  188.      RED1(K1,a,al,k,K2,b,be,p,K3,c,ga,pp,K4,d,de,kp,J1,J2,J3,J4) )) )) ))
  189.  
  190.    + DS(K1;K3;-J8;TAP,(DS(J8;-J5;J7;TAP,(
  191.      DS(K2;J5;-J6;TAP,(
  192.      DC("F,TFE,-1,J5,J6,J7)*R1(J8,J8)*
  193.      RED2(K1,a,al,k,K2,b,be,p,K3,c,ga,pp,K4,d,de,kp,J5,J6,J7,J8) )) )) ))
  194.  
  195.    + DS(K1;K3;-J0;JA;Sym;-J0;JA;TAP,(DS(J0;-JA;-JB;TAP,(
  196.      DC("F,TFE,-1,J0,JA)*R1(JB,JB)*
  197.      RED3(K1,a,al,k,K2,b,be,p,K3,c,ga,pp,K4,d,de,kp,J0,JA,JB) )) ))
  198.  
  199.    + DS(K1;K3;-JE;TAP,(DS(JE;-JC;JD;Sym;-JC;JD;TAP,(
  200.      DC("F,TFE,-1,JC,JD)*R1(JE,JE)*
  201.      RED4(K1,a,al,k,K2,b,be,p,K3,c,ga,pp,K4,d,de,kp,JC,JD,JE) )) ))
  202.  
  203.    + DS(K1;K3;-JI;TAP,(DS(JI;-JF;JG;Sym;-JF;JG;TAP,(
  204.      DS(JF;-JG;-JH;TAP,(DC("F,TFE,-1,JF,JG)*R5(JI,JI)*
  205.      RED5(K1,a,al,k,K2,b,be,p,K3,c,ga,pp,K4,d,de,kp,JF,JG,JH,JI) )) )) ))
  206.  
  207.    + DS(K1;-JM;K3;TAP,(DS(JM;-JL;-JK;JK;Sym;-JK;JK;TAP,(R5(JM,JM)*
  208.      RED6(K1,a,al,k,K2,b,be,p,K3,c,ga,pp,K4,d,de,kp,JK,JL,JM) )) ))
  209.  
  210. Al,Redup(K1~,a~,al~,k~,K2~,b~,be~,p~,K3~,c~,ga~,pp~,K4~,d~,de~,kp~) =
  211.     DS(K2;K4;J3;TAP,(
  212.       DS(-J2;J1;-J3;K3;Sym;-J2;J1;TAP,(R1(J3,J3)*
  213.     RED3A(K1,a,al,k,K2,b,be,p,K3,c,ga,pp,K4,d,de,kp,J1,J2,J3) ))
  214.     + DS(J5;-J4;-J3;K1;Sym;J5;-J4;TAP,(R1(J3,J3)*
  215.     RED3B(K1,a,al,k,K2,b,be,p,K3,c,ga,pp,K4,d,de,kp,J4,J5,J3) ))
  216.     ))
  217.  
  218.   + DS(K1;K3;J8;TAP,(
  219.       DS(J7;-J6;-J8;K4;Sym;J7;-J6;TAP,(R1(J8,J8)*
  220.     RED4A(K1,a,al,k,K2,b,be,p,K3,c,ga,pp,K4,d,de,kp,J6,J7,J8) ))
  221.     + DS(JA;-J9;-J8;K2;Sym;JA;-J9;TAP,(R1(J8,J8)*
  222.     RED4B(K1,a,al,k,K2,b,be,p,K3,c,ga,pp,K4,d,de,kp,J9,JA,J8) ))
  223.     ))
  224.  
  225. Al,Tadp(K1~,a~,al~,k~,K2~,b~,be~,p~,K3~,c~,ga~,pp~,K4~,d~,de~,kp~) =
  226.     DS(K2;K4;J2;"Z;TAP,(DS("Z;J1;-J1;Sym;J1;-J1;TAP,(
  227.     DC("F,TFE,-1,J1)*
  228.    T1*TAD1(K1,a,al,k,K2,b,be,p,K3,c,ga,pp,K4,d,de,kp,J1,J2) )) ))
  229.  
  230.   + DS(K1;K3;-J4;"Z;TAP,(DS("Z;J3;-J3;Sym;J3;-J3;TAP,(
  231.     DC("F,TFE,-1,J3)*
  232.    T2*TAD2(K1,a,al,k,K2,b,be,p,K3,c,ga,pp,K4,d,de,kp,J3,J4) )) ))
  233.  
  234.   + DS(K1;-J6;K3;TAP,(DS(J6;-J7;"Z;TAP,(DS("Z;J5;-J5;Sym;J5;-J5;TAP,(
  235.     DC("F,TFE,-1,J5)*
  236.    T3*TAD3(K1,a,al,k,K2,b,be,p,K3,c,ga,pp,K4,d,de,kp,J5,J6,J7) )) )) ))
  237.  
  238. Id,RED1(K1~,a~,al~,k~,K2~,b~,be~,p~,K3~,c~,ga~,pp~,
  239.     K4~,d~,de~,kp~,J1~,J2~,J3~,J4~) =
  240.    VE3(K1,-J1,J3,*,a,al,k,*,l1,m1,-q,*,l6,m6,q3)*
  241.    VE3(J1,-J4,-J2,*,l2,m0,q,*,l7,m7,-qu,*,l3,m3,-q4)*
  242.    VE3(K2,K4,J4,*,b,be,p,*,d,de,kp,*,l8,m8,qu)*
  243.    VE3(K3,J2,-J3,*,c,ga,pp,*,l4,m4,q4,*,l5,m5,-q3)*
  244.    PROP(J1,-J1,*,l1,m1,q,*,l2,m0,-q)*
  245.    PROP(J2,-J2,*,l3,m3,q4,*,l4,m4,-q4)*
  246.    PROP(J3,-J3,*,l5,m5,q3,*,l6,m6,-q3)*
  247.    PROP(J4,-J4,*,l7,m7,qu,*,l8,m8,-qu)
  248.  
  249. Al,RED2(K1~,a~,al~,k~,K2~,b~,be~,p~,K3~,c~,ga~,pp~,
  250.     K4~,d~,de~,kp~,J1~,J2~,J3~,J4~) =
  251.    VE3(K1,-J4,K3,*,a,al,k,*,l7,m7,-qu,*,c,ga,pp)*
  252.    VE3(J4,-J1,J3,*,l8,m8,qu,*,l1,m1,-q,*,l6,m6,q4)*
  253.    VE3(K2,J1,-J2,*,b,be,p,*,l2,m0,q,*,l3,m3,-q1)*
  254.    VE3(K4,J2,-J3,*,d,de,kp,*,l4,m4,q1,*,l5,m5,-q4)*
  255.    PROP(J1,-J1,*,l1,m1,q,*,l2,m0,-q)*
  256.    PROP(J2,-J2,*,l3,m3,q1,*,l4,m4,-q1)*
  257.    PROP(J3,-J3,*,l5,m5,q4,*,l6,m6,-q4)*
  258.    PROP(J4,-J4,*,l7,m7,qu,*,l8,m8,-qu)
  259.  
  260. Al,RED3(K1~,a~,al~,k~,K2~,b~,be~,p~,K3~,c~,ga~,pp~,
  261.     K4~,d~,de~,kp~,J1~,J2~,J3~) =
  262.    VE4(K1,-J1,J2,K3,*,a,al,k,*,l1,m1,-q,*,l4,m4,q4,*,c,ga,pp)*
  263.    VE3(J1,-J2,-J3,*,l2,m0,q,*,l3,m3,-q4,*,l5,m5,-qu)*
  264.    VE3(K2,J3,K4,*,b,be,p,*,l6,m6,qu,*,d,de,kp)*
  265.    PROP(J1,-J1,*,l1,m1,q,*,l2,m0,-q)*
  266.    PROP(J2,-J2,*,l3,m3,q4,*,l4,m4,-q4)*
  267.    PROP(J3,-J3,*,l5,m5,qu,*,l6,m6,-qu)
  268.  
  269. Al,RED3A(K1~,a~,al~,k~,K2~,b~,be~,p~,K3~,c~,ga~,pp~,
  270.     K4~,d~,de~,kp~,J1~,J2~,J3~) =
  271.    VE3(K2,K4,J3,*,b,be,p,*,d,de,kp,*,l6,m6,qu)*
  272.    VE4(-J2,J1,-J3,K3,*,l3,m3,-q3,*,l2,m0,q,*,l5,m5,-qu,*,c,ga,pp)*
  273.    VE3(K1,-J1,J2,*,a,al,k,*,l1,m1,-q,*,l4,m4,q3)*
  274.    PROP(J1,-J1,*,l1,m1,q,*,l2,m0,-q)*
  275.    PROP(J2,-J2,*,l3,m3,q3,*,l4,m4,-q3)*
  276.    PROP(J3,-J3,*,l5,m5,qu,*,l6,m6,-qu)
  277.  
  278. Al,RED3B(K1~,a~,al~,k~,K2~,b~,be~,p~,K3~,c~,ga~,pp~,
  279.     K4~,d~,de~,kp~,J1~,J2~,J3~) =
  280.    VE3(K2,K4,J3,*,b,be,p,*,d,de,kp,*,l6,m6,qu)*
  281.    VE4(J2,-J1,-J3,K1,*,l4,m4,q2,*,l1,m1,-q1,*,l5,m5,-qu,*,a,al,k)*
  282.    VE3(K3,J1,-J2,*,c,ga,pp,*,l2,m0,q1,*,l3,m3,-q2)*
  283.    PROP(J1,-J1,*,l1,m1,q1,*,l2,m0,-q1)*
  284.    PROP(J2,-J2,*,l3,m3,q2,*,l4,m4,-q2)*
  285.    PROP(J3,-J3,*,l5,m5,qu,*,l6,m6,-qu)
  286.  
  287. Al,RED4(K1~,a~,al~,k~,K2~,b~,be~,p~,K3~,c~,ga~,pp~,
  288.     K4~,d~,de~,kp~,J1~,J2~,J3~) =
  289.    VE3(K1,-J3,K3,*,a,al,k,*,l5,m5,-qu,*,c,ga,pp)*
  290.    VE3(-J1,J2,J3,*,l1,m1,-q,*,l4,m4,q4,*,l6,m6,qu)*
  291.    VE4(K2,J1,-J2,K4,*,b,be,p,*,l2,m0,q,*,l3,m3,-q4,*,d,de,kp)*
  292.    PROP(J1,-J1,*,l1,m1,q,*,l2,m0,-q)*
  293.    PROP(J2,-J2,*,l3,m3,q4,*,l4,m4,-q4)*
  294.    PROP(J3,-J3,*,l5,m5,qu,*,l6,m6,-qu)
  295.  
  296. Al,RED4A(K1~,a~,al~,k~,K2~,b~,be~,p~,K3~,c~,ga~,pp~,
  297.     K4~,d~,de~,kp~,J1~,J2~,J3~) =
  298.    VE3(K1,K3,-J3,*,a,al,k,*,c,ga,pp,*,l5,m5,-qu)*
  299.    VE4(J2,-J1,J3,K4,*,l4,m4,q1,*,l1,m1,q,*,l6,m6,qu,*,d,de,kp)*
  300.    VE3(K2,J1,-J2,*,b,be,p,*,l2,m0,q,*,l3,m3,-q1)*
  301.    PROP(J1,-J1,*,l1,m1,q,*,l2,m0,-q)*
  302.    PROP(J2,-J2,*,l3,m3,q1,*,l4,m4,-q1)*
  303.    PROP(J3,-J3,*,l5,m5,qu,*,l6,m6,-qu)
  304.  
  305. Al,RED4B(K1~,a~,al~,k~,K2~,b~,be~,p~,K3~,c~,ga~,pp~,
  306.     K4~,d~,de~,kp~,J1~,J2~,J3~) =
  307.    VE3(K1,K3,-J3,*,a,al,k,*,c,ga,pp,*,l5,m5,-qu)*
  308.    VE4(J2,-J1,J3,K2,*,l4,m4,q3,*,l1,m1,q2,*,l6,m6,qu,*,b,be,p)*
  309.    VE3(K4,J1,-J2,*,d,de,kp,*,l2,m0,q2,*,l3,m3,-q3)*
  310.    PROP(J1,-J1,*,l1,m1,q2,*,l2,m0,-q2)*
  311.    PROP(J2,-J2,*,l3,m3,q3,*,l4,m4,-q3)*
  312.    PROP(J3,-J3,*,l5,m5,qu,*,l6,m6,-qu)
  313.  
  314. Al,RED5(K1~,a~,al~,k~,K2~,b~,be~,p~,K3~,c~,ga~,pp~,
  315.     K4~,d~,de~,kp~,J1~,J2~,J3~,J4~) =
  316.    VE3(K1,-J4,K3,*,a,al,k,*,l7,m7,-qu,*,c,ga,pp)*
  317.    VE3(J4,-J1,J2,*,l8,m8,qu,*,l1,m1,-q,*,l3,m3,q4)*
  318.    VE3(J1,-J2,-J3,*,l2,m0,q,*,l4,m4,-q4,*,l5,m5,-qu)*
  319.    VE3(K2,J3,K4,*,b,be,p,*,l6,m6,qu,*,d,de,kp)*
  320.    PROP(J1,-J1,*,l1,m1,q,*,l2,m0,-q)*
  321.    PROP(J2,-J2,*,l3,m3,q4,*,l4,m4,-q4)*
  322.    PROP(J3,-J3,*,l5,m5,qu,*,l6,m6,-qu)*
  323.    PROP(J4,-J4,*,l7,m7,qu,*,l8,m8,-qu)
  324.  
  325. Al,RED6(K1~,a~,al~,k~,K2~,b~,be~,p~,K3~,c~,ga~,pp~,
  326.     K4~,d~,de~,kp~,J1~,J2~,J3~) =
  327.    VE3(K1,-J3,K3,*,a,al,k,*,l5,m5,-qu,*,c,ga,pp)*
  328.    VE4(J3,-J2,-J1,J1,*,l6,m6,qu,*,l3,m3,-qu,*,l1,m1,-q,*,l2,m0,q)*
  329.    VE3(K2,J2,K4,*,b,be,p,*,l4,m4,qu,*,d,de,kp)*
  330.    PROP(J1,-J1,*,l1,m1,q,*,l2,m0,-q)*
  331.    PROP(J2,-J2,*,l3,m3,qu,*,l4,m4,-qu)*
  332.    PROP(J3,-J3,*,l5,m5,qu,*,l6,m6,-qu)
  333.  
  334. Id,TAD1(K1~,a~,al~,k~,K2~,b~,be~,p~,K3~,c~,ga~,pp~,
  335.     K4~,d~,de~,kp~,J1~,J2~) =
  336.    VE4(K2,K4,J2,"Z,*,b,be,p,*,d,de,kp,*,l4,m4,qu,*,l5,m5,q0)*
  337.    VE3(K1,K3,-J2,*,a,al,k,*,c,ga,pp,*,l3,m3,-qu)*
  338.    VE3("Z,J1,-J1,*,l6,m6,-q0,*,l1,m1,-q,*,l2,m0,q)*
  339.    PROP(J2,-J2,*,l3,m3,qu,*,l4,m4,-qu)*
  340.    PROP("Z,"Z,*,l5,m5,q0,*,l6,m6,-q0)*
  341.    PROP(J1,-J1,*,l1,m1,q,*,l2,m0,-q)
  342.  
  343. Al,TAD2(K1~,a~,al~,k~,K2~,b~,be~,p~,K3~,c~,ga~,pp~,
  344.     K4~,d~,de~,kp~,J1~,J2~) =
  345.    VE4(K1,K3,-J2,"Z,*,a,al,k,*,c,ga,pp,*,l3,m3,-qu,*,l5,m5,q0)*
  346.    VE3(K2,K4,J2,*,b,be,p,*,d,de,kp,*,l4,m4,qu)*
  347.    VE3("Z,J1,-J1,*,l6,m6,-q0,*,l1,m1,-q,*,l2,m0,q)*
  348.    PROP(J2,-J2,*,l3,m3,qu,*,l4,m4,-qu)*
  349.    PROP("Z,"Z,*,l5,m5,q0,*,l6,m6,-q0)*
  350.    PROP(J1,-J1,*,l1,m1,q,*,l2,m0,-q)
  351.  
  352. Al,TAD3(K1~,a~,al~,k~,K2~,b~,be~,p~,K3~,c~,ga~,pp~,
  353.     K4~,d~,de~,kp~,J1~,J2~,J3~) =
  354.    VE3(K1,K3,-J2,*,a,al,k,*,c,ga,pp,*,l3,m3,-qu)*
  355.    VE3(J2,-J3,"Z,*,l4,m4,qu,*,l7,m7,-qu,*,l5,m5,-q0)*
  356.    VE3(K2,K4,J3,*,b,be,p,*,d,de,kp,*,l8,m8,qu)*
  357.    VE3("Z,J1,-J1,*,l6,m6,-q0,*,l1,m1,-q,*,l2,m0,q)*
  358.    PROP(J2,-J2,*,l3,m3,qu,*,l4,m4,-qu)*
  359.    PROP(J3,-J3,*,l7,m7,qu,*,l8,m8,-qu)*
  360.    PROP("Z,"Z,*,l5,m5,q0,*,l6,m6,-q0)*
  361.    PROP(J1,-J1,*,l1,m1,q,*,l2,m0,-q)
  362.  
  363. Id,Anti,TAP
  364. Al,Stats,0
  365. Al,R1("Z,"Z)=R1Z
  366. Al,R5("Z,"Z)=R5Z
  367. Al,R1(J1~,J2~)=1
  368. Al,R5(J1~,J2~)=1
  369.  
  370. Id,Compo,<X>,VE4,VE3,PROP
  371.  
  372. Id,VE4(FF~,l1~,al~,k~,l2~,be~,p~,l3~,ga~,pp~,l4~,la~,kp~)=
  373.  FF(l1,al,k,l2,be,p,l3,ga,pp,l4,la,kp)
  374. Al,VE3(FF~,l1~,al~,k~,l2~,be~,q~,l3~,ga~,p~)=
  375.        FF(l1,al,k,l2,be,q,l3,ga,p)
  376. Al,PROP(FF~,l1~,al~,q~,l2~,be~,k~)=FF(l1,al,l2,be,k)
  377. Al,Stats,1
  378. ENDBLOCK
  379.  
  380. BLOCK ETE1{}
  381. C Counterterms.
  382. Gotoif 2,_Sw0=0
  383.  
  384. Id,Et=i*Pi^2
  385.   * ( - 3/4 - 3/2*M^2*m^-2 + 9/2*M^2*m^-2*LogM2 - 3/4*M^-2*m^2
  386.   + 3/4*M^-2*m^2*Logm2 + 3/4*LogM2
  387.   - 1/4*gu + 1/4*LogM2*gu )
  388.  
  389.  + i*Pi^2*N_^-1
  390.   * ( 3/2 + 9*M^2*m^-2 + 3/2*M^-2*m^2 + 1/2*gu)
  391. Goto 3
  392.  
  393. @2
  394. Id,Et=i*Pi^2
  395.   * ( - 3/4 - 3/2*M^2*m^-2 + 9/2*M^2*m^-2*LogM2 - 3/4*M^-2*m^2
  396.   + 3/4*M^-2*m^2*Logm2 + 3/4*LogM2
  397.   - 1/4*M^-2*m^2*gu + 1/4*M^-2*m^2*Logm2*gu )
  398.  
  399.  + i*Pi^2*N_^-1
  400.   * ( 3/2 + 9*M^2*m^-2 + 3/2*M^-2*m^2 + 1/2*M^-2*m^2*gu)
  401.  
  402. @3
  403. Al,E1= i*Pi^2
  404.   * ( 1/16*M^-2*m^2 + 5/12*Logm2)
  405.  
  406.  - 25/6*i*Pi^2*N_^-1
  407.  
  408. Goto 2,_Sw0=0
  409. Al,E2 = i*Pi^2*( E2a*m^2/M^2 + E2al*m^2*Logm2/M^2 + E2b + E2bl*Logm2
  410.  + E2c*M^2/m^2 + E2cl*Logm2*M^2/m^2)
  411.  
  412.  + i*Pi^2*N_^-1
  413.   * ( - 8/3 - 9/2*M^2*m^-2 - 3/2*M^-2*m^2 - 1/8*M^-2*m^2*gu^2)
  414.  
  415. Goto 3
  416. @2
  417. Id,E2 = i*Pi^2
  418.   * ( 7/16*M^-2*m^2 - 3/4*M^-2*m^2*Logm2 - 3/2 +7/6*Logm2
  419.   - 9/4*M^2/m^2*Logm2 - 9/16*m^2/M^2*[Pi/Sqrt(3)-2]
  420.   - 1/16*M^-2*m^2*Logm2*gu^2 - 1/16*m^2/M^2*[Pi/Sqrt(3)-2]*gu^2)
  421.  
  422.  + i*Pi^2*N_^-1
  423.   * ( - 8/3 - 9/2*M^2*m^-2 - 3/2*M^-2*m^2 - 1/8*M^-2*m^2*gu^2)
  424.  
  425. @3 
  426. Al,Eh=i*Pi^2*(3/2/N_ + m^2/M^2/16 + 1/8*Logm2)
  427.  
  428. Al,Ew=i*Pi^2*(19/6/N_ - 1/24*Logm2)
  429.  
  430. Al,Eg=- 43/6*i*Pi^2/N_
  431.  
  432. Gotoif 5,_Sw0=0
  433. Id,E2a  = 7/16 - 9/16*[Pi/Sqrt(3)-2] + gu^2/8
  434. Al,E2al = - 3/4 - 1/16*gu^2
  435. Al,E2b  = - 3/2
  436. Al,E2bl = 7/6
  437. Al,E2c  = 0
  438. Al,E2cl = - 9/4
  439. @5
  440.  
  441. ENDBLOCK
  442.  
  443. BLOCK ASSIGN{}
  444.  
  445. A N,N_,M,m,n,n1,n2,n3,n4,Div,Fact,Nom,Nohm
  446.  
  447. F Fxx,Two,Three,Fq
  448.  
  449. C q1 = q+p
  450.   q2 = q+p+pp
  451.   q3 = q-k
  452.   q4 = q-k-pp
  453.   q5 = q-k-p
  454.   q6 = q+pp
  455.   q7 = q+kp
  456.   qu = k+pp
  457.   qs = q-k-p
  458.   qt =
  459.  
  460.   Crossing relations.
  461.         p <-> pp                pp <-> kp
  462.   q1 -> q6    pDk  -> ppDk        q1 -> q1    pDk  -> ppDk
  463.   q2 -> q2      s  -> u          q2 -> q4      s  -> s
  464.   q3 -> q3    ppDk -> pDk        q3 -> q3    ppDk -> kDkp
  465.   q4 -> q5      u  -> s        q4 -> q2      u  -> t
  466.   q5 -> q4    pDpp -> pDpp        q5 -> q5    pDpp -> pDkp
  467.   q6 -> q1      t  -> t        q6 -> q7      t  -> u
  468.   q7 -> q7                q7 -> q6
  469.  
  470. V q,q1,q2,q3,q4,q5,q6,q7,qs,qu,qt
  471.  
  472. I al=N,be=N,la=N,de=N,ga=N,la=N
  473.  
  474. I a=3,b=3,c=3,d=3
  475.  
  476. X dede(al,be,ga,de)=D(al,be)*D(ga,de)+D(al,ga)*D(be,de)+D(al,de)*D(be,ga)
  477.  
  478. C n1: -2 for every factor 1/(q^2+m^2)
  479.   n2: number of factors m
  480.   n3: degree of divergence with respect to integration variable q not
  481.       counting n1 types. Integral is convergent if n3+4 < 0.
  482.  
  483. X Fdiv(n1,n2,n3)= DT(-n3-4)*DT(n1+n2) + DT(n3+4-1)*DT(n1+n2+4+n3)
  484.  
  485. C Series expansion for { Nohm/(1-x*Nohm) }^n4
  486. C
  487. X Exp(n1,n2,n3,x,n4) =
  488.    DT(-n3-4)*Nohm^n4*DS(J,0,n1+n2,(DB(n4+J-1,J)*x^J*Nohm^J))
  489.  + DT(n3+4-1)*Nohm^n4*DS(K,0,n1+n2+4+n3,(DB(n4+K-1,K)*x^K*Nohm^K))
  490. ENDBLOCK
  491.  
  492. BLOCK COUNT{}
  493. Id,Count,Div,q,1,NOM,-2,Nom,-2,Two,-4
  494. Id,m^n~*Fxx(n1~,n2~,n3~,n4~)=m^n*Fxx(n1,n2+n,n3,n4)
  495. Id,[m2-M2]^n~*Fxx(n1~,n2~,n3~,n4~)=[m2-M2]^n*Fxx(n1,n2+2*n,n3,n4)
  496. Id,Div^n~*Fxx(n1~,n2~,n3~,n4~)=Fxx(n1,n2,n3+n,n4)
  497. ENDBLOCK
  498.  
  499. BLOCK HCOUNT{}
  500. C Count behaviour with respect to m for large m.
  501.   Eliminate if zero in that limit.
  502. IF Nohm^n~=Fxx(-2*n,0,0,n)*Nohm^n
  503. COUNT{}
  504. Id,Fxx(n1~,n2~,n3~,n4~)=Fdiv(n1,n2,n3)
  505. ELSE
  506. Id,Count,0,m,1,[m2-M2],2
  507. ENDIF
  508. ENDBLOCK
  509.  
  510. BLOCK SHIFT{}
  511.  
  512. IF Sh1
  513. Al,qDq=qDq-2*qDp+pDp
  514. Al,Dotpr,q(al~)=q(al)-p(al)
  515. ENDIF
  516. IF Sh2
  517. Al,qDq=qDq-2*qDp-2*qDpp+2*pDpp+pDp+ppDpp
  518. Al,Dotpr,q(al~)=q(al)-p(al) - pp(al)
  519. ENDIF
  520. IF Sh3
  521. Al,qDq=qDq+2*qDk+kDk
  522. Al,Dotpr,q(al~)=q(al)+k(al)
  523. ENDIF
  524. IF Sh4
  525. Al,qDq=qDq+2*qDk+2*qDpp+2*kDpp+kDk+ppDpp
  526. Al,Dotpr,q(al~)=q(al)+k(al)+pp(al)
  527. ENDIF
  528. IF Sh5
  529. Al,qDq=qDq+2*qDk+2*qDp+2*kDp+kDk+pDp
  530. Al,Dotpr,q(al~)=q(al)+k(al)+p(al)
  531. ENDIF
  532. IF Sh6
  533. Al,qDq=qDq-2*qDpp+ppDpp
  534. Al,Dotpr,q(al~)=q(al)-pp(al)
  535. ENDIF
  536. IF Sh7
  537. Al,qDq=qDq+2*qDk+2*qDp+2*qDpp+kpDkp
  538. Al,Dotpr,q(al~)=q(al)+k(al)+p(al)+pp(al)
  539. ENDIF
  540.  
  541. IF NOT Nohm
  542. Id,Sh1=1
  543. Al,Sh2=1
  544. Al,Sh3=1
  545. Al,Sh4=1
  546. Al,Sh5=1
  547. Al,Sh6=1
  548. Al,Sh7=1
  549. ENDIF
  550.  
  551. Id,pDp=-M^2
  552. Al,kDk=-M^2
  553. Al,ppDpp=-M^2
  554. Al,kpDkp=-M^2
  555. Id,Count,0,NOM,-2,Two,-4,Nom,-2,Nohm,-2,[m2-M2],2,p,1,k,1,pp,1,kp,1,q,1,m,1
  556.  
  557. *yep
  558. C Working out of shifted 1/(q^2+m^2)^n
  559.  
  560. IF Nohm^n~*Sh1=Fxx(-2*n,0,0,n)*Sh1
  561. OR Nohm^n~*Sh2=Fxx(-2*n,0,0,n)*Sh2
  562. OR Nohm^n~*Sh3=Fxx(-2*n,0,0,n)*Sh3
  563. OR Nohm^n~*Sh4=Fxx(-2*n,0,0,n)*Sh4
  564. OR Nohm^n~*Sh5=Fxx(-2*n,0,0,n)*Sh5
  565. OR Nohm^n~*Sh6=Fxx(-2*n,0,0,n)*Sh6
  566. OR Nohm^n~*Sh7=Fxx(-2*n,0,0,n)*Sh7
  567.  
  568. COUNT{}
  569.  
  570. Id,Sh1*Fxx(n1~,n2~,n3~,n4~)=Fdiv(n1,n2,n3)*Exp(n1,n2,n3,(2*qDp),n4)
  571. Al,Sh2*Fxx(n1~,n2~,n3~,n4~)=Fdiv(n1,n2,n3)*
  572.  Exp(n1,n2,n3,(2*qDp+2*qDpp-2*pDpp),n4)
  573. Al,Sh3*Fxx(n1~,n2~,n3~,n4~)=Fdiv(n1,n2,n3)*Exp(n1,n2,n3,(-2*qDk),n4)
  574. Al,Sh4*Fxx(n1~,n2~,n3~,n4~)=Fdiv(n1,n2,n3)
  575.  *Exp(n1,n2,n3,(-2*qDk-2*qDpp-2*kDpp),n4)
  576. Al,Sh5*Fxx(n1~,n2~,n3~,n4~)=Fdiv(n1,n2,n3)
  577.  *Exp(n1,n2,n3,(-2*qDk-2*qDp-2*kDp),n4)
  578. Al,Sh6*Fxx(n1~,n2~,n3~,n4~)=Fdiv(n1,n2,n3)*Exp(n1,n2,n3,(2*qDpp),n4)
  579. Al,Sh7*Fxx(n1~,n2~,n3~,n4~)=Fdiv(n1,n2,n3)*Exp(n1,n2,n3,(2*qDkp),n4)
  580. ENDIF
  581.  
  582. Id,pDp=-M^2
  583. Al,kDk=-M^2
  584. Al,ppDpp=-M^2
  585. Al,kpDkp=-M^2
  586. Al,qDkp=-qDk-qDp-qDpp
  587. Id,Count,0,NOM,-2,Two,-4,Nom,-2,Nohm,-2,[m2-M2],2,p,1,k,1,pp,1,kp,1,q,1,m,1
  588.  
  589. Id,Multi,Chsi^2=1
  590. IF Chsi=1
  591. Al,qDq=qDq
  592. Al,Dotpr,q(al~)=-q(al)
  593. ENDIF
  594.  
  595. ENDBLOCK
  596.  
  597.  
  598. BLOCK STINT{}
  599. C Standard integrals.
  600.  
  601. C Type Fn = 1/(q^2+M^2)^n
  602.  
  603. Id,F(1,m2~) = 2*i*Pi^2*m2/N_ + i*Pi^2*m2*(-1+Log(m2))
  604. Al,F(2,m2~) = - 2*i*Pi^2/N_ - i*Pi^2*Log(m2)
  605. Al,F(3,m2~) = 0.5*i*Pi^2/m2
  606. Al,F(4,m2~) = i*Pi^2/6/m2^2
  607. Al,F(5,m2~) = 1/12*i*Pi^2*m2^-3
  608. Al,F(6,m2~) = 1/20*i*Pi^2*m2^-4
  609. Al,F(7,m2~) = 1/30*i*Pi^2*m2^-5
  610.  
  611. Id,G(1,m2~) = - 0.5*i*Pi^2*m2^2/N_ + 3/8*i*Pi^2*m2^2
  612.   - 0.25*i*Pi^2*m2^2*Log(m2)
  613.  
  614. Al,G(2,m2~) = i*Pi^2 * ( - 1/2*m2 + m2*N_^-1 )
  615.  + 0.5*m2*Log(m2)*i*Pi^2
  616.  
  617. Al,G(3,m2~) = i*Pi^2 * ( - 1/2*N_^-1 )
  618.  - 1/4*Log(m2)*i*Pi^2
  619.  
  620. Al,G(4,m2~) = 1/12*i*Pi^2*m2^-1
  621.  
  622. Al,G(5,m2~) = 1/48*i*Pi^2*m2^-2
  623.  
  624. Al,G(6,m2~) = 1/120*i*Pi^2*m2^-3
  625.  
  626. Al,G(7,m2~) = 1/240*i*Pi^2*m2^-4
  627.  
  628. Id,H(1,m2~) = 1/12*i*Pi^2*m2^3/N_ - 11/144*i*Pi^2*m2^3
  629.  + 1/24*i*Pi^2*m2^3*Log(m2)
  630.  
  631. Al,H(2,m2~) = i*Pi^2 * ( 3/16*m2^2 - 1/4*m2^2*N_^-1 )
  632.  - 1/8*Log(m2)*i*Pi^2*m2^2
  633.  
  634. Al,H(3,m2~) = i*Pi^2 * ( - 1/8*m2 + 1/4*m2*N_^-1 )
  635.  + 1/8*Log(m2)*i*Pi^2  *m2
  636.  
  637. Al,H(4,m2~) = - 1/12*i*Pi^2*N_^-1
  638.  - 1/24*Log(m2)*i*Pi^2
  639.  
  640. Al,H(5,m2~) = i*Pi^2/96/m2
  641.  
  642. Al,H(6,m2~) = 1/480*i*Pi^2*m2^-2
  643.  
  644. Al,H(7,m2~) = 1/1200*i*Pi^2*m2^-3
  645.  
  646. C Type Fnm = 1/[(q^2+M^2)^n*(q^2+m^2)^m]
  647.  
  648. Id,F(1,1,M2,m2) = - 2*i*Pi^2/N_
  649.   + i*Pi^2*{ 1 - m2*Log(m2)/[m2-M2] + M2*Log(M2)/[m2-M2]}
  650.  
  651. Al,F(1,2,M2,m2) = i*Pi^2*{ 1/[m2-M2] - M2*Log(m2,M2)/[m2-M2]^2}
  652.  
  653. Al,F(2,2,M2,m2) = - 2*i*Pi^2*[m2-M2]^-2
  654.  + Log(m2,M2)*i*Pi^2 * ( 2*M2*[m2-M2]^-3 + [m2-M2]^-2 )
  655.  
  656. Al,F(1,3,M2,m2) = 0.5*i*Pi^2*{ 1/[m2-M2]^2 + M2/m2/[m2-M2]^2
  657.   - 2*M2*Log(m2,M2)/[m2-M2]^3 }
  658.  
  659. Al,F(2,3,M2,m2) = i*Pi^2 * ( 1/4*M2^-2*m2^-1 - 1/4*M2^-2*[m2-M2]^-1
  660.    + 1/4*M2^-1*[m2-M2]^-2 - 3/2*[m2-M2]^-3 )
  661.  + Log(m2,M2)*i*Pi^2 * ( 3/2*M2*[m2-M2]^-4 + 1/2*[m2-M2]^-3 )
  662.  
  663. Al,F(3,3,M2,m2) = i*Pi^2
  664.   * ( 1/4*M2^-3*m2^-1 - 1/4*M2^-3*[m2-M2]^-1 + 1/4*M2^-2*[m2-M2]^-2
  665.    + 3*[m2-M2]^-4 )
  666.  + Log(m2,M2)*i*Pi^2 * ( - 3*M2*[m2-M2]^-5 - 3/2*[m2-M2]^-4 )
  667.  
  668. Al,F(1,4,M2,m2) = i*Pi^2/6*{ 2/[m2-M2]^3 + 5*M2/m2/[m2-M2]^3
  669.  - M2^2/m2^2/[m2-M2]^3 - 6*M2*Log(m2,M2)/[m2-M2]^4 }
  670.  
  671. Al,F(2,4,M2,m2) = + i*Pi^2
  672.   * ( - 2/3*M2^-3*m2^-1 + 2/3*M2^-3*[m2-M2]^-1 + 1/6*M2^-2*m2^-2
  673.   - 5/6*M2^-2*[m2-M2]^-2 + M2^-1*[m2-M2]^-3 - 4*[m2-M2]^-4 )
  674.  + Log(m2,M2)*i*Pi^2 * ( 4*M2*[m2-M2]^-5 + [m2-M2]^-4 )
  675.  
  676. Al,F(3,4,M2,m2) = i*Pi^2
  677.   * ( - M2^-4*m2^-1 + M2^-4*[m2-M2]^-1 + 1/6*M2^-3*m2^-2 - 7/6*M2^-3
  678.   *[m2-M2]^-2 + 4/3*M2^-2*[m2-M2]^-3 - M2^-1*[m2-M2]^-4 + 10*
  679.  [m2-M2]^-5 )
  680.  + Log(m2,M2)*i*Pi^2 * ( - 10*M2*[m2-M2]^-6 - 4*[m2-M2]^-5 )
  681.  
  682. Al,F(4,4,M2,m2) = i*Pi^2
  683.   * ( - 2/3*M2^-4*m2^-1 + 2/3*M2^-4*[m2-M2]^-1 + 1/9*M2^-3*m2^-2
  684.   - 7/9*M2^-3*[m2-M2]^-2 + 8/9*M2^-2*[m2-M2]^-3 - 2/3*M2^-1*
  685.  [m2-M2]^-4 + 20/3*[m2-M2]^-5 )
  686.  + Log(m2,M2)*i*Pi^2 * ( - 20/3*M2*[m2-M2]^-6 - 8/3*[m2-M2]^-5 )
  687.  
  688. C Type Gnm = q(mu)*q(nu)/[(q^2+M^2)^n*(q^2+m^2)^m]
  689.   Function D(mu,nu) understood.
  690.  
  691. Id,G(1,1,M2,m2) = + 0.5*i*Pi^2*(m2+M2)/N_ - 3*i*Pi^2*(m2+M2)/8
  692.   + 0.25*i*Pi^2*(m2^2*Log(m2) - M2^2*Log(M2))/[m2-M2]
  693.  
  694. Al,G(1,2,M2,m2) = i*Pi^2*( 1/8 - 1/4*M2*[m2-M2]^-1 - 1/2*N_^-1 )
  695.  + 0.25*Log(m2,M2)*i*Pi^2*M2^2*[m2-M2]^-2
  696.  - 1/4*Log(m2)*i*Pi^2
  697.  
  698. Al,G(2,2,M2,m2) = i*Pi^2 * ( 1/2*M2*[m2-M2]^-2 + 1/4*[m2-M2]^-1 )
  699.  + Log(m2,M2)*i*Pi^2 * ( - 1/2*M2*[m2-M2]^-2 - 1/2*M2^2*[m2-M2]^-3 )
  700.  
  701. Al,G(1,3,M2,m2) = i*Pi^2*( - 1/4*M2*[m2-M2]^-2 + 1/8*[m2-M2]^-1 )
  702.  + 1/4*Log(m2,M2)*i*Pi^2*M2^2*[m2-M2]^-3
  703.  
  704. Al,G(2,3,M2,m2) = i*Pi^2 * ( 3/4*M2*[m2-M2]^-3 + 1/8*[m2-M2]^-2 )
  705.  + Log(m2,M2)*i*Pi^2 * ( - 1/2*M2*[m2-M2]^-3 - 3/4*M2^2*[m2-M2]^-4 )
  706.  
  707. Al,G(3,3,M2,m2) = + i*Pi^2 * ( - 3/2*M2*[m2-M2]^-4 - 3/4*[m2-M2]^-3 )
  708.  + Log(m2,M2)*i*Pi^2
  709.   * ( 3/2*M2*[m2-M2]^-4 + 3/2*M2^2*[m2-M2]^-5 + 1/4*[m2-M2]^-3 )
  710.  
  711. Al,G(1,4,M2,m2) = i*Pi^2 * ( - 1/4*M2*[m2-M2]^-3 + 1/12*M2^-1*m2^-1
  712.  - 1/12*M2^-1*[m2-M2]^-1 + 1/8*[m2-M2]^-2 )
  713.  + 1/4*Log(m2,M2)*i*Pi^2*M2^2*[m2-M2]^-4
  714.  
  715. Al,G(2,4,M2,m2) = i*Pi^2
  716.   * ( M2*[m2-M2]^-4 + 1/12*M2^-2*m2^-1 - 1/12*M2^-2*[m2-M2]^-1
  717.   + 1/12*M2^-1*[m2-M2]^-2 ) 
  718.  + Log(m2,M2)*i*Pi^2  * ( - 1/2*M2*[m2-M2]^-4 - M2^2*[m2-M2]^-5 )
  719.  
  720. Al,G(3,4,M2,m2) = i*Pi^2
  721.   * ( - 5/2*M2*[m2-M2]^-5 + 1/12*M2^-3*m2^-1 - 1/12*M2^-3*
  722.  [m2-M2]^-1 + 1/12*M2^-2*[m2-M2]^-2 - 1/12*M2^-1*[m2-M2]^-3
  723.   - 3/4*[m2-M2]^-4 )
  724.  + Log(m2,M2)*i*Pi^2
  725.   * ( 2*M2*[m2-M2]^-5 + 5/2*M2^2*[m2-M2]^-6 + 1/4*[m2-M2]^-4 )
  726.  
  727. Al,G(4,4,M2,m2) = i*Pi^2
  728.   * ( 5*M2*[m2-M2]^-6 + 1/12*M2^-4*m2^-1 - 1/12*M2^-4*[m2-M2]^-1
  729.   + 1/12*M2^-3*[m2-M2]^-2 - 1/12*M2^-2*[m2-M2]^-3 + 1/6*M2^-1*
  730.  [m2-M2]^-4 + 5/2*[m2-M2]^-5 )
  731.  + Log(m2,M2)*i*Pi^2
  732.   * ( - 5*M2*[m2-M2]^-6 - 5*M2^2*[m2-M2]^-7 - [m2-M2]^-5 )
  733.  
  734.  
  735. C Type Hnm = q(mu)*q(nu)*q(al)*q(be)/[(q^2+M^2)^n*(q^2+m^2)^m]
  736.   Function d(mu,nu,al,be)
  737.     = D(mu,nu)*D(al,be) + D(mu,al)*D(nu,be) + D(mu,be)*D(nu,de)
  738.   understood. Derived from
  739.   H11(M2,m2) = {- m2*F1(m2) - M2*F1(M2) + m2*M2*F11(M2,m2)}/[N^2+2*N]
  740.  
  741. Id,H(1,1,M2,m2) = i*Pi^2 * ( 11/144*M2*m2 - 1/12*M2*m2*N_^-1 + 11/144*M2^2
  742.    - 1/12*M2^2*N_^-1 + 11/144*m2^2 - 1/12*m2^2*N_^-1 )
  743.   - 1/24*Log(m2,M2)*i*Pi^2*M2^3*[m2-M2]^-1
  744.   + Log(m2)*i*Pi^2*( - 1/24*M2*m2 - 1/24*M2^2 - 1/24*m2^2 )
  745.  
  746. Al,H(1,2,M2,m2) = i*Pi^2 * ( - 5/144*M2 + 1/12*M2*N_^-1
  747.   + 1/24*M2^2*[m2-M2]^-1 - 1/9*m2 + 1/6*m2*N_^-1 )
  748.   -1/24*Log(m2,M2)*i*Pi^2*M2^3*[m2-M2]^-2
  749.   + Log(m2)*i*Pi^2* ( 1/24*M2 + 1/12*m2 )
  750.  
  751. Al,H(2,2,M2,m2) = i*Pi^2
  752.   * ( 5/144 - 1/12*M2*[m2-M2]^-1 - 1/12*M2^2*[m2-M2]^-2 - 1/12*N_^-1 )
  753.  + Log(m2,M2)*i*Pi^2 * ( 1/8*M2^2*[m2-M2]^-2 + 1/12*M2^3*[m2-M2]^-3 )
  754.  - 1/24*Log(m2)*i*Pi^2
  755.  
  756. Al,H(1,3,M2,m2) = i*Pi^2
  757.   * ( 1/72 - 1/48*M2*[m2-M2]^-1 + 1/24*M2^2*[m2-M2]^-2 - 1/12*N_^-1 )
  758.   -1/24*Log(m2,M2)*i*Pi^2*M2^3*[m2-M2]^-3
  759.  - 1/24*Log(m2)*i*Pi^2
  760.  
  761. Al,H(2,3,M2,m2) = i*Pi^2
  762.   * ( - 1/16*M2*[m2-M2]^-2 - 1/8*M2^2*[m2-M2]^-3 + 1/48*[m2-M2]^-1 )
  763.  + Log(m2,M2)*i*Pi^2
  764.   * ( 1/8*M2^2*[m2-M2]^-3 + 1/8*M2^3*[m2-M2]^-4 )
  765.  
  766. Al,H(3,3,M2,m2) = i*Pi^2
  767.   * ( 1/4*M2*[m2-M2]^-3 + 1/4*M2^2*[m2-M2]^-4 + 1/48*[m2-M2]^-2 )
  768.  + Log(m2,M2)*i*Pi^2
  769.   * ( - 1/8*M2*[m2-M2]^-3 - 3/8*M2^2*[m2-M2]^-4 - 1/4*M2^3*
  770.  [m2-M2]^-5 )
  771.  
  772. Al,H(1,4,M2,m2) = + i*Pi^2
  773.   * ( - 1/48*M2*[m2-M2]^-2 + 1/24*M2^2*[m2-M2]^-3 + 1/72*[m2-M2]^-1 )
  774.   -1/24*Log(m2,M2)*i*Pi^2*M2^3*[m2-M2]^-4
  775.  
  776. Al,H(2,4,M2,m2) = + i*Pi^2
  777.   * ( - 1/24*M2*[m2-M2]^-3 - 1/6*M2^2*[m2-M2]^-4 + 1/144*[m2-M2]^-2 )
  778.  + Log(m2,M2)*i*Pi^2 * ( 1/8*M2^2*[m2-M2]^-4 + 1/6*M2^3*[m2-M2]^-5 )
  779.  
  780. Al,H(3,4,M2,m2) = i*Pi^2
  781.   * ( 7/24*M2*[m2-M2]^-4 + 5/12*M2^2*[m2-M2]^-5 + 1/72*[m2-M2]^-3 )
  782.  + Log(m2,M2)*i*Pi^2
  783.   * ( - 1/8*M2*[m2-M2]^-4 - 1/2*M2^2*[m2-M2]^-5 - 5/12*M2^3*
  784.  [m2-M2]^-6 )
  785.  
  786. Al,H(4,4,M2,m2) = i*Pi^2
  787.   * ( - 5/6*M2*[m2-M2]^-5 - 5/6*M2^2*[m2-M2]^-6 - 11/72*[m2-M2]^-4 )
  788.  + Log(m2,M2)*i*Pi^2
  789.   * ( 1/2*M2*[m2-M2]^-5 + 5/4*M2^2*[m2-M2]^-6 + 5/6*M2^3*[m2-M2]^-7
  790.    + 1/24*[m2-M2]^-4 )
  791.  
  792. ENDBLOCK
  793.  
  794. End
  795.