home *** CD-ROM | disk | FTP | other *** search
/ Frozen Fish 1: Amiga / FrozenFish-Apr94.iso / bbs / alib / d1xx / d178 / ls.lha / Ls / c2.a < prev    next >
Text File  |  1989-02-04  |  9KB  |  397 lines
  1. *
  2. * C initial startup procedure under AmigaDOS
  3. * 
  4. * Use the following command line to make c.o
  5. * asm -u -iINCLUDE: c.a
  6. *
  7. * Use the following command line to make cres.o
  8. * asm -u -dRESIDENT -iINCLUDE: -ocres.o c.a
  9.  
  10.     IDNT    "c2.a"
  11.  
  12.     OPTION    L
  13.     LISTSYMS
  14.     BASEREG    B
  15.     SMALLOBJ
  16.     OPTIMON
  17.     ADDSYM
  18.     DEBUG
  19.  
  20. * --------------------------------------------------------------------- *
  21. * Macros:
  22. * --------------------------------------------------------------------- *
  23. SYS    MACRO    *
  24.     IFGT    NARG-2
  25.     FAIL    !!!
  26.     ENDC
  27.     IFEQ    NARG-2
  28.     MOVE.L    \2,a6
  29.     ENDC
  30.     JSR    _LVO\1(a6)
  31.     ENDM
  32.  
  33. XLVO    MACRO    *
  34.     XREF    _LVO\1
  35.     ENDM
  36.  
  37. * --------------------------------------------------------------------- *
  38. * Equates:
  39. * --------------------------------------------------------------------- *
  40. RESIDENT    EQU    1
  41.  
  42. MEMF_PUBLIC    EQU    $1
  43. MEMF_CLEAR    EQU    $10000
  44. MEMFLAGS    EQU    MEMF_CLEAR+MEMF_PUBLIC
  45. AbsExecBase    EQU    $0004
  46. cli_CommandName    EQU    $10
  47. pr_CLI        EQU    $AC
  48. pr_CurrentDir    EQU    $98
  49. ThisTask    EQU    $114
  50.  
  51. _LVOCloseLibrary EQU    $FE62
  52. _LVOAllocMem    EQU    $FF3A
  53. _LVOFreeMem    EQU    $FF2E
  54. _LVOSetSignal    EQU    $FECE
  55. _LVOOpenLibrary    EQU    $FDD8
  56.  
  57.     XREF    _DOSBase
  58.     XREF    _LinkerDB        ; linker defined base value
  59.     XREF    __BSSBAS        ; linker defined base of BSS
  60.     XREF    __BSSLEN        ; linker defined length of BSS
  61.  
  62.      IFD    RESIDENT
  63.     XREF    _RESLEN
  64.     XREF    _RESBASE
  65.     XREF    _NEWDATAL
  66.      ENDC
  67.     
  68.     XREF    __main            ; Name of C program to start with.
  69.     XREF    _MemCleanup        ; Free all allocated memory
  70.     XREF    ___fpinit        ; initialize floating point
  71.     XREF    ___fpterm        ; terminate floating point
  72.  
  73. * --------------------------------------------------------------------- *
  74.     SECTION    TEXT,CODE
  75. * --------------------------------------------------------------------- *
  76.     XDEF    zzstart
  77. zzstart:
  78.     move.l    a0,a2            ; save command pointer
  79.     move.l    d0,d2            ; and command length
  80.     lea    _LinkerDB,a4        ; load base register
  81.  
  82.      IFND    RESIDENT
  83.     lea    __BSSBAS,a3        ; get base of BSS
  84.     moveq    #0,d1
  85.     move.l    #__BSSLEN,d0        ; get length of BSS in longwords
  86.      bra.b    clr_lp             ; and clear for length given
  87. clr_bss move.l    d1,(a3)+
  88. clr_lp    dbf    d0,clr_bss
  89.      ENDC
  90.  
  91.      IFD    RESIDENT
  92.     movea.l    AbsExecBase,a6
  93.  
  94.     movem.l    d0-d1/a0-a2,-(sp)
  95.     sub.l    #_RESBASE,a4
  96.     move.l    #_RESLEN,d0
  97.     move.l    #MEMFLAGS,d1
  98.     SYS    AllocMem
  99.     tst.l    d0
  100.      beq.w    abort
  101.     move.l    d0,a0
  102.     move.l     d0,a2
  103.  
  104. ;a2 now has difference
  105.     move.l    d0,a1
  106.     move.l    #_NEWDATAL,d0
  107. ;copy data over
  108. cpy:    move.l    (a4)+,(a0)+
  109.     subq.l    #1,d0
  110.      bne    cpy
  111. ;a4 now points at number of relocs
  112.     move.l    (a4)+,d0
  113. reloc:     beq.b    nreloc
  114.     move.l    a1,a0
  115.     add.l    (a4)+,a0        ; a0 now has add of reloc
  116.     add.l    (a0),a2
  117.     move.l    a2,(a0) 
  118.     move.l    a1,a2            ; restore offset
  119.     subq.l    #1,d0
  120.     bra    reloc
  121.     
  122. nreloc: move.l    a1,a4            ; set up new base register
  123.     add.l    #_RESBASE,a4
  124.     movem.l    (sp)+,d0-d1/a0-a2
  125.      ENDC
  126.  
  127.     movea.l    AbsExecBase,a6
  128.     move.l    a6,_SysBase(a4)
  129.     move.l    sp,__StackPtr(a4)    ; Save stack ptr
  130.     clr.l    _WBenchMsg(a4)
  131.  
  132. * get the address of our task
  133.     move.l    ThisTask(a6),a3
  134.  
  135. *-    clear any pending signals
  136.     moveq    #0,d0
  137.     move.l    #$00003000,d1
  138.     SYS    SetSignal
  139.     
  140. * are we running as a son of Workbench?
  141.     move.l    pr_CurrentDir(a3),_curdir(a4)
  142.  
  143.     IFD    WBENCH
  144.     tst.l    pr_CLI(a3)
  145.      beq    fromWorkbench
  146.     ENDC
  147.  
  148. *=======================================================================
  149. *====== CLI Startup Code ===============================================
  150. *=======================================================================
  151. *
  152. ; Entry: d2 = command length
  153. ;     a2 = Command pointer
  154. fromCLI:
  155.     move.l    sp,d0             ; get top of stack
  156.     sub.l    4(sp),d0        ; compute bottom 
  157.     add.l    #128,d0             ; allow for parms overflow
  158.     move.l    d0,__base(a4)        ; save for stack checking
  159.  
  160. * attempt to open DOS library:
  161.     bsr.w    openDOS
  162.  
  163. * find command name:
  164.     move.l    pr_CLI(a3),a0
  165.     add.l    a0,a0             ; bcpl pointer conversion
  166.     add.l    a0,a0
  167.     move.l    cli_CommandName(a0),a1
  168.     add.l    a1,a1             ; bcpl pointer conversion
  169.     add.l    a1,a1
  170.  
  171. * collect parameters:
  172.     move.l    d2,d0            ; get command line length
  173.     moveq.l    #0,d1
  174.     move.b    (a1)+,d1
  175.     move.l    a1,__ProgramName(a4)
  176.     add.l    d1,d0            ; add length of command name
  177.     addq.l    #1,d0            ; allow for space after command 
  178.  
  179.     clr.w    -(sp)            ; set null terminator for command line
  180.     addq.l    #1,d0            ; force to even number of bytes
  181.     andi.w    #$fffe,d0        ; (round up)
  182.     sub.l    d0,sp            ; make room on stack for command line
  183.     subq.l    #2,d0
  184.     clr.w    0(sp,d0)
  185.  
  186. * copy command line onto stack
  187.     move.l    d2,d0            ; get command line length
  188.     subq.l    #1,d0
  189.     add.l    d1,d2
  190.  
  191. copy_line:
  192.     move.b    0(a2,d0.w),0(sp,d2.w)    ; copy command line to stack
  193.     subq.l    #1,d2
  194.     dbf    d0,copy_line
  195.     move.b    #' ',0(sp,d2.w)         ; add space between command and parms
  196.     subq.l    #1,d2
  197.  
  198. copy_cmd:
  199.     move.b    0(a1,d2.w),0(sp,d2.w)    ; copy command name to stack
  200.     dbf    d2,copy_cmd
  201.     move.l    sp,a1
  202.     move.l    a1,-(sp)        ; push command line address
  203.  
  204.     IFD    WBENCH
  205.     bra    main            ; call C entrypoint
  206. * --------------------------------------------------------------------- *
  207. * Workbench Startup Code
  208. * --------------------------------------------------------------------- *
  209. fromWorkbench:
  210.     move.l    TC_SPLOWER(a3),__base(a4) ; set base of stack
  211.     moveq     #127,d0
  212.     addq.l    #1,d0            ; Efficient way of getting in 128
  213.     add.l    d0,__base(a4)        ; allow for parms overflow
  214.  
  215. * open the DOS library:
  216.     bsr.w    openDOS
  217.  
  218. * we are now set up. wait for a message from our starter
  219.     lea    pr_MsgPort(a3),a0    ; our process base
  220.     SYS    WaitPort
  221.     lea    pr_MsgPort(a3),a0    ; our process base
  222.     SYS    GetMsg
  223.     move.l    d0,_WBenchMsg(a4)
  224.     move.l    d0,-(sp)
  225.  
  226.     move.l    d0,a2            ; get first argument
  227.     move.l    sm_ArgList(a2),d0
  228.      beq    do_cons
  229.     move.l    _DOSBase(a4),a6
  230.     move.l    d0,a0
  231.     move.l    wa_Lock(a0),d1
  232.     move.l    d1,_curdir(a4)
  233.     SYS    CurrentDir
  234. do_cons:
  235.     move.l    sm_ToolWindow(a2),d1    ; get the window argument
  236.      beq    do_main
  237.     move.l    #MODE_OLDFILE,d2
  238.     SYS    Open
  239.     move.l    d0,_stdin(a4)
  240.      beq    do_main
  241.     lsl.l    #2,d0
  242.     move.l    d0,a0
  243.     move.l    fh_Type(a0),pr_ConsoleTask(a3)
  244. do_main:
  245.     move.l    _WBenchMsg(a4),a0    ; get address of workbench message
  246.     move.l    a0,-(sp)        ; push argv
  247.     pea    _NULL(a4)        ; push argc
  248.     move.l    sm_ArgList(a0),a0    ; get address of arguments
  249.     move.l    wa_Name(a0),__ProgramName(a4)     ; get name of program
  250.     ENDC
  251.  
  252. * --------------------------------------------------------------------- *
  253. * Common CLI/WBENCH code
  254. * --------------------------------------------------------------------- *
  255. main:
  256.      IFD    FLOAT
  257.     jsr    ___fpinit(pc)        ; Initialize floating point
  258.      ENDC
  259.     jsr    __main(pc)        ; call C entrypoint
  260.     moveq.l    #0,d0            ; set successful status
  261.     bra.b    exit2
  262.  
  263.     XDEF    _XCEXIT
  264. _XCEXIT:
  265.     move.l    4(sp),d0        ; extract return code
  266.  
  267.     XDEF    xXCEXIT
  268. xXCEXIT:
  269. exit2:
  270.      IFD    ERRTRAPS
  271.     move.l    d0,-(sp)
  272.     move.l    __ONEXIT(a4),d0        ; exit trap function?
  273.      beq.b    exit3
  274.     move.l    d0,a0
  275.     jsr    (a0)
  276. exit3:
  277.      ENDC
  278.  
  279.      IFD    MALLOC
  280.     jsr    _MemCleanup(pc)        ; cleanup leftover memory alloc.
  281.      ENDC
  282.  
  283.     movea.l    AbsExecBase,a6
  284.     move.l    _DOSBase(a4),a1
  285.     SYS    CloseLibrary        ; close Dos library
  286.  
  287.      IFD    FLOAT
  288.     jsr    ___fpterm(pc)        ; clean up any floating point
  289.      ENDC
  290.  
  291.      IFD    WBENCH
  292. done_1c:
  293. * if we ran from CLI, skip workbench cleanup:
  294.     tst.l    _WBenchMsg(a4)
  295.      beq    exitToDOS
  296.     move.l    _stdin(a4),d1
  297.      beq.b    done_4
  298.     SYS    Close
  299. done_4:
  300. * return the startup message to our parent
  301. *     we forbid so workbench can't UnLoadSeg() us
  302. *     before we are done:
  303.     movea.l    AbsExecBase,a6
  304.     SYS    Forbid
  305.     move.l     _WBenchMsg(a4),a1
  306.     SYS    ReplyMsg
  307.      ENDC
  308.  
  309. * this rts sends us back to DOS:
  310. exitToDOS:
  311.      IFD    RESIDENT
  312.     move.l    #_RESLEN,d0
  313.     move.l     a4,a1
  314.     sub.l    #_RESBASE,a1
  315.     movea.l    AbsExecBase,a6
  316.     SYS    FreeMem
  317.      ENDC
  318.     
  319.     move.l    (sp)+,d0
  320.     movea.l    __StackPtr(a4),sp    ; restore stack ptr
  321.  
  322.     XDEF    xchkabort
  323. xchkabort:
  324.     rts
  325.  
  326.      IFD    RESIDENT
  327. abort:
  328.     movem.l    (sp)+,d0-d1/a0-a2
  329.     rts
  330.      ENDC
  331.  
  332. * --------------------------------------------------------------------- *
  333. noDOS:
  334.     moveq.l    #100,d0
  335.     bra    exit2
  336.  
  337. * --------------------------------------------------------------------- *
  338. *    Open the DOS library:
  339. * --------------------------------------------------------------------- *
  340. openDOS:
  341.     lea    DOSName(pc),a1
  342.     moveq.l #0,d0
  343.     SYS    OpenLibrary
  344.     move.l    d0,_DOSBase(a4)
  345.      beq    noDOS
  346.     rts
  347.  
  348. DOSName:    dc.b    'dos.library',0
  349.  
  350. * --------------------------------------------------------------------- *
  351.     section __MERGED,BSS
  352. * --------------------------------------------------------------------- *
  353.  
  354.     XDEF    _NULL,_SysBase,_WBenchMsg
  355.     XDEF    _curdir,__mbase,__mnext,__msize,__tsize
  356.     XDEF    __oserr,__OSERR
  357.      IFD    FLOAT
  358.     XDEF    __FPERR
  359.     XDEF    __SIGFPE
  360.      ENDC
  361.      IFD    ERRTRAPS
  362.     XDEF    __ONERR,__ONEXIT,__ONBREAK
  363.     XDEF    __SIGINT
  364.      ENDC
  365.     XDEF    _stdin
  366.     XDEF    __ProgramName,__StackPtr,__base
  367.  
  368. * --------------------------------------------------------------------- *
  369. _NULL        ds.l    1         ; Huh?
  370. __base        ds.l    1         ; base of stack
  371. __mbase        ds.l    1         ; base of memory pool
  372. __mnext        ds.l    1         ; next available memory location
  373. __msize        ds.l    1         ; size of memory pool
  374. __tsize        ds.l    1         ; total size?
  375. __oserr
  376. __OSERR        ds.l    1
  377.      IFD    FLOAT
  378. __FPERR        ds.l    1
  379. __SIGFPE    ds.l    1
  380.      ENDC
  381.      IFD    ERRTRAPS
  382. __SIGINT    ds.l    1
  383. __ONERR        ds.l    1
  384. __ONEXIT    ds.l    1
  385. __ONBREAK    ds.l    1
  386.      ENDC
  387. _curdir        ds.l    1
  388. _SysBase    ds.l    1
  389. _WBenchMsg    ds.l    1
  390. __StackPtr    ds.l    1
  391. _stdin        ds.l    1
  392. __ProgramName    ds.l    1
  393.  
  394. * --------------------------------------------------------------------- *
  395.     END
  396. * --------------------------------------------------------------------- *
  397.